SRC/chpgv.f

   1 *> \brief \b CHPGV
   2 *
   3 *  =========== DOCUMENTATION ===========
   4 *
   5 * Online html documentation available at
   6 *            http://www.netlib.org/lapack/explore-html/
   7 *
   8 *> \htmlonly
   9 *> Download CHPGV + dependencies
  10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/chpgv.f">
  11 *> [TGZ]</a>
  12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/chpgv.f">
  13 *> [ZIP]</a>
  14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/chpgv.f">
  15 *> [TXT]</a>
  16 *> \endhtmlonly
  17 *
  18 *  Definition:
  19 *  ===========
  20 *
  21 *       SUBROUTINE CHPGV( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
  22 *                         RWORK, INFO )
  23 *
  24 *       .. Scalar Arguments ..
  25 *       CHARACTER          JOBZ, UPLO
  26 *       INTEGER            INFO, ITYPE, LDZ, N
  27 *       ..
  28 *       .. Array Arguments ..
  29 *       REAL               RWORK( * ), W( * )
  30 *       COMPLEX            AP( * ), BP( * ), WORK( * ), Z( LDZ, * )
  31 *       ..
  32 *
  33 *
  34 *> \par Purpose:
  35 *  =============
  36 *>
  37 *> \verbatim
  38 *>
  39 *> CHPGV computes all the eigenvalues and, optionally, the eigenvectors
  40 *> of a complex generalized Hermitian-definite eigenproblem, of the form
  41 *> A*x=(lambda)*B*x,  A*Bx=(lambda)*x,  or B*A*x=(lambda)*x.
  42 *> Here A and B are assumed to be Hermitian, stored in packed format,
  43 *> and B is also positive definite.
  44 *> \endverbatim
  45 *
  46 *  Arguments:
  47 *  ==========
  48 *
  49 *> \param[in] ITYPE
  50 *> \verbatim
  51 *>          ITYPE is INTEGER
  52 *>          Specifies the problem type to be solved:
  53 *>          = 1:  A*x = (lambda)*B*x
  54 *>          = 2:  A*B*x = (lambda)*x
  55 *>          = 3:  B*A*x = (lambda)*x
  56 *> \endverbatim
  57 *>
  58 *> \param[in] JOBZ
  59 *> \verbatim
  60 *>          JOBZ is CHARACTER*1
  61 *>          = 'N':  Compute eigenvalues only;
  62 *>          = 'V':  Compute eigenvalues and eigenvectors.
  63 *> \endverbatim
  64 *>
  65 *> \param[in] UPLO
  66 *> \verbatim
  67 *>          UPLO is CHARACTER*1
  68 *>          = 'U':  Upper triangles of A and B are stored;
  69 *>          = 'L':  Lower triangles of A and B are stored.
  70 *> \endverbatim
  71 *>
  72 *> \param[in] N
  73 *> \verbatim
  74 *>          N is INTEGER
  75 *>          The order of the matrices A and B.  N >= 0.
  76 *> \endverbatim
  77 *>
  78 *> \param[in,out] AP
  79 *> \verbatim
  80 *>          AP is COMPLEX array, dimension (N*(N+1)/2)
  81 *>          On entry, the upper or lower triangle of the Hermitian matrix
  82 *>          A, packed columnwise in a linear array.  The j-th column of A
  83 *>          is stored in the array AP as follows:
  84 *>          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
  85 *>          if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
  86 *>
  87 *>          On exit, the contents of AP are destroyed.
  88 *> \endverbatim
  89 *>
  90 *> \param[in,out] BP
  91 *> \verbatim
  92 *>          BP is COMPLEX array, dimension (N*(N+1)/2)
  93 *>          On entry, the upper or lower triangle of the Hermitian matrix
  94 *>          B, packed columnwise in a linear array.  The j-th column of B
  95 *>          is stored in the array BP as follows:
  96 *>          if UPLO = 'U', BP(i + (j-1)*j/2) = B(i,j) for 1<=i<=j;
  97 *>          if UPLO = 'L', BP(i + (j-1)*(2*n-j)/2) = B(i,j) for j<=i<=n.
  98 *>
  99 *>          On exit, the triangular factor U or L from the Cholesky
 100 *>          factorization B = U**H*U or B = L*L**H, in the same storage
 101 *>          format as B.
 102 *> \endverbatim
 103 *>
 104 *> \param[out] W
 105 *> \verbatim
 106 *>          W is REAL array, dimension (N)
 107 *>          If INFO = 0, the eigenvalues in ascending order.
 108 *> \endverbatim
 109 *>
 110 *> \param[out] Z
 111 *> \verbatim
 112 *>          Z is COMPLEX array, dimension (LDZ, N)
 113 *>          If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of
 114 *>          eigenvectors.  The eigenvectors are normalized as follows:
 115 *>          if ITYPE = 1 or 2, Z**H*B*Z = I;
 116 *>          if ITYPE = 3, Z**H*inv(B)*Z = I.
 117 *>          If JOBZ = 'N', then Z is not referenced.
 118 *> \endverbatim
 119 *>
 120 *> \param[in] LDZ
 121 *> \verbatim
 122 *>          LDZ is INTEGER
 123 *>          The leading dimension of the array Z.  LDZ >= 1, and if
 124 *>          JOBZ = 'V', LDZ >= max(1,N).
 125 *> \endverbatim
 126 *>
 127 *> \param[out] WORK
 128 *> \verbatim
 129 *>          WORK is COMPLEX array, dimension (max(1, 2*N-1))
 130 *> \endverbatim
 131 *>
 132 *> \param[out] RWORK
 133 *> \verbatim
 134 *>          RWORK is REAL array, dimension (max(1, 3*N-2))
 135 *> \endverbatim
 136 *>
 137 *> \param[out] INFO
 138 *> \verbatim
 139 *>          INFO is INTEGER
 140 *>          = 0:  successful exit
 141 *>          < 0:  if INFO = -i, the i-th argument had an illegal value
 142 *>          > 0:  CPPTRF or CHPEV returned an error code:
 143 *>             <= N:  if INFO = i, CHPEV failed to converge;
 144 *>                    i off-diagonal elements of an intermediate
 145 *>                    tridiagonal form did not convergeto zero;
 146 *>             > N:   if INFO = N + i, for 1 <= i <= n, then the leading
 147 *>                    minor of order i of B is not positive definite.
 148 *>                    The factorization of B could not be completed and
 149 *>                    no eigenvalues or eigenvectors were computed.
 150 *> \endverbatim
 151 *
 152 *  Authors:
 153 *  ========
 154 *
 155 *> \author Univ. of Tennessee
 156 *> \author Univ. of California Berkeley
 157 *> \author Univ. of Colorado Denver
 158 *> \author NAG Ltd.
 159 *
 160 *> \date November 2015
 161 *
 162 *> \ingroup complexOTHEReigen
 163 *
 164 *  =====================================================================
 165       SUBROUTINE CHPGV( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
 166      $                  RWORK, INFO )
 167 *
 168 *  -- LAPACK driver routine (version 3.6.0) --
 169 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 170 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 171 *     November 2015
 172 *
 173 *     .. Scalar Arguments ..
 174       CHARACTER          JOBZ, UPLO
 175       INTEGER            INFO, ITYPE, LDZ, N
 176 *     ..
 177 *     .. Array Arguments ..
 178       REAL               RWORK( * ), W( * )
 179       COMPLEX            AP( * ), BP( * ), WORK( * ), Z( LDZ, * )
 180 *     ..
 181 *
 182 *  =====================================================================
 183 *
 184 *     .. Local Scalars ..
 185       LOGICAL            UPPER, WANTZ
 186       CHARACTER          TRANS
 187       INTEGER            J, NEIG
 188 *     ..
 189 *     .. External Functions ..
 190       LOGICAL            LSAME
 191       EXTERNAL           LSAME
 192 *     ..
 193 *     .. External Subroutines ..
 194       EXTERNAL           CHPEV, CHPGST, CPPTRF, CTPMV, CTPSV, XERBLA
 195 *     ..
 196 *     .. Executable Statements ..
 197 *
 198 *     Test the input parameters.
 199 *
 200       WANTZ = LSAME( JOBZ, 'V' )
 201       UPPER = LSAME( UPLO, 'U' )
 202 *
 203       INFO = 0
 204       IF( ITYPE.LT.1 .OR. ITYPE.GT.3 ) THEN
 205          INFO = -1
 206       ELSE IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
 207          INFO = -2
 208       ELSE IF( .NOT.( UPPER .OR. LSAME( UPLO, 'L' ) ) ) THEN
 209          INFO = -3
 210       ELSE IF( N.LT.0 ) THEN
 211          INFO = -4
 212       ELSE IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
 213          INFO = -9
 214       END IF
 215       IF( INFO.NE.0 ) THEN
 216          CALL XERBLA( 'CHPGV ', -INFO )
 217          RETURN
 218       END IF
 219 *
 220 *     Quick return if possible
 221 *
 222       IF( N.EQ.0 )
 223      $   RETURN
 224 *
 225 *     Form a Cholesky factorization of B.
 226 *
 227       CALL CPPTRF( UPLO, N, BP, INFO )
 228       IF( INFO.NE.0 ) THEN
 229          INFO = N + INFO
 230          RETURN
 231       END IF
 232 *
 233 *     Transform problem to standard eigenvalue problem and solve.
 234 *
 235       CALL CHPGST( ITYPE, UPLO, N, AP, BP, INFO )
 236       CALL CHPEV( JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, RWORK, INFO )
 237 *
 238       IF( WANTZ ) THEN
 239 *
 240 *        Backtransform eigenvectors to the original problem.
 241 *
 242          NEIG = N
 243          IF( INFO.GT.0 )
 244      $      NEIG = INFO - 1
 245          IF( ITYPE.EQ.1 .OR. ITYPE.EQ.2 ) THEN
 246 *
 247 *           For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
 248 *           backtransform eigenvectors: x = inv(L)**H*y or inv(U)*y
 249 *
 250             IF( UPPER ) THEN
 251                TRANS = 'N'
 252             ELSE
 253                TRANS = 'C'
 254             END IF
 255 *
 256             DO 10 J = 1, NEIG
 257                CALL CTPSV( UPLO, TRANS, 'Non-unit', N, BP, Z( 1, J ),
 258      $                     1 )
 259    10       CONTINUE
 260 *
 261          ELSE IF( ITYPE.EQ.3 ) THEN
 262 *
 263 *           For B*A*x=(lambda)*x;
 264 *           backtransform eigenvectors: x = L*y or U**H*y
 265 *
 266             IF( UPPER ) THEN
 267                TRANS = 'C'
 268             ELSE
 269                TRANS = 'N'
 270             END IF
 271 *
 272             DO 20 J = 1, NEIG
 273                CALL CTPMV( UPLO, TRANS, 'Non-unit', N, BP, Z( 1, J ),
 274      $                     1 )
 275    20       CONTINUE
 276          END IF
 277       END IF
 278       RETURN
 279 *
 280 *     End of CHPGV
 281 *
 282       END