SRC/cunbdb1.f

   1 *> \brief \b CUNBDB1
   2 *
   3 *  =========== DOCUMENTATION ===========
   4 *
   5 * Online html documentation available at
   6 *            http://www.netlib.org/lapack/explore-html/
   7 *
   8 *> \htmlonly
   9 *> Download CUNBDB1 + dependencies
  10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cunbdb1.f">
  11 *> [TGZ]</a>
  12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cunbdb1.f">
  13 *> [ZIP]</a>
  14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cunbdb1.f">
  15 *> [TXT]</a>
  16 *> \endhtmlonly
  17 *
  18 *  Definition:
  19 *  ===========
  20 *
  21 *       SUBROUTINE CUNBDB1( M, P, Q, X11, LDX11, X21, LDX21, THETA, PHI,
  22 *                           TAUP1, TAUP2, TAUQ1, WORK, LWORK, INFO )
  23 *
  24 *       .. Scalar Arguments ..
  25 *       INTEGER            INFO, LWORK, M, P, Q, LDX11, LDX21
  26 *       ..
  27 *       .. Array Arguments ..
  28 *       REAL               PHI(*), THETA(*)
  29 *       COMPLEX            TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
  30 *      $                   X11(LDX11,*), X21(LDX21,*)
  31 *       ..
  32 *
  33 *
  34 *> \par Purpose:
  35 *> =============
  36 *>
  37 *>\verbatim
  38 *>
  39 *> CUNBDB1 simultaneously bidiagonalizes the blocks of a tall and skinny
  40 *> matrix X with orthonomal columns:
  41 *>
  42 *>                            [ B11 ]
  43 *>      [ X11 ]   [ P1 |    ] [  0  ]
  44 *>      [-----] = [---------] [-----] Q1**T .
  45 *>      [ X21 ]   [    | P2 ] [ B21 ]
  46 *>                            [  0  ]
  47 *>
  48 *> X11 is P-by-Q, and X21 is (M-P)-by-Q. Q must be no larger than P,
  49 *> M-P, or M-Q. Routines CUNBDB2, CUNBDB3, and CUNBDB4 handle cases in
  50 *> which Q is not the minimum dimension.
  51 *>
  52 *> The unitary matrices P1, P2, and Q1 are P-by-P, (M-P)-by-(M-P),
  53 *> and (M-Q)-by-(M-Q), respectively. They are represented implicitly by
  54 *> Householder vectors.
  55 *>
  56 *> B11 and B12 are Q-by-Q bidiagonal matrices represented implicitly by
  57 *> angles THETA, PHI.
  58 *>
  59 *>\endverbatim
  60 *
  61 *  Arguments:
  62 *  ==========
  63 *
  64 *> \param[in] M
  65 *> \verbatim
  66 *>          M is INTEGER
  67 *>           The number of rows X11 plus the number of rows in X21.
  68 *> \endverbatim
  69 *>
  70 *> \param[in] P
  71 *> \verbatim
  72 *>          P is INTEGER
  73 *>           The number of rows in X11. 0 <= P <= M.
  74 *> \endverbatim
  75 *>
  76 *> \param[in] Q
  77 *> \verbatim
  78 *>          Q is INTEGER
  79 *>           The number of columns in X11 and X21. 0 <= Q <=
  80 *>           MIN(P,M-P,M-Q).
  81 *> \endverbatim
  82 *>
  83 *> \param[in,out] X11
  84 *> \verbatim
  85 *>          X11 is COMPLEX array, dimension (LDX11,Q)
  86 *>           On entry, the top block of the matrix X to be reduced. On
  87 *>           exit, the columns of tril(X11) specify reflectors for P1 and
  88 *>           the rows of triu(X11,1) specify reflectors for Q1.
  89 *> \endverbatim
  90 *>
  91 *> \param[in] LDX11
  92 *> \verbatim
  93 *>          LDX11 is INTEGER
  94 *>           The leading dimension of X11. LDX11 >= P.
  95 *> \endverbatim
  96 *>
  97 *> \param[in,out] X21
  98 *> \verbatim
  99 *>          X21 is COMPLEX array, dimension (LDX21,Q)
 100 *>           On entry, the bottom block of the matrix X to be reduced. On
 101 *>           exit, the columns of tril(X21) specify reflectors for P2.
 102 *> \endverbatim
 103 *>
 104 *> \param[in] LDX21
 105 *> \verbatim
 106 *>          LDX21 is INTEGER
 107 *>           The leading dimension of X21. LDX21 >= M-P.
 108 *> \endverbatim
 109 *>
 110 *> \param[out] THETA
 111 *> \verbatim
 112 *>          THETA is REAL array, dimension (Q)
 113 *>           The entries of the bidiagonal blocks B11, B21 are defined by
 114 *>           THETA and PHI. See Further Details.
 115 *> \endverbatim
 116 *>
 117 *> \param[out] PHI
 118 *> \verbatim
 119 *>          PHI is REAL array, dimension (Q-1)
 120 *>           The entries of the bidiagonal blocks B11, B21 are defined by
 121 *>           THETA and PHI. See Further Details.
 122 *> \endverbatim
 123 *>
 124 *> \param[out] TAUP1
 125 *> \verbatim
 126 *>          TAUP1 is COMPLEX array, dimension (P)
 127 *>           The scalar factors of the elementary reflectors that define
 128 *>           P1.
 129 *> \endverbatim
 130 *>
 131 *> \param[out] TAUP2
 132 *> \verbatim
 133 *>          TAUP2 is COMPLEX array, dimension (M-P)
 134 *>           The scalar factors of the elementary reflectors that define
 135 *>           P2.
 136 *> \endverbatim
 137 *>
 138 *> \param[out] TAUQ1
 139 *> \verbatim
 140 *>          TAUQ1 is COMPLEX array, dimension (Q)
 141 *>           The scalar factors of the elementary reflectors that define
 142 *>           Q1.
 143 *> \endverbatim
 144 *>
 145 *> \param[out] WORK
 146 *> \verbatim
 147 *>          WORK is COMPLEX array, dimension (LWORK)
 148 *> \endverbatim
 149 *>
 150 *> \param[in] LWORK
 151 *> \verbatim
 152 *>          LWORK is INTEGER
 153 *>           The dimension of the array WORK. LWORK >= M-Q.
 154 *>
 155 *>           If LWORK = -1, then a workspace query is assumed; the routine
 156 *>           only calculates the optimal size of the WORK array, returns
 157 *>           this value as the first entry of the WORK array, and no error
 158 *>           message related to LWORK is issued by XERBLA.
 159 *> \endverbatim
 160 *>
 161 *> \param[out] INFO
 162 *> \verbatim
 163 *>          INFO is INTEGER
 164 *>           = 0:  successful exit.
 165 *>           < 0:  if INFO = -i, the i-th argument had an illegal value.
 166 *> \endverbatim
 167 *
 168 *  Authors:
 169 *  ========
 170 *
 171 *> \author Univ. of Tennessee
 172 *> \author Univ. of California Berkeley
 173 *> \author Univ. of Colorado Denver
 174 *> \author NAG Ltd.
 175 *
 176 *> \date July 2012
 177 *
 178 *> \ingroup complexOTHERcomputational
 179 *
 180 *> \par Further Details:
 181 *  =====================
 182
 183 *> \verbatim
 184 *>
 185 *>  The upper-bidiagonal blocks B11, B21 are represented implicitly by
 186 *>  angles THETA(1), ..., THETA(Q) and PHI(1), ..., PHI(Q-1). Every entry
 187 *>  in each bidiagonal band is a product of a sine or cosine of a THETA
 188 *>  with a sine or cosine of a PHI. See [1] or CUNCSD for details.
 189 *>
 190 *>  P1, P2, and Q1 are represented as products of elementary reflectors.
 191 *>  See CUNCSD2BY1 for details on generating P1, P2, and Q1 using CUNGQR
 192 *>  and CUNGLQ.
 193 *> \endverbatim
 194 *
 195 *> \par References:
 196 *  ================
 197 *>
 198 *>  [1] Brian D. Sutton. Computing the complete CS decomposition. Numer.
 199 *>      Algorithms, 50(1):33-65, 2009.
 200 *>
 201 *  =====================================================================
 202       SUBROUTINE CUNBDB1( M, P, Q, X11, LDX11, X21, LDX21, THETA, PHI,
 203      $                    TAUP1, TAUP2, TAUQ1, WORK, LWORK, INFO )
 204 *
 205 *  -- LAPACK computational routine (version 3.6.1) --
 206 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 207 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 208 *     July 2012
 209 *
 210 *     .. Scalar Arguments ..
 211       INTEGER            INFO, LWORK, M, P, Q, LDX11, LDX21
 212 *     ..
 213 *     .. Array Arguments ..
 214       REAL               PHI(*), THETA(*)
 215       COMPLEX            TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
 216      $                   X11(LDX11,*), X21(LDX21,*)
 217 *     ..
 218 *
 219 *  ====================================================================
 220 *
 221 *     .. Parameters ..
 222       COMPLEX            ONE
 223       PARAMETER          ( ONE = (1.0E0,0.0E0) )
 224 *     ..
 225 *     .. Local Scalars ..
 226       REAL               C, S
 227       INTEGER            CHILDINFO, I, ILARF, IORBDB5, LLARF, LORBDB5,
 228      $                   LWORKMIN, LWORKOPT
 229       LOGICAL            LQUERY
 230 *     ..
 231 *     .. External Subroutines ..
 232       EXTERNAL           CLARF, CLARFGP, CUNBDB5, CSROT, XERBLA
 233       EXTERNAL           CLACGV
 234 *     ..
 235 *     .. External Functions ..
 236       REAL               SCNRM2
 237       EXTERNAL           SCNRM2
 238 *     ..
 239 *     .. Intrinsic Function ..
 240       INTRINSIC          ATAN2, COS, MAX, SIN, SQRT
 241 *     ..
 242 *     .. Executable Statements ..
 243 *
 244 *     Test input arguments
 245 *
 246       INFO = 0
 247       LQUERY = LWORK .EQ. -1
 248 *
 249       IF( M .LT. 0 ) THEN
 250          INFO = -1
 251       ELSE IF( P .LT. Q .OR. M-P .LT. Q ) THEN
 252          INFO = -2
 253       ELSE IF( Q .LT. 0 .OR. M-Q .LT. Q ) THEN
 254          INFO = -3
 255       ELSE IF( LDX11 .LT. MAX( 1, P ) ) THEN
 256          INFO = -5
 257       ELSE IF( LDX21 .LT. MAX( 1, M-P ) ) THEN
 258          INFO = -7
 259       END IF
 260 *
 261 *     Compute workspace
 262 *
 263       IF( INFO .EQ. 0 ) THEN
 264          ILARF = 2
 265          LLARF = MAX( P-1, M-P-1, Q-1 )
 266          IORBDB5 = 2
 267          LORBDB5 = Q-2
 268          LWORKOPT = MAX( ILARF+LLARF-1, IORBDB5+LORBDB5-1 )
 269          LWORKMIN = LWORKOPT
 270          WORK(1) = LWORKOPT
 271          IF( LWORK .LT. LWORKMIN .AND. .NOT.LQUERY ) THEN
 272            INFO = -14
 273          END IF
 274       END IF
 275       IF( INFO .NE. 0 ) THEN
 276          CALL XERBLA( 'CUNBDB1', -INFO )
 277          RETURN
 278       ELSE IF( LQUERY ) THEN
 279          RETURN
 280       END IF
 281 *
 282 *     Reduce columns 1, ..., Q of X11 and X21
 283 *
 284       DO I = 1, Q
 285 *
 286          CALL CLARFGP( P-I+1, X11(I,I), X11(I+1,I), 1, TAUP1(I) )
 287          CALL CLARFGP( M-P-I+1, X21(I,I), X21(I+1,I), 1, TAUP2(I) )
 288          THETA(I) = ATAN2( REAL( X21(I,I) ), REAL( X11(I,I) ) )
 289          C = COS( THETA(I) )
 290          S = SIN( THETA(I) )
 291          X11(I,I) = ONE
 292          X21(I,I) = ONE
 293          CALL CLARF( 'L', P-I+1, Q-I, X11(I,I), 1, CONJG(TAUP1(I)),
 294      $               X11(I,I+1), LDX11, WORK(ILARF) )
 295          CALL CLARF( 'L', M-P-I+1, Q-I, X21(I,I), 1, CONJG(TAUP2(I)),
 296      $               X21(I,I+1), LDX21, WORK(ILARF) )
 297 *
 298          IF( I .LT. Q ) THEN
 299             CALL CSROT( Q-I, X11(I,I+1), LDX11, X21(I,I+1), LDX21, C,
 300      $                  S )
 301             CALL CLACGV( Q-I, X21(I,I+1), LDX21 )
 302             CALL CLARFGP( Q-I, X21(I,I+1), X21(I,I+2), LDX21, TAUQ1(I) )
 303             S = REAL( X21(I,I+1) )
 304             X21(I,I+1) = ONE
 305             CALL CLARF( 'R', P-I, Q-I, X21(I,I+1), LDX21, TAUQ1(I),
 306      $                  X11(I+1,I+1), LDX11, WORK(ILARF) )
 307             CALL CLARF( 'R', M-P-I, Q-I, X21(I,I+1), LDX21, TAUQ1(I),
 308      $                  X21(I+1,I+1), LDX21, WORK(ILARF) )
 309             CALL CLACGV( Q-I, X21(I,I+1), LDX21 )
 310             C = SQRT( SCNRM2( P-I, X11(I+1,I+1), 1 )**2
 311      $              + SCNRM2( M-P-I, X21(I+1,I+1), 1 )**2 )
 312             PHI(I) = ATAN2( S, C )
 313             CALL CUNBDB5( P-I, M-P-I, Q-I-1, X11(I+1,I+1), 1,
 314      $                    X21(I+1,I+1), 1, X11(I+1,I+2), LDX11,
 315      $                    X21(I+1,I+2), LDX21, WORK(IORBDB5), LORBDB5,
 316      $                    CHILDINFO )
 317          END IF
 318 *
 319       END DO
 320 *
 321       RETURN
 322 *
 323 *     End of CUNBDB1
 324 *
 325       END
 326