SRC/dlamtsqr.f

   1 *
   2 *  Definition:
   3 *  ===========
   4 *
   5 *      SUBROUTINE DLAMTSQR( SIDE, TRANS, M, N, K, MB, NB, A, LDA, T,
   6 *     $                     LDT, C, LDC, WORK, LWORK, INFO )
   7 *
   8 *
   9 *     .. Scalar Arguments ..
  10 *      CHARACTER         SIDE, TRANS
  11 *      INTEGER           INFO, LDA, M, N, K, MB, NB, LDT, LWORK, LDC
  12 *     ..
  13 *     .. Array Arguments ..
  14 *      DOUBLE        A( LDA, * ), WORK( * ), C(LDC, * ),
  15 *     $                  T( LDT, * )
  16 *> \par Purpose:
  17 *  =============
  18 *>
  19 *> \verbatim
  20 *>
  21 *>      DLAMTSQR overwrites the general real M-by-N matrix C with
  22 *>
  23 *>
  24 *>                 SIDE = 'L'     SIDE = 'R'
  25 *> TRANS = 'N':      Q * C          C * Q
  26 *> TRANS = 'T':      Q**T * C       C * Q**T
  27 *>      where Q is a real orthogonal matrix defined as the product
  28 *>      of blocked elementary reflectors computed by tall skinny
  29 *>      QR factorization (DLATSQR)
  30 *> \endverbatim
  31 *
  32 *  Arguments:
  33 *  ==========
  34 *
  35 *> \param[in] SIDE
  36 *>          SIDE is CHARACTER*1
  37 *>          = 'L': apply Q or Q**T from the Left;
  38 *>          = 'R': apply Q or Q**T from the Right.
  39 *>
  40 *> \param[in] TRANS
  41 *>          TRANS is CHARACTER*1
  42 *>          = 'N':  No transpose, apply Q;
  43 *>          = 'T':  Transpose, apply Q**T.
  44 *> \param[in] M
  45 *> \verbatim
  46 *>          M is INTEGER
  47 *>          The number of rows of the matrix A.  M >=0.
  48 *> \endverbatim
  49 *>
  50 *> \param[in] N
  51 *> \verbatim
  52 *>          N is INTEGER
  53 *>          The number of columns of the matrix C. M >= N >= 0.
  54 *> \endverbatim
  55 *>
  56 *> \param[in] K
  57 *> \verbatim
  58 *>          K is INTEGER
  59 *>          The number of elementary reflectors whose product defines
  60 *>          the matrix Q.
  61 *>          N >= K >= 0;
  62 *>
  63 *> \endverbatim
  64 *>
  65 *> \param[in] MB
  66 *> \verbatim
  67 *>          MB is INTEGER
  68 *>          The block size to be used in the blocked QR.
  69 *>          MB > N. (must be the same as DLATSQR)
  70 *> \endverbatim
  71 *>
  72 *> \param[in] NB
  73 *> \verbatim
  74 *>          NB is INTEGER
  75 *>          The column block size to be used in the blocked QR.
  76 *>          N >= NB >= 1.
  77 *> \endverbatim
  78 *>
  79 *> \param[in,out] A
  80 *> \verbatim
  81 *>          A is DOUBLE PRECISION array, dimension (LDA,K)
  82 *>          The i-th column must contain the vector which defines the
  83 *>          blockedelementary reflector H(i), for i = 1,2,...,k, as
  84 *>          returned by DLATSQR in the first k columns of
  85 *>          its array argument A.
  86 *> \endverbatim
  87 *>
  88 *> \param[in] LDA
  89 *> \verbatim
  90 *>          LDA is INTEGER
  91 *>          The leading dimension of the array A.
  92 *>          If SIDE = 'L', LDA >= max(1,M);
  93 *>          if SIDE = 'R', LDA >= max(1,N).
  94 *> \endverbatim
  95 *>
  96 *> \param[in] T
  97 *> \verbatim
  98 *>          T is DOUBLE PRECISION array, dimension
  99 *>          ( N * Number of blocks(CEIL(M-K/MB-K)),
 100 *>          The blocked upper triangular block reflectors stored in compact form
 101 *>          as a sequence of upper triangular blocks.  See below
 102 *>          for further details.
 103 *> \endverbatim
 104 *>
 105 *> \param[in] LDT
 106 *> \verbatim
 107 *>          LDT is INTEGER
 108 *>          The leading dimension of the array T.  LDT >= NB.
 109 *> \endverbatim
 110 *>
 111 *> \param[in,out] C
 112 *>          C is DOUBLE PRECISION array, dimension (LDC,N)
 113 *>          On entry, the M-by-N matrix C.
 114 *>          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
 115 *> \param[in] LDC
 116 *>          LDC is INTEGER
 117 *>          The leading dimension of the array C. LDC >= max(1,M).
 118 *>
 119 *> \param[out] WORK
 120 *> \verbatim
 121 *>         (workspace) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
 122 *>
 123 *> \endverbatim
 124 *> \param[in] LWORK
 125 *> \verbatim
 126 *>          LWORK is INTEGER
 127 *>          The dimension of the array WORK.
 128 *>
 129 *>          If SIDE = 'L', LWORK >= max(1,N)*NB;
 130 *>          if SIDE = 'R', LWORK >= max(1,MB)*NB.
 131 *>          If LWORK = -1, then a workspace query is assumed; the routine
 132 *>          only calculates the optimal size of the WORK array, returns
 133 *>          this value as the first entry of the WORK array, and no error
 134 *>          message related to LWORK is issued by XERBLA.
 135 *>
 136 *> \endverbatim
 137 *> \param[out] INFO
 138 *> \verbatim
 139 *>          INFO is INTEGER
 140 *>          = 0:  successful exit
 141 *>          < 0:  if INFO = -i, the i-th argument had an illegal value
 142 *> \endverbatim
 143 *
 144 *  Authors:
 145 *  ========
 146 *
 147 *> \author Univ. of Tennessee
 148 *> \author Univ. of California Berkeley
 149 *> \author Univ. of Colorado Denver
 150 *> \author NAG Ltd.
 151 *
 152 *> \par Further Details:
 153 *  =====================
 154 *>
 155 *> \verbatim
 156 *> Tall-Skinny QR (TSQR) performs QR by a sequence of orthogonal transformations,
 157 *> representing Q as a product of other orthogonal matrices
 158 *>   Q = Q(1) * Q(2) * . . . * Q(k)
 159 *> where each Q(i) zeros out subdiagonal entries of a block of MB rows of A:
 160 *>   Q(1) zeros out the subdiagonal entries of rows 1:MB of A
 161 *>   Q(2) zeros out the bottom MB-N rows of rows [1:N,MB+1:2*MB-N] of A
 162 *>   Q(3) zeros out the bottom MB-N rows of rows [1:N,2*MB-N+1:3*MB-2*N] of A
 163 *>   . . .
 164 *>
 165 *> Q(1) is computed by GEQRT, which represents Q(1) by Householder vectors
 166 *> stored under the diagonal of rows 1:MB of A, and by upper triangular
 167 *> block reflectors, stored in array T(1:LDT,1:N).
 168 *> For more information see Further Details in GEQRT.
 169 *>
 170 *> Q(i) for i>1 is computed by TPQRT, which represents Q(i) by Householder vectors
 171 *> stored in rows [(i-1)*(MB-N)+N+1:i*(MB-N)+N] of A, and by upper triangular
 172 *> block reflectors, stored in array T(1:LDT,(i-1)*N+1:i*N).
 173 *> The last Q(k) may use fewer rows.
 174 *> For more information see Further Details in TPQRT.
 175 *>
 176 *> For more details of the overall algorithm, see the description of
 177 *> Sequential TSQR in Section 2.2 of [1].
 178 *>
 179 *> [1] “Communication-Optimal Parallel and Sequential QR and LU Factorizations,”
 180 *>     J. Demmel, L. Grigori, M. Hoemmen, J. Langou,
 181 *>     SIAM J. Sci. Comput, vol. 34, no. 1, 2012
 182 *> \endverbatim
 183 *>
 184 *  =====================================================================
 185       SUBROUTINE DLAMTSQR( SIDE, TRANS, M, N, K, MB, NB, A, LDA, T,
 186      $        LDT, C, LDC, WORK, LWORK, INFO )
 187 *
 188 *  -- LAPACK computational routine (version 3.5.0) --
 189 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 190 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 191 *     November 2013
 192 *
 193 *     .. Scalar Arguments ..
 194       CHARACTER         SIDE, TRANS
 195       INTEGER           INFO, LDA, M, N, K, MB, NB, LDT, LWORK, LDC
 196 *     ..
 197 *     .. Array Arguments ..
 198       DOUBLE PRECISION A( LDA, * ), WORK( * ), C(LDC, * ),
 199      $                T( LDT, * )
 200 *     ..
 201 *
 202 * =====================================================================
 203 *
 204 *     ..
 205 *     .. Local Scalars ..
 206       LOGICAL    LEFT, RIGHT, TRAN, NOTRAN, LQUERY
 207       INTEGER    I, II, KK, LW, CTR
 208 *     ..
 209 *     .. External Functions ..
 210       LOGICAL            LSAME
 211       EXTERNAL           LSAME
 212 *     .. External Subroutines ..
 213       EXTERNAL           DGEMQRT, DTPMQRT, XERBLA
 214 *     ..
 215 *     .. Executable Statements ..
 216 *
 217 *     Test the input arguments
 218 *
 219       LQUERY  = LWORK.LT.0
 220       NOTRAN  = LSAME( TRANS, 'N' )
 221       TRAN    = LSAME( TRANS, 'T' )
 222       LEFT    = LSAME( SIDE, 'L' )
 223       RIGHT   = LSAME( SIDE, 'R' )
 224       IF (LEFT) THEN
 225         LW = N * NB
 226       ELSE
 227         LW = MB * NB
 228       END IF
 229 *
 230       INFO = 0
 231       IF( .NOT.LEFT .AND. .NOT.RIGHT ) THEN
 232          INFO = -1
 233       ELSE IF( .NOT.TRAN .AND. .NOT.NOTRAN ) THEN
 234          INFO = -2
 235       ELSE IF( M.LT.0 ) THEN
 236         INFO = -3
 237       ELSE IF( N.LT.0 ) THEN
 238         INFO = -4
 239       ELSE IF( K.LT.0 ) THEN
 240         INFO = -5
 241       ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
 242         INFO = -9
 243       ELSE IF( LDT.LT.MAX( 1, NB) ) THEN
 244         INFO = -11
 245       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
 246          INFO = -13
 247       ELSE IF(( LWORK.LT.MAX(1,LW)).AND.(.NOT.LQUERY)) THEN
 248         INFO = -15
 249       END IF
 250 *
 251 *     Determine the block size if it is tall skinny or short and wide
 252 *
 253       IF( INFO.EQ.0)  THEN
 254           WORK(1) = LW
 255       END IF
 256       IF( INFO.NE.0 ) THEN
 257         CALL XERBLA( 'DLAMTSQR', -INFO )
 258         RETURN
 259       ELSE IF (LQUERY) THEN
 260        RETURN
 261       END IF
 262 *
 263 *     Quick return if possible
 264 *
 265       IF( MIN(M,N,K).EQ.0 ) THEN
 266         RETURN
 267       END IF
 268 *
 269       IF((MB.LE.K).OR.(MB.GE.MAX(M,N,K))) THEN
 270         CALL DGEMQRT( SIDE, TRANS, M, N, K, NB, A, LDA,
 271      $        T, LDT, C, LDC, WORK, INFO)
 272         RETURN
 273        END IF
 274 *
 275       IF(LEFT.AND.NOTRAN) THEN
 276 *
 277 *         Multiply Q to the last block of C
 278 *
 279          KK = MOD((M-K),(MB-K))
 280          CTR = (M-K)/(MB-K)
 281          IF (KK.GT.0) THEN
 282            II=M-KK+1
 283            CALL DTPMQRT('L','N',KK , N, K, 0, NB, A(II,1), LDA,
 284      $       T(1,CTR*K+1),LDT , C(1,1), LDC,
 285      $       C(II,1), LDC, WORK, INFO )
 286          ELSE
 287            II=M+1
 288          END IF
 289 *
 290          DO I=II-(MB-K),MB+1,-(MB-K)
 291 *
 292 *         Multiply Q to the current block of C (I:I+MB,1:N)
 293 *
 294            CTR = CTR - 1
 295            CALL DTPMQRT('L','N',MB-K , N, K, 0,NB, A(I,1), LDA,
 296      $         T(1,CTR*K+1),LDT, C(1,1), LDC,
 297      $         C(I,1), LDC, WORK, INFO )
 298 *
 299          END DO
 300 *
 301 *         Multiply Q to the first block of C (1:MB,1:N)
 302 *
 303          CALL DGEMQRT('L','N',MB , N, K, NB, A(1,1), LDA, T
 304      $            ,LDT ,C(1,1), LDC, WORK, INFO )
 305 *
 306       ELSE IF (LEFT.AND.TRAN) THEN
 307 *
 308 *         Multiply Q to the first block of C
 309 *
 310          KK = MOD((M-K),(MB-K))
 311          II=M-KK+1
 312          CTR = 1
 313          CALL DGEMQRT('L','T',MB , N, K, NB, A(1,1), LDA, T
 314      $            ,LDT ,C(1,1), LDC, WORK, INFO )
 315 *
 316          DO I=MB+1,II-MB+K,(MB-K)
 317 *
 318 *         Multiply Q to the current block of C (I:I+MB,1:N)
 319 *
 320           CALL DTPMQRT('L','T',MB-K , N, K, 0,NB, A(I,1), LDA,
 321      $       T(1,CTR * K + 1),LDT, C(1,1), LDC,
 322      $       C(I,1), LDC, WORK, INFO )
 323           CTR = CTR + 1
 324 *
 325          END DO
 326          IF(II.LE.M) THEN
 327 *
 328 *         Multiply Q to the last block of C
 329 *
 330           CALL DTPMQRT('L','T',KK , N, K, 0,NB, A(II,1), LDA,
 331      $      T(1,CTR * K + 1), LDT, C(1,1), LDC,
 332      $      C(II,1), LDC, WORK, INFO )
 333 *
 334          END IF
 335 *
 336       ELSE IF(RIGHT.AND.TRAN) THEN
 337 *
 338 *         Multiply Q to the last block of C
 339 *
 340           KK = MOD((N-K),(MB-K))
 341           CTR = (N-K)/(MB-K)
 342           IF (KK.GT.0) THEN
 343             II=N-KK+1
 344             CALL DTPMQRT('R','T',M , KK, K, 0, NB, A(II,1), LDA,
 345      $        T(1,CTR*K+1), LDT, C(1,1), LDC,
 346      $        C(1,II), LDC, WORK, INFO )
 347           ELSE
 348             II=N+1
 349           END IF
 350 *
 351           DO I=II-(MB-K),MB+1,-(MB-K)
 352 *
 353 *         Multiply Q to the current block of C (1:M,I:I+MB)
 354 *
 355              CTR = CTR - 1
 356              CALL DTPMQRT('R','T',M , MB-K, K, 0,NB, A(I,1), LDA,
 357      $          T(1,CTR*K+1), LDT, C(1,1), LDC,
 358      $          C(1,I), LDC, WORK, INFO )
 359 *
 360           END DO
 361 *
 362 *         Multiply Q to the first block of C (1:M,1:MB)
 363 *
 364           CALL DGEMQRT('R','T',M , MB, K, NB, A(1,1), LDA, T
 365      $              ,LDT ,C(1,1), LDC, WORK, INFO )
 366 *
 367       ELSE IF (RIGHT.AND.NOTRAN) THEN
 368 *
 369 *         Multiply Q to the first block of C
 370 *
 371          KK = MOD((N-K),(MB-K))
 372          II=N-KK+1
 373          CTR = 1
 374          CALL DGEMQRT('R','N', M, MB , K, NB, A(1,1), LDA, T
 375      $              ,LDT ,C(1,1), LDC, WORK, INFO )
 376 *
 377          DO I=MB+1,II-MB+K,(MB-K)
 378 *
 379 *         Multiply Q to the current block of C (1:M,I:I+MB)
 380 *
 381           CALL DTPMQRT('R','N', M, MB-K, K, 0,NB, A(I,1), LDA,
 382      $         T(1, CTR * K + 1),LDT, C(1,1), LDC,
 383      $         C(1,I), LDC, WORK, INFO )
 384           CTR = CTR + 1
 385 *
 386          END DO
 387          IF(II.LE.N) THEN
 388 *
 389 *         Multiply Q to the last block of C
 390 *
 391           CALL DTPMQRT('R','N', M, KK , K, 0,NB, A(II,1), LDA,
 392      $        T(1, CTR * K + 1),LDT, C(1,1), LDC,
 393      $        C(1,II), LDC, WORK, INFO )
 394 *
 395          END IF
 396 *
 397       END IF
 398 *
 399       WORK(1) = LW
 400       RETURN
 401 *
 402 *     End of DLAMTSQR
 403 *
 404       END