SRC/cunmqr.f

   1 *> \brief \b CUNMQR
   2 *
   3 *  =========== DOCUMENTATION ===========
   4 *
   5 * Online html documentation available at
   6 *            http://www.netlib.org/lapack/explore-html/
   7 *
   8 *> \htmlonly
   9 *> Download CUNMQR + dependencies
  10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cunmqr.f">
  11 *> [TGZ]</a>
  12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cunmqr.f">
  13 *> [ZIP]</a>
  14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cunmqr.f">
  15 *> [TXT]</a>
  16 *> \endhtmlonly
  17 *
  18 *  Definition:
  19 *  ===========
  20 *
  21 *       SUBROUTINE CUNMQR( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
  22 *                          WORK, LWORK, INFO )
  23 *
  24 *       .. Scalar Arguments ..
  25 *       CHARACTER          SIDE, TRANS
  26 *       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
  27 *       ..
  28 *       .. Array Arguments ..
  29 *       COMPLEX            A( LDA, * ), C( LDC, * ), TAU( * ),
  30 *      $                   WORK( * )
  31 *       ..
  32 *
  33 *
  34 *> \par Purpose:
  35 *  =============
  36 *>
  37 *> \verbatim
  38 *>
  39 *> CUNMQR overwrites the general complex M-by-N matrix C with
  40 *>
  41 *>                 SIDE = 'L'     SIDE = 'R'
  42 *> TRANS = 'N':      Q * C          C * Q
  43 *> TRANS = 'C':      Q**H * C       C * Q**H
  44 *>
  45 *> where Q is a complex unitary matrix defined as the product of k
  46 *> elementary reflectors
  47 *>
  48 *>       Q = H(1) H(2) . . . H(k)
  49 *>
  50 *> as returned by CGEQRF. Q is of order M if SIDE = 'L' and of order N
  51 *> if SIDE = 'R'.
  52 *> \endverbatim
  53 *
  54 *  Arguments:
  55 *  ==========
  56 *
  57 *> \param[in] SIDE
  58 *> \verbatim
  59 *>          SIDE is CHARACTER*1
  60 *>          = 'L': apply Q or Q**H from the Left;
  61 *>          = 'R': apply Q or Q**H from the Right.
  62 *> \endverbatim
  63 *>
  64 *> \param[in] TRANS
  65 *> \verbatim
  66 *>          TRANS is CHARACTER*1
  67 *>          = 'N':  No transpose, apply Q;
  68 *>          = 'C':  Conjugate transpose, apply Q**H.
  69 *> \endverbatim
  70 *>
  71 *> \param[in] M
  72 *> \verbatim
  73 *>          M is INTEGER
  74 *>          The number of rows of the matrix C. M >= 0.
  75 *> \endverbatim
  76 *>
  77 *> \param[in] N
  78 *> \verbatim
  79 *>          N is INTEGER
  80 *>          The number of columns of the matrix C. N >= 0.
  81 *> \endverbatim
  82 *>
  83 *> \param[in] K
  84 *> \verbatim
  85 *>          K is INTEGER
  86 *>          The number of elementary reflectors whose product defines
  87 *>          the matrix Q.
  88 *>          If SIDE = 'L', M >= K >= 0;
  89 *>          if SIDE = 'R', N >= K >= 0.
  90 *> \endverbatim
  91 *>
  92 *> \param[in] A
  93 *> \verbatim
  94 *>          A is COMPLEX array, dimension (LDA,K)
  95 *>          The i-th column must contain the vector which defines the
  96 *>          elementary reflector H(i), for i = 1,2,...,k, as returned by
  97 *>          CGEQRF in the first k columns of its array argument A.
  98 *> \endverbatim
  99 *>
 100 *> \param[in] LDA
 101 *> \verbatim
 102 *>          LDA is INTEGER
 103 *>          The leading dimension of the array A.
 104 *>          If SIDE = 'L', LDA >= max(1,M);
 105 *>          if SIDE = 'R', LDA >= max(1,N).
 106 *> \endverbatim
 107 *>
 108 *> \param[in] TAU
 109 *> \verbatim
 110 *>          TAU is COMPLEX array, dimension (K)
 111 *>          TAU(i) must contain the scalar factor of the elementary
 112 *>          reflector H(i), as returned by CGEQRF.
 113 *> \endverbatim
 114 *>
 115 *> \param[in,out] C
 116 *> \verbatim
 117 *>          C is COMPLEX array, dimension (LDC,N)
 118 *>          On entry, the M-by-N matrix C.
 119 *>          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
 120 *> \endverbatim
 121 *>
 122 *> \param[in] LDC
 123 *> \verbatim
 124 *>          LDC is INTEGER
 125 *>          The leading dimension of the array C. LDC >= max(1,M).
 126 *> \endverbatim
 127 *>
 128 *> \param[out] WORK
 129 *> \verbatim
 130 *>          WORK is COMPLEX array, dimension (MAX(1,LWORK))
 131 *>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
 132 *> \endverbatim
 133 *>
 134 *> \param[in] LWORK
 135 *> \verbatim
 136 *>          LWORK is INTEGER
 137 *>          The dimension of the array WORK.
 138 *>          If SIDE = 'L', LWORK >= max(1,N);
 139 *>          if SIDE = 'R', LWORK >= max(1,M).
 140 *>          For good performance, LWORK should generally be larger.
 141 *>
 142 *>          If LWORK = -1, then a workspace query is assumed; the routine
 143 *>          only calculates the optimal size of the WORK array, returns
 144 *>          this value as the first entry of the WORK array, and no error
 145 *>          message related to LWORK is issued by XERBLA.
 146 *> \endverbatim
 147 *>
 148 *> \param[out] INFO
 149 *> \verbatim
 150 *>          INFO is INTEGER
 151 *>          = 0:  successful exit
 152 *>          < 0:  if INFO = -i, the i-th argument had an illegal value
 153 *> \endverbatim
 154 *
 155 *  Authors:
 156 *  ========
 157 *
 158 *> \author Univ. of Tennessee
 159 *> \author Univ. of California Berkeley
 160 *> \author Univ. of Colorado Denver
 161 *> \author NAG Ltd.
 162 *
 163 *> \date November 2015
 164 *
 165 *> \ingroup complexOTHERcomputational
 166 *
 167 *  =====================================================================
 168       SUBROUTINE CUNMQR( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
 169      $                   WORK, LWORK, INFO )
 170 *
 171 *  -- LAPACK computational routine (version 3.6.0) --
 172 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 173 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 174 *     November 2015
 175 *
 176 *     .. Scalar Arguments ..
 177       CHARACTER          SIDE, TRANS
 178       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
 179 *     ..
 180 *     .. Array Arguments ..
 181       COMPLEX            A( LDA, * ), C( LDC, * ), TAU( * ),
 182      $                   WORK( * )
 183 *     ..
 184 *
 185 *  =====================================================================
 186 *
 187 *     .. Parameters ..
 188       INTEGER            NBMAX, LDT, TSIZE
 189       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1,
 190      $                     TSIZE = LDT*NBMAX )
 191 *     ..
 192 *     .. Local Scalars ..
 193       LOGICAL            LEFT, LQUERY, NOTRAN
 194       INTEGER            I, I1, I2, I3, IB, IC, IINFO, IWT, JC, LDWORK,
 195      $                   LWKOPT, MI, NB, NBMIN, NI, NQ, NW
 196 *     ..
 197 *     .. External Functions ..
 198       LOGICAL            LSAME
 199       INTEGER            ILAENV
 200       EXTERNAL           LSAME, ILAENV
 201 *     ..
 202 *     .. External Subroutines ..
 203       EXTERNAL           CLARFB, CLARFT, CUNM2R, XERBLA
 204 *     ..
 205 *     .. Intrinsic Functions ..
 206       INTRINSIC          MAX, MIN
 207 *     ..
 208 *     .. Executable Statements ..
 209 *
 210 *     Test the input arguments
 211 *
 212       INFO = 0
 213       LEFT = LSAME( SIDE, 'L' )
 214       NOTRAN = LSAME( TRANS, 'N' )
 215       LQUERY = ( LWORK.EQ.-1 )
 216 *
 217 *     NQ is the order of Q and NW is the minimum dimension of WORK
 218 *
 219       IF( LEFT ) THEN
 220          NQ = M
 221          NW = N
 222       ELSE
 223          NQ = N
 224          NW = M
 225       END IF
 226       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
 227          INFO = -1
 228       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
 229          INFO = -2
 230       ELSE IF( M.LT.0 ) THEN
 231          INFO = -3
 232       ELSE IF( N.LT.0 ) THEN
 233          INFO = -4
 234       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
 235          INFO = -5
 236       ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
 237          INFO = -7
 238       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
 239          INFO = -10
 240       ELSE IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
 241          INFO = -12
 242       END IF
 243 *
 244       IF( INFO.EQ.0 ) THEN
 245 *
 246 *        Compute the workspace requirements
 247 *
 248          NB = MIN( NBMAX, ILAENV( 1, 'CUNMQR', SIDE // TRANS, M, N, K,
 249      $        -1 ) )
 250          LWKOPT = MAX( 1, NW )*NB + TSIZE
 251          WORK( 1 ) = LWKOPT
 252       END IF
 253 *
 254       IF( INFO.NE.0 ) THEN
 255          CALL XERBLA( 'CUNMQR', -INFO )
 256          RETURN
 257       ELSE IF( LQUERY ) THEN
 258          RETURN
 259       END IF
 260 *
 261 *     Quick return if possible
 262 *
 263       IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 ) THEN
 264          WORK( 1 ) = 1
 265          RETURN
 266       END IF
 267 *
 268       NBMIN = 2
 269       LDWORK = NW
 270       IF( NB.GT.1 .AND. NB.LT.K ) THEN
 271          IF( LWORK.LT.NW*NB+TSIZE ) THEN
 272             NB = (LWORK-TSIZE) / LDWORK
 273             NBMIN = MAX( 2, ILAENV( 2, 'CUNMQR', SIDE // TRANS, M, N, K,
 274      $              -1 ) )
 275          END IF
 276       END IF
 277 *
 278       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
 279 *
 280 *        Use unblocked code
 281 *
 282          CALL CUNM2R( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
 283      $                IINFO )
 284       ELSE
 285 *
 286 *        Use blocked code
 287 *
 288          IWT = 1 + NW*NB
 289          IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
 290      $       ( .NOT.LEFT .AND. NOTRAN ) ) THEN
 291             I1 = 1
 292             I2 = K
 293             I3 = NB
 294          ELSE
 295             I1 = ( ( K-1 ) / NB )*NB + 1
 296             I2 = 1
 297             I3 = -NB
 298          END IF
 299 *
 300          IF( LEFT ) THEN
 301             NI = N
 302             JC = 1
 303          ELSE
 304             MI = M
 305             IC = 1
 306          END IF
 307 *
 308          DO 10 I = I1, I2, I3
 309             IB = MIN( NB, K-I+1 )
 310 *
 311 *           Form the triangular factor of the block reflector
 312 *           H = H(i) H(i+1) . . . H(i+ib-1)
 313 *
 314             CALL CLARFT( 'Forward', 'Columnwise', NQ-I+1, IB, A( I, I ),
 315      $                   LDA, TAU( I ), WORK( IWT ), LDT )
 316             IF( LEFT ) THEN
 317 *
 318 *              H or H**H is applied to C(i:m,1:n)
 319 *
 320                MI = M - I + 1
 321                IC = I
 322             ELSE
 323 *
 324 *              H or H**H is applied to C(1:m,i:n)
 325 *
 326                NI = N - I + 1
 327                JC = I
 328             END IF
 329 *
 330 *           Apply H or H**H
 331 *
 332             CALL CLARFB( SIDE, TRANS, 'Forward', 'Columnwise', MI, NI,
 333      $                   IB, A( I, I ), LDA, WORK( IWT ), LDT,
 334      $                   C( IC, JC ), LDC, WORK, LDWORK )
 335    10    CONTINUE
 336       END IF
 337       WORK( 1 ) = LWKOPT
 338       RETURN
 339 *
 340 *     End of CUNMQR
 341 *
 342       END