Modules/Platform/Windows-Clang.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4
   5 # This module is shared by multiple languages; use include blocker.
   6 if(__WINDOWS_CLANG)
   7   return()
   8 endif()
   9 set(__WINDOWS_CLANG 1)
  10
  11 set(__pch_header_C "c-header")
  12 set(__pch_header_CXX "c++-header")
  13 set(__pch_header_OBJC "objective-c-header")
  14 set(__pch_header_OBJCXX "objective-c++-header")
  15
  16 macro(__windows_compiler_clang_gnu lang)
  17   set(CMAKE_LIBRARY_PATH_FLAG "-L")
  18   set(CMAKE_LINK_LIBRARY_FLAG "-l")
  19
  20   set(CMAKE_IMPORT_LIBRARY_PREFIX "")
  21   set(CMAKE_SHARED_LIBRARY_PREFIX "")
  22   set(CMAKE_SHARED_MODULE_PREFIX  "")
  23   set(CMAKE_STATIC_LIBRARY_PREFIX "")
  24   set(CMAKE_EXECUTABLE_SUFFIX     ".exe")
  25   set(CMAKE_IMPORT_LIBRARY_SUFFIX ".lib")
  26   set(CMAKE_SHARED_LIBRARY_SUFFIX ".dll")
  27   set(CMAKE_SHARED_MODULE_SUFFIX  ".dll")
  28   set(CMAKE_STATIC_LIBRARY_SUFFIX ".lib")
  29   if(NOT "${lang}" STREQUAL "ASM")
  30     set(CMAKE_DEPFILE_FLAGS_${lang} "-MD -MT <DEP_TARGET> -MF <DEP_FILE>")
  31   endif()
  32
  33   set(CMAKE_FIND_LIBRARY_PREFIXES "lib" "")
  34   set(CMAKE_FIND_LIBRARY_SUFFIXES ".dll.a" ".a" ".lib")
  35   set(CMAKE_SUPPORT_WINDOWS_EXPORT_ALL_SYMBOLS 1)
  36   set (CMAKE_LINK_DEF_FILE_FLAG "-Xlinker /DEF:")
  37
  38   set(CMAKE_${lang}_LINKER_WRAPPER_FLAG "-Xlinker" " ")
  39   set(CMAKE_${lang}_LINKER_WRAPPER_FLAG_SEP)
  40
  41   set(CMAKE_${lang}_LINKER_MANIFEST_FLAG " -Xlinker /MANIFESTINPUT:")
  42   set(CMAKE_${lang}_COMPILE_OPTIONS_WARNING_AS_ERROR "-Werror")
  43
  44   if("${CMAKE_${lang}_SIMULATE_VERSION}" MATCHES "^([0-9]+)\\.([0-9]+)")
  45     math(EXPR MSVC_VERSION "${CMAKE_MATCH_1}*100 + ${CMAKE_MATCH_2}")
  46   endif()
  47
  48   # No -fPIC on Windows
  49   set(CMAKE_${lang}_COMPILE_OPTIONS_PIC "")
  50   set(CMAKE_${lang}_COMPILE_OPTIONS_PIE "")
  51   set(_CMAKE_${lang}_PIE_MAY_BE_SUPPORTED_BY_LINKER NO)
  52   set(CMAKE_${lang}_LINK_OPTIONS_PIE "")
  53   set(CMAKE_${lang}_LINK_OPTIONS_NO_PIE "")
  54   set(CMAKE_SHARED_LIBRARY_${lang}_FLAGS "")
  55
  56   set(CMAKE_${lang}_USE_RESPONSE_FILE_FOR_OBJECTS 1)
  57   set(CMAKE_${lang}_USE_RESPONSE_FILE_FOR_LIBRARIES 1)
  58   set(CMAKE_${lang}_USE_RESPONSE_FILE_FOR_INCLUDES 1)
  59
  60   if(CMAKE_${lang}_COMPILER_VERSION VERSION_GREATER_EQUAL 3.9)
  61     set(CMAKE_${lang}_COMPILE_OPTIONS_IPO "-flto=thin")
  62   else()
  63     set(CMAKE_${lang}_COMPILE_OPTIONS_IPO "-flto")
  64   endif()
  65
  66   set(_CMAKE_${lang}_IPO_SUPPORTED_BY_CMAKE YES)
  67   set(_CMAKE_${lang}_IPO_MAY_BE_SUPPORTED_BY_COMPILER YES)
  68   set(CMAKE_${lang}_ARCHIVE_CREATE_IPO "<CMAKE_AR> qc <TARGET> <LINK_FLAGS> <OBJECTS>")
  69   set(CMAKE_${lang}_ARCHIVE_APPEND_IPO "<CMAKE_AR> q <TARGET> <LINK_FLAGS> <OBJECTS>")
  70   set(CMAKE_${lang}_ARCHIVE_FINISH_IPO "<CMAKE_RANLIB> <TARGET>")
  71
  72   # Create archiving rules to support large object file lists for static libraries.
  73   set(CMAKE_${lang}_ARCHIVE_CREATE "<CMAKE_AR> qc <TARGET> <LINK_FLAGS> <OBJECTS>")
  74   set(CMAKE_${lang}_ARCHIVE_APPEND "<CMAKE_AR> q <TARGET> <LINK_FLAGS> <OBJECTS>")
  75   set(CMAKE_${lang}_ARCHIVE_FINISH "<CMAKE_RANLIB> <TARGET>")
  76   set(CMAKE_${lang}_CREATE_SHARED_LIBRARY
  77     "<CMAKE_${lang}_COMPILER> -fuse-ld=lld-link -nostartfiles -nostdlib <CMAKE_SHARED_LIBRARY_${lang}_FLAGS> <LANGUAGE_COMPILE_FLAGS> <LINK_FLAGS> <CMAKE_SHARED_LIBRARY_CREATE_${lang}_FLAGS> -o <TARGET> ${CMAKE_GNULD_IMAGE_VERSION} -Xlinker /MANIFEST:EMBED -Xlinker /implib:<TARGET_IMPLIB> -Xlinker /pdb:<TARGET_PDB> -Xlinker /version:<TARGET_VERSION_MAJOR>.<TARGET_VERSION_MINOR> <OBJECTS> <LINK_LIBRARIES> <MANIFESTS>")
  78   set(CMAKE_${lang}_CREATE_SHARED_MODULE ${CMAKE_${lang}_CREATE_SHARED_LIBRARY})
  79   set(CMAKE_${lang}_LINK_EXECUTABLE
  80     "<CMAKE_${lang}_COMPILER> -fuse-ld=lld-link -nostartfiles -nostdlib <FLAGS> <CMAKE_${lang}_LINK_FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> -Xlinker /MANIFEST:EMBED -Xlinker /implib:<TARGET_IMPLIB> -Xlinker /pdb:<TARGET_PDB> -Xlinker /version:<TARGET_VERSION_MAJOR>.<TARGET_VERSION_MINOR> ${CMAKE_GNULD_IMAGE_VERSION} <LINK_LIBRARIES> <MANIFESTS>")
  81
  82   set(CMAKE_${lang}_CREATE_WIN32_EXE "-Xlinker /subsystem:windows")
  83   set(CMAKE_${lang}_CREATE_CONSOLE_EXE "-Xlinker /subsystem:console")
  84
  85   if(NOT "${lang}" STREQUAL "ASM")
  86     set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_RUNTIME_LIBRARY_MultiThreaded         -Xclang -flto-visibility-public-std -D_MT -Xclang --dependent-lib=libcmt)
  87     set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_RUNTIME_LIBRARY_MultiThreadedDLL      -D_DLL -D_MT -Xclang --dependent-lib=msvcrt)
  88     set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_RUNTIME_LIBRARY_MultiThreadedDebug    -D_DEBUG -Xclang -flto-visibility-public-std -D_MT -Xclang --dependent-lib=libcmtd)
  89     set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_RUNTIME_LIBRARY_MultiThreadedDebugDLL -D_DEBUG -D_DLL -D_MT -Xclang --dependent-lib=msvcrtd)
  90
  91     if(CMAKE_MSVC_RUNTIME_LIBRARY_DEFAULT)
  92       set(_RTL_FLAGS "")
  93       set(_RTL_FLAGS_DEBUG "")
  94     else()
  95       set(_RTL_FLAGS_DEBUG " -D_DEBUG -D_DLL -D_MT -Xclang --dependent-lib=msvcrtd")
  96       set(_RTL_FLAGS " -D_DLL -D_MT -Xclang --dependent-lib=msvcrt")
  97     endif()
  98
  99     if(CMAKE_MSVC_DEBUG_INFORMATION_FORMAT_DEFAULT)
 100       set(_DBG_FLAGS "")
 101     else()
 102       set(_DBG_FLAGS " -g -Xclang -gcodeview")
 103     endif()
 104
 105     string(APPEND CMAKE_${lang}_FLAGS_DEBUG_INIT " -O0${_DBG_FLAGS}${_RTL_FLAGS_DEBUG}")
 106     string(APPEND CMAKE_${lang}_FLAGS_MINSIZEREL_INIT " -Os -DNDEBUG${_RTL_FLAGS}")
 107     string(APPEND CMAKE_${lang}_FLAGS_RELEASE_INIT " -O3 -DNDEBUG${_RTL_FLAGS}")
 108     string(APPEND CMAKE_${lang}_FLAGS_RELWITHDEBINFO_INIT " -O2 -DNDEBUG${_DBG_FLAGS}${_RTL_FLAGS}")
 109
 110     set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_DEBUG_INFORMATION_FORMAT_Embedded        -g -Xclang -gcodeview)
 111     #set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_DEBUG_INFORMATION_FORMAT_ProgramDatabase) # not supported by Clang
 112     #set(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_DEBUG_INFORMATION_FORMAT_EditAndContinue) # not supported by Clang
 113   endif()
 114   set(CMAKE_INCLUDE_SYSTEM_FLAG_${lang} "-isystem ")
 115   set(CMAKE_${lang}_LINKER_SUPPORTS_PDB ON)
 116
 117   set(CMAKE_PCH_EXTENSION .pch)
 118   set(CMAKE_PCH_PROLOGUE "#pragma clang system_header")
 119   set(CMAKE_${lang}_COMPILE_OPTIONS_USE_PCH -Xclang -include-pch -Xclang <PCH_FILE> -Xclang -include -Xclang <PCH_HEADER>)
 120   set(CMAKE_${lang}_COMPILE_OPTIONS_CREATE_PCH -Xclang -emit-pch -Xclang -include -Xclang <PCH_HEADER> -x ${__pch_header_${lang}})
 121
 122   unset(_DBG_FLAGS)
 123   unset(_RTL_FLAGS)
 124   unset(_RTL_FLAGS_DEBUG)
 125   string(TOLOWER "${CMAKE_BUILD_TYPE}" BUILD_TYPE_LOWER)
 126   set(CMAKE_${lang}_STANDARD_LIBRARIES_INIT "-lkernel32 -luser32 -lgdi32 -lwinspool -lshell32 -lole32 -loleaut32 -luuid -lcomdlg32 -ladvapi32 -loldnames")
 127
 128   # Features for LINK_LIBRARY generator expression
 129   if(MSVC_VERSION GREATER "1900")
 130     ## WHOLE_ARCHIVE: Force loading all members of an archive
 131     set(CMAKE_${lang}_LINK_LIBRARY_USING_WHOLE_ARCHIVE "LINKER:/WHOLEARCHIVE:<LIBRARY>")
 132     set(CMAKE_${lang}_LINK_LIBRARY_USING_WHOLE_ARCHIVE_SUPPORTED TRUE)
 133   endif()
 134
 135   enable_language(RC)
 136 endmacro()
 137
 138 macro(__enable_llvm_rc_preprocessing clang_option_prefix extra_pp_flags)
 139   # Feed the preprocessed rc file to llvm-rc
 140   if(CMAKE_RC_COMPILER_INIT MATCHES "llvm-rc" OR CMAKE_RC_COMPILER MATCHES "llvm-rc")
 141     if(DEFINED CMAKE_C_COMPILER_ID)
 142       set(CMAKE_RC_PREPROCESSOR CMAKE_C_COMPILER)
 143     elseif(DEFINED CMAKE_CXX_COMPILER_ID)
 144       set(CMAKE_RC_PREPROCESSOR CMAKE_CXX_COMPILER)
 145     endif()
 146     if(DEFINED CMAKE_RC_PREPROCESSOR)
 147       set(CMAKE_DEPFILE_FLAGS_RC "${clang_option_prefix}-MD ${clang_option_prefix}-MF ${clang_option_prefix}<DEP_FILE>")
 148       # The <FLAGS> are passed to the preprocess and the resource compiler to pick
 149       # up the eventual -D / -C options passed through the CMAKE_RC_FLAGS.
 150       set(CMAKE_RC_COMPILE_OBJECT "<CMAKE_COMMAND> -E cmake_llvm_rc <SOURCE> <OBJECT>.pp <${CMAKE_RC_PREPROCESSOR}> <DEFINES> -DRC_INVOKED <INCLUDES> <FLAGS> ${extra_pp_flags} -E -- <SOURCE> ++ <CMAKE_RC_COMPILER> <DEFINES> -I <SOURCE_DIR> <INCLUDES> <FLAGS> /fo <OBJECT> <OBJECT>.pp")
 151       if(CMAKE_GENERATOR MATCHES "Ninja")
 152         set(CMAKE_NINJA_CMCLDEPS_RC 0)
 153         set(CMAKE_NINJA_DEP_TYPE_RC gcc)
 154       endif()
 155       unset(CMAKE_RC_PREPROCESSOR)
 156     endif()
 157   endif()
 158 endmacro()
 159
 160 macro(__verify_same_language_values variable)
 161   foreach(lang "C" "CXX" "HIP")
 162     if(DEFINED CMAKE_${lang}_${variable})
 163       list(APPEND __LANGUAGE_VALUES_${variable} "${CMAKE_${lang}_${variable}}")
 164     endif()
 165   endforeach()
 166   list(REMOVE_DUPLICATES __LANGUAGE_VALUES_${variable})
 167   list(LENGTH __LANGUAGE_VALUES_${variable} __NUM_VALUES)
 168
 169   if(__NUM_VALUES GREATER 1)
 170     message(FATAL_ERROR ${ARGN})
 171   endif()
 172   unset(__NUM_VALUES)
 173   unset(__LANGUAGE_VALUES_${variable})
 174 endmacro()
 175
 176 if("x${CMAKE_C_SIMULATE_ID}" STREQUAL "xMSVC"
 177     OR "x${CMAKE_CXX_SIMULATE_ID}" STREQUAL "xMSVC"
 178     OR "x${CMAKE_HIP_SIMULATE_ID}" STREQUAL "xMSVC")
 179
 180   __verify_same_language_values(COMPILER_ID
 181                                 "The current configuration mixes Clang and MSVC or "
 182                                 "some other CL compatible compiler tool. This is not supported. "
 183                                 "Use either clang or MSVC as both C, C++ and/or HIP compilers.")
 184
 185   __verify_same_language_values(COMPILER_FRONTEND_VARIANT
 186                                 "The current configuration uses the Clang compiler "
 187                                 "tool with mixed frontend variants, both the GNU and in MSVC CL "
 188                                 "like variants. This is not supported. Use either clang/clang++ "
 189                                 "or clang-cl as both C, C++ and/or HIP compilers.")
 190
 191   if(NOT CMAKE_RC_COMPILER_INIT)
 192     # Check if rc is already in the path
 193     # This may happen in cases where the user is already in a visual studio environment when CMake is invoked
 194     find_program(__RC_COMPILER_PATH NAMES rc)
 195
 196     # Default to rc if it's available, otherwise fall back to llvm-rc
 197     if(__RC_COMPILER_PATH)
 198       set(CMAKE_RC_COMPILER_INIT rc)
 199     else()
 200       find_program(__RC_COMPILER_PATH NAMES llvm-rc)
 201       if(__RC_COMPILER_PATH)
 202         set(CMAKE_RC_COMPILER_INIT llvm-rc)
 203       endif()
 204     endif()
 205
 206     unset(__RC_COMPILER_PATH CACHE)
 207   endif()
 208
 209   if ( "x${CMAKE_CXX_COMPILER_FRONTEND_VARIANT}" STREQUAL "xMSVC"
 210       OR "x${CMAKE_C_COMPILER_FRONTEND_VARIANT}" STREQUAL "xMSVC"
 211       OR "x${CMAKE_HIP_COMPILER_FRONTEND_VARIANT}" STREQUAL "xMSVC")
 212
 213     include(Platform/Windows-MSVC)
 214     # Set the clang option forwarding prefix for clang-cl usage in the llvm-rc processing stage
 215     __enable_llvm_rc_preprocessing("-clang:" "")
 216     macro(__windows_compiler_clang_base lang)
 217       set(_COMPILE_${lang} "${_COMPILE_${lang}_MSVC}")
 218       __windows_compiler_msvc(${lang})
 219       unset(CMAKE_${lang}_COMPILE_OPTIONS_MSVC_DEBUG_INFORMATION_FORMAT_EditAndContinue) # -ZI not supported by Clang
 220       set(CMAKE_${lang}_COMPILE_OPTIONS_WARNING_AS_ERROR "-WX")
 221       set(CMAKE_INCLUDE_SYSTEM_FLAG_${lang} "-imsvc")
 222     endmacro()
 223   else()
 224     cmake_policy(GET CMP0091 __WINDOWS_CLANG_CMP0091)
 225     if(__WINDOWS_CLANG_CMP0091 STREQUAL "NEW")
 226       set(CMAKE_MSVC_RUNTIME_LIBRARY_DEFAULT "MultiThreaded$<$<CONFIG:Debug>:Debug>DLL")
 227     else()
 228       set(CMAKE_MSVC_RUNTIME_LIBRARY_DEFAULT "")
 229     endif()
 230     unset(__WINDOWS_CLANG_CMP0091)
 231
 232     cmake_policy(GET CMP0141 __WINDOWS_MSVC_CMP0141)
 233     if(__WINDOWS_MSVC_CMP0141 STREQUAL "NEW")
 234       set(CMAKE_MSVC_DEBUG_INFORMATION_FORMAT_DEFAULT "$<$<CONFIG:Debug,RelWithDebInfo>:Embedded>")
 235     else()
 236       set(CMAKE_MSVC_DEBUG_INFORMATION_FORMAT_DEFAULT "")
 237     endif()
 238     unset(__WINDOWS_MSVC_CMP0141)
 239
 240     set(CMAKE_BUILD_TYPE_INIT Debug)
 241
 242     __enable_llvm_rc_preprocessing("" "-x c")
 243     macro(__windows_compiler_clang_base lang)
 244       __windows_compiler_clang_gnu(${lang})
 245     endmacro()
 246   endif()
 247
 248 else()
 249   include(Platform/Windows-GNU)
 250   __enable_llvm_rc_preprocessing("" "-x c")
 251   macro(__windows_compiler_clang_base lang)
 252     __windows_compiler_gnu(${lang})
 253   endmacro()
 254 endif()
 255
 256 macro(__windows_compiler_clang lang)
 257   if(CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.4.0)
 258     set(CMAKE_${lang}_COMPILE_OPTIONS_TARGET "-target ")
 259   else()
 260     set(CMAKE_${lang}_COMPILE_OPTIONS_TARGET "--target=")
 261   endif()
 262   __windows_compiler_clang_base(${lang})
 263 endmacro()