Modules/Platform/Windows-Clang.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4
   5 # This module is shared by multiple languages; use include blocker.
   6 if(__WINDOWS_CLANG)
   7   return()
   8 endif()
   9 set(__WINDOWS_CLANG 1)
  10
  11 set(__pch_header_C "c-header")
  12 set(__pch_header_CXX "c++-header")
  13 set(__pch_header_OBJC "objective-c-header")
  14 set(__pch_header_OBJCXX "objective-c++-header")
  15
  16 macro(__windows_compiler_clang_gnu lang)
  17   set(CMAKE_LIBRARY_PATH_FLAG "-L")
  18   set(CMAKE_LINK_LIBRARY_FLAG "-l")
  19
  20   set(CMAKE_IMPORT_LIBRARY_PREFIX "")
  21   set(CMAKE_SHARED_LIBRARY_PREFIX "")
  22   set(CMAKE_SHARED_MODULE_PREFIX  "")
  23   set(CMAKE_STATIC_LIBRARY_PREFIX "")
  24   set(CMAKE_EXECUTABLE_SUFFIX     ".exe")
  25   set(CMAKE_IMPORT_LIBRARY_SUFFIX ".lib")
  26   set(CMAKE_SHARED_LIBRARY_SUFFIX ".dll")
  27   set(CMAKE_SHARED_MODULE_SUFFIX  ".dll")
  28   set(CMAKE_STATIC_LIBRARY_SUFFIX ".lib")
  29   if(NOT "${lang}" STREQUAL "ASM")
  30     set(CMAKE_DEPFILE_FLAGS_${lang} "-MD -MT <DEP_TARGET> -MF <DEP_FILE>")
  31   endif()
  32
  33   set(CMAKE_FIND_LIBRARY_PREFIXES "lib" "")
  34   set(CMAKE_FIND_LIBRARY_SUFFIXES ".dll.a" ".a" ".lib")
  35   set(CMAKE_SUPPORT_WINDOWS_EXPORT_ALL_SYMBOLS 1)
  36   set (CMAKE_LINK_DEF_FILE_FLAG "-Xlinker /DEF:")
  37
  38   set(CMAKE_${lang}_LINKER_WRAPPER_FLAG "-Xlinker" " ")
  39   set(CMAKE_${lang}_LINKER_WRAPPER_FLAG_SEP)
  40
  41   set(CMAKE_${lang}_LINKER_MANIFEST_FLAG " -Xlinker /MANIFESTINPUT:")
  42   set(CMAKE_${lang}_COMPILE_OPTIONS_WARNING_AS_ERROR "-Werror")
  43
  44   if("${CMAKE_${lang}_SIMULATE_VERSION}" MATCHES "^([0-9]+)\\.([0-9]+)")
  45     math(EXPR MSVC_VERSION "${CMAKE_MATCH_1}*100 + ${CMAKE_MATCH_2}")
  46   endif()
  47
  48   # No -fPIC on Windows
  49   set(CMAKE_${lang}_COMPILE_OPTIONS_PIC "")
  50   set(CMAKE_${lang}_COMPILE_OPTIONS_PIE "")
  51   set(_CMAKE_${lang}_PIE_MAY_BE_SUPPORTED_BY_LINKER NO)
  52   set(CMAKE_${lang}_LINK_OPTIONS_PIE "")
  53   set(CMAKE_${lang}_LINK_OPTIONS_NO_PIE "")
  54   set(CMAKE_SHARED_LIBRARY_${lang}_FLAGS "")
  55
  56   set(CMAKE_${lang}_USE_RESPONSE_FILE_FOR_OBJECTS 1)
  57   set(CMAKE_${lang}_USE_RESPONSE_FILE_FOR_LIBRARIES 1)
  58   set(CMAKE_${lang}_USE_RESPONSE_FILE_FOR_INCLUDES 1)
  59
  60   if(CMAKE_${lang}_COMPILER_VERSION VERSION_GREATER_EQUAL 3.9)
  61     set(CMAKE_${lang}_COMPILE_OPTIONS_IPO "-flto=thin")
  62   else()
  63     set(CMAKE_${lang}_COMPILE_OPTIONS_IPO "-flto")
  64   endif()
  65
  66   set(_CMAKE_${lang}_IPO_SUPPORTED_BY_CMAKE YES)
  67   set(_CMAKE_${lang}_IPO_MAY_BE_SUPPORTED_BY_COMPILER YES)
  68   set(CMAKE_${lang}_ARCHIVE_CREATE_IPO "<CMAKE_AR> qc <TARGET> <LINK_FLAGS> <OBJECTS>")
  69   set(CMAKE_${lang}_ARCHIVE_APPEND_IPO "<CMAKE_AR> q <TARGET> <LINK_FLAGS> <OBJECTS>")
  70   set(CMAKE_${lang}_ARCHIVE_FINISH_IPO "<CMAKE_RANLIB> <TARGET>")
  71
  72   # Create archiving rules to support large object file lists for static libraries.
  73   set(CMAKE_${lang}_ARCHIVE_CREATE "<CMAKE_AR> qc <TARGET> <LINK_FLAGS> <OBJECTS>")
  74   set(CMAKE_${lang}_ARCHIVE_APPEND "<CMAKE_AR> q <TARGET> <LINK_FLAGS> <OBJECTS>")
  75   set(CMAKE_${lang}_ARCHIVE_FINISH "<CMAKE_RANLIB> <TARGET>")
  76   set(CMAKE_${lang}_CREATE_SHARED_LIBRARY
  77     "<CMAKE_${lang}_COMPILER> -fuse-ld=lld-link -nostartfiles -nostdlib <CMAKE_SHARED_LIBRARY_${lang}_FLAGS> <LANGUAGE_COMPILE_FLAGS> <LINK_FLAGS> <CMAKE_SHARED_LIBRARY_CREATE_${lang}_FLAGS> -o <TARGET> ${CMAKE_GNULD_IMAGE_VERSION} -Xlinker /MANIFEST:EMBED -Xlinker /implib:<TARGET_IMPLIB> -Xlinker /pdb:<TARGET_PDB> -Xlinker /version:<TARGET_VERSION_MAJOR>.<TARGET_VERSION_MINOR> <OBJECTS> <LINK_LIBRARIES> <MANIFESTS>")
  78   set(CMAKE_${lang}_CREATE_SHARED_MODULE ${CMAKE_${lang}_CREATE_SHARED_LIBRARY})
  79   set(CMAKE_${lang}_LINK_EXECUTABLE
  80     "<CMAKE_${lang}_COMPILER> -fuse-ld=lld-link -nostartfiles -nostdlib <FLAGS> <CMAKE_${lang}_LINK_FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> -Xlinker /MANIFEST:EMBED -Xlinker /implib:<TARGET_IMPLIB> -Xlinker /pdb:<TARGET_PDB> -Xlinker /version:<TARGET_VERSION_MAJOR>.<TARGET_VERSION_MINOR> ${CMAKE_GNULD_IMAGE_VERSION} <LINK_LIBRARIES> <MANIFESTS>")
  81
  82   set(CMAKE_${lang}_CREATE_WIN32_EXE "-Xlinker /subsystem:windows")
  83   set(CMAKE_${lang}_CREATE_CONSOLE_EXE "-Xlinker /subsystem:console")
  84
  85   if(NOT "${lang}" STREQUAL "ASM")
  86     set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_RUNTIME_LIBRARY_MultiThreaded         -Xclang -flto-visibility-public-std -D_MT -Xclang --dependent-lib=libcmt)
  87     set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_RUNTIME_LIBRARY_MultiThreadedDLL      -D_DLL -D_MT -Xclang --dependent-lib=msvcrt)
  88     set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_RUNTIME_LIBRARY_MultiThreadedDebug    -D_DEBUG -Xclang -flto-visibility-public-std -D_MT -Xclang --dependent-lib=libcmtd)
  89     set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_RUNTIME_LIBRARY_MultiThreadedDebugDLL -D_DEBUG -D_DLL -D_MT -Xclang --dependent-lib=msvcrtd)
  90
  91     if(CMAKE_MSVC_RUNTIME_LIBRARY_DEFAULT)
  92       set(__ADDED_FLAGS "")
  93       set(__ADDED_FLAGS_DEBUG "")
  94     else()
  95       set(__ADDED_FLAGS_DEBUG "-D_DEBUG -D_DLL -D_MT -Xclang --dependent-lib=msvcrtd")
  96       set(__ADDED_FLAGS "-D_DLL -D_MT -Xclang --dependent-lib=msvcrt")
  97     endif()
  98
  99     string(APPEND CMAKE_${lang}_FLAGS_DEBUG_INIT " -g -Xclang -gcodeview -O0 ${__ADDED_FLAGS_DEBUG}")
 100     string(APPEND CMAKE_${lang}_FLAGS_MINSIZEREL_INIT " -Os -DNDEBUG ${__ADDED_FLAGS}")
 101     string(APPEND CMAKE_${lang}_FLAGS_RELEASE_INIT " -O3 -DNDEBUG ${__ADDED_FLAGS}")
 102     string(APPEND CMAKE_${lang}_FLAGS_RELWITHDEBINFO_INIT " -O2 -g -DNDEBUG -Xclang -gcodeview ${__ADDED_FLAGS}")
 103   endif()
 104   set(CMAKE_INCLUDE_SYSTEM_FLAG_${lang} "-isystem ")
 105   set(CMAKE_${lang}_LINKER_SUPPORTS_PDB ON)
 106
 107   set(CMAKE_PCH_EXTENSION .pch)
 108   set(CMAKE_PCH_PROLOGUE "#pragma clang system_header")
 109   set(CMAKE_${lang}_COMPILE_OPTIONS_USE_PCH -Xclang -include-pch -Xclang <PCH_FILE> -Xclang -include -Xclang <PCH_HEADER>)
 110   set(CMAKE_${lang}_COMPILE_OPTIONS_CREATE_PCH -Xclang -emit-pch -Xclang -include -Xclang <PCH_HEADER> -x ${__pch_header_${lang}})
 111
 112   unset(__ADDED_FLAGS)
 113   unset(__ADDED_FLAGS_DEBUG)
 114   string(TOLOWER "${CMAKE_BUILD_TYPE}" BUILD_TYPE_LOWER)
 115   set(CMAKE_${lang}_STANDARD_LIBRARIES_INIT "-lkernel32 -luser32 -lgdi32 -lwinspool -lshell32 -lole32 -loleaut32 -luuid -lcomdlg32 -ladvapi32 -loldnames")
 116
 117   # Features for LINK_LIBRARY generator expression
 118   if(MSVC_VERSION GREATER "1900")
 119     ## WHOLE_ARCHIVE: Force loading all members of an archive
 120     set(CMAKE_${lang}_LINK_LIBRARY_USING_WHOLE_ARCHIVE "LINKER:/WHOLEARCHIVE:<LIBRARY>")
 121     set(CMAKE_${lang}_LINK_LIBRARY_USING_WHOLE_ARCHIVE_SUPPORTED TRUE)
 122   endif()
 123
 124   enable_language(RC)
 125 endmacro()
 126
 127 macro(__enable_llvm_rc_preprocessing clang_option_prefix extra_pp_flags)
 128   # Feed the preprocessed rc file to llvm-rc
 129   if(CMAKE_RC_COMPILER_INIT MATCHES "llvm-rc" OR CMAKE_RC_COMPILER MATCHES "llvm-rc")
 130     if(DEFINED CMAKE_C_COMPILER_ID)
 131       set(CMAKE_RC_PREPROCESSOR CMAKE_C_COMPILER)
 132     elseif(DEFINED CMAKE_CXX_COMPILER_ID)
 133       set(CMAKE_RC_PREPROCESSOR CMAKE_CXX_COMPILER)
 134     endif()
 135     if(DEFINED CMAKE_RC_PREPROCESSOR)
 136       set(CMAKE_DEPFILE_FLAGS_RC "${clang_option_prefix}-MD ${clang_option_prefix}-MF ${clang_option_prefix}<DEP_FILE>")
 137       # The <FLAGS> are passed to the preprocess and the resource compiler to pick
 138       # up the eventual -D / -C options passed through the CMAKE_RC_FLAGS.
 139       set(CMAKE_RC_COMPILE_OBJECT "<CMAKE_COMMAND> -E cmake_llvm_rc <SOURCE> <OBJECT>.pp <${CMAKE_RC_PREPROCESSOR}> <DEFINES> -DRC_INVOKED <INCLUDES> <FLAGS> ${extra_pp_flags} -E -- <SOURCE> ++ <CMAKE_RC_COMPILER> <DEFINES> -I <SOURCE_DIR> <INCLUDES> <FLAGS> /fo <OBJECT> <OBJECT>.pp")
 140       if(CMAKE_GENERATOR MATCHES "Ninja")
 141         set(CMAKE_NINJA_CMCLDEPS_RC 0)
 142         set(CMAKE_NINJA_DEP_TYPE_RC gcc)
 143       endif()
 144       unset(CMAKE_RC_PREPROCESSOR)
 145     endif()
 146   endif()
 147 endmacro()
 148
 149
 150 if("x${CMAKE_C_SIMULATE_ID}" STREQUAL "xMSVC"
 151     OR "x${CMAKE_CXX_SIMULATE_ID}" STREQUAL "xMSVC")
 152
 153   if ( DEFINED CMAKE_C_COMPILER_ID AND DEFINED CMAKE_CXX_COMPILER_ID
 154        AND NOT "x${CMAKE_C_COMPILER_ID}" STREQUAL "x${CMAKE_CXX_COMPILER_ID}")
 155     message(FATAL_ERROR "The current configuration mixes Clang and MSVC or "
 156             "some other CL compatible compiler tool. This is not supported. "
 157             "Use either clang or MSVC as both C and C++ compilers.")
 158   endif()
 159
 160   if ( DEFINED CMAKE_C_COMPILER_FRONTEND_VARIANT AND DEFINED CMAKE_CXX_COMPILER_FRONTEND_VARIANT
 161        AND NOT "x${CMAKE_C_COMPILER_FRONTEND_VARIANT}" STREQUAL "x${CMAKE_CXX_COMPILER_FRONTEND_VARIANT}")
 162     message(FATAL_ERROR "The current configuration uses the Clang compiler "
 163             "tool with mixed frontend variants, both the GNU and in MSVC CL "
 164             "like variants. This is not supported. Use either clang/clang++ "
 165             "or clang-cl as both C and C++ compilers.")
 166   endif()
 167
 168   if(NOT CMAKE_RC_COMPILER_INIT)
 169     # Check if rc is already in the path
 170     # This may happen in cases where the user is already in a visual studio environment when CMake is invoked
 171     find_program(__RC_COMPILER_PATH NAMES rc)
 172
 173     # Default to rc if it's available, otherwise fall back to llvm-rc
 174     if(__RC_COMPILER_PATH)
 175       set(CMAKE_RC_COMPILER_INIT rc)
 176     else()
 177       find_program(__RC_COMPILER_PATH NAMES llvm-rc)
 178       if(__RC_COMPILER_PATH)
 179         set(CMAKE_RC_COMPILER_INIT llvm-rc)
 180       endif()
 181     endif()
 182
 183     unset(__RC_COMPILER_PATH CACHE)
 184   endif()
 185
 186   if ( "x${CMAKE_CXX_COMPILER_FRONTEND_VARIANT}" STREQUAL "xMSVC" OR "x${CMAKE_C_COMPILER_FRONTEND_VARIANT}" STREQUAL "xMSVC" )
 187     include(Platform/Windows-MSVC)
 188     # Set the clang option forwarding prefix for clang-cl usage in the llvm-rc processing stage
 189     __enable_llvm_rc_preprocessing("-clang:" "")
 190     macro(__windows_compiler_clang_base lang)
 191       set(_COMPILE_${lang} "${_COMPILE_${lang}_MSVC}")
 192       __windows_compiler_msvc(${lang})
 193       set(CMAKE_${lang}_COMPILE_OPTIONS_WARNING_AS_ERROR "-WX")
 194       set(CMAKE_INCLUDE_SYSTEM_FLAG_${lang} "-imsvc")
 195     endmacro()
 196   else()
 197     cmake_policy(GET CMP0091 __WINDOWS_CLANG_CMP0091)
 198     if(__WINDOWS_CLANG_CMP0091 STREQUAL "NEW")
 199       set(CMAKE_MSVC_RUNTIME_LIBRARY_DEFAULT "MultiThreaded$<$<CONFIG:Debug>:Debug>DLL")
 200     else()
 201       set(CMAKE_MSVC_RUNTIME_LIBRARY_DEFAULT "")
 202     endif()
 203     unset(__WINDOWS_CLANG_CMP0091)
 204
 205     set(CMAKE_BUILD_TYPE_INIT Debug)
 206
 207     __enable_llvm_rc_preprocessing("" "-x c")
 208     macro(__windows_compiler_clang_base lang)
 209       __windows_compiler_clang_gnu(${lang})
 210     endmacro()
 211   endif()
 212
 213 else()
 214   include(Platform/Windows-GNU)
 215   __enable_llvm_rc_preprocessing("" "-x c")
 216   macro(__windows_compiler_clang_base lang)
 217     __windows_compiler_gnu(${lang})
 218   endmacro()
 219 endif()
 220
 221 macro(__windows_compiler_clang lang)
 222   if(CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.4.0)
 223     set(CMAKE_${lang}_COMPILE_OPTIONS_TARGET "-target ")
 224   else()
 225     set(CMAKE_${lang}_COMPILE_OPTIONS_TARGET "--target=")
 226   endif()
 227   __windows_compiler_clang_base(${lang})
 228 endmacro()