Modules/Platform/Linux-IntelLLVM.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4
   5 # This module is shared by multiple languages; use include blocker.
   6 if(__LINUX_COMPILER_INTEL_LLVM)
   7   return()
   8 endif()
   9 set(__LINUX_COMPILER_INTEL_LLVM 1)
  10
  11 if(NOT XIAR)
  12   set(_intel_xiar_hints)
  13   foreach(lang C CXX Fortran)
  14     if(IS_ABSOLUTE "${CMAKE_${lang}_COMPILER}")
  15       get_filename_component(_hint "${CMAKE_${lang}_COMPILER}" PATH)
  16       list(APPEND _intel_xiar_hints ${_hint})
  17     endif()
  18   endforeach()
  19   find_program(XIAR NAMES xiar HINTS ${_intel_xiar_hints})
  20   mark_as_advanced(XIAR)
  21 endif()
  22
  23 macro(__linux_compiler_intel_llvm lang)
  24   set(CMAKE_${lang}_COMPILE_OPTIONS_PIC "-fPIC")
  25   set(CMAKE_${lang}_COMPILE_OPTIONS_PIE "-fPIE")
  26   set(_CMAKE_${lang}_PIE_MAY_BE_SUPPORTED_BY_LINKER NO)
  27   set(_CMAKE_${lang}_PIE_MAY_BE_SUPPORTED_BY_LINKER YES)
  28   set(CMAKE_${lang}_LINK_OPTIONS_PIE ${CMAKE_${lang}_COMPILE_OPTIONS_PIE} "-pie")
  29   set(CMAKE_${lang}_LINK_OPTIONS_NO_PIE "-no-pie")
  30   set(CMAKE_SHARED_LIBRARY_${lang}_FLAGS "-fPIC")
  31   set(CMAKE_SHARED_LIBRARY_CREATE_${lang}_FLAGS "-shared")
  32
  33   # We pass this for historical reasons.  Projects may have
  34   # executables that use dlopen but do not set ENABLE_EXPORTS.
  35   set(CMAKE_SHARED_LIBRARY_LINK_${lang}_FLAGS "-rdynamic")
  36
  37   set(CMAKE_${lang}_LINKER_WRAPPER_FLAG "-Wl,")
  38   set(CMAKE_${lang}_LINKER_WRAPPER_FLAG_SEP ",")
  39
  40   set(_CMAKE_${lang}_IPO_SUPPORTED_BY_CMAKE YES)
  41
  42   if(XIAR)
  43     # INTERPROCEDURAL_OPTIMIZATION
  44     set(CMAKE_${lang}_COMPILE_OPTIONS_IPO -ipo)
  45     set(CMAKE_${lang}_CREATE_STATIC_LIBRARY_IPO
  46       "${XIAR} cr <TARGET> <LINK_FLAGS> <OBJECTS> "
  47       "${XIAR} -s <TARGET> ")
  48     set(_CMAKE_${lang}_IPO_MAY_BE_SUPPORTED_BY_COMPILER YES)
  49     set(_CMAKE_${lang}_IPO_LEGACY_BEHAVIOR YES)
  50   else()
  51     set(_CMAKE_${lang}_IPO_MAY_BE_SUPPORTED_BY_COMPILER NO)
  52   endif()
  53
  54   set(CMAKE_${lang}_COMPILE_OPTIONS_VISIBILITY "-fvisibility=")
  55 endmacro()