SRC/dspgv.f

   1 *> \brief \b DSPGV
   2 *
   3 *  =========== DOCUMENTATION ===========
   4 *
   5 * Online html documentation available at
   6 *            http://www.netlib.org/lapack/explore-html/
   7 *
   8 *> \htmlonly
   9 *> Download DSPGV + dependencies
  10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dspgv.f">
  11 *> [TGZ]</a>
  12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dspgv.f">
  13 *> [ZIP]</a>
  14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dspgv.f">
  15 *> [TXT]</a>
  16 *> \endhtmlonly
  17 *
  18 *  Definition:
  19 *  ===========
  20 *
  21 *       SUBROUTINE DSPGV( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
  22 *                         INFO )
  23 *
  24 *       .. Scalar Arguments ..
  25 *       CHARACTER          JOBZ, UPLO
  26 *       INTEGER            INFO, ITYPE, LDZ, N
  27 *       ..
  28 *       .. Array Arguments ..
  29 *       DOUBLE PRECISION   AP( * ), BP( * ), W( * ), WORK( * ),
  30 *      $                   Z( LDZ, * )
  31 *       ..
  32 *
  33 *
  34 *> \par Purpose:
  35 *  =============
  36 *>
  37 *> \verbatim
  38 *>
  39 *> DSPGV computes all the eigenvalues and, optionally, the eigenvectors
  40 *> of a real generalized symmetric-definite eigenproblem, of the form
  41 *> A*x=(lambda)*B*x,  A*Bx=(lambda)*x,  or B*A*x=(lambda)*x.
  42 *> Here A and B are assumed to be symmetric, stored in packed format,
  43 *> and B is also positive definite.
  44 *> \endverbatim
  45 *
  46 *  Arguments:
  47 *  ==========
  48 *
  49 *> \param[in] ITYPE
  50 *> \verbatim
  51 *>          ITYPE is INTEGER
  52 *>          Specifies the problem type to be solved:
  53 *>          = 1:  A*x = (lambda)*B*x
  54 *>          = 2:  A*B*x = (lambda)*x
  55 *>          = 3:  B*A*x = (lambda)*x
  56 *> \endverbatim
  57 *>
  58 *> \param[in] JOBZ
  59 *> \verbatim
  60 *>          JOBZ is CHARACTER*1
  61 *>          = 'N':  Compute eigenvalues only;
  62 *>          = 'V':  Compute eigenvalues and eigenvectors.
  63 *> \endverbatim
  64 *>
  65 *> \param[in] UPLO
  66 *> \verbatim
  67 *>          UPLO is CHARACTER*1
  68 *>          = 'U':  Upper triangles of A and B are stored;
  69 *>          = 'L':  Lower triangles of A and B are stored.
  70 *> \endverbatim
  71 *>
  72 *> \param[in] N
  73 *> \verbatim
  74 *>          N is INTEGER
  75 *>          The order of the matrices A and B.  N >= 0.
  76 *> \endverbatim
  77 *>
  78 *> \param[in,out] AP
  79 *> \verbatim
  80 *>          AP is DOUBLE PRECISION array, dimension
  81 *>                            (N*(N+1)/2)
  82 *>          On entry, the upper or lower triangle of the symmetric matrix
  83 *>          A, packed columnwise in a linear array.  The j-th column of A
  84 *>          is stored in the array AP as follows:
  85 *>          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
  86 *>          if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
  87 *>
  88 *>          On exit, the contents of AP are destroyed.
  89 *> \endverbatim
  90 *>
  91 *> \param[in,out] BP
  92 *> \verbatim
  93 *>          BP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
  94 *>          On entry, the upper or lower triangle of the symmetric matrix
  95 *>          B, packed columnwise in a linear array.  The j-th column of B
  96 *>          is stored in the array BP as follows:
  97 *>          if UPLO = 'U', BP(i + (j-1)*j/2) = B(i,j) for 1<=i<=j;
  98 *>          if UPLO = 'L', BP(i + (j-1)*(2*n-j)/2) = B(i,j) for j<=i<=n.
  99 *>
 100 *>          On exit, the triangular factor U or L from the Cholesky
 101 *>          factorization B = U**T*U or B = L*L**T, in the same storage
 102 *>          format as B.
 103 *> \endverbatim
 104 *>
 105 *> \param[out] W
 106 *> \verbatim
 107 *>          W is DOUBLE PRECISION array, dimension (N)
 108 *>          If INFO = 0, the eigenvalues in ascending order.
 109 *> \endverbatim
 110 *>
 111 *> \param[out] Z
 112 *> \verbatim
 113 *>          Z is DOUBLE PRECISION array, dimension (LDZ, N)
 114 *>          If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of
 115 *>          eigenvectors.  The eigenvectors are normalized as follows:
 116 *>          if ITYPE = 1 or 2, Z**T*B*Z = I;
 117 *>          if ITYPE = 3, Z**T*inv(B)*Z = I.
 118 *>          If JOBZ = 'N', then Z is not referenced.
 119 *> \endverbatim
 120 *>
 121 *> \param[in] LDZ
 122 *> \verbatim
 123 *>          LDZ is INTEGER
 124 *>          The leading dimension of the array Z.  LDZ >= 1, and if
 125 *>          JOBZ = 'V', LDZ >= max(1,N).
 126 *> \endverbatim
 127 *>
 128 *> \param[out] WORK
 129 *> \verbatim
 130 *>          WORK is DOUBLE PRECISION array, dimension (3*N)
 131 *> \endverbatim
 132 *>
 133 *> \param[out] INFO
 134 *> \verbatim
 135 *>          INFO is INTEGER
 136 *>          = 0:  successful exit
 137 *>          < 0:  if INFO = -i, the i-th argument had an illegal value
 138 *>          > 0:  DPPTRF or DSPEV returned an error code:
 139 *>             <= N:  if INFO = i, DSPEV failed to converge;
 140 *>                    i off-diagonal elements of an intermediate
 141 *>                    tridiagonal form did not converge to zero.
 142 *>             > N:   if INFO = n + i, for 1 <= i <= n, then the leading
 143 *>                    minor of order i of B is not positive definite.
 144 *>                    The factorization of B could not be completed and
 145 *>                    no eigenvalues or eigenvectors were computed.
 146 *> \endverbatim
 147 *
 148 *  Authors:
 149 *  ========
 150 *
 151 *> \author Univ. of Tennessee
 152 *> \author Univ. of California Berkeley
 153 *> \author Univ. of Colorado Denver
 154 *> \author NAG Ltd.
 155 *
 156 *> \date November 2015
 157 *
 158 *> \ingroup doubleOTHEReigen
 159 *
 160 *  =====================================================================
 161       SUBROUTINE DSPGV( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
 162      $                  INFO )
 163 *
 164 *  -- LAPACK driver routine (version 3.6.0) --
 165 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 166 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 167 *     November 2015
 168 *
 169 *     .. Scalar Arguments ..
 170       CHARACTER          JOBZ, UPLO
 171       INTEGER            INFO, ITYPE, LDZ, N
 172 *     ..
 173 *     .. Array Arguments ..
 174       DOUBLE PRECISION   AP( * ), BP( * ), W( * ), WORK( * ),
 175      $                   Z( LDZ, * )
 176 *     ..
 177 *
 178 *  =====================================================================
 179 *
 180 *     .. Local Scalars ..
 181       LOGICAL            UPPER, WANTZ
 182       CHARACTER          TRANS
 183       INTEGER            J, NEIG
 184 *     ..
 185 *     .. External Functions ..
 186       LOGICAL            LSAME
 187       EXTERNAL           LSAME
 188 *     ..
 189 *     .. External Subroutines ..
 190       EXTERNAL           DPPTRF, DSPEV, DSPGST, DTPMV, DTPSV, XERBLA
 191 *     ..
 192 *     .. Executable Statements ..
 193 *
 194 *     Test the input parameters.
 195 *
 196       WANTZ = LSAME( JOBZ, 'V' )
 197       UPPER = LSAME( UPLO, 'U' )
 198 *
 199       INFO = 0
 200       IF( ITYPE.LT.1 .OR. ITYPE.GT.3 ) THEN
 201          INFO = -1
 202       ELSE IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
 203          INFO = -2
 204       ELSE IF( .NOT.( UPPER .OR. LSAME( UPLO, 'L' ) ) ) THEN
 205          INFO = -3
 206       ELSE IF( N.LT.0 ) THEN
 207          INFO = -4
 208       ELSE IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
 209          INFO = -9
 210       END IF
 211       IF( INFO.NE.0 ) THEN
 212          CALL XERBLA( 'DSPGV ', -INFO )
 213          RETURN
 214       END IF
 215 *
 216 *     Quick return if possible
 217 *
 218       IF( N.EQ.0 )
 219      $   RETURN
 220 *
 221 *     Form a Cholesky factorization of B.
 222 *
 223       CALL DPPTRF( UPLO, N, BP, INFO )
 224       IF( INFO.NE.0 ) THEN
 225          INFO = N + INFO
 226          RETURN
 227       END IF
 228 *
 229 *     Transform problem to standard eigenvalue problem and solve.
 230 *
 231       CALL DSPGST( ITYPE, UPLO, N, AP, BP, INFO )
 232       CALL DSPEV( JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, INFO )
 233 *
 234       IF( WANTZ ) THEN
 235 *
 236 *        Backtransform eigenvectors to the original problem.
 237 *
 238          NEIG = N
 239          IF( INFO.GT.0 )
 240      $      NEIG = INFO - 1
 241          IF( ITYPE.EQ.1 .OR. ITYPE.EQ.2 ) THEN
 242 *
 243 *           For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
 244 *           backtransform eigenvectors: x = inv(L)**T*y or inv(U)*y
 245 *
 246             IF( UPPER ) THEN
 247                TRANS = 'N'
 248             ELSE
 249                TRANS = 'T'
 250             END IF
 251 *
 252             DO 10 J = 1, NEIG
 253                CALL DTPSV( UPLO, TRANS, 'Non-unit', N, BP, Z( 1, J ),
 254      $                     1 )
 255    10       CONTINUE
 256 *
 257          ELSE IF( ITYPE.EQ.3 ) THEN
 258 *
 259 *           For B*A*x=(lambda)*x;
 260 *           backtransform eigenvectors: x = L*y or U**T*y
 261 *
 262             IF( UPPER ) THEN
 263                TRANS = 'T'
 264             ELSE
 265                TRANS = 'N'
 266             END IF
 267 *
 268             DO 20 J = 1, NEIG
 269                CALL DTPMV( UPLO, TRANS, 'Non-unit', N, BP, Z( 1, J ),
 270      $                     1 )
 271    20       CONTINUE
 272          END IF
 273       END IF
 274       RETURN
 275 *
 276 *     End of DSPGV
 277 *
 278       END