Modules/Qt4ConfigDependentSettings.cmake

   1 # This file is included by FindQt4.cmake, don't include it directly.
   2
   3 #=============================================================================
   4 # Copyright 2005-2009 Kitware, Inc.
   5 #
   6 # Distributed under the OSI-approved BSD License (the "License");
   7 # see accompanying file Copyright.txt for details.
   8 #
   9 # This software is distributed WITHOUT ANY WARRANTY; without even the
  10 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  11 # See the License for more information.
  12 #=============================================================================
  13 # (To distribute this file outside of CMake, substitute the full
  14 #  License text for the above reference.)
  15
  16
  17 ###############################################
  18 #
  19 #       configuration/system dependent settings
  20 #
  21 ###############################################
  22
  23 # find dependencies for some Qt modules
  24 # when doing builds against a static Qt, they are required
  25 # when doing builds against a shared Qt, they are not required
  26 # if a user needs the dependencies, and they couldn't be found, they can set
  27 # the variables themselves.
  28
  29 set(QT_QTGUI_LIB_DEPENDENCIES "")
  30 set(QT_QTCORE_LIB_DEPENDENCIES "")
  31 set(QT_QTNETWORK_LIB_DEPENDENCIES "")
  32 set(QT_QTOPENGL_LIB_DEPENDENCIES "")
  33 set(QT_QTDBUS_LIB_DEPENDENCIES "")
  34 set(QT_QTHELP_LIB_DEPENDENCIES ${QT_QTCLUCENE_LIBRARY})
  35
  36
  37 if(Q_WS_WIN)
  38   # On Windows, qconfig.pri has "shared" for shared library builds
  39   if(NOT QT_CONFIG MATCHES "shared")
  40     set(QT_IS_STATIC 1)
  41   endif()
  42 else()
  43   # On other platforms, check file extension to know if its static
  44   if(QT_QTCORE_LIBRARY_RELEASE)
  45     get_filename_component(qtcore_lib_ext "${QT_QTCORE_LIBRARY_RELEASE}" EXT)
  46     if("${qtcore_lib_ext}" STREQUAL "${CMAKE_STATIC_LIBRARY_SUFFIX}")
  47       set(QT_IS_STATIC 1)
  48     endif()
  49   endif()
  50   if(QT_QTCORE_LIBRARY_DEBUG)
  51     get_filename_component(qtcore_lib_ext "${QT_QTCORE_LIBRARY_DEBUG}" EXT)
  52     if(${qtcore_lib_ext} STREQUAL ${CMAKE_STATIC_LIBRARY_SUFFIX})
  53       set(QT_IS_STATIC 1)
  54     endif()
  55   endif()
  56 endif()
  57
  58 # build using shared Qt needs -DQT_DLL on Windows
  59 if(Q_WS_WIN  AND  NOT QT_IS_STATIC)
  60   set(QT_DEFINITIONS ${QT_DEFINITIONS} -DQT_DLL)
  61 endif()
  62
  63 if(NOT QT_IS_STATIC)
  64   return()
  65 endif()
  66
  67 # QtOpenGL dependencies
  68 find_package(OpenGL)
  69 set (QT_QTOPENGL_LIB_DEPENDENCIES ${OPENGL_glu_LIBRARY} ${OPENGL_gl_LIBRARY})
  70
  71
  72 ## system png
  73 if(QT_QCONFIG MATCHES "system-png")
  74   find_package(PNG)
  75   set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${PNG_LIBRARY})
  76 endif()
  77
  78 ## system jpeg
  79 if(QT_QCONFIG MATCHES "system-jpeg")
  80   find_package(JPEG)
  81   set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${JPEG_LIBRARIES})
  82 endif()
  83
  84 ## system tiff
  85 if(QT_QCONFIG MATCHES "system-tiff")
  86   find_package(TIFF)
  87   set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${TIFF_LIBRARIES})
  88 endif()
  89
  90 ## system mng
  91 if(QT_QCONFIG MATCHES "system-mng")
  92   find_library(MNG_LIBRARY NAMES mng)
  93   set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${MNG_LIBRARY})
  94 endif()
  95
  96 # for X11, get X11 library directory
  97 if(Q_WS_X11)
  98   find_package(X11)
  99 endif()
 100
 101
 102 ## X11 SM
 103 if(QT_QCONFIG MATCHES "x11sm")
 104   if(X11_SM_LIB AND X11_ICE_LIB)
 105     set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${X11_SM_LIB} ${X11_ICE_LIB})
 106   endif()
 107 endif()
 108
 109
 110 ## Xi
 111 if(QT_QCONFIG MATCHES "tablet")
 112   if(X11_Xi_LIB)
 113     set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${X11_Xi_LIB})
 114   endif()
 115 endif()
 116
 117
 118 ## Xrender
 119 if(QT_QCONFIG MATCHES "xrender")
 120   if(X11_Xrender_LIB)
 121     set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${X11_Xrender_LIB})
 122   endif()
 123 endif()
 124
 125
 126 ## Xrandr
 127 if(QT_QCONFIG MATCHES "xrandr")
 128   if(X11_Xrandr_LIB)
 129     set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${X11_Xrandr_LIB})
 130   endif()
 131 endif()
 132
 133
 134 ## Xcursor
 135 if(QT_QCONFIG MATCHES "xcursor")
 136   if(X11_Xcursor_LIB)
 137     set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${X11_Xcursor_LIB})
 138   endif()
 139 endif()
 140
 141
 142 ## Xinerama
 143 if(QT_QCONFIG MATCHES "xinerama")
 144   if(X11_Xinerama_LIB)
 145     set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${X11_Xinerama_LIB})
 146   endif()
 147 endif()
 148
 149
 150 ## Xfixes
 151 if(QT_QCONFIG MATCHES "xfixes")
 152   if(X11_Xfixes_LIB)
 153     set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${X11_Xfixes_LIB})
 154   endif()
 155 endif()
 156
 157
 158 ## fontconfig
 159 if(QT_QCONFIG MATCHES "fontconfig")
 160   find_library(QT_FONTCONFIG_LIBRARY NAMES fontconfig)
 161   mark_as_advanced(QT_FONTCONFIG_LIBRARY)
 162   if(QT_FONTCONFIG_LIBRARY)
 163     set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${QT_FONTCONFIG_LIBRARY})
 164   endif()
 165 endif()
 166
 167
 168 ## system-freetype
 169 if(QT_QCONFIG MATCHES "system-freetype")
 170   find_package(Freetype)
 171   if(FREETYPE_LIBRARIES)
 172     set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${FREETYPE_LIBRARIES})
 173   endif()
 174 endif()
 175
 176
 177 ## system-zlib
 178 if(QT_QCONFIG MATCHES "system-zlib")
 179   find_package(ZLIB)
 180   set(QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES} ${ZLIB_LIBRARIES})
 181 endif()
 182
 183
 184 ## openssl
 185 if(NOT Q_WS_WIN)
 186   set(_QT_NEED_OPENSSL 0)
 187   if(QT_VERSION_MINOR LESS 4 AND QT_QCONFIG MATCHES "openssl")
 188     set(_QT_NEED_OPENSSL 1)
 189   endif()
 190   if(QT_VERSION_MINOR GREATER 3 AND QT_QCONFIG MATCHES "openssl-linked")
 191     set(_QT_NEED_OPENSSL 1)
 192   endif()
 193   if(_QT_NEED_OPENSSL)
 194     find_package(OpenSSL)
 195     if(OPENSSL_LIBRARIES)
 196       set(QT_QTNETWORK_LIB_DEPENDENCIES ${QT_QTNETWORK_LIB_DEPENDENCIES} ${OPENSSL_LIBRARIES})
 197     endif()
 198   endif()
 199 endif()
 200
 201
 202 ## dbus
 203 if(QT_QCONFIG MATCHES "dbus")
 204
 205   find_library(QT_DBUS_LIBRARY NAMES dbus-1 )
 206   if(QT_DBUS_LIBRARY)
 207     set(QT_QTDBUS_LIB_DEPENDENCIES ${QT_QTDBUS_LIB_DEPENDENCIES} ${QT_DBUS_LIBRARY})
 208   endif()
 209   mark_as_advanced(QT_DBUS_LIBRARY)
 210
 211 endif()
 212
 213
 214 ## glib
 215 if(QT_QCONFIG MATCHES "glib")
 216
 217   # Qt 4.2.0+ uses glib-2.0
 218   find_library(QT_GLIB_LIBRARY NAMES glib-2.0 )
 219   find_library(QT_GTHREAD_LIBRARY NAMES gthread-2.0 )
 220   mark_as_advanced(QT_GLIB_LIBRARY)
 221   mark_as_advanced(QT_GTHREAD_LIBRARY)
 222
 223   if(QT_GLIB_LIBRARY AND QT_GTHREAD_LIBRARY)
 224     set(QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES}
 225         ${QT_GTHREAD_LIBRARY} ${QT_GLIB_LIBRARY})
 226   endif()
 227
 228
 229   # Qt 4.5+ also links to gobject-2.0
 230   if(QT_VERSION_MINOR GREATER 4)
 231      find_library(QT_GOBJECT_LIBRARY NAMES gobject-2.0 PATHS ${_glib_query_output} )
 232      mark_as_advanced(QT_GOBJECT_LIBRARY)
 233
 234      if(QT_GOBJECT_LIBRARY)
 235        set(QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES}
 236            ${QT_GOBJECT_LIBRARY})
 237      endif()
 238   endif()
 239
 240 endif()
 241
 242
 243 ## clock-monotonic, just see if we need to link with rt
 244 if(QT_QCONFIG MATCHES "clock-monotonic")
 245   set(CMAKE_REQUIRED_LIBRARIES_SAVE ${CMAKE_REQUIRED_LIBRARIES})
 246   set(CMAKE_REQUIRED_LIBRARIES rt)
 247   CHECK_SYMBOL_EXISTS(_POSIX_TIMERS "unistd.h;time.h" QT_POSIX_TIMERS)
 248   set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES_SAVE})
 249   if(QT_POSIX_TIMERS)
 250     find_library(QT_RT_LIBRARY NAMES rt)
 251     mark_as_advanced(QT_RT_LIBRARY)
 252     if(QT_RT_LIBRARY)
 253       set(QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES} ${QT_RT_LIBRARY})
 254     endif()
 255   endif()
 256 endif()
 257
 258
 259 if(Q_WS_X11)
 260   # X11 libraries Qt always depends on
 261   set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${X11_Xext_LIB} ${X11_X11_LIB})
 262
 263   set(CMAKE_THREAD_PREFER_PTHREADS 1)
 264   find_package(Threads)
 265   if(CMAKE_USE_PTHREADS_INIT)
 266     set(QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES} ${CMAKE_THREAD_LIBS_INIT})
 267   endif()
 268
 269   set (QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES} ${CMAKE_DL_LIBS})
 270
 271 endif()
 272
 273
 274 if(Q_WS_WIN)
 275   set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} imm32 winmm)
 276   set(QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES} ws2_32)
 277 endif()
 278
 279
 280 if(Q_WS_MAC)
 281   set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} "-framework Carbon")
 282
 283   # Qt 4.0, 4.1, 4.2 use QuickTime
 284   if(QT_VERSION_MINOR LESS 3)
 285     set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} "-framework QuickTime")
 286   endif()
 287
 288   # Qt 4.2+ use AppKit
 289   if(QT_VERSION_MINOR GREATER 1)
 290     set(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} "-framework AppKit")
 291   endif()
 292
 293   set(QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES} "-framework ApplicationServices")
 294 endif()
 295