Modules/Platform/Windows-Clang.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4
   5 # This module is shared by multiple languages; use include blocker.
   6 if(__WINDOWS_CLANG)
   7   return()
   8 endif()
   9 set(__WINDOWS_CLANG 1)
  10
  11 macro(__windows_compiler_clang_gnu lang)
  12   set(CMAKE_LIBRARY_PATH_FLAG "-L")
  13   set(CMAKE_LINK_LIBRARY_FLAG "-l")
  14
  15   set(CMAKE_IMPORT_LIBRARY_PREFIX "")
  16   set(CMAKE_SHARED_LIBRARY_PREFIX "")
  17   set(CMAKE_SHARED_MODULE_PREFIX  "")
  18   set(CMAKE_STATIC_LIBRARY_PREFIX "")
  19   set(CMAKE_EXECUTABLE_SUFFIX     ".exe")
  20   set(CMAKE_IMPORT_LIBRARY_SUFFIX ".lib")
  21   set(CMAKE_SHARED_LIBRARY_SUFFIX ".dll")
  22   set(CMAKE_SHARED_MODULE_SUFFIX  ".dll")
  23   set(CMAKE_STATIC_LIBRARY_SUFFIX ".lib")
  24   if(NOT "${lang}" STREQUAL "ASM")
  25     set(CMAKE_DEPFILE_FLAGS_${lang} "-MD -MT <OBJECT> -MF <DEPFILE>")
  26   endif()
  27
  28   set(CMAKE_FIND_LIBRARY_PREFIXES "lib" "")
  29   set(CMAKE_FIND_LIBRARY_SUFFIXES ".dll.a" ".a" ".lib")
  30   set(CMAKE_SUPPORT_WINDOWS_EXPORT_ALL_SYMBOLS 1)
  31   set (CMAKE_LINK_DEF_FILE_FLAG "-Xlinker /DEF:")
  32
  33   if("${CMAKE_${lang}_SIMULATE_VERSION}" MATCHES "^([0-9]+)\\.([0-9]+)")
  34     math(EXPR MSVC_VERSION "${CMAKE_MATCH_1}*100 + ${CMAKE_MATCH_2}")
  35   endif()
  36
  37   # No -fPIC on Windows
  38   set(CMAKE_${lang}_COMPILE_OPTIONS_PIC "")
  39   set(CMAKE_${lang}_COMPILE_OPTIONS_PIE "")
  40   set(_CMAKE_${lang}_PIE_MAY_BE_SUPPORTED_BY_LINKER NO)
  41   set(CMAKE_${lang}_LINK_OPTIONS_PIE "")
  42   set(CMAKE_${lang}_LINK_OPTIONS_NO_PIE "")
  43   set(CMAKE_SHARED_LIBRARY_${lang}_FLAGS "")
  44
  45   set(CMAKE_${lang}_USE_RESPONSE_FILE_FOR_OBJECTS 1)
  46   set(CMAKE_${lang}_USE_RESPONSE_FILE_FOR_LIBRARIES 1)
  47   set(CMAKE_${lang}_USE_RESPONSE_FILE_FOR_INCLUDES 1)
  48
  49   set(CMAKE_${lang}_COMPILE_OPTIONS_IPO "-flto")
  50   set(_CMAKE_${lang}_IPO_SUPPORTED_BY_CMAKE YES)
  51   set(_CMAKE_${lang}_IPO_MAY_BE_SUPPORTED_BY_COMPILER YES)
  52   set(CMAKE_${lang}_ARCHIVE_CREATE_IPO "<CMAKE_AR> cr <TARGET> <LINK_FLAGS> <OBJECTS>")
  53   set(CMAKE_${lang}_ARCHIVE_APPEND_IPO "<CMAKE_AR> r <TARGET> <LINK_FLAGS> <OBJECTS>")
  54   set(CMAKE_${lang}_ARCHIVE_FINISH_IPO "<CMAKE_RANLIB> <TARGET>")
  55
  56   # Create archiving rules to support large object file lists for static libraries.
  57   set(CMAKE_${lang}_ARCHIVE_CREATE "<CMAKE_AR> qc <TARGET> <LINK_FLAGS> <OBJECTS>")
  58   set(CMAKE_${lang}_ARCHIVE_APPEND "<CMAKE_AR> q <TARGET> <LINK_FLAGS> <OBJECTS>")
  59   set(CMAKE_${lang}_ARCHIVE_FINISH "<CMAKE_RANLIB> <TARGET>")
  60   set(CMAKE_${lang}_CREATE_SHARED_LIBRARY
  61     "<CMAKE_${lang}_COMPILER> -fuse-ld=lld-link -nostartfiles -nostdlib <CMAKE_SHARED_LIBRARY_${lang}_FLAGS> <LANGUAGE_COMPILE_FLAGS> <LINK_FLAGS> <CMAKE_SHARED_LIBRARY_CREATE_${lang}_FLAGS> -o <TARGET> ${CMAKE_GNULD_IMAGE_VERSION} -Xlinker /implib:<TARGET_IMPLIB> -Xlinker /pdb:<TARGET_PDB> -Xlinker /version:<TARGET_VERSION_MAJOR>.<TARGET_VERSION_MINOR> <OBJECTS> <LINK_LIBRARIES>")
  62   set(CMAKE_${lang}_CREATE_SHARED_MODULE ${CMAKE_${lang}_CREATE_SHARED_LIBRARY})
  63   set(CMAKE_${lang}_LINK_EXECUTABLE
  64     "<CMAKE_${lang}_COMPILER> -fuse-ld=lld-link -nostartfiles -nostdlib <FLAGS> <CMAKE_${lang}_LINK_FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> -Xlinker /implib:<TARGET_IMPLIB> -Xlinker /pdb:<TARGET_PDB> -Xlinker /version:<TARGET_VERSION_MAJOR>.<TARGET_VERSION_MINOR> ${CMAKE_GNULD_IMAGE_VERSION} <LINK_LIBRARIES>")
  65
  66   if(NOT "${lang}" STREQUAL "ASM")
  67     set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_RUNTIME_LIBRARY_MultiThreaded         -Xclang -flto-visibility-public-std -D_MT -Xclang --dependent-lib=libcmt)
  68     set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_RUNTIME_LIBRARY_MultiThreadedDLL      -D_DLL -D_MT -Xclang --dependent-lib=msvcrt)
  69     set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_RUNTIME_LIBRARY_MultiThreadedDebug    -D_DEBUG -Xclang -flto-visibility-public-std -D_MT -Xclang --dependent-lib=libcmtd)
  70     set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_RUNTIME_LIBRARY_MultiThreadedDebugDLL -D_DEBUG -D_DLL -D_MT -Xclang --dependent-lib=msvcrtd)
  71
  72     if(CMAKE_MSVC_RUNTIME_LIBRARY_DEFAULT)
  73       set(__ADDED_FLAGS "")
  74       set(__ADDED_FLAGS_DEBUG "")
  75     else()
  76       set(__ADDED_FLAGS_DEBUG "-D_DEBUG -D_DLL -D_MT -Xclang --dependent-lib=msvcrtd")
  77       set(__ADDED_FLAGS "-D_DLL -D_MT -Xclang --dependent-lib=msvcrt")
  78     endif()
  79
  80     string(APPEND CMAKE_${lang}_FLAGS_DEBUG_INIT " -g -Xclang -gcodeview -O0 ${__ADDED_FLAGS_DEBUG}")
  81     string(APPEND CMAKE_${lang}_FLAGS_MINSIZEREL_INIT " -Os -DNDEBUG ${__ADDED_FLAGS}")
  82     string(APPEND CMAKE_${lang}_FLAGS_RELEASE_INIT " -O3 -DNDEBUG ${__ADDED_FLAGS}")
  83     string(APPEND CMAKE_${lang}_FLAGS_RELWITHDEBINFO_INIT " -O2 -g -DNDEBUG -Xclang -gcodeview ${__ADDED_FLAGS}")
  84   endif()
  85   set(CMAKE_INCLUDE_SYSTEM_FLAG_${lang} "-isystem ")
  86
  87   set(CMAKE_PCH_EXTENSION .pch)
  88   set(CMAKE_PCH_PROLOGUE "#pragma clang system_header")
  89   set(CMAKE_${lang}_COMPILE_OPTIONS_USE_PCH -Xclang -include-pch -Xclang <PCH_FILE> -Xclang -include -Xclang <PCH_HEADER>)
  90   set(CMAKE_${lang}_COMPILE_OPTIONS_CREATE_PCH -Xclang -emit-pch -Xclang -include -Xclang <PCH_HEADER>)
  91
  92   unset(__ADDED_FLAGS)
  93   unset(__ADDED_FLAGS_DEBUG)
  94   string(TOLOWER "${CMAKE_BUILD_TYPE}" BUILD_TYPE_LOWER)
  95   set(CMAKE_${lang}_STANDARD_LIBRARIES_INIT "-lkernel32 -luser32 -lgdi32 -lwinspool -lshell32 -lole32 -loleaut32 -luuid -lcomdlg32 -ladvapi32 -loldnames")
  96
  97   enable_language(RC)
  98 endmacro()
  99
 100 if("x${CMAKE_C_SIMULATE_ID}" STREQUAL "xMSVC"
 101     OR "x${CMAKE_CXX_SIMULATE_ID}" STREQUAL "xMSVC")
 102
 103   if ( DEFINED CMAKE_C_COMPILER_ID AND DEFINED CMAKE_CXX_COMPILER_ID
 104        AND NOT "x${CMAKE_C_COMPILER_ID}" STREQUAL "x${CMAKE_CXX_COMPILER_ID}")
 105     message(FATAL_ERROR "The current configuration mixes Clang and MSVC or "
 106             "some other CL compatible compiler tool. This is not supported. "
 107             "Use either clang or MSVC as both C and C++ compilers.")
 108   endif()
 109
 110   if ( DEFINED CMAKE_C_COMPILER_FRONTEND_VARIANT AND DEFINED CMAKE_CXX_COMPILER_FRONTEND_VARIANT
 111        AND NOT "x${CMAKE_C_COMPILER_FRONTEND_VARIANT}" STREQUAL "x${CMAKE_CXX_COMPILER_FRONTEND_VARIANT}")
 112     message(FATAL_ERROR "The current configuration uses the Clang compiler "
 113             "tool with mixed frontend variants, both the GNU and in MSVC CL "
 114             "like variants. This is not supported. Use either clang/clang++ "
 115             "or clang-cl as both C and C++ compilers.")
 116   endif()
 117
 118   if(NOT CMAKE_RC_COMPILER_INIT)
 119     # Check if rc is already in the path
 120     # This may happen in cases where the user is already in a visual studio environment when CMake is invoked
 121     find_program(__RC_COMPILER_PATH NAMES rc)
 122
 123     # Default to rc if it's available, otherwise fall back to llvm-rc
 124     if(__RC_COMPILER_PATH)
 125       set(CMAKE_RC_COMPILER_INIT rc)
 126     else()
 127       set(CMAKE_RC_COMPILER_INIT llvm-rc)
 128     endif()
 129
 130     unset(__RC_COMPILER_PATH CACHE)
 131   endif()
 132
 133   if ( "x${CMAKE_CXX_COMPILER_FRONTEND_VARIANT}" STREQUAL "xMSVC" OR "x${CMAKE_C_COMPILER_FRONTEND_VARIANT}" STREQUAL "xMSVC" )
 134     include(Platform/Windows-MSVC)
 135
 136     # Feed the preprocessed rc file to llvm-rc
 137     if(CMAKE_RC_COMPILER_INIT MATCHES "llvm-rc")
 138       if(DEFINED CMAKE_C_COMPILER_ID)
 139         set(CMAKE_RC_PREPROCESSOR CMAKE_C_COMPILER)
 140       elseif(DEFINED CMAKE_CXX_COMPILER_ID)
 141         set(CMAKE_RC_PREPROCESSOR CMAKE_CXX_COMPILER)
 142       endif()
 143       if(DEFINED CMAKE_RC_PREPROCESSOR)
 144         set(CMAKE_DEPFILE_FLAGS_RC "-clang:-MD -clang:-MF -clang:<DEPFILE>")
 145         set(CMAKE_RC_COMPILE_OBJECT "<CMAKE_COMMAND> -E cmake_llvm_rc <SOURCE> <OBJECT>.pp <${CMAKE_RC_PREPROCESSOR}> <DEFINES> -DRC_INVOKED <INCLUDES> <FLAGS> -E <SOURCE> -- <CMAKE_RC_COMPILER> <DEFINES> -I <SOURCE_DIR> <INCLUDES> /fo <OBJECT> <OBJECT>.pp")
 146         if(CMAKE_GENERATOR STREQUAL "Ninja")
 147           set(CMAKE_NINJA_CMCLDEPS_RC 0)
 148           set(CMAKE_NINJA_DEP_TYPE_RC gcc)
 149         endif()
 150         unset(CMAKE_RC_PREPROCESSOR)
 151       endif()
 152     endif()
 153
 154     macro(__windows_compiler_clang lang)
 155       set(_COMPILE_${lang} "${_COMPILE_${lang}_MSVC}")
 156       __windows_compiler_msvc(${lang})
 157     endmacro()
 158   else()
 159     cmake_policy(GET CMP0091 __WINDOWS_CLANG_CMP0091)
 160     if(__WINDOWS_CLANG_CMP0091 STREQUAL "NEW")
 161       set(CMAKE_MSVC_RUNTIME_LIBRARY_DEFAULT "MultiThreaded$<$<CONFIG:Debug>:Debug>DLL")
 162     else()
 163       set(CMAKE_MSVC_RUNTIME_LIBRARY_DEFAULT "")
 164     endif()
 165     unset(__WINDOWS_CLANG_CMP0091)
 166
 167     set(CMAKE_BUILD_TYPE_INIT Debug)
 168
 169     macro(__windows_compiler_clang lang)
 170       __windows_compiler_clang_gnu(${lang})
 171     endmacro()
 172   endif()
 173
 174 else()
 175   include(Platform/Windows-GNU)
 176   macro(__windows_compiler_clang lang)
 177     __windows_compiler_gnu(${lang})
 178   endmacro()
 179 endif()