SRC/dpptri.f

   1       SUBROUTINE DPPTRI( UPLO, N, AP, INFO )
   2 *
   3 *  -- LAPACK routine (version 3.2) --
   4 *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
   5 *     November 2006
   6 *
   7 *     .. Scalar Arguments ..
   8       CHARACTER          UPLO
   9       INTEGER            INFO, N
  10 *     ..
  11 *     .. Array Arguments ..
  12       DOUBLE PRECISION   AP( * )
  13 *     ..
  14 *
  15 *  Purpose
  16 *  =======
  17 *
  18 *  DPPTRI computes the inverse of a real symmetric positive definite
  19 *  matrix A using the Cholesky factorization A = U**T*U or A = L*L**T
  20 *  computed by DPPTRF.
  21 *
  22 *  Arguments
  23 *  =========
  24 *
  25 *  UPLO    (input) CHARACTER*1
  26 *          = 'U':  Upper triangular factor is stored in AP;
  27 *          = 'L':  Lower triangular factor is stored in AP.
  28 *
  29 *  N       (input) INTEGER
  30 *          The order of the matrix A.  N >= 0.
  31 *
  32 *  AP      (input/output) DOUBLE PRECISION array, dimension (N*(N+1)/2)
  33 *          On entry, the triangular factor U or L from the Cholesky
  34 *          factorization A = U**T*U or A = L*L**T, packed columnwise as
  35 *          a linear array.  The j-th column of U or L is stored in the
  36 *          array AP as follows:
  37 *          if UPLO = 'U', AP(i + (j-1)*j/2) = U(i,j) for 1<=i<=j;
  38 *          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = L(i,j) for j<=i<=n.
  39 *
  40 *          On exit, the upper or lower triangle of the (symmetric)
  41 *          inverse of A, overwriting the input factor U or L.
  42 *
  43 *  INFO    (output) INTEGER
  44 *          = 0:  successful exit
  45 *          < 0:  if INFO = -i, the i-th argument had an illegal value
  46 *          > 0:  if INFO = i, the (i,i) element of the factor U or L is
  47 *                zero, and the inverse could not be computed.
  48 *
  49 *  =====================================================================
  50 *
  51 *     .. Parameters ..
  52       DOUBLE PRECISION   ONE
  53       PARAMETER          ( ONE = 1.0D+0 )
  54 *     ..
  55 *     .. Local Scalars ..
  56       LOGICAL            UPPER
  57       INTEGER            J, JC, JJ, JJN
  58       DOUBLE PRECISION   AJJ
  59 *     ..
  60 *     .. External Functions ..
  61       LOGICAL            LSAME
  62       DOUBLE PRECISION   DDOT
  63       EXTERNAL           LSAME, DDOT
  64 *     ..
  65 *     .. External Subroutines ..
  66       EXTERNAL           DSCAL, DSPR, DTPMV, DTPTRI, XERBLA
  67 *     ..
  68 *     .. Executable Statements ..
  69 *
  70 *     Test the input parameters.
  71 *
  72       INFO = 0
  73       UPPER = LSAME( UPLO, 'U' )
  74       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
  75          INFO = -1
  76       ELSE IF( N.LT.0 ) THEN
  77          INFO = -2
  78       END IF
  79       IF( INFO.NE.0 ) THEN
  80          CALL XERBLA( 'DPPTRI', -INFO )
  81          RETURN
  82       END IF
  83 *
  84 *     Quick return if possible
  85 *
  86       IF( N.EQ.0 )
  87      $   RETURN
  88 *
  89 *     Invert the triangular Cholesky factor U or L.
  90 *
  91       CALL DTPTRI( UPLO, 'Non-unit', N, AP, INFO )
  92       IF( INFO.GT.0 )
  93      $   RETURN
  94 *
  95       IF( UPPER ) THEN
  96 *
  97 *        Compute the product inv(U) * inv(U)'.
  98 *
  99          JJ = 0
 100          DO 10 J = 1, N
 101             JC = JJ + 1
 102             JJ = JJ + J
 103             IF( J.GT.1 )
 104      $         CALL DSPR( 'Upper', J-1, ONE, AP( JC ), 1, AP )
 105             AJJ = AP( JJ )
 106             CALL DSCAL( J, AJJ, AP( JC ), 1 )
 107    10    CONTINUE
 108 *
 109       ELSE
 110 *
 111 *        Compute the product inv(L)' * inv(L).
 112 *
 113          JJ = 1
 114          DO 20 J = 1, N
 115             JJN = JJ + N - J + 1
 116             AP( JJ ) = DDOT( N-J+1, AP( JJ ), 1, AP( JJ ), 1 )
 117             IF( J.LT.N )
 118      $         CALL DTPMV( 'Lower', 'Transpose', 'Non-unit', N-J,
 119      $                     AP( JJN ), AP( JJ+1 ), 1 )
 120             JJ = JJN
 121    20    CONTINUE
 122       END IF
 123 *
 124       RETURN
 125 *
 126 *     End of DPPTRI
 127 *
 128       END