SRC/dtrtrs.f

   1 *> \brief \b DTRTRS
   2 *
   3 *  =========== DOCUMENTATION ===========
   4 *
   5 * Online html documentation available at
   6 *            http://www.netlib.org/lapack/explore-html/
   7 *
   8 *> \htmlonly
   9 *> Download DTRTRS + dependencies
  10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dtrtrs.f">
  11 *> [TGZ]</a>
  12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dtrtrs.f">
  13 *> [ZIP]</a>
  14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dtrtrs.f">
  15 *> [TXT]</a>
  16 *> \endhtmlonly
  17 *
  18 *  Definition:
  19 *  ===========
  20 *
  21 *       SUBROUTINE DTRTRS( UPLO, TRANS, DIAG, N, NRHS, A, LDA, B, LDB,
  22 *                          INFO )
  23 *
  24 *       .. Scalar Arguments ..
  25 *       CHARACTER          DIAG, TRANS, UPLO
  26 *       INTEGER            INFO, LDA, LDB, N, NRHS
  27 *       ..
  28 *       .. Array Arguments ..
  29 *       DOUBLE PRECISION   A( LDA, * ), B( LDB, * )
  30 *       ..
  31 *
  32 *
  33 *> \par Purpose:
  34 *  =============
  35 *>
  36 *> \verbatim
  37 *>
  38 *> DTRTRS solves a triangular system of the form
  39 *>
  40 *>    A * X = B  or  A**T * X = B,
  41 *>
  42 *> where A is a triangular matrix of order N, and B is an N-by-NRHS
  43 *> matrix.  A check is made to verify that A is nonsingular.
  44 *> \endverbatim
  45 *
  46 *  Arguments:
  47 *  ==========
  48 *
  49 *> \param[in] UPLO
  50 *> \verbatim
  51 *>          UPLO is CHARACTER*1
  52 *>          = 'U':  A is upper triangular;
  53 *>          = 'L':  A is lower triangular.
  54 *> \endverbatim
  55 *>
  56 *> \param[in] TRANS
  57 *> \verbatim
  58 *>          TRANS is CHARACTER*1
  59 *>          Specifies the form of the system of equations:
  60 *>          = 'N':  A * X = B  (No transpose)
  61 *>          = 'T':  A**T * X = B  (Transpose)
  62 *>          = 'C':  A**H * X = B  (Conjugate transpose = Transpose)
  63 *> \endverbatim
  64 *>
  65 *> \param[in] DIAG
  66 *> \verbatim
  67 *>          DIAG is CHARACTER*1
  68 *>          = 'N':  A is non-unit triangular;
  69 *>          = 'U':  A is unit triangular.
  70 *> \endverbatim
  71 *>
  72 *> \param[in] N
  73 *> \verbatim
  74 *>          N is INTEGER
  75 *>          The order of the matrix A.  N >= 0.
  76 *> \endverbatim
  77 *>
  78 *> \param[in] NRHS
  79 *> \verbatim
  80 *>          NRHS is INTEGER
  81 *>          The number of right hand sides, i.e., the number of columns
  82 *>          of the matrix B.  NRHS >= 0.
  83 *> \endverbatim
  84 *>
  85 *> \param[in] A
  86 *> \verbatim
  87 *>          A is DOUBLE PRECISION array, dimension (LDA,N)
  88 *>          The triangular matrix A.  If UPLO = 'U', the leading N-by-N
  89 *>          upper triangular part of the array A contains the upper
  90 *>          triangular matrix, and the strictly lower triangular part of
  91 *>          A is not referenced.  If UPLO = 'L', the leading N-by-N lower
  92 *>          triangular part of the array A contains the lower triangular
  93 *>          matrix, and the strictly upper triangular part of A is not
  94 *>          referenced.  If DIAG = 'U', the diagonal elements of A are
  95 *>          also not referenced and are assumed to be 1.
  96 *> \endverbatim
  97 *>
  98 *> \param[in] LDA
  99 *> \verbatim
 100 *>          LDA is INTEGER
 101 *>          The leading dimension of the array A.  LDA >= max(1,N).
 102 *> \endverbatim
 103 *>
 104 *> \param[in,out] B
 105 *> \verbatim
 106 *>          B is DOUBLE PRECISION array, dimension (LDB,NRHS)
 107 *>          On entry, the right hand side matrix B.
 108 *>          On exit, if INFO = 0, the solution matrix X.
 109 *> \endverbatim
 110 *>
 111 *> \param[in] LDB
 112 *> \verbatim
 113 *>          LDB is INTEGER
 114 *>          The leading dimension of the array B.  LDB >= max(1,N).
 115 *> \endverbatim
 116 *>
 117 *> \param[out] INFO
 118 *> \verbatim
 119 *>          INFO is INTEGER
 120 *>          = 0:  successful exit
 121 *>          < 0: if INFO = -i, the i-th argument had an illegal value
 122 *>          > 0: if INFO = i, the i-th diagonal element of A is zero,
 123 *>               indicating that the matrix is singular and the solutions
 124 *>               X have not been computed.
 125 *> \endverbatim
 126 *
 127 *  Authors:
 128 *  ========
 129 *
 130 *> \author Univ. of Tennessee
 131 *> \author Univ. of California Berkeley
 132 *> \author Univ. of Colorado Denver
 133 *> \author NAG Ltd.
 134 *
 135 *> \date November 2011
 136 *
 137 *> \ingroup doubleOTHERcomputational
 138 *
 139 *  =====================================================================
 140       SUBROUTINE DTRTRS( UPLO, TRANS, DIAG, N, NRHS, A, LDA, B, LDB,
 141      $                   INFO )
 142 *
 143 *  -- LAPACK computational routine (version 3.4.0) --
 144 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 145 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 146 *     November 2011
 147 *
 148 *     .. Scalar Arguments ..
 149       CHARACTER          DIAG, TRANS, UPLO
 150       INTEGER            INFO, LDA, LDB, N, NRHS
 151 *     ..
 152 *     .. Array Arguments ..
 153       DOUBLE PRECISION   A( LDA, * ), B( LDB, * )
 154 *     ..
 155 *
 156 *  =====================================================================
 157 *
 158 *     .. Parameters ..
 159       DOUBLE PRECISION   ZERO, ONE
 160       PARAMETER          ( ZERO = 0.0D+0, ONE = 1.0D+0 )
 161 *     ..
 162 *     .. Local Scalars ..
 163       LOGICAL            NOUNIT
 164 *     ..
 165 *     .. External Functions ..
 166       LOGICAL            LSAME
 167       EXTERNAL           LSAME
 168 *     ..
 169 *     .. External Subroutines ..
 170       EXTERNAL           DTRSM, XERBLA
 171 *     ..
 172 *     .. Intrinsic Functions ..
 173       INTRINSIC          MAX
 174 *     ..
 175 *     .. Executable Statements ..
 176 *
 177 *     Test the input parameters.
 178 *
 179       INFO = 0
 180       NOUNIT = LSAME( DIAG, 'N' )
 181       IF( .NOT.LSAME( UPLO, 'U' ) .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
 182          INFO = -1
 183       ELSE IF( .NOT.LSAME( TRANS, 'N' ) .AND. .NOT.
 184      $         LSAME( TRANS, 'T' ) .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
 185          INFO = -2
 186       ELSE IF( .NOT.NOUNIT .AND. .NOT.LSAME( DIAG, 'U' ) ) THEN
 187          INFO = -3
 188       ELSE IF( N.LT.0 ) THEN
 189          INFO = -4
 190       ELSE IF( NRHS.LT.0 ) THEN
 191          INFO = -5
 192       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
 193          INFO = -7
 194       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
 195          INFO = -9
 196       END IF
 197       IF( INFO.NE.0 ) THEN
 198          CALL XERBLA( 'DTRTRS', -INFO )
 199          RETURN
 200       END IF
 201 *
 202 *     Quick return if possible
 203 *
 204       IF( N.EQ.0 )
 205      $   RETURN
 206 *
 207 *     Check for singularity.
 208 *
 209       IF( NOUNIT ) THEN
 210          DO 10 INFO = 1, N
 211             IF( A( INFO, INFO ).EQ.ZERO )
 212      $         RETURN
 213    10    CONTINUE
 214       END IF
 215       INFO = 0
 216 *
 217 *     Solve A * x = b  or  A**T * x = b.
 218 *
 219       CALL DTRSM( 'Left', UPLO, TRANS, DIAG, N, NRHS, ONE, A, LDA, B,
 220      $            LDB )
 221 *
 222       RETURN
 223 *
 224 *     End of DTRTRS
 225 *
 226       END