SRC/dstevr.f

   1 *> \brief <b> DSTEVR computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrices</b>
   2 *
   3 *  =========== DOCUMENTATION ===========
   4 *
   5 * Online html documentation available at
   6 *            http://www.netlib.org/lapack/explore-html/
   7 *
   8 *> \htmlonly
   9 *> Download DSTEVR + dependencies
  10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dstevr.f">
  11 *> [TGZ]</a>
  12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dstevr.f">
  13 *> [ZIP]</a>
  14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dstevr.f">
  15 *> [TXT]</a>
  16 *> \endhtmlonly
  17 *
  18 *  Definition:
  19 *  ===========
  20 *
  21 *       SUBROUTINE DSTEVR( JOBZ, RANGE, N, D, E, VL, VU, IL, IU, ABSTOL,
  22 *                          M, W, Z, LDZ, ISUPPZ, WORK, LWORK, IWORK,
  23 *                          LIWORK, INFO )
  24 *
  25 *       .. Scalar Arguments ..
  26 *       CHARACTER          JOBZ, RANGE
  27 *       INTEGER            IL, INFO, IU, LDZ, LIWORK, LWORK, M, N
  28 *       DOUBLE PRECISION   ABSTOL, VL, VU
  29 *       ..
  30 *       .. Array Arguments ..
  31 *       INTEGER            ISUPPZ( * ), IWORK( * )
  32 *       DOUBLE PRECISION   D( * ), E( * ), W( * ), WORK( * ), Z( LDZ, * )
  33 *       ..
  34 *
  35 *
  36 *> \par Purpose:
  37 *  =============
  38 *>
  39 *> \verbatim
  40 *>
  41 *> DSTEVR computes selected eigenvalues and, optionally, eigenvectors
  42 *> of a real symmetric tridiagonal matrix T.  Eigenvalues and
  43 *> eigenvectors can be selected by specifying either a range of values
  44 *> or a range of indices for the desired eigenvalues.
  45 *>
  46 *> Whenever possible, DSTEVR calls DSTEMR to compute the
  47 *> eigenspectrum using Relatively Robust Representations.  DSTEMR
  48 *> computes eigenvalues by the dqds algorithm, while orthogonal
  49 *> eigenvectors are computed from various "good" L D L^T representations
  50 *> (also known as Relatively Robust Representations). Gram-Schmidt
  51 *> orthogonalization is avoided as far as possible. More specifically,
  52 *> the various steps of the algorithm are as follows. For the i-th
  53 *> unreduced block of T,
  54 *>    (a) Compute T - sigma_i = L_i D_i L_i^T, such that L_i D_i L_i^T
  55 *>         is a relatively robust representation,
  56 *>    (b) Compute the eigenvalues, lambda_j, of L_i D_i L_i^T to high
  57 *>        relative accuracy by the dqds algorithm,
  58 *>    (c) If there is a cluster of close eigenvalues, "choose" sigma_i
  59 *>        close to the cluster, and go to step (a),
  60 *>    (d) Given the approximate eigenvalue lambda_j of L_i D_i L_i^T,
  61 *>        compute the corresponding eigenvector by forming a
  62 *>        rank-revealing twisted factorization.
  63 *> The desired accuracy of the output can be specified by the input
  64 *> parameter ABSTOL.
  65 *>
  66 *> For more details, see "A new O(n^2) algorithm for the symmetric
  67 *> tridiagonal eigenvalue/eigenvector problem", by Inderjit Dhillon,
  68 *> Computer Science Division Technical Report No. UCB//CSD-97-971,
  69 *> UC Berkeley, May 1997.
  70 *>
  71 *>
  72 *> Note 1 : DSTEVR calls DSTEMR when the full spectrum is requested
  73 *> on machines which conform to the ieee-754 floating point standard.
  74 *> DSTEVR calls DSTEBZ and DSTEIN on non-ieee machines and
  75 *> when partial spectrum requests are made.
  76 *>
  77 *> Normal execution of DSTEMR may create NaNs and infinities and
  78 *> hence may abort due to a floating point exception in environments
  79 *> which do not handle NaNs and infinities in the ieee standard default
  80 *> manner.
  81 *> \endverbatim
  82 *
  83 *  Arguments:
  84 *  ==========
  85 *
  86 *> \param[in] JOBZ
  87 *> \verbatim
  88 *>          JOBZ is CHARACTER*1
  89 *>          = 'N':  Compute eigenvalues only;
  90 *>          = 'V':  Compute eigenvalues and eigenvectors.
  91 *> \endverbatim
  92 *>
  93 *> \param[in] RANGE
  94 *> \verbatim
  95 *>          RANGE is CHARACTER*1
  96 *>          = 'A': all eigenvalues will be found.
  97 *>          = 'V': all eigenvalues in the half-open interval (VL,VU]
  98 *>                 will be found.
  99 *>          = 'I': the IL-th through IU-th eigenvalues will be found.
 100 *>          For RANGE = 'V' or 'I' and IU - IL < N - 1, DSTEBZ and
 101 *>          DSTEIN are called
 102 *> \endverbatim
 103 *>
 104 *> \param[in] N
 105 *> \verbatim
 106 *>          N is INTEGER
 107 *>          The order of the matrix.  N >= 0.
 108 *> \endverbatim
 109 *>
 110 *> \param[in,out] D
 111 *> \verbatim
 112 *>          D is DOUBLE PRECISION array, dimension (N)
 113 *>          On entry, the n diagonal elements of the tridiagonal matrix
 114 *>          A.
 115 *>          On exit, D may be multiplied by a constant factor chosen
 116 *>          to avoid over/underflow in computing the eigenvalues.
 117 *> \endverbatim
 118 *>
 119 *> \param[in,out] E
 120 *> \verbatim
 121 *>          E is DOUBLE PRECISION array, dimension (max(1,N-1))
 122 *>          On entry, the (n-1) subdiagonal elements of the tridiagonal
 123 *>          matrix A in elements 1 to N-1 of E.
 124 *>          On exit, E may be multiplied by a constant factor chosen
 125 *>          to avoid over/underflow in computing the eigenvalues.
 126 *> \endverbatim
 127 *>
 128 *> \param[in] VL
 129 *> \verbatim
 130 *>          VL is DOUBLE PRECISION
 131 *>          If RANGE='V', the lower bound of the interval to
 132 *>          be searched for eigenvalues. VL < VU.
 133 *>          Not referenced if RANGE = 'A' or 'I'.
 134 *> \endverbatim
 135 *>
 136 *> \param[in] VU
 137 *> \verbatim
 138 *>          VU is DOUBLE PRECISION
 139 *>          If RANGE='V', the upper bound of the interval to
 140 *>          be searched for eigenvalues. VL < VU.
 141 *>          Not referenced if RANGE = 'A' or 'I'.
 142 *> \endverbatim
 143 *>
 144 *> \param[in] IL
 145 *> \verbatim
 146 *>          IL is INTEGER
 147 *>          If RANGE='I', the index of the
 148 *>          smallest eigenvalue to be returned.
 149 *>          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
 150 *>          Not referenced if RANGE = 'A' or 'V'.
 151 *> \endverbatim
 152 *>
 153 *> \param[in] IU
 154 *> \verbatim
 155 *>          IU is INTEGER
 156 *>          If RANGE='I', the index of the
 157 *>          largest eigenvalue to be returned.
 158 *>          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
 159 *>          Not referenced if RANGE = 'A' or 'V'.
 160 *> \endverbatim
 161 *>
 162 *> \param[in] ABSTOL
 163 *> \verbatim
 164 *>          ABSTOL is DOUBLE PRECISION
 165 *>          The absolute error tolerance for the eigenvalues.
 166 *>          An approximate eigenvalue is accepted as converged
 167 *>          when it is determined to lie in an interval [a,b]
 168 *>          of width less than or equal to
 169 *>
 170 *>                  ABSTOL + EPS *   max( |a|,|b| ) ,
 171 *>
 172 *>          where EPS is the machine precision.  If ABSTOL is less than
 173 *>          or equal to zero, then  EPS*|T|  will be used in its place,
 174 *>          where |T| is the 1-norm of the tridiagonal matrix obtained
 175 *>          by reducing A to tridiagonal form.
 176 *>
 177 *>          See "Computing Small Singular Values of Bidiagonal Matrices
 178 *>          with Guaranteed High Relative Accuracy," by Demmel and
 179 *>          Kahan, LAPACK Working Note #3.
 180 *>
 181 *>          If high relative accuracy is important, set ABSTOL to
 182 *>          DLAMCH( 'Safe minimum' ).  Doing so will guarantee that
 183 *>          eigenvalues are computed to high relative accuracy when
 184 *>          possible in future releases.  The current code does not
 185 *>          make any guarantees about high relative accuracy, but
 186 *>          future releases will. See J. Barlow and J. Demmel,
 187 *>          "Computing Accurate Eigensystems of Scaled Diagonally
 188 *>          Dominant Matrices", LAPACK Working Note #7, for a discussion
 189 *>          of which matrices define their eigenvalues to high relative
 190 *>          accuracy.
 191 *> \endverbatim
 192 *>
 193 *> \param[out] M
 194 *> \verbatim
 195 *>          M is INTEGER
 196 *>          The total number of eigenvalues found.  0 <= M <= N.
 197 *>          If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1.
 198 *> \endverbatim
 199 *>
 200 *> \param[out] W
 201 *> \verbatim
 202 *>          W is DOUBLE PRECISION array, dimension (N)
 203 *>          The first M elements contain the selected eigenvalues in
 204 *>          ascending order.
 205 *> \endverbatim
 206 *>
 207 *> \param[out] Z
 208 *> \verbatim
 209 *>          Z is DOUBLE PRECISION array, dimension (LDZ, max(1,M) )
 210 *>          If JOBZ = 'V', then if INFO = 0, the first M columns of Z
 211 *>          contain the orthonormal eigenvectors of the matrix A
 212 *>          corresponding to the selected eigenvalues, with the i-th
 213 *>          column of Z holding the eigenvector associated with W(i).
 214 *>          Note: the user must ensure that at least max(1,M) columns are
 215 *>          supplied in the array Z; if RANGE = 'V', the exact value of M
 216 *>          is not known in advance and an upper bound must be used.
 217 *> \endverbatim
 218 *>
 219 *> \param[in] LDZ
 220 *> \verbatim
 221 *>          LDZ is INTEGER
 222 *>          The leading dimension of the array Z.  LDZ >= 1, and if
 223 *>          JOBZ = 'V', LDZ >= max(1,N).
 224 *> \endverbatim
 225 *>
 226 *> \param[out] ISUPPZ
 227 *> \verbatim
 228 *>          ISUPPZ is INTEGER array, dimension ( 2*max(1,M) )
 229 *>          The support of the eigenvectors in Z, i.e., the indices
 230 *>          indicating the nonzero elements in Z. The i-th eigenvector
 231 *>          is nonzero only in elements ISUPPZ( 2*i-1 ) through
 232 *>          ISUPPZ( 2*i ).
 233 *>          Implemented only for RANGE = 'A' or 'I' and IU - IL = N - 1
 234 *> \endverbatim
 235 *>
 236 *> \param[out] WORK
 237 *> \verbatim
 238 *>          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
 239 *>          On exit, if INFO = 0, WORK(1) returns the optimal (and
 240 *>          minimal) LWORK.
 241 *> \endverbatim
 242 *>
 243 *> \param[in] LWORK
 244 *> \verbatim
 245 *>          LWORK is INTEGER
 246 *>          The dimension of the array WORK.  LWORK >= max(1,20*N).
 247 *>
 248 *>          If LWORK = -1, then a workspace query is assumed; the routine
 249 *>          only calculates the optimal sizes of the WORK and IWORK
 250 *>          arrays, returns these values as the first entries of the WORK
 251 *>          and IWORK arrays, and no error message related to LWORK or
 252 *>          LIWORK is issued by XERBLA.
 253 *> \endverbatim
 254 *>
 255 *> \param[out] IWORK
 256 *> \verbatim
 257 *>          IWORK is INTEGER array, dimension (MAX(1,LIWORK))
 258 *>          On exit, if INFO = 0, IWORK(1) returns the optimal (and
 259 *>          minimal) LIWORK.
 260 *> \endverbatim
 261 *>
 262 *> \param[in] LIWORK
 263 *> \verbatim
 264 *>          LIWORK is INTEGER
 265 *>          The dimension of the array IWORK.  LIWORK >= max(1,10*N).
 266 *>
 267 *>          If LIWORK = -1, then a workspace query is assumed; the
 268 *>          routine only calculates the optimal sizes of the WORK and
 269 *>          IWORK arrays, returns these values as the first entries of
 270 *>          the WORK and IWORK arrays, and no error message related to
 271 *>          LWORK or LIWORK is issued by XERBLA.
 272 *> \endverbatim
 273 *>
 274 *> \param[out] INFO
 275 *> \verbatim
 276 *>          INFO is INTEGER
 277 *>          = 0:  successful exit
 278 *>          < 0:  if INFO = -i, the i-th argument had an illegal value
 279 *>          > 0:  Internal error
 280 *> \endverbatim
 281 *
 282 *  Authors:
 283 *  ========
 284 *
 285 *> \author Univ. of Tennessee
 286 *> \author Univ. of California Berkeley
 287 *> \author Univ. of Colorado Denver
 288 *> \author NAG Ltd.
 289 *
 290 *> \date June 2016
 291 *
 292 *> \ingroup doubleOTHEReigen
 293 *
 294 *> \par Contributors:
 295 *  ==================
 296 *>
 297 *>     Inderjit Dhillon, IBM Almaden, USA \n
 298 *>     Osni Marques, LBNL/NERSC, USA \n
 299 *>     Ken Stanley, Computer Science Division, University of
 300 *>       California at Berkeley, USA \n
 301 *>
 302 *  =====================================================================
 303       SUBROUTINE DSTEVR( JOBZ, RANGE, N, D, E, VL, VU, IL, IU, ABSTOL,
 304      $                   M, W, Z, LDZ, ISUPPZ, WORK, LWORK, IWORK,
 305      $                   LIWORK, INFO )
 306 *
 307 *  -- LAPACK driver routine (version 3.6.1) --
 308 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 309 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 310 *     June 2016
 311 *
 312 *     .. Scalar Arguments ..
 313       CHARACTER          JOBZ, RANGE
 314       INTEGER            IL, INFO, IU, LDZ, LIWORK, LWORK, M, N
 315       DOUBLE PRECISION   ABSTOL, VL, VU
 316 *     ..
 317 *     .. Array Arguments ..
 318       INTEGER            ISUPPZ( * ), IWORK( * )
 319       DOUBLE PRECISION   D( * ), E( * ), W( * ), WORK( * ), Z( LDZ, * )
 320 *     ..
 321 *
 322 *  =====================================================================
 323 *
 324 *     .. Parameters ..
 325       DOUBLE PRECISION   ZERO, ONE, TWO
 326       PARAMETER          ( ZERO = 0.0D+0, ONE = 1.0D+0, TWO = 2.0D+0 )
 327 *     ..
 328 *     .. Local Scalars ..
 329       LOGICAL            ALLEIG, INDEIG, TEST, LQUERY, VALEIG, WANTZ,
 330      $                   TRYRAC
 331       CHARACTER          ORDER
 332       INTEGER            I, IEEEOK, IMAX, INDIBL, INDIFL, INDISP,
 333      $                   INDIWO, ISCALE, ITMP1, J, JJ, LIWMIN, LWMIN,
 334      $                   NSPLIT
 335       DOUBLE PRECISION   BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA, SMLNUM,
 336      $                   TMP1, TNRM, VLL, VUU
 337 *     ..
 338 *     .. External Functions ..
 339       LOGICAL            LSAME
 340       INTEGER            ILAENV
 341       DOUBLE PRECISION   DLAMCH, DLANST
 342       EXTERNAL           LSAME, ILAENV, DLAMCH, DLANST
 343 *     ..
 344 *     .. External Subroutines ..
 345       EXTERNAL           DCOPY, DSCAL, DSTEBZ, DSTEMR, DSTEIN, DSTERF,
 346      $                   DSWAP, XERBLA
 347 *     ..
 348 *     .. Intrinsic Functions ..
 349       INTRINSIC          MAX, MIN, SQRT
 350 *     ..
 351 *     .. Executable Statements ..
 352 *
 353 *
 354 *     Test the input parameters.
 355 *
 356       IEEEOK = ILAENV( 10, 'DSTEVR', 'N', 1, 2, 3, 4 )
 357 *
 358       WANTZ = LSAME( JOBZ, 'V' )
 359       ALLEIG = LSAME( RANGE, 'A' )
 360       VALEIG = LSAME( RANGE, 'V' )
 361       INDEIG = LSAME( RANGE, 'I' )
 362 *
 363       LQUERY = ( ( LWORK.EQ.-1 ) .OR. ( LIWORK.EQ.-1 ) )
 364       LWMIN = MAX( 1, 20*N )
 365       LIWMIN = MAX( 1, 10*N )
 366 *
 367 *
 368       INFO = 0
 369       IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
 370          INFO = -1
 371       ELSE IF( .NOT.( ALLEIG .OR. VALEIG .OR. INDEIG ) ) THEN
 372          INFO = -2
 373       ELSE IF( N.LT.0 ) THEN
 374          INFO = -3
 375       ELSE
 376          IF( VALEIG ) THEN
 377             IF( N.GT.0 .AND. VU.LE.VL )
 378      $         INFO = -7
 379          ELSE IF( INDEIG ) THEN
 380             IF( IL.LT.1 .OR. IL.GT.MAX( 1, N ) ) THEN
 381                INFO = -8
 382             ELSE IF( IU.LT.MIN( N, IL ) .OR. IU.GT.N ) THEN
 383                INFO = -9
 384             END IF
 385          END IF
 386       END IF
 387       IF( INFO.EQ.0 ) THEN
 388          IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
 389             INFO = -14
 390          END IF
 391       END IF
 392 *
 393       IF( INFO.EQ.0 ) THEN
 394          WORK( 1 ) = LWMIN
 395          IWORK( 1 ) = LIWMIN
 396 *
 397          IF( LWORK.LT.LWMIN .AND. .NOT.LQUERY ) THEN
 398             INFO = -17
 399          ELSE IF( LIWORK.LT.LIWMIN .AND. .NOT.LQUERY ) THEN
 400             INFO = -19
 401          END IF
 402       END IF
 403 *
 404       IF( INFO.NE.0 ) THEN
 405          CALL XERBLA( 'DSTEVR', -INFO )
 406          RETURN
 407       ELSE IF( LQUERY ) THEN
 408          RETURN
 409       END IF
 410 *
 411 *     Quick return if possible
 412 *
 413       M = 0
 414       IF( N.EQ.0 )
 415      $   RETURN
 416 *
 417       IF( N.EQ.1 ) THEN
 418          IF( ALLEIG .OR. INDEIG ) THEN
 419             M = 1
 420             W( 1 ) = D( 1 )
 421          ELSE
 422             IF( VL.LT.D( 1 ) .AND. VU.GE.D( 1 ) ) THEN
 423                M = 1
 424                W( 1 ) = D( 1 )
 425             END IF
 426          END IF
 427          IF( WANTZ )
 428      $      Z( 1, 1 ) = ONE
 429          RETURN
 430       END IF
 431 *
 432 *     Get machine constants.
 433 *
 434       SAFMIN = DLAMCH( 'Safe minimum' )
 435       EPS = DLAMCH( 'Precision' )
 436       SMLNUM = SAFMIN / EPS
 437       BIGNUM = ONE / SMLNUM
 438       RMIN = SQRT( SMLNUM )
 439       RMAX = MIN( SQRT( BIGNUM ), ONE / SQRT( SQRT( SAFMIN ) ) )
 440 *
 441 *
 442 *     Scale matrix to allowable range, if necessary.
 443 *
 444       ISCALE = 0
 445       IF( VALEIG ) THEN
 446          VLL = VL
 447          VUU = VU
 448       END IF
 449 *
 450       TNRM = DLANST( 'M', N, D, E )
 451       IF( TNRM.GT.ZERO .AND. TNRM.LT.RMIN ) THEN
 452          ISCALE = 1
 453          SIGMA = RMIN / TNRM
 454       ELSE IF( TNRM.GT.RMAX ) THEN
 455          ISCALE = 1
 456          SIGMA = RMAX / TNRM
 457       END IF
 458       IF( ISCALE.EQ.1 ) THEN
 459          CALL DSCAL( N, SIGMA, D, 1 )
 460          CALL DSCAL( N-1, SIGMA, E( 1 ), 1 )
 461          IF( VALEIG ) THEN
 462             VLL = VL*SIGMA
 463             VUU = VU*SIGMA
 464          END IF
 465       END IF
 466
 467 *     Initialize indices into workspaces.  Note: These indices are used only
 468 *     if DSTERF or DSTEMR fail.
 469
 470 *     IWORK(INDIBL:INDIBL+M-1) corresponds to IBLOCK in DSTEBZ and
 471 *     stores the block indices of each of the M<=N eigenvalues.
 472       INDIBL = 1
 473 *     IWORK(INDISP:INDISP+NSPLIT-1) corresponds to ISPLIT in DSTEBZ and
 474 *     stores the starting and finishing indices of each block.
 475       INDISP = INDIBL + N
 476 *     IWORK(INDIFL:INDIFL+N-1) stores the indices of eigenvectors
 477 *     that corresponding to eigenvectors that fail to converge in
 478 *     DSTEIN.  This information is discarded; if any fail, the driver
 479 *     returns INFO > 0.
 480       INDIFL = INDISP + N
 481 *     INDIWO is the offset of the remaining integer workspace.
 482       INDIWO = INDISP + N
 483 *
 484 *     If all eigenvalues are desired, then
 485 *     call DSTERF or DSTEMR.  If this fails for some eigenvalue, then
 486 *     try DSTEBZ.
 487 *
 488 *
 489       TEST = .FALSE.
 490       IF( INDEIG ) THEN
 491          IF( IL.EQ.1 .AND. IU.EQ.N ) THEN
 492             TEST = .TRUE.
 493          END IF
 494       END IF
 495       IF( ( ALLEIG .OR. TEST ) .AND. IEEEOK.EQ.1 ) THEN
 496          CALL DCOPY( N-1, E( 1 ), 1, WORK( 1 ), 1 )
 497          IF( .NOT.WANTZ ) THEN
 498             CALL DCOPY( N, D, 1, W, 1 )
 499             CALL DSTERF( N, W, WORK, INFO )
 500          ELSE
 501             CALL DCOPY( N, D, 1, WORK( N+1 ), 1 )
 502             IF (ABSTOL .LE. TWO*N*EPS) THEN
 503                TRYRAC = .TRUE.
 504             ELSE
 505                TRYRAC = .FALSE.
 506             END IF
 507             CALL DSTEMR( JOBZ, 'A', N, WORK( N+1 ), WORK, VL, VU, IL,
 508      $                   IU, M, W, Z, LDZ, N, ISUPPZ, TRYRAC,
 509      $                   WORK( 2*N+1 ), LWORK-2*N, IWORK, LIWORK, INFO )
 510 *
 511          END IF
 512          IF( INFO.EQ.0 ) THEN
 513             M = N
 514             GO TO 10
 515          END IF
 516          INFO = 0
 517       END IF
 518 *
 519 *     Otherwise, call DSTEBZ and, if eigenvectors are desired, DSTEIN.
 520 *
 521       IF( WANTZ ) THEN
 522          ORDER = 'B'
 523       ELSE
 524          ORDER = 'E'
 525       END IF
 526
 527       CALL DSTEBZ( RANGE, ORDER, N, VLL, VUU, IL, IU, ABSTOL, D, E, M,
 528      $             NSPLIT, W, IWORK( INDIBL ), IWORK( INDISP ), WORK,
 529      $             IWORK( INDIWO ), INFO )
 530 *
 531       IF( WANTZ ) THEN
 532          CALL DSTEIN( N, D, E, M, W, IWORK( INDIBL ), IWORK( INDISP ),
 533      $                Z, LDZ, WORK, IWORK( INDIWO ), IWORK( INDIFL ),
 534      $                INFO )
 535       END IF
 536 *
 537 *     If matrix was scaled, then rescale eigenvalues appropriately.
 538 *
 539    10 CONTINUE
 540       IF( ISCALE.EQ.1 ) THEN
 541          IF( INFO.EQ.0 ) THEN
 542             IMAX = M
 543          ELSE
 544             IMAX = INFO - 1
 545          END IF
 546          CALL DSCAL( IMAX, ONE / SIGMA, W, 1 )
 547       END IF
 548 *
 549 *     If eigenvalues are not in order, then sort them, along with
 550 *     eigenvectors.
 551 *
 552       IF( WANTZ ) THEN
 553          DO 30 J = 1, M - 1
 554             I = 0
 555             TMP1 = W( J )
 556             DO 20 JJ = J + 1, M
 557                IF( W( JJ ).LT.TMP1 ) THEN
 558                   I = JJ
 559                   TMP1 = W( JJ )
 560                END IF
 561    20       CONTINUE
 562 *
 563             IF( I.NE.0 ) THEN
 564                ITMP1 = IWORK( I )
 565                W( I ) = W( J )
 566                IWORK( I ) = IWORK( J )
 567                W( J ) = TMP1
 568                IWORK( J ) = ITMP1
 569                CALL DSWAP( N, Z( 1, I ), 1, Z( 1, J ), 1 )
 570             END IF
 571    30    CONTINUE
 572       END IF
 573 *
 574 *      Causes problems with tests 19 & 20:
 575 *      IF (wantz .and. INDEIG ) Z( 1,1) = Z(1,1) / 1.002 + .002
 576 *
 577 *
 578       WORK( 1 ) = LWMIN
 579       IWORK( 1 ) = LIWMIN
 580       RETURN
 581 *
 582 *     End of DSTEVR
 583 *
 584       END