SRC/sgbsvx.f

   1 *> \brief <b> SGBSVX computes the solution to system of linear equations A * X = B for GB matrices</b>
   2 *
   3 *  =========== DOCUMENTATION ===========
   4 *
   5 * Online html documentation available at
   6 *            http://www.netlib.org/lapack/explore-html/
   7 *
   8 *> \htmlonly
   9 *> Download SGBSVX + dependencies
  10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sgbsvx.f">
  11 *> [TGZ]</a>
  12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sgbsvx.f">
  13 *> [ZIP]</a>
  14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sgbsvx.f">
  15 *> [TXT]</a>
  16 *> \endhtmlonly
  17 *
  18 *  Definition:
  19 *  ===========
  20 *
  21 *       SUBROUTINE SGBSVX( FACT, TRANS, N, KL, KU, NRHS, AB, LDAB, AFB,
  22 *                          LDAFB, IPIV, EQUED, R, C, B, LDB, X, LDX,
  23 *                          RCOND, FERR, BERR, WORK, IWORK, INFO )
  24 *
  25 *       .. Scalar Arguments ..
  26 *       CHARACTER          EQUED, FACT, TRANS
  27 *       INTEGER            INFO, KL, KU, LDAB, LDAFB, LDB, LDX, N, NRHS
  28 *       REAL               RCOND
  29 *       ..
  30 *       .. Array Arguments ..
  31 *       INTEGER            IPIV( * ), IWORK( * )
  32 *       REAL               AB( LDAB, * ), AFB( LDAFB, * ), B( LDB, * ),
  33 *      $                   BERR( * ), C( * ), FERR( * ), R( * ),
  34 *      $                   WORK( * ), X( LDX, * )
  35 *       ..
  36 *
  37 *
  38 *> \par Purpose:
  39 *  =============
  40 *>
  41 *> \verbatim
  42 *>
  43 *> SGBSVX uses the LU factorization to compute the solution to a real
  44 *> system of linear equations A * X = B, A**T * X = B, or A**H * X = B,
  45 *> where A is a band matrix of order N with KL subdiagonals and KU
  46 *> superdiagonals, and X and B are N-by-NRHS matrices.
  47 *>
  48 *> Error bounds on the solution and a condition estimate are also
  49 *> provided.
  50 *> \endverbatim
  51 *
  52 *> \par Description:
  53 *  =================
  54 *>
  55 *> \verbatim
  56 *>
  57 *> The following steps are performed by this subroutine:
  58 *>
  59 *> 1. If FACT = 'E', real scaling factors are computed to equilibrate
  60 *>    the system:
  61 *>       TRANS = 'N':  diag(R)*A*diag(C)     *inv(diag(C))*X = diag(R)*B
  62 *>       TRANS = 'T': (diag(R)*A*diag(C))**T *inv(diag(R))*X = diag(C)*B
  63 *>       TRANS = 'C': (diag(R)*A*diag(C))**H *inv(diag(R))*X = diag(C)*B
  64 *>    Whether or not the system will be equilibrated depends on the
  65 *>    scaling of the matrix A, but if equilibration is used, A is
  66 *>    overwritten by diag(R)*A*diag(C) and B by diag(R)*B (if TRANS='N')
  67 *>    or diag(C)*B (if TRANS = 'T' or 'C').
  68 *>
  69 *> 2. If FACT = 'N' or 'E', the LU decomposition is used to factor the
  70 *>    matrix A (after equilibration if FACT = 'E') as
  71 *>       A = L * U,
  72 *>    where L is a product of permutation and unit lower triangular
  73 *>    matrices with KL subdiagonals, and U is upper triangular with
  74 *>    KL+KU superdiagonals.
  75 *>
  76 *> 3. If some U(i,i)=0, so that U is exactly singular, then the routine
  77 *>    returns with INFO = i. Otherwise, the factored form of A is used
  78 *>    to estimate the condition number of the matrix A.  If the
  79 *>    reciprocal of the condition number is less than machine precision,
  80 *>    INFO = N+1 is returned as a warning, but the routine still goes on
  81 *>    to solve for X and compute error bounds as described below.
  82 *>
  83 *> 4. The system of equations is solved for X using the factored form
  84 *>    of A.
  85 *>
  86 *> 5. Iterative refinement is applied to improve the computed solution
  87 *>    matrix and calculate error bounds and backward error estimates
  88 *>    for it.
  89 *>
  90 *> 6. If equilibration was used, the matrix X is premultiplied by
  91 *>    diag(C) (if TRANS = 'N') or diag(R) (if TRANS = 'T' or 'C') so
  92 *>    that it solves the original system before equilibration.
  93 *> \endverbatim
  94 *
  95 *  Arguments:
  96 *  ==========
  97 *
  98 *> \param[in] FACT
  99 *> \verbatim
 100 *>          FACT is CHARACTER*1
 101 *>          Specifies whether or not the factored form of the matrix A is
 102 *>          supplied on entry, and if not, whether the matrix A should be
 103 *>          equilibrated before it is factored.
 104 *>          = 'F':  On entry, AFB and IPIV contain the factored form of
 105 *>                  A.  If EQUED is not 'N', the matrix A has been
 106 *>                  equilibrated with scaling factors given by R and C.
 107 *>                  AB, AFB, and IPIV are not modified.
 108 *>          = 'N':  The matrix A will be copied to AFB and factored.
 109 *>          = 'E':  The matrix A will be equilibrated if necessary, then
 110 *>                  copied to AFB and factored.
 111 *> \endverbatim
 112 *>
 113 *> \param[in] TRANS
 114 *> \verbatim
 115 *>          TRANS is CHARACTER*1
 116 *>          Specifies the form of the system of equations.
 117 *>          = 'N':  A * X = B     (No transpose)
 118 *>          = 'T':  A**T * X = B  (Transpose)
 119 *>          = 'C':  A**H * X = B  (Transpose)
 120 *> \endverbatim
 121 *>
 122 *> \param[in] N
 123 *> \verbatim
 124 *>          N is INTEGER
 125 *>          The number of linear equations, i.e., the order of the
 126 *>          matrix A.  N >= 0.
 127 *> \endverbatim
 128 *>
 129 *> \param[in] KL
 130 *> \verbatim
 131 *>          KL is INTEGER
 132 *>          The number of subdiagonals within the band of A.  KL >= 0.
 133 *> \endverbatim
 134 *>
 135 *> \param[in] KU
 136 *> \verbatim
 137 *>          KU is INTEGER
 138 *>          The number of superdiagonals within the band of A.  KU >= 0.
 139 *> \endverbatim
 140 *>
 141 *> \param[in] NRHS
 142 *> \verbatim
 143 *>          NRHS is INTEGER
 144 *>          The number of right hand sides, i.e., the number of columns
 145 *>          of the matrices B and X.  NRHS >= 0.
 146 *> \endverbatim
 147 *>
 148 *> \param[in,out] AB
 149 *> \verbatim
 150 *>          AB is REAL array, dimension (LDAB,N)
 151 *>          On entry, the matrix A in band storage, in rows 1 to KL+KU+1.
 152 *>          The j-th column of A is stored in the j-th column of the
 153 *>          array AB as follows:
 154 *>          AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl)
 155 *>
 156 *>          If FACT = 'F' and EQUED is not 'N', then A must have been
 157 *>          equilibrated by the scaling factors in R and/or C.  AB is not
 158 *>          modified if FACT = 'F' or 'N', or if FACT = 'E' and
 159 *>          EQUED = 'N' on exit.
 160 *>
 161 *>          On exit, if EQUED .ne. 'N', A is scaled as follows:
 162 *>          EQUED = 'R':  A := diag(R) * A
 163 *>          EQUED = 'C':  A := A * diag(C)
 164 *>          EQUED = 'B':  A := diag(R) * A * diag(C).
 165 *> \endverbatim
 166 *>
 167 *> \param[in] LDAB
 168 *> \verbatim
 169 *>          LDAB is INTEGER
 170 *>          The leading dimension of the array AB.  LDAB >= KL+KU+1.
 171 *> \endverbatim
 172 *>
 173 *> \param[in,out] AFB
 174 *> \verbatim
 175 *>          AFB is REAL array, dimension (LDAFB,N)
 176 *>          If FACT = 'F', then AFB is an input argument and on entry
 177 *>          contains details of the LU factorization of the band matrix
 178 *>          A, as computed by SGBTRF.  U is stored as an upper triangular
 179 *>          band matrix with KL+KU superdiagonals in rows 1 to KL+KU+1,
 180 *>          and the multipliers used during the factorization are stored
 181 *>          in rows KL+KU+2 to 2*KL+KU+1.  If EQUED .ne. 'N', then AFB is
 182 *>          the factored form of the equilibrated matrix A.
 183 *>
 184 *>          If FACT = 'N', then AFB is an output argument and on exit
 185 *>          returns details of the LU factorization of A.
 186 *>
 187 *>          If FACT = 'E', then AFB is an output argument and on exit
 188 *>          returns details of the LU factorization of the equilibrated
 189 *>          matrix A (see the description of AB for the form of the
 190 *>          equilibrated matrix).
 191 *> \endverbatim
 192 *>
 193 *> \param[in] LDAFB
 194 *> \verbatim
 195 *>          LDAFB is INTEGER
 196 *>          The leading dimension of the array AFB.  LDAFB >= 2*KL+KU+1.
 197 *> \endverbatim
 198 *>
 199 *> \param[in,out] IPIV
 200 *> \verbatim
 201 *>          IPIV is INTEGER array, dimension (N)
 202 *>          If FACT = 'F', then IPIV is an input argument and on entry
 203 *>          contains the pivot indices from the factorization A = L*U
 204 *>          as computed by SGBTRF; row i of the matrix was interchanged
 205 *>          with row IPIV(i).
 206 *>
 207 *>          If FACT = 'N', then IPIV is an output argument and on exit
 208 *>          contains the pivot indices from the factorization A = L*U
 209 *>          of the original matrix A.
 210 *>
 211 *>          If FACT = 'E', then IPIV is an output argument and on exit
 212 *>          contains the pivot indices from the factorization A = L*U
 213 *>          of the equilibrated matrix A.
 214 *> \endverbatim
 215 *>
 216 *> \param[in,out] EQUED
 217 *> \verbatim
 218 *>          EQUED is CHARACTER*1
 219 *>          Specifies the form of equilibration that was done.
 220 *>          = 'N':  No equilibration (always true if FACT = 'N').
 221 *>          = 'R':  Row equilibration, i.e., A has been premultiplied by
 222 *>                  diag(R).
 223 *>          = 'C':  Column equilibration, i.e., A has been postmultiplied
 224 *>                  by diag(C).
 225 *>          = 'B':  Both row and column equilibration, i.e., A has been
 226 *>                  replaced by diag(R) * A * diag(C).
 227 *>          EQUED is an input argument if FACT = 'F'; otherwise, it is an
 228 *>          output argument.
 229 *> \endverbatim
 230 *>
 231 *> \param[in,out] R
 232 *> \verbatim
 233 *>          R is REAL array, dimension (N)
 234 *>          The row scale factors for A.  If EQUED = 'R' or 'B', A is
 235 *>          multiplied on the left by diag(R); if EQUED = 'N' or 'C', R
 236 *>          is not accessed.  R is an input argument if FACT = 'F';
 237 *>          otherwise, R is an output argument.  If FACT = 'F' and
 238 *>          EQUED = 'R' or 'B', each element of R must be positive.
 239 *> \endverbatim
 240 *>
 241 *> \param[in,out] C
 242 *> \verbatim
 243 *>          C is REAL array, dimension (N)
 244 *>          The column scale factors for A.  If EQUED = 'C' or 'B', A is
 245 *>          multiplied on the right by diag(C); if EQUED = 'N' or 'R', C
 246 *>          is not accessed.  C is an input argument if FACT = 'F';
 247 *>          otherwise, C is an output argument.  If FACT = 'F' and
 248 *>          EQUED = 'C' or 'B', each element of C must be positive.
 249 *> \endverbatim
 250 *>
 251 *> \param[in,out] B
 252 *> \verbatim
 253 *>          B is REAL array, dimension (LDB,NRHS)
 254 *>          On entry, the right hand side matrix B.
 255 *>          On exit,
 256 *>          if EQUED = 'N', B is not modified;
 257 *>          if TRANS = 'N' and EQUED = 'R' or 'B', B is overwritten by
 258 *>          diag(R)*B;
 259 *>          if TRANS = 'T' or 'C' and EQUED = 'C' or 'B', B is
 260 *>          overwritten by diag(C)*B.
 261 *> \endverbatim
 262 *>
 263 *> \param[in] LDB
 264 *> \verbatim
 265 *>          LDB is INTEGER
 266 *>          The leading dimension of the array B.  LDB >= max(1,N).
 267 *> \endverbatim
 268 *>
 269 *> \param[out] X
 270 *> \verbatim
 271 *>          X is REAL array, dimension (LDX,NRHS)
 272 *>          If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X
 273 *>          to the original system of equations.  Note that A and B are
 274 *>          modified on exit if EQUED .ne. 'N', and the solution to the
 275 *>          equilibrated system is inv(diag(C))*X if TRANS = 'N' and
 276 *>          EQUED = 'C' or 'B', or inv(diag(R))*X if TRANS = 'T' or 'C'
 277 *>          and EQUED = 'R' or 'B'.
 278 *> \endverbatim
 279 *>
 280 *> \param[in] LDX
 281 *> \verbatim
 282 *>          LDX is INTEGER
 283 *>          The leading dimension of the array X.  LDX >= max(1,N).
 284 *> \endverbatim
 285 *>
 286 *> \param[out] RCOND
 287 *> \verbatim
 288 *>          RCOND is REAL
 289 *>          The estimate of the reciprocal condition number of the matrix
 290 *>          A after equilibration (if done).  If RCOND is less than the
 291 *>          machine precision (in particular, if RCOND = 0), the matrix
 292 *>          is singular to working precision.  This condition is
 293 *>          indicated by a return code of INFO > 0.
 294 *> \endverbatim
 295 *>
 296 *> \param[out] FERR
 297 *> \verbatim
 298 *>          FERR is REAL array, dimension (NRHS)
 299 *>          The estimated forward error bound for each solution vector
 300 *>          X(j) (the j-th column of the solution matrix X).
 301 *>          If XTRUE is the true solution corresponding to X(j), FERR(j)
 302 *>          is an estimated upper bound for the magnitude of the largest
 303 *>          element in (X(j) - XTRUE) divided by the magnitude of the
 304 *>          largest element in X(j).  The estimate is as reliable as
 305 *>          the estimate for RCOND, and is almost always a slight
 306 *>          overestimate of the true error.
 307 *> \endverbatim
 308 *>
 309 *> \param[out] BERR
 310 *> \verbatim
 311 *>          BERR is REAL array, dimension (NRHS)
 312 *>          The componentwise relative backward error of each solution
 313 *>          vector X(j) (i.e., the smallest relative change in
 314 *>          any element of A or B that makes X(j) an exact solution).
 315 *> \endverbatim
 316 *>
 317 *> \param[out] WORK
 318 *> \verbatim
 319 *>          WORK is REAL array, dimension (3*N)
 320 *>          On exit, WORK(1) contains the reciprocal pivot growth
 321 *>          factor norm(A)/norm(U). The "max absolute element" norm is
 322 *>          used. If WORK(1) is much less than 1, then the stability
 323 *>          of the LU factorization of the (equilibrated) matrix A
 324 *>          could be poor. This also means that the solution X, condition
 325 *>          estimator RCOND, and forward error bound FERR could be
 326 *>          unreliable. If factorization fails with 0<INFO<=N, then
 327 *>          WORK(1) contains the reciprocal pivot growth factor for the
 328 *>          leading INFO columns of A.
 329 *> \endverbatim
 330 *>
 331 *> \param[out] IWORK
 332 *> \verbatim
 333 *>          IWORK is INTEGER array, dimension (N)
 334 *> \endverbatim
 335 *>
 336 *> \param[out] INFO
 337 *> \verbatim
 338 *>          INFO is INTEGER
 339 *>          = 0:  successful exit
 340 *>          < 0:  if INFO = -i, the i-th argument had an illegal value
 341 *>          > 0:  if INFO = i, and i is
 342 *>                <= N:  U(i,i) is exactly zero.  The factorization
 343 *>                       has been completed, but the factor U is exactly
 344 *>                       singular, so the solution and error bounds
 345 *>                       could not be computed. RCOND = 0 is returned.
 346 *>                = N+1: U is nonsingular, but RCOND is less than machine
 347 *>                       precision, meaning that the matrix is singular
 348 *>                       to working precision.  Nevertheless, the
 349 *>                       solution and error bounds are computed because
 350 *>                       there are a number of situations where the
 351 *>                       computed solution can be more accurate than the
 352 *> \endverbatim
 353 *
 354 *  Authors:
 355 *  ========
 356 *
 357 *> \author Univ. of Tennessee
 358 *> \author Univ. of California Berkeley
 359 *> \author Univ. of Colorado Denver
 360 *> \author NAG Ltd.
 361 *
 362 *> \date April 2012
 363 *
 364 *> \ingroup realGBsolve
 365 *
 366 *  =====================================================================
 367       SUBROUTINE SGBSVX( FACT, TRANS, N, KL, KU, NRHS, AB, LDAB, AFB,
 368      $                   LDAFB, IPIV, EQUED, R, C, B, LDB, X, LDX,
 369      $                   RCOND, FERR, BERR, WORK, IWORK, INFO )
 370 *
 371 *  -- LAPACK driver routine (version 3.4.1) --
 372 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 373 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 374 *     April 2012
 375 *
 376 *     .. Scalar Arguments ..
 377       CHARACTER          EQUED, FACT, TRANS
 378       INTEGER            INFO, KL, KU, LDAB, LDAFB, LDB, LDX, N, NRHS
 379       REAL               RCOND
 380 *     ..
 381 *     .. Array Arguments ..
 382       INTEGER            IPIV( * ), IWORK( * )
 383       REAL               AB( LDAB, * ), AFB( LDAFB, * ), B( LDB, * ),
 384      $                   BERR( * ), C( * ), FERR( * ), R( * ),
 385      $                   WORK( * ), X( LDX, * )
 386 *     ..
 387 *
 388 *  =====================================================================
 389 *  Moved setting of INFO = N+1 so INFO does not subsequently get
 390 *  overwritten.  Sven, 17 Mar 05.
 391 *  =====================================================================
 392 *
 393 *     .. Parameters ..
 394       REAL               ZERO, ONE
 395       PARAMETER          ( ZERO = 0.0E+0, ONE = 1.0E+0 )
 396 *     ..
 397 *     .. Local Scalars ..
 398       LOGICAL            COLEQU, EQUIL, NOFACT, NOTRAN, ROWEQU
 399       CHARACTER          NORM
 400       INTEGER            I, INFEQU, J, J1, J2
 401       REAL               AMAX, ANORM, BIGNUM, COLCND, RCMAX, RCMIN,
 402      $                   ROWCND, RPVGRW, SMLNUM
 403 *     ..
 404 *     .. External Functions ..
 405       LOGICAL            LSAME
 406       REAL               SLAMCH, SLANGB, SLANTB
 407       EXTERNAL           LSAME, SLAMCH, SLANGB, SLANTB
 408 *     ..
 409 *     .. External Subroutines ..
 410       EXTERNAL           SCOPY, SGBCON, SGBEQU, SGBRFS, SGBTRF, SGBTRS,
 411      $                   SLACPY, SLAQGB, XERBLA
 412 *     ..
 413 *     .. Intrinsic Functions ..
 414       INTRINSIC          ABS, MAX, MIN
 415 *     ..
 416 *     .. Executable Statements ..
 417 *
 418       INFO = 0
 419       NOFACT = LSAME( FACT, 'N' )
 420       EQUIL = LSAME( FACT, 'E' )
 421       NOTRAN = LSAME( TRANS, 'N' )
 422       IF( NOFACT .OR. EQUIL ) THEN
 423          EQUED = 'N'
 424          ROWEQU = .FALSE.
 425          COLEQU = .FALSE.
 426       ELSE
 427          ROWEQU = LSAME( EQUED, 'R' ) .OR. LSAME( EQUED, 'B' )
 428          COLEQU = LSAME( EQUED, 'C' ) .OR. LSAME( EQUED, 'B' )
 429          SMLNUM = SLAMCH( 'Safe minimum' )
 430          BIGNUM = ONE / SMLNUM
 431       END IF
 432 *
 433 *     Test the input parameters.
 434 *
 435       IF( .NOT.NOFACT .AND. .NOT.EQUIL .AND. .NOT.LSAME( FACT, 'F' ) )
 436      $     THEN
 437          INFO = -1
 438       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) .AND. .NOT.
 439      $         LSAME( TRANS, 'C' ) ) THEN
 440          INFO = -2
 441       ELSE IF( N.LT.0 ) THEN
 442          INFO = -3
 443       ELSE IF( KL.LT.0 ) THEN
 444          INFO = -4
 445       ELSE IF( KU.LT.0 ) THEN
 446          INFO = -5
 447       ELSE IF( NRHS.LT.0 ) THEN
 448          INFO = -6
 449       ELSE IF( LDAB.LT.KL+KU+1 ) THEN
 450          INFO = -8
 451       ELSE IF( LDAFB.LT.2*KL+KU+1 ) THEN
 452          INFO = -10
 453       ELSE IF( LSAME( FACT, 'F' ) .AND. .NOT.
 454      $         ( ROWEQU .OR. COLEQU .OR. LSAME( EQUED, 'N' ) ) ) THEN
 455          INFO = -12
 456       ELSE
 457          IF( ROWEQU ) THEN
 458             RCMIN = BIGNUM
 459             RCMAX = ZERO
 460             DO 10 J = 1, N
 461                RCMIN = MIN( RCMIN, R( J ) )
 462                RCMAX = MAX( RCMAX, R( J ) )
 463    10       CONTINUE
 464             IF( RCMIN.LE.ZERO ) THEN
 465                INFO = -13
 466             ELSE IF( N.GT.0 ) THEN
 467                ROWCND = MAX( RCMIN, SMLNUM ) / MIN( RCMAX, BIGNUM )
 468             ELSE
 469                ROWCND = ONE
 470             END IF
 471          END IF
 472          IF( COLEQU .AND. INFO.EQ.0 ) THEN
 473             RCMIN = BIGNUM
 474             RCMAX = ZERO
 475             DO 20 J = 1, N
 476                RCMIN = MIN( RCMIN, C( J ) )
 477                RCMAX = MAX( RCMAX, C( J ) )
 478    20       CONTINUE
 479             IF( RCMIN.LE.ZERO ) THEN
 480                INFO = -14
 481             ELSE IF( N.GT.0 ) THEN
 482                COLCND = MAX( RCMIN, SMLNUM ) / MIN( RCMAX, BIGNUM )
 483             ELSE
 484                COLCND = ONE
 485             END IF
 486          END IF
 487          IF( INFO.EQ.0 ) THEN
 488             IF( LDB.LT.MAX( 1, N ) ) THEN
 489                INFO = -16
 490             ELSE IF( LDX.LT.MAX( 1, N ) ) THEN
 491                INFO = -18
 492             END IF
 493          END IF
 494       END IF
 495 *
 496       IF( INFO.NE.0 ) THEN
 497          CALL XERBLA( 'SGBSVX', -INFO )
 498          RETURN
 499       END IF
 500 *
 501       IF( EQUIL ) THEN
 502 *
 503 *        Compute row and column scalings to equilibrate the matrix A.
 504 *
 505          CALL SGBEQU( N, N, KL, KU, AB, LDAB, R, C, ROWCND, COLCND,
 506      $                AMAX, INFEQU )
 507          IF( INFEQU.EQ.0 ) THEN
 508 *
 509 *           Equilibrate the matrix.
 510 *
 511             CALL SLAQGB( N, N, KL, KU, AB, LDAB, R, C, ROWCND, COLCND,
 512      $                   AMAX, EQUED )
 513             ROWEQU = LSAME( EQUED, 'R' ) .OR. LSAME( EQUED, 'B' )
 514             COLEQU = LSAME( EQUED, 'C' ) .OR. LSAME( EQUED, 'B' )
 515          END IF
 516       END IF
 517 *
 518 *     Scale the right hand side.
 519 *
 520       IF( NOTRAN ) THEN
 521          IF( ROWEQU ) THEN
 522             DO 40 J = 1, NRHS
 523                DO 30 I = 1, N
 524                   B( I, J ) = R( I )*B( I, J )
 525    30          CONTINUE
 526    40       CONTINUE
 527          END IF
 528       ELSE IF( COLEQU ) THEN
 529          DO 60 J = 1, NRHS
 530             DO 50 I = 1, N
 531                B( I, J ) = C( I )*B( I, J )
 532    50       CONTINUE
 533    60    CONTINUE
 534       END IF
 535 *
 536       IF( NOFACT .OR. EQUIL ) THEN
 537 *
 538 *        Compute the LU factorization of the band matrix A.
 539 *
 540          DO 70 J = 1, N
 541             J1 = MAX( J-KU, 1 )
 542             J2 = MIN( J+KL, N )
 543             CALL SCOPY( J2-J1+1, AB( KU+1-J+J1, J ), 1,
 544      $                  AFB( KL+KU+1-J+J1, J ), 1 )
 545    70    CONTINUE
 546 *
 547          CALL SGBTRF( N, N, KL, KU, AFB, LDAFB, IPIV, INFO )
 548 *
 549 *        Return if INFO is non-zero.
 550 *
 551          IF( INFO.GT.0 ) THEN
 552 *
 553 *           Compute the reciprocal pivot growth factor of the
 554 *           leading rank-deficient INFO columns of A.
 555 *
 556             ANORM = ZERO
 557             DO 90 J = 1, INFO
 558                DO 80 I = MAX( KU+2-J, 1 ), MIN( N+KU+1-J, KL+KU+1 )
 559                   ANORM = MAX( ANORM, ABS( AB( I, J ) ) )
 560    80          CONTINUE
 561    90       CONTINUE
 562             RPVGRW = SLANTB( 'M', 'U', 'N', INFO, MIN( INFO-1, KL+KU ),
 563      $                       AFB( MAX( 1, KL+KU+2-INFO ), 1 ), LDAFB,
 564      $                       WORK )
 565             IF( RPVGRW.EQ.ZERO ) THEN
 566                RPVGRW = ONE
 567             ELSE
 568                RPVGRW = ANORM / RPVGRW
 569             END IF
 570             WORK( 1 ) = RPVGRW
 571             RCOND = ZERO
 572             RETURN
 573          END IF
 574       END IF
 575 *
 576 *     Compute the norm of the matrix A and the
 577 *     reciprocal pivot growth factor RPVGRW.
 578 *
 579       IF( NOTRAN ) THEN
 580          NORM = '1'
 581       ELSE
 582          NORM = 'I'
 583       END IF
 584       ANORM = SLANGB( NORM, N, KL, KU, AB, LDAB, WORK )
 585       RPVGRW = SLANTB( 'M', 'U', 'N', N, KL+KU, AFB, LDAFB, WORK )
 586       IF( RPVGRW.EQ.ZERO ) THEN
 587          RPVGRW = ONE
 588       ELSE
 589          RPVGRW = SLANGB( 'M', N, KL, KU, AB, LDAB, WORK ) / RPVGRW
 590       END IF
 591 *
 592 *     Compute the reciprocal of the condition number of A.
 593 *
 594       CALL SGBCON( NORM, N, KL, KU, AFB, LDAFB, IPIV, ANORM, RCOND,
 595      $             WORK, IWORK, INFO )
 596 *
 597 *     Compute the solution matrix X.
 598 *
 599       CALL SLACPY( 'Full', N, NRHS, B, LDB, X, LDX )
 600       CALL SGBTRS( TRANS, N, KL, KU, NRHS, AFB, LDAFB, IPIV, X, LDX,
 601      $             INFO )
 602 *
 603 *     Use iterative refinement to improve the computed solution and
 604 *     compute error bounds and backward error estimates for it.
 605 *
 606       CALL SGBRFS( TRANS, N, KL, KU, NRHS, AB, LDAB, AFB, LDAFB, IPIV,
 607      $             B, LDB, X, LDX, FERR, BERR, WORK, IWORK, INFO )
 608 *
 609 *     Transform the solution matrix X to a solution of the original
 610 *     system.
 611 *
 612       IF( NOTRAN ) THEN
 613          IF( COLEQU ) THEN
 614             DO 110 J = 1, NRHS
 615                DO 100 I = 1, N
 616                   X( I, J ) = C( I )*X( I, J )
 617   100          CONTINUE
 618   110       CONTINUE
 619             DO 120 J = 1, NRHS
 620                FERR( J ) = FERR( J ) / COLCND
 621   120       CONTINUE
 622          END IF
 623       ELSE IF( ROWEQU ) THEN
 624          DO 140 J = 1, NRHS
 625             DO 130 I = 1, N
 626                X( I, J ) = R( I )*X( I, J )
 627   130       CONTINUE
 628   140    CONTINUE
 629          DO 150 J = 1, NRHS
 630             FERR( J ) = FERR( J ) / ROWCND
 631   150    CONTINUE
 632       END IF
 633 *
 634 *     Set INFO = N+1 if the matrix is singular to working precision.
 635 *
 636       IF( RCOND.LT.SLAMCH( 'Epsilon' ) )
 637      $   INFO = N + 1
 638 *
 639       WORK( 1 ) = RPVGRW
 640       RETURN
 641 *
 642 *     End of SGBSVX
 643 *
 644       END