SRC/cgtrfs.f

   1 *> \brief \b CGTRFS
   2 *
   3 *  =========== DOCUMENTATION ===========
   4 *
   5 * Online html documentation available at
   6 *            http://www.netlib.org/lapack/explore-html/
   7 *
   8 *> \htmlonly
   9 *> Download CGTRFS + dependencies
  10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cgtrfs.f">
  11 *> [TGZ]</a>
  12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cgtrfs.f">
  13 *> [ZIP]</a>
  14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cgtrfs.f">
  15 *> [TXT]</a>
  16 *> \endhtmlonly
  17 *
  18 *  Definition:
  19 *  ===========
  20 *
  21 *       SUBROUTINE CGTRFS( TRANS, N, NRHS, DL, D, DU, DLF, DF, DUF, DU2,
  22 *                          IPIV, B, LDB, X, LDX, FERR, BERR, WORK, RWORK,
  23 *                          INFO )
  24 *
  25 *       .. Scalar Arguments ..
  26 *       CHARACTER          TRANS
  27 *       INTEGER            INFO, LDB, LDX, N, NRHS
  28 *       ..
  29 *       .. Array Arguments ..
  30 *       INTEGER            IPIV( * )
  31 *       REAL               BERR( * ), FERR( * ), RWORK( * )
  32 *       COMPLEX            B( LDB, * ), D( * ), DF( * ), DL( * ),
  33 *      $                   DLF( * ), DU( * ), DU2( * ), DUF( * ),
  34 *      $                   WORK( * ), X( LDX, * )
  35 *       ..
  36 *
  37 *
  38 *> \par Purpose:
  39 *  =============
  40 *>
  41 *> \verbatim
  42 *>
  43 *> CGTRFS improves the computed solution to a system of linear
  44 *> equations when the coefficient matrix is tridiagonal, and provides
  45 *> error bounds and backward error estimates for the solution.
  46 *> \endverbatim
  47 *
  48 *  Arguments:
  49 *  ==========
  50 *
  51 *> \param[in] TRANS
  52 *> \verbatim
  53 *>          TRANS is CHARACTER*1
  54 *>          Specifies the form of the system of equations:
  55 *>          = 'N':  A * X = B     (No transpose)
  56 *>          = 'T':  A**T * X = B  (Transpose)
  57 *>          = 'C':  A**H * X = B  (Conjugate transpose)
  58 *> \endverbatim
  59 *>
  60 *> \param[in] N
  61 *> \verbatim
  62 *>          N is INTEGER
  63 *>          The order of the matrix A.  N >= 0.
  64 *> \endverbatim
  65 *>
  66 *> \param[in] NRHS
  67 *> \verbatim
  68 *>          NRHS is INTEGER
  69 *>          The number of right hand sides, i.e., the number of columns
  70 *>          of the matrix B.  NRHS >= 0.
  71 *> \endverbatim
  72 *>
  73 *> \param[in] DL
  74 *> \verbatim
  75 *>          DL is COMPLEX array, dimension (N-1)
  76 *>          The (n-1) subdiagonal elements of A.
  77 *> \endverbatim
  78 *>
  79 *> \param[in] D
  80 *> \verbatim
  81 *>          D is COMPLEX array, dimension (N)
  82 *>          The diagonal elements of A.
  83 *> \endverbatim
  84 *>
  85 *> \param[in] DU
  86 *> \verbatim
  87 *>          DU is COMPLEX array, dimension (N-1)
  88 *>          The (n-1) superdiagonal elements of A.
  89 *> \endverbatim
  90 *>
  91 *> \param[in] DLF
  92 *> \verbatim
  93 *>          DLF is COMPLEX array, dimension (N-1)
  94 *>          The (n-1) multipliers that define the matrix L from the
  95 *>          LU factorization of A as computed by CGTTRF.
  96 *> \endverbatim
  97 *>
  98 *> \param[in] DF
  99 *> \verbatim
 100 *>          DF is COMPLEX array, dimension (N)
 101 *>          The n diagonal elements of the upper triangular matrix U from
 102 *>          the LU factorization of A.
 103 *> \endverbatim
 104 *>
 105 *> \param[in] DUF
 106 *> \verbatim
 107 *>          DUF is COMPLEX array, dimension (N-1)
 108 *>          The (n-1) elements of the first superdiagonal of U.
 109 *> \endverbatim
 110 *>
 111 *> \param[in] DU2
 112 *> \verbatim
 113 *>          DU2 is COMPLEX array, dimension (N-2)
 114 *>          The (n-2) elements of the second superdiagonal of U.
 115 *> \endverbatim
 116 *>
 117 *> \param[in] IPIV
 118 *> \verbatim
 119 *>          IPIV is INTEGER array, dimension (N)
 120 *>          The pivot indices; for 1 <= i <= n, row i of the matrix was
 121 *>          interchanged with row IPIV(i).  IPIV(i) will always be either
 122 *>          i or i+1; IPIV(i) = i indicates a row interchange was not
 123 *>          required.
 124 *> \endverbatim
 125 *>
 126 *> \param[in] B
 127 *> \verbatim
 128 *>          B is COMPLEX array, dimension (LDB,NRHS)
 129 *>          The right hand side matrix B.
 130 *> \endverbatim
 131 *>
 132 *> \param[in] LDB
 133 *> \verbatim
 134 *>          LDB is INTEGER
 135 *>          The leading dimension of the array B.  LDB >= max(1,N).
 136 *> \endverbatim
 137 *>
 138 *> \param[in,out] X
 139 *> \verbatim
 140 *>          X is COMPLEX array, dimension (LDX,NRHS)
 141 *>          On entry, the solution matrix X, as computed by CGTTRS.
 142 *>          On exit, the improved solution matrix X.
 143 *> \endverbatim
 144 *>
 145 *> \param[in] LDX
 146 *> \verbatim
 147 *>          LDX is INTEGER
 148 *>          The leading dimension of the array X.  LDX >= max(1,N).
 149 *> \endverbatim
 150 *>
 151 *> \param[out] FERR
 152 *> \verbatim
 153 *>          FERR is REAL array, dimension (NRHS)
 154 *>          The estimated forward error bound for each solution vector
 155 *>          X(j) (the j-th column of the solution matrix X).
 156 *>          If XTRUE is the true solution corresponding to X(j), FERR(j)
 157 *>          is an estimated upper bound for the magnitude of the largest
 158 *>          element in (X(j) - XTRUE) divided by the magnitude of the
 159 *>          largest element in X(j).  The estimate is as reliable as
 160 *>          the estimate for RCOND, and is almost always a slight
 161 *>          overestimate of the true error.
 162 *> \endverbatim
 163 *>
 164 *> \param[out] BERR
 165 *> \verbatim
 166 *>          BERR is REAL array, dimension (NRHS)
 167 *>          The componentwise relative backward error of each solution
 168 *>          vector X(j) (i.e., the smallest relative change in
 169 *>          any element of A or B that makes X(j) an exact solution).
 170 *> \endverbatim
 171 *>
 172 *> \param[out] WORK
 173 *> \verbatim
 174 *>          WORK is COMPLEX array, dimension (2*N)
 175 *> \endverbatim
 176 *>
 177 *> \param[out] RWORK
 178 *> \verbatim
 179 *>          RWORK is REAL array, dimension (N)
 180 *> \endverbatim
 181 *>
 182 *> \param[out] INFO
 183 *> \verbatim
 184 *>          INFO is INTEGER
 185 *>          = 0:  successful exit
 186 *>          < 0:  if INFO = -i, the i-th argument had an illegal value
 187 *> \endverbatim
 188 *
 189 *> \par Internal Parameters:
 190 *  =========================
 191 *>
 192 *> \verbatim
 193 *>  ITMAX is the maximum number of steps of iterative refinement.
 194 *> \endverbatim
 195 *
 196 *  Authors:
 197 *  ========
 198 *
 199 *> \author Univ. of Tennessee
 200 *> \author Univ. of California Berkeley
 201 *> \author Univ. of Colorado Denver
 202 *> \author NAG Ltd.
 203 *
 204 *> \date September 2012
 205 *
 206 *> \ingroup complexGTcomputational
 207 *
 208 *  =====================================================================
 209       SUBROUTINE CGTRFS( TRANS, N, NRHS, DL, D, DU, DLF, DF, DUF, DU2,
 210      $                   IPIV, B, LDB, X, LDX, FERR, BERR, WORK, RWORK,
 211      $                   INFO )
 212 *
 213 *  -- LAPACK computational routine (version 3.4.2) --
 214 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 215 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 216 *     September 2012
 217 *
 218 *     .. Scalar Arguments ..
 219       CHARACTER          TRANS
 220       INTEGER            INFO, LDB, LDX, N, NRHS
 221 *     ..
 222 *     .. Array Arguments ..
 223       INTEGER            IPIV( * )
 224       REAL               BERR( * ), FERR( * ), RWORK( * )
 225       COMPLEX            B( LDB, * ), D( * ), DF( * ), DL( * ),
 226      $                   DLF( * ), DU( * ), DU2( * ), DUF( * ),
 227      $                   WORK( * ), X( LDX, * )
 228 *     ..
 229 *
 230 *  =====================================================================
 231 *
 232 *     .. Parameters ..
 233       INTEGER            ITMAX
 234       PARAMETER          ( ITMAX = 5 )
 235       REAL               ZERO, ONE
 236       PARAMETER          ( ZERO = 0.0E+0, ONE = 1.0E+0 )
 237       REAL               TWO
 238       PARAMETER          ( TWO = 2.0E+0 )
 239       REAL               THREE
 240       PARAMETER          ( THREE = 3.0E+0 )
 241 *     ..
 242 *     .. Local Scalars ..
 243       LOGICAL            NOTRAN
 244       CHARACTER          TRANSN, TRANST
 245       INTEGER            COUNT, I, J, KASE, NZ
 246       REAL               EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN
 247       COMPLEX            ZDUM
 248 *     ..
 249 *     .. Local Arrays ..
 250       INTEGER            ISAVE( 3 )
 251 *     ..
 252 *     .. External Subroutines ..
 253       EXTERNAL           CAXPY, CCOPY, CGTTRS, CLACN2, CLAGTM, XERBLA
 254 *     ..
 255 *     .. Intrinsic Functions ..
 256       INTRINSIC          ABS, AIMAG, CMPLX, MAX, REAL
 257 *     ..
 258 *     .. External Functions ..
 259       LOGICAL            LSAME
 260       REAL               SLAMCH
 261       EXTERNAL           LSAME, SLAMCH
 262 *     ..
 263 *     .. Statement Functions ..
 264       REAL               CABS1
 265 *     ..
 266 *     .. Statement Function definitions ..
 267       CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
 268 *     ..
 269 *     .. Executable Statements ..
 270 *
 271 *     Test the input parameters.
 272 *
 273       INFO = 0
 274       NOTRAN = LSAME( TRANS, 'N' )
 275       IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) .AND. .NOT.
 276      $    LSAME( TRANS, 'C' ) ) THEN
 277          INFO = -1
 278       ELSE IF( N.LT.0 ) THEN
 279          INFO = -2
 280       ELSE IF( NRHS.LT.0 ) THEN
 281          INFO = -3
 282       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
 283          INFO = -13
 284       ELSE IF( LDX.LT.MAX( 1, N ) ) THEN
 285          INFO = -15
 286       END IF
 287       IF( INFO.NE.0 ) THEN
 288          CALL XERBLA( 'CGTRFS', -INFO )
 289          RETURN
 290       END IF
 291 *
 292 *     Quick return if possible
 293 *
 294       IF( N.EQ.0 .OR. NRHS.EQ.0 ) THEN
 295          DO 10 J = 1, NRHS
 296             FERR( J ) = ZERO
 297             BERR( J ) = ZERO
 298    10    CONTINUE
 299          RETURN
 300       END IF
 301 *
 302       IF( NOTRAN ) THEN
 303          TRANSN = 'N'
 304          TRANST = 'C'
 305       ELSE
 306          TRANSN = 'C'
 307          TRANST = 'N'
 308       END IF
 309 *
 310 *     NZ = maximum number of nonzero elements in each row of A, plus 1
 311 *
 312       NZ = 4
 313       EPS = SLAMCH( 'Epsilon' )
 314       SAFMIN = SLAMCH( 'Safe minimum' )
 315       SAFE1 = NZ*SAFMIN
 316       SAFE2 = SAFE1 / EPS
 317 *
 318 *     Do for each right hand side
 319 *
 320       DO 110 J = 1, NRHS
 321 *
 322          COUNT = 1
 323          LSTRES = THREE
 324    20    CONTINUE
 325 *
 326 *        Loop until stopping criterion is satisfied.
 327 *
 328 *        Compute residual R = B - op(A) * X,
 329 *        where op(A) = A, A**T, or A**H, depending on TRANS.
 330 *
 331          CALL CCOPY( N, B( 1, J ), 1, WORK, 1 )
 332          CALL CLAGTM( TRANS, N, 1, -ONE, DL, D, DU, X( 1, J ), LDX, ONE,
 333      $                WORK, N )
 334 *
 335 *        Compute abs(op(A))*abs(x) + abs(b) for use in the backward
 336 *        error bound.
 337 *
 338          IF( NOTRAN ) THEN
 339             IF( N.EQ.1 ) THEN
 340                RWORK( 1 ) = CABS1( B( 1, J ) ) +
 341      $                      CABS1( D( 1 ) )*CABS1( X( 1, J ) )
 342             ELSE
 343                RWORK( 1 ) = CABS1( B( 1, J ) ) +
 344      $                      CABS1( D( 1 ) )*CABS1( X( 1, J ) ) +
 345      $                      CABS1( DU( 1 ) )*CABS1( X( 2, J ) )
 346                DO 30 I = 2, N - 1
 347                   RWORK( I ) = CABS1( B( I, J ) ) +
 348      $                         CABS1( DL( I-1 ) )*CABS1( X( I-1, J ) ) +
 349      $                         CABS1( D( I ) )*CABS1( X( I, J ) ) +
 350      $                         CABS1( DU( I ) )*CABS1( X( I+1, J ) )
 351    30          CONTINUE
 352                RWORK( N ) = CABS1( B( N, J ) ) +
 353      $                      CABS1( DL( N-1 ) )*CABS1( X( N-1, J ) ) +
 354      $                      CABS1( D( N ) )*CABS1( X( N, J ) )
 355             END IF
 356          ELSE
 357             IF( N.EQ.1 ) THEN
 358                RWORK( 1 ) = CABS1( B( 1, J ) ) +
 359      $                      CABS1( D( 1 ) )*CABS1( X( 1, J ) )
 360             ELSE
 361                RWORK( 1 ) = CABS1( B( 1, J ) ) +
 362      $                      CABS1( D( 1 ) )*CABS1( X( 1, J ) ) +
 363      $                      CABS1( DL( 1 ) )*CABS1( X( 2, J ) )
 364                DO 40 I = 2, N - 1
 365                   RWORK( I ) = CABS1( B( I, J ) ) +
 366      $                         CABS1( DU( I-1 ) )*CABS1( X( I-1, J ) ) +
 367      $                         CABS1( D( I ) )*CABS1( X( I, J ) ) +
 368      $                         CABS1( DL( I ) )*CABS1( X( I+1, J ) )
 369    40          CONTINUE
 370                RWORK( N ) = CABS1( B( N, J ) ) +
 371      $                      CABS1( DU( N-1 ) )*CABS1( X( N-1, J ) ) +
 372      $                      CABS1( D( N ) )*CABS1( X( N, J ) )
 373             END IF
 374          END IF
 375 *
 376 *        Compute componentwise relative backward error from formula
 377 *
 378 *        max(i) ( abs(R(i)) / ( abs(op(A))*abs(X) + abs(B) )(i) )
 379 *
 380 *        where abs(Z) is the componentwise absolute value of the matrix
 381 *        or vector Z.  If the i-th component of the denominator is less
 382 *        than SAFE2, then SAFE1 is added to the i-th components of the
 383 *        numerator and denominator before dividing.
 384 *
 385          S = ZERO
 386          DO 50 I = 1, N
 387             IF( RWORK( I ).GT.SAFE2 ) THEN
 388                S = MAX( S, CABS1( WORK( I ) ) / RWORK( I ) )
 389             ELSE
 390                S = MAX( S, ( CABS1( WORK( I ) )+SAFE1 ) /
 391      $             ( RWORK( I )+SAFE1 ) )
 392             END IF
 393    50    CONTINUE
 394          BERR( J ) = S
 395 *
 396 *        Test stopping criterion. Continue iterating if
 397 *           1) The residual BERR(J) is larger than machine epsilon, and
 398 *           2) BERR(J) decreased by at least a factor of 2 during the
 399 *              last iteration, and
 400 *           3) At most ITMAX iterations tried.
 401 *
 402          IF( BERR( J ).GT.EPS .AND. TWO*BERR( J ).LE.LSTRES .AND.
 403      $       COUNT.LE.ITMAX ) THEN
 404 *
 405 *           Update solution and try again.
 406 *
 407             CALL CGTTRS( TRANS, N, 1, DLF, DF, DUF, DU2, IPIV, WORK, N,
 408      $                   INFO )
 409             CALL CAXPY( N, CMPLX( ONE ), WORK, 1, X( 1, J ), 1 )
 410             LSTRES = BERR( J )
 411             COUNT = COUNT + 1
 412             GO TO 20
 413          END IF
 414 *
 415 *        Bound error from formula
 416 *
 417 *        norm(X - XTRUE) / norm(X) .le. FERR =
 418 *        norm( abs(inv(op(A)))*
 419 *           ( abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) ))) / norm(X)
 420 *
 421 *        where
 422 *          norm(Z) is the magnitude of the largest component of Z
 423 *          inv(op(A)) is the inverse of op(A)
 424 *          abs(Z) is the componentwise absolute value of the matrix or
 425 *             vector Z
 426 *          NZ is the maximum number of nonzeros in any row of A, plus 1
 427 *          EPS is machine epsilon
 428 *
 429 *        The i-th component of abs(R)+NZ*EPS*(abs(op(A))*abs(X)+abs(B))
 430 *        is incremented by SAFE1 if the i-th component of
 431 *        abs(op(A))*abs(X) + abs(B) is less than SAFE2.
 432 *
 433 *        Use CLACN2 to estimate the infinity-norm of the matrix
 434 *           inv(op(A)) * diag(W),
 435 *        where W = abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) )))
 436 *
 437          DO 60 I = 1, N
 438             IF( RWORK( I ).GT.SAFE2 ) THEN
 439                RWORK( I ) = CABS1( WORK( I ) ) + NZ*EPS*RWORK( I )
 440             ELSE
 441                RWORK( I ) = CABS1( WORK( I ) ) + NZ*EPS*RWORK( I ) +
 442      $                      SAFE1
 443             END IF
 444    60    CONTINUE
 445 *
 446          KASE = 0
 447    70    CONTINUE
 448          CALL CLACN2( N, WORK( N+1 ), WORK, FERR( J ), KASE, ISAVE )
 449          IF( KASE.NE.0 ) THEN
 450             IF( KASE.EQ.1 ) THEN
 451 *
 452 *              Multiply by diag(W)*inv(op(A)**H).
 453 *
 454                CALL CGTTRS( TRANST, N, 1, DLF, DF, DUF, DU2, IPIV, WORK,
 455      $                      N, INFO )
 456                DO 80 I = 1, N
 457                   WORK( I ) = RWORK( I )*WORK( I )
 458    80          CONTINUE
 459             ELSE
 460 *
 461 *              Multiply by inv(op(A))*diag(W).
 462 *
 463                DO 90 I = 1, N
 464                   WORK( I ) = RWORK( I )*WORK( I )
 465    90          CONTINUE
 466                CALL CGTTRS( TRANSN, N, 1, DLF, DF, DUF, DU2, IPIV, WORK,
 467      $                      N, INFO )
 468             END IF
 469             GO TO 70
 470          END IF
 471 *
 472 *        Normalize error.
 473 *
 474          LSTRES = ZERO
 475          DO 100 I = 1, N
 476             LSTRES = MAX( LSTRES, CABS1( X( I, J ) ) )
 477   100    CONTINUE
 478          IF( LSTRES.NE.ZERO )
 479      $      FERR( J ) = FERR( J ) / LSTRES
 480 *
 481   110 CONTINUE
 482 *
 483       RETURN
 484 *
 485 *     End of CGTRFS
 486 *
 487       END