Modules/Internal/CPack/CPackDeb.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 # CPack script for creating Debian package
   5 # Author: Mathieu Malaterre
   6 #
   7 # http://wiki.debian.org/HowToPackageForDebian
   8
   9 if(CMAKE_BINARY_DIR)
  10   message(FATAL_ERROR "CPackDeb.cmake may only be used by CPack internally.")
  11 endif()
  12
  13 cmake_policy(PUSH)
  14 cmake_policy(SET CMP0057 NEW) # if IN_LIST
  15
  16 function(cpack_deb_variable_fallback OUTPUT_VAR_NAME)
  17   set(FALLBACK_VAR_NAMES ${ARGN})
  18
  19   foreach(variable_name IN LISTS FALLBACK_VAR_NAMES)
  20     if(${variable_name})
  21       set(${OUTPUT_VAR_NAME} "${${variable_name}}" PARENT_SCOPE)
  22       break()
  23     endif()
  24   endforeach()
  25 endfunction()
  26
  27 function(get_component_package_name var component)
  28   string(TOUPPER "${component}" component_upcase)
  29   if(CPACK_DEBIAN_${component_upcase}_PACKAGE_NAME)
  30     string(TOLOWER "${CPACK_DEBIAN_${component_upcase}_PACKAGE_NAME}" package_name)
  31   else()
  32     string(TOLOWER "${CPACK_DEBIAN_PACKAGE_NAME}-${component}" package_name)
  33   endif()
  34
  35   set("${var}" "${package_name}" PARENT_SCOPE)
  36 endfunction()
  37
  38 #extract library name and version for given shared object
  39 function(extract_so_info shared_object libname version)
  40   if(READELF_EXECUTABLE)
  41     execute_process(COMMAND "${READELF_EXECUTABLE}" -d "${shared_object}"
  42       WORKING_DIRECTORY "${CPACK_TEMPORARY_DIRECTORY}"
  43       RESULT_VARIABLE result
  44       OUTPUT_VARIABLE output
  45       ERROR_QUIET
  46       OUTPUT_STRIP_TRAILING_WHITESPACE)
  47     if(result EQUAL 0)
  48       string(REGEX MATCH "\\(?SONAME\\)?[^\n]*\\[([^\n]+)\\.so\\.([^\n]*)\\]" soname "${output}")
  49       set(${libname} "${CMAKE_MATCH_1}" PARENT_SCOPE)
  50       set(${version} "${CMAKE_MATCH_2}" PARENT_SCOPE)
  51     else()
  52       message(WARNING "Error running readelf for \"${shared_object}\"")
  53     endif()
  54   else()
  55     message(FATAL_ERROR "Readelf utility is not available.")
  56   endif()
  57 endfunction()
  58
  59 function(cpack_deb_check_description SUMMARY LINES RESULT_VARIABLE)
  60   set(_result TRUE)
  61
  62   # Get the summary line
  63   if(NOT SUMMARY MATCHES "^[^\\s].*$")
  64     set(_result FALSE)
  65     set(${RESULT_VARIABLE} ${_result} PARENT_SCOPE)
  66     return()
  67   endif()
  68
  69   foreach(_line IN LISTS LINES)
  70     if(NOT _line MATCHES "^ +[^ ]+.*$")
  71       set(_result FALSE)
  72       break()
  73     endif()
  74   endforeach()
  75
  76   set(${RESULT_VARIABLE} ${_result} PARENT_SCOPE)
  77 endfunction()
  78
  79 function(cpack_deb_format_package_description TEXT OUTPUT_VAR)
  80   # Turn the possible multi-line string into a list
  81   string(UUID uuid NAMESPACE 00000000-0000-0000-0000-000000000000 TYPE SHA1)
  82   string(REPLACE ";" "${uuid}" _text "${TEXT}")
  83   string(REPLACE "\n" ";" _lines "${_text}")
  84   list(POP_FRONT _lines _summary)
  85
  86   # If the description ends with a newline (e.g. typically if it was read
  87   # from a file) the last line will be empty. We drop it here, otherwise
  88   # it would be replaced by a `.` which would lead to the package violating
  89   # the extended-description-contains-empty-paragraph debian policy
  90   list(POP_BACK _lines _last_line)
  91   string(STRIP "${_last_line}" _last_line_strip)
  92   if(_last_line_strip)
  93     list(APPEND _lines "${_last_line_strip}")
  94   endif()
  95
  96   # Check if reformatting required
  97   cpack_deb_check_description("${_summary}" "${_lines}" _result)
  98   if(_result)
  99     # Ok, no formatting required
 100     set(${OUTPUT_VAR} "${TEXT}" PARENT_SCOPE)
 101     return()
 102   endif()
 103
 104   # Format the summary line
 105   string(STRIP "${_summary}" _summary)
 106
 107   # Make sure the rest formatted properly
 108   set(_result)
 109   foreach(_line IN LISTS _lines)
 110     string(STRIP "${_line}" _line_strip)
 111     if(NOT _line_strip)
 112       # Replace empty lines w/ a _single full stop character_
 113       set(_line " .")
 114     else()
 115       # Prepend the normal lines w/ a single space.
 116       # If the line already starts w/ at least one space,
 117       # it'll become _verbatim_ (assuming it supposed to be
 118       # verbatim in the original text).
 119       string(PREPEND _line " ")
 120     endif()
 121     list(APPEND _result "${_line}")
 122   endforeach()
 123
 124   list(PREPEND _result "${_summary}")
 125   list(JOIN _result "\n" _result)
 126   string(REPLACE "${uuid}"  ";" _result "${_result}")
 127   set(${OUTPUT_VAR} "${_result}" PARENT_SCOPE)
 128 endfunction()
 129
 130 function(cpack_deb_prepare_package_vars)
 131   # CPACK_DEBIAN_PACKAGE_SHLIBDEPS
 132   # If specify OFF, only user depends are used
 133   if(NOT DEFINED CPACK_DEBIAN_PACKAGE_SHLIBDEPS)
 134     set(CPACK_DEBIAN_PACKAGE_SHLIBDEPS OFF)
 135   endif()
 136
 137   set(WDIR "${CPACK_TOPLEVEL_DIRECTORY}/${CPACK_PACKAGE_FILE_NAME}${CPACK_DEB_PACKAGE_COMPONENT_PART_PATH}")
 138   set(DBGSYMDIR "${CPACK_TOPLEVEL_DIRECTORY}/${CPACK_PACKAGE_FILE_NAME}${CPACK_DEB_PACKAGE_COMPONENT_PART_PATH}-dbgsym")
 139   file(REMOVE_RECURSE "${DBGSYMDIR}")
 140
 141   # per component automatic discover: some of the component might not have
 142   # binaries.
 143   if(CPACK_DEB_PACKAGE_COMPONENT)
 144     string(TOUPPER "${CPACK_DEB_PACKAGE_COMPONENT}" _local_component_name)
 145     set(_component_shlibdeps_var "CPACK_DEBIAN_${_local_component_name}_PACKAGE_SHLIBDEPS")
 146
 147     # if set, overrides the global configuration
 148     if(DEFINED ${_component_shlibdeps_var})
 149       set(CPACK_DEBIAN_PACKAGE_SHLIBDEPS "${${_component_shlibdeps_var}}")
 150       if(CPACK_DEBIAN_PACKAGE_DEBUG)
 151         message("CPackDeb Debug: component '${CPACK_DEB_PACKAGE_COMPONENT}' dpkg-shlibdeps set to ${CPACK_DEBIAN_PACKAGE_SHLIBDEPS}")
 152       endif()
 153     endif()
 154   endif()
 155
 156   cpack_deb_variable_fallback("CPACK_DEBIAN_DEBUGINFO_PACKAGE"
 157     "CPACK_DEBIAN_${_local_component_name}_DEBUGINFO_PACKAGE"
 158     "CPACK_DEBIAN_DEBUGINFO_PACKAGE")
 159   if(CPACK_DEBIAN_PACKAGE_SHLIBDEPS OR CPACK_DEBIAN_PACKAGE_GENERATE_SHLIBS OR CPACK_DEBIAN_DEBUGINFO_PACKAGE)
 160     # Generating binary list - Get type of all install files
 161     file(GLOB_RECURSE FILE_PATHS_ LIST_DIRECTORIES false RELATIVE "${WDIR}" "${WDIR}/*")
 162
 163     find_program(FILE_EXECUTABLE file)
 164     if(NOT FILE_EXECUTABLE)
 165       message(FATAL_ERROR "CPackDeb: file utility is not available. CPACK_DEBIAN_PACKAGE_SHLIBDEPS and CPACK_DEBIAN_PACKAGE_GENERATE_SHLIBS options are not available.")
 166     endif()
 167
 168     # get file info so that we can determine if file is executable or not
 169     unset(CPACK_DEB_INSTALL_FILES)
 170     foreach(FILE_ IN LISTS FILE_PATHS_)
 171       execute_process(COMMAND ${CMAKE_COMMAND} -E env LC_ALL=C ${FILE_EXECUTABLE} "./${FILE_}"
 172         WORKING_DIRECTORY "${WDIR}"
 173         RESULT_VARIABLE FILE_RESULT_
 174         OUTPUT_VARIABLE INSTALL_FILE_)
 175       if(NOT FILE_RESULT_ EQUAL 0)
 176         message(FATAL_ERROR "CPackDeb: execution of command: '${FILE_EXECUTABLE} ./${FILE_}' failed with exit code: ${FILE_RESULT_}")
 177       endif()
 178       list(APPEND CPACK_DEB_INSTALL_FILES "${INSTALL_FILE_}")
 179     endforeach()
 180
 181     # Only dynamically linked ELF files are included
 182     # Extract only file name infront of ":"
 183     foreach(_FILE IN LISTS CPACK_DEB_INSTALL_FILES)
 184       if(_FILE MATCHES "ELF.*dynamically linked")
 185         string(REGEX MATCH "(^.*):" _FILE_NAME "${_FILE}")
 186         list(APPEND CPACK_DEB_BINARY_FILES "${CMAKE_MATCH_1}")
 187         set(CONTAINS_EXECUTABLE_FILES_ TRUE)
 188       endif()
 189       if(_FILE MATCHES "ELF.*shared object")
 190         string(REGEX MATCH "(^.*):" _FILE_NAME "${_FILE}")
 191         list(APPEND CPACK_DEB_SHARED_OBJECT_FILES "${CMAKE_MATCH_1}")
 192       endif()
 193       if(_FILE MATCHES "ELF.*not stripped")
 194         string(REGEX MATCH "(^.*):" _FILE_NAME "${_FILE}")
 195         list(APPEND CPACK_DEB_UNSTRIPPED_FILES "${CMAKE_MATCH_1}")
 196       endif()
 197     endforeach()
 198   endif()
 199
 200   find_program(READELF_EXECUTABLE NAMES readelf)
 201
 202   if(CPACK_DEBIAN_DEBUGINFO_PACKAGE AND CPACK_DEB_UNSTRIPPED_FILES)
 203     find_program(OBJCOPY_EXECUTABLE NAMES objcopy)
 204
 205     if(NOT OBJCOPY_EXECUTABLE)
 206       message(FATAL_ERROR "debuginfo packages require the objcopy tool")
 207     endif()
 208     if(NOT READELF_EXECUTABLE)
 209       message(FATAL_ERROR "debuginfo packages require the readelf tool")
 210     endif()
 211
 212     file(RELATIVE_PATH _DBGSYM_ROOT "${CPACK_TEMPORARY_DIRECTORY}" "${DBGSYMDIR}")
 213     foreach(_FILE IN LISTS CPACK_DEB_UNSTRIPPED_FILES)
 214
 215       # Get the file's Build ID
 216       execute_process(COMMAND env LC_ALL=C ${READELF_EXECUTABLE} -n "${_FILE}"
 217         WORKING_DIRECTORY "${CPACK_TEMPORARY_DIRECTORY}"
 218         OUTPUT_VARIABLE READELF_OUTPUT
 219         RESULT_VARIABLE READELF_RESULT
 220         ERROR_VARIABLE READELF_ERROR
 221         OUTPUT_STRIP_TRAILING_WHITESPACE )
 222       if(NOT READELF_RESULT EQUAL 0)
 223         message(FATAL_ERROR "CPackDeb: readelf: '${READELF_ERROR}';\n"
 224             "executed command: '${READELF_EXECUTABLE} -n ${_FILE}'")
 225       endif()
 226       if(READELF_OUTPUT MATCHES "Build ID: ([0-9a-zA-Z][0-9a-zA-Z])([0-9a-zA-Z]*)")
 227         set(_BUILD_ID_START ${CMAKE_MATCH_1})
 228         set(_BUILD_ID_REMAINING ${CMAKE_MATCH_2})
 229         list(APPEND BUILD_IDS ${_BUILD_ID_START}${_BUILD_ID_REMAINING})
 230       else()
 231         message(FATAL_ERROR "Unable to determine Build ID for ${_FILE}")
 232       endif()
 233
 234       # Split out the debug symbols from the binaries
 235       set(_FILE_DBGSYM ${_DBGSYM_ROOT}/usr/lib/debug/.build-id/${_BUILD_ID_START}/${_BUILD_ID_REMAINING}.debug)
 236       get_filename_component(_OUT_DIR "${_FILE_DBGSYM}" DIRECTORY)
 237       file(MAKE_DIRECTORY "${CPACK_TEMPORARY_DIRECTORY}/${_OUT_DIR}")
 238       execute_process(COMMAND ${OBJCOPY_EXECUTABLE} --only-keep-debug "${_FILE}" "${_FILE_DBGSYM}"
 239         WORKING_DIRECTORY "${CPACK_TEMPORARY_DIRECTORY}"
 240         OUTPUT_VARIABLE OBJCOPY_OUTPUT
 241         RESULT_VARIABLE OBJCOPY_RESULT
 242         ERROR_VARIABLE OBJCOPY_ERROR
 243         OUTPUT_STRIP_TRAILING_WHITESPACE )
 244       if(NOT OBJCOPY_RESULT EQUAL 0)
 245         message(FATAL_ERROR "CPackDeb: objcopy: '${OBJCOPY_ERROR}';\n"
 246             "executed command: '${OBJCOPY_EXECUTABLE} --only-keep-debug ${_FILE} ${_FILE_DBGSYM}'")
 247       endif()
 248       execute_process(COMMAND ${OBJCOPY_EXECUTABLE} --strip-unneeded ${_FILE}
 249         WORKING_DIRECTORY "${CPACK_TEMPORARY_DIRECTORY}"
 250         OUTPUT_VARIABLE OBJCOPY_OUTPUT
 251         RESULT_VARIABLE OBJCOPY_RESULT
 252         ERROR_VARIABLE OBJCOPY_ERROR
 253         OUTPUT_STRIP_TRAILING_WHITESPACE )
 254       if(NOT OBJCOPY_RESULT EQUAL 0)
 255         message(FATAL_ERROR "CPackDeb: objcopy: '${OBJCOPY_ERROR}';\n"
 256             "executed command: '${OBJCOPY_EXECUTABLE} --strip-debug ${_FILE}'")
 257       endif()
 258       execute_process(COMMAND ${OBJCOPY_EXECUTABLE} --add-gnu-debuglink=${_FILE_DBGSYM} ${_FILE}
 259         WORKING_DIRECTORY "${CPACK_TEMPORARY_DIRECTORY}"
 260         OUTPUT_VARIABLE OBJCOPY_OUTPUT
 261         RESULT_VARIABLE OBJCOPY_RESULT
 262         ERROR_VARIABLE OBJCOPY_ERROR
 263         OUTPUT_STRIP_TRAILING_WHITESPACE )
 264       if(NOT OBJCOPY_RESULT EQUAL 0)
 265         message(FATAL_ERROR "CPackDeb: objcopy: '${OBJCOPY_ERROR}';\n"
 266             "executed command: '${OBJCOPY_EXECUTABLE} --add-gnu-debuglink=${_FILE_DBGSYM} ${_FILE}'")
 267       endif()
 268     endforeach()
 269   endif()
 270
 271   if(CPACK_DEBIAN_PACKAGE_SHLIBDEPS)
 272     # dpkg-shlibdeps is a Debian utility for generating dependency list
 273     find_program(SHLIBDEPS_EXECUTABLE dpkg-shlibdeps)
 274
 275     if(SHLIBDEPS_EXECUTABLE)
 276       # Check version of the dpkg-shlibdeps tool using CPackDEB method
 277       execute_process(COMMAND ${CMAKE_COMMAND} -E env LC_ALL=C ${SHLIBDEPS_EXECUTABLE} --version
 278         OUTPUT_VARIABLE _TMP_VERSION
 279         ERROR_QUIET
 280         OUTPUT_STRIP_TRAILING_WHITESPACE)
 281       if(_TMP_VERSION MATCHES "dpkg-shlibdeps version ([0-9]+\\.[0-9]+\\.[0-9]+)")
 282         set(SHLIBDEPS_EXECUTABLE_VERSION "${CMAKE_MATCH_1}")
 283       else()
 284         unset(SHLIBDEPS_EXECUTABLE_VERSION)
 285       endif()
 286
 287       if(CPACK_DEBIAN_PACKAGE_DEBUG)
 288         message("CPackDeb Debug: dpkg-shlibdeps --version output is '${_TMP_VERSION}'")
 289         message("CPackDeb Debug: dpkg-shlibdeps version is <${SHLIBDEPS_EXECUTABLE_VERSION}>")
 290       endif()
 291
 292       if(CONTAINS_EXECUTABLE_FILES_)
 293         message("CPackDeb: - Generating dependency list")
 294
 295         # Create blank control file for running dpkg-shlibdeps
 296         # There might be some other way to invoke dpkg-shlibdeps without creating this file
 297         # but standard debian package should not have anything that can collide with this file or directory
 298         file(MAKE_DIRECTORY ${CPACK_TEMPORARY_DIRECTORY}/debian)
 299         file(WRITE ${CPACK_TEMPORARY_DIRECTORY}/debian/control "")
 300
 301         # Create a DEBIAN directory so that dpkg-shlibdeps can find the package dir when resolving $ORIGIN.
 302         file(MAKE_DIRECTORY "${CPACK_TEMPORARY_DIRECTORY}/DEBIAN")
 303
 304         # Add --ignore-missing-info if the tool supports it
 305         execute_process(COMMAND ${CMAKE_COMMAND} -E env LC_ALL=C ${SHLIBDEPS_EXECUTABLE} --help
 306           OUTPUT_VARIABLE _TMP_HELP
 307           ERROR_QUIET
 308           OUTPUT_STRIP_TRAILING_WHITESPACE)
 309         if(_TMP_HELP MATCHES "--ignore-missing-info")
 310           set(IGNORE_MISSING_INFO_FLAG "--ignore-missing-info")
 311         endif()
 312
 313         if(CPACK_DEBIAN_PACKAGE_SHLIBDEPS_PRIVATE_DIRS)
 314           unset(PRIVATE_SEARCH_DIR_OPTIONS)
 315           # Add -l option if the tool supports it
 316           if(DEFINED SHLIBDEPS_EXECUTABLE_VERSION AND SHLIBDEPS_EXECUTABLE_VERSION VERSION_GREATER_EQUAL 1.17.0)
 317             foreach(dir IN LISTS CPACK_DEBIAN_PACKAGE_SHLIBDEPS_PRIVATE_DIRS)
 318               list(APPEND PRIVATE_SEARCH_DIR_OPTIONS "-l${dir}")
 319             endforeach()
 320           else()
 321             message(WARNING "CPackDeb: dkpg-shlibdeps is too old. \"CPACK_DEBIAN_PACKAGE_SHLIBDEPS_PRIVATE_DIRS\" is therefore ignored.")
 322           endif()
 323         endif()
 324
 325         # Execute dpkg-shlibdeps
 326         # --ignore-missing-info : allow dpkg-shlibdeps to run even if some libs do not belong to a package
 327         # -l<dir>: make dpkg-shlibdeps also search in this directory for (private) shared library dependencies
 328         # -O : print to STDOUT
 329         execute_process(COMMAND ${SHLIBDEPS_EXECUTABLE} ${PRIVATE_SEARCH_DIR_OPTIONS} ${IGNORE_MISSING_INFO_FLAG} -O ${CPACK_DEB_BINARY_FILES}
 330           WORKING_DIRECTORY "${CPACK_TEMPORARY_DIRECTORY}"
 331           OUTPUT_VARIABLE SHLIBDEPS_OUTPUT
 332           RESULT_VARIABLE SHLIBDEPS_RESULT
 333           ERROR_VARIABLE SHLIBDEPS_ERROR
 334           OUTPUT_STRIP_TRAILING_WHITESPACE )
 335
 336         # E2K OSL 6.0.1 and prior has broken dpkg-shlibdeps. CPack will deal with that (mocking SHLIBDEPS_OUTPUT), but inform user of this.
 337         if("${SHLIBDEPS_ERROR}" MATCHES "unknown gcc system type e2k.*, falling back to default")
 338           message(WARNING "CPackDeb: broken dpkg-shlibdeps on E2K detected, will fall back to minimal dependencies.\n"
 339                   "You should expect that dependencies list in the package will be incomplete.")
 340           set(SHLIBDEPS_OUTPUT "shlibs:Depends=libc6, lcc-libs")
 341         endif()
 342
 343         if(CPACK_DEBIAN_PACKAGE_DEBUG)
 344           # dpkg-shlibdeps will throw some warnings if some input files are not binary
 345           message( "CPackDeb Debug: dpkg-shlibdeps warnings \n${SHLIBDEPS_ERROR}")
 346         endif()
 347         if(NOT SHLIBDEPS_RESULT EQUAL 0)
 348           message(FATAL_ERROR "CPackDeb: dpkg-shlibdeps: '${SHLIBDEPS_ERROR}';\n"
 349               "executed command: '${SHLIBDEPS_EXECUTABLE} ${PRIVATE_SEARCH_DIR_OPTIONS} ${IGNORE_MISSING_INFO_FLAG} -O ${CPACK_DEB_BINARY_FILES}';\n"
 350               "found files: '${INSTALL_FILE_}';\n"
 351               "files info: '${CPACK_DEB_INSTALL_FILES}';\n"
 352               "binary files: '${CPACK_DEB_BINARY_FILES}'")
 353         endif()
 354
 355         #Get rid of prefix generated by dpkg-shlibdeps
 356         string(REGEX REPLACE "^.*Depends=" "" CPACK_DEBIAN_PACKAGE_AUTO_DEPENDS "${SHLIBDEPS_OUTPUT}")
 357
 358         if(CPACK_DEBIAN_PACKAGE_DEBUG)
 359           message("CPackDeb Debug: Found dependency: ${CPACK_DEBIAN_PACKAGE_AUTO_DEPENDS} from output ${SHLIBDEPS_OUTPUT}")
 360         endif()
 361
 362         # Remove blank control file
 363         # Might not be safe if package actual contain file or directory named debian
 364         file(REMOVE_RECURSE "${CPACK_TEMPORARY_DIRECTORY}/debian")
 365
 366         # remove temporary directory that was created only for dpkg-shlibdeps execution
 367         file(REMOVE_RECURSE "${CPACK_TEMPORARY_DIRECTORY}/DEBIAN")
 368       else()
 369         if(CPACK_DEBIAN_PACKAGE_DEBUG)
 370           message(AUTHOR_WARNING "CPackDeb Debug: Using only user-provided depends because package does not contain executable files that link to shared libraries.")
 371         endif()
 372       endif()
 373     else()
 374       message("CPackDeb: Using only user-provided dependencies because dpkg-shlibdeps is not found.")
 375     endif()
 376
 377   else()
 378     if(CPACK_DEBIAN_PACKAGE_DEBUG)
 379       message("CPackDeb Debug: Using only user-provided dependencies")
 380     endif()
 381   endif()
 382
 383   # Let's define the control file found in debian package:
 384
 385   # Binary package:
 386   # http://www.debian.org/doc/debian-policy/ch-controlfields.html#s-binarycontrolfiles
 387
 388   # DEBIAN/control
 389   # debian policy enforce lower case for package name
 390   # Package: (mandatory)
 391   if(NOT CPACK_DEBIAN_PACKAGE_NAME)
 392     string(TOLOWER "${CPACK_PACKAGE_NAME}" CPACK_DEBIAN_PACKAGE_NAME)
 393   endif()
 394
 395   # Version: (mandatory)
 396   if(NOT CPACK_DEBIAN_PACKAGE_VERSION)
 397     if(NOT CPACK_PACKAGE_VERSION)
 398       message(FATAL_ERROR "CPackDeb: Debian package requires a package version")
 399     endif()
 400     set(CPACK_DEBIAN_PACKAGE_VERSION ${CPACK_PACKAGE_VERSION})
 401   endif()
 402
 403   if(DEFINED CPACK_DEBIAN_PACKAGE_RELEASE OR DEFINED CPACK_DEBIAN_PACKAGE_EPOCH)
 404     # only test the version format if CPACK_DEBIAN_PACKAGE_RELEASE or
 405     # CPACK_DEBIAN_PACKAGE_EPOCH is set
 406     if(NOT CPACK_DEBIAN_PACKAGE_VERSION MATCHES "^[0-9][A-Za-z0-9.+~-]*$")
 407       message(FATAL_ERROR
 408         "CPackDeb: Debian package version must confirm to \"^[0-9][A-Za-z0-9.+~-]*$\" regex!")
 409     endif()
 410   else()
 411     # before CMake 3.10 version format was not tested so only warn to preserve
 412     # backward compatibility
 413     if(NOT CPACK_DEBIAN_PACKAGE_VERSION MATCHES "^([0-9]+:)?[0-9][A-Za-z0-9.+~-]*$")
 414       message(AUTHOR_WARNING
 415         "CPackDeb: Debian package versioning ([<epoch>:]<version>[-<release>])"
 416         " should confirm to \"^([0-9]+:)?[0-9][A-Za-z0-9.+~-]*$\" regex in"
 417         " order to satisfy Debian packaging rules.")
 418     endif()
 419   endif()
 420
 421   if(CPACK_DEBIAN_PACKAGE_RELEASE)
 422     if(NOT CPACK_DEBIAN_PACKAGE_RELEASE MATCHES "^[A-Za-z0-9.+~]+$")
 423       message(FATAL_ERROR
 424         "CPackDeb: Debian package release must confirm to \"^[A-Za-z0-9.+~]+$\" regex!")
 425     endif()
 426     string(APPEND CPACK_DEBIAN_PACKAGE_VERSION
 427       "-${CPACK_DEBIAN_PACKAGE_RELEASE}")
 428   elseif(DEFINED CPACK_DEBIAN_PACKAGE_EPOCH)
 429     # only test the version format if CPACK_DEBIAN_PACKAGE_RELEASE or
 430     # CPACK_DEBIAN_PACKAGE_EPOCH is set - versions CPack/Deb generator before
 431     # CMake 3.10 did not check for version format so we have to preserve
 432     # backward compatibility
 433     if(CPACK_DEBIAN_PACKAGE_VERSION MATCHES ".*-.*")
 434       message(FATAL_ERROR
 435         "CPackDeb: Debian package version must not contain hyphens when CPACK_DEBIAN_PACKAGE_RELEASE is not provided!")
 436     endif()
 437   endif()
 438
 439   if(CPACK_DEBIAN_PACKAGE_EPOCH)
 440     if(NOT CPACK_DEBIAN_PACKAGE_EPOCH MATCHES "^[0-9]+$")
 441       message(FATAL_ERROR
 442         "CPackDeb: Debian package epoch must confirm to \"^[0-9]+$\" regex!")
 443     endif()
 444     set(CPACK_DEBIAN_PACKAGE_VERSION
 445       "${CPACK_DEBIAN_PACKAGE_EPOCH}:${CPACK_DEBIAN_PACKAGE_VERSION}")
 446   endif()
 447
 448   # Architecture: (mandatory)
 449   if(CPACK_DEB_PACKAGE_COMPONENT AND CPACK_DEBIAN_${_local_component_name}_PACKAGE_ARCHITECTURE)
 450     set(CPACK_DEBIAN_PACKAGE_ARCHITECTURE "${CPACK_DEBIAN_${_local_component_name}_PACKAGE_ARCHITECTURE}")
 451   elseif(NOT CPACK_DEBIAN_PACKAGE_ARCHITECTURE)
 452     # There is no such thing as i686 architecture on debian, you should use i386 instead
 453     # $ dpkg --print-architecture
 454     find_program(DPKG_CMD dpkg)
 455     if(NOT DPKG_CMD)
 456       message(STATUS "CPackDeb: Can not find dpkg in your path, default to i386.")
 457       set(CPACK_DEBIAN_PACKAGE_ARCHITECTURE i386)
 458     endif()
 459     execute_process(COMMAND "${DPKG_CMD}" --print-architecture
 460       OUTPUT_VARIABLE CPACK_DEBIAN_PACKAGE_ARCHITECTURE
 461       OUTPUT_STRIP_TRAILING_WHITESPACE
 462       )
 463   endif()
 464
 465   # Source: (optional)
 466   # in case several packages are constructed from a unique source
 467   # (multipackaging), the source may be indicated as well.
 468   # The source might contain a version if the generated package
 469   # version is different from the source version
 470   if(NOT CPACK_DEBIAN_PACKAGE_SOURCE)
 471     set(CPACK_DEBIAN_PACKAGE_SOURCE "")
 472   endif()
 473
 474   # have a look at get_property(result GLOBAL PROPERTY ENABLED_FEATURES),
 475   # this returns the successful find_package() calls, maybe this can help
 476   # Depends:
 477   # You should set: DEBIAN_PACKAGE_DEPENDS
 478   # TODO: automate 'objdump -p | grep NEEDED'
 479
 480   # if per-component variable, overrides the global CPACK_DEBIAN_PACKAGE_${variable_type_}
 481   # automatic dependency discovery will be performed afterwards.
 482   if(CPACK_DEB_PACKAGE_COMPONENT)
 483     foreach(value_type_ IN ITEMS DEPENDS RECOMMENDS SUGGESTS PREDEPENDS ENHANCES BREAKS CONFLICTS PROVIDES REPLACES SOURCE SECTION PRIORITY NAME)
 484       set(_component_var "CPACK_DEBIAN_${_local_component_name}_PACKAGE_${value_type_}")
 485
 486       # if set, overrides the global variable
 487       if(DEFINED ${_component_var})
 488         set(CPACK_DEBIAN_PACKAGE_${value_type_} "${${_component_var}}")
 489         if(CPACK_DEBIAN_PACKAGE_DEBUG)
 490           message("CPackDeb Debug: component '${_local_component_name}' ${value_type_} "
 491             "value set to '${CPACK_DEBIAN_PACKAGE_${value_type_}}'")
 492         endif()
 493       endif()
 494     endforeach()
 495
 496     if(CPACK_DEBIAN_ENABLE_COMPONENT_DEPENDS)
 497       unset(COMPONENT_DEPENDS)
 498       foreach(_PACK IN LISTS CPACK_COMPONENT_${_local_component_name}_DEPENDS)
 499         get_component_package_name(_PACK_NAME "${_PACK}")
 500         list(PREPEND COMPONENT_DEPENDS "${_PACK_NAME} (= ${CPACK_DEBIAN_PACKAGE_VERSION})")
 501       endforeach()
 502       list(JOIN COMPONENT_DEPENDS ", " COMPONENT_DEPENDS)
 503       if(COMPONENT_DEPENDS)
 504         list(PREPEND CPACK_DEBIAN_PACKAGE_DEPENDS ${COMPONENT_DEPENDS})
 505         list(JOIN CPACK_DEBIAN_PACKAGE_DEPENDS ", " CPACK_DEBIAN_PACKAGE_DEPENDS)
 506       endif()
 507     endif()
 508   endif()
 509
 510   # at this point, the CPACK_DEBIAN_PACKAGE_DEPENDS is properly set
 511   # to the minimal dependency of the package
 512   # Append automatically discovered dependencies .
 513   if(CPACK_DEBIAN_PACKAGE_AUTO_DEPENDS)
 514     list(APPEND CPACK_DEBIAN_PACKAGE_DEPENDS ${CPACK_DEBIAN_PACKAGE_AUTO_DEPENDS})
 515     list(JOIN CPACK_DEBIAN_PACKAGE_DEPENDS ", " CPACK_DEBIAN_PACKAGE_DEPENDS)
 516   endif()
 517
 518   if(NOT CPACK_DEBIAN_PACKAGE_DEPENDS)
 519     message(STATUS "CPACK_DEBIAN_PACKAGE_DEPENDS not set, the package will have no dependencies.")
 520   endif()
 521
 522   # Maintainer: (mandatory)
 523   if(NOT CPACK_DEBIAN_PACKAGE_MAINTAINER)
 524     if(NOT CPACK_PACKAGE_CONTACT)
 525       message(FATAL_ERROR "CPackDeb: Debian package requires a maintainer for a package, set CPACK_PACKAGE_CONTACT or CPACK_DEBIAN_PACKAGE_MAINTAINER")
 526     endif()
 527     set(CPACK_DEBIAN_PACKAGE_MAINTAINER ${CPACK_PACKAGE_CONTACT})
 528   endif()
 529
 530   # Description: (mandatory)
 531   # Try package description first
 532   if(CPACK_USED_DEFAULT_PACKAGE_DESCRIPTION_FILE)
 533     set(_desc_fallback)
 534   else()
 535     set(_desc_fallback "CPACK_PACKAGE_DESCRIPTION")
 536   endif()
 537   if(CPACK_DEB_PACKAGE_COMPONENT)
 538     cpack_deb_variable_fallback("CPACK_DEBIAN_PACKAGE_DESCRIPTION"
 539       "CPACK_DEBIAN_${_local_component_name}_DESCRIPTION"
 540       "CPACK_COMPONENT_${_local_component_name}_DESCRIPTION")
 541   else()
 542     cpack_deb_variable_fallback("CPACK_DEBIAN_PACKAGE_DESCRIPTION"
 543       "CPACK_DEBIAN_PACKAGE_DESCRIPTION"
 544       ${_desc_fallback})
 545   endif()
 546
 547   # Still no description? ... and description file has set ...
 548   if(NOT CPACK_DEBIAN_PACKAGE_DESCRIPTION
 549      AND CPACK_PACKAGE_DESCRIPTION_FILE
 550      AND NOT CPACK_PACKAGE_DESCRIPTION_FILE STREQUAL CPACK_DEFAULT_PACKAGE_DESCRIPTION_FILE)
 551     # Read `CPACK_PACKAGE_DESCRIPTION_FILE` then...
 552     file(READ ${CPACK_PACKAGE_DESCRIPTION_FILE} CPACK_DEBIAN_PACKAGE_DESCRIPTION)
 553   endif()
 554
 555   # Still no description? #2
 556   if(NOT CPACK_DEBIAN_PACKAGE_DESCRIPTION)
 557     # Try to get `CPACK_PACKAGE_DESCRIPTION_SUMMARY` as the last hope
 558     if(CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 559       set(CPACK_DEBIAN_PACKAGE_DESCRIPTION ${CPACK_PACKAGE_DESCRIPTION_SUMMARY})
 560     else()
 561       # Giving up! Report an error...
 562       set(_description_failure_message
 563         "CPackDeb: Debian package requires a summary for a package, set CPACK_PACKAGE_DESCRIPTION_SUMMARY or CPACK_DEBIAN_PACKAGE_DESCRIPTION")
 564       if(CPACK_DEB_PACKAGE_COMPONENT)
 565         string(APPEND _description_failure_message
 566           " or CPACK_DEBIAN_${_local_component_name}_DESCRIPTION")
 567       endif()
 568       message(FATAL_ERROR "${_description_failure_message}")
 569     endif()
 570
 571   # Ok, description has set. According to the `Debian Policy Manual`_ the first
 572   # line is a package summary.  Try to get it as well...
 573   # See also: https://www.debian.org/doc/debian-policy/ch-controlfields.html#description
 574   elseif(CPACK_PACKAGE_DESCRIPTION_SUMMARY AND
 575          NOT CPACK_PACKAGE_DESCRIPTION_SUMMARY STREQUAL CPACK_DEFAULT_PACKAGE_DESCRIPTION_SUMMARY)
 576     # Merge summary w/ the detailed description
 577     string(PREPEND CPACK_DEBIAN_PACKAGE_DESCRIPTION "${CPACK_PACKAGE_DESCRIPTION_SUMMARY}\n")
 578   endif()
 579   # assert(CPACK_DEBIAN_PACKAGE_DESCRIPTION)
 580
 581   # Make sure description is properly formatted
 582   cpack_deb_format_package_description(
 583     "${CPACK_DEBIAN_PACKAGE_DESCRIPTION}"
 584     CPACK_DEBIAN_PACKAGE_DESCRIPTION
 585   )
 586
 587   # Homepage: (optional)
 588   if(NOT CPACK_DEBIAN_PACKAGE_HOMEPAGE AND CPACK_PACKAGE_HOMEPAGE_URL)
 589     set(CPACK_DEBIAN_PACKAGE_HOMEPAGE "${CPACK_PACKAGE_HOMEPAGE_URL}")
 590   endif()
 591
 592   # Section: (recommended)
 593   if(NOT CPACK_DEBIAN_PACKAGE_SECTION)
 594     set(CPACK_DEBIAN_PACKAGE_SECTION "devel")
 595   endif()
 596
 597   # Priority: (recommended)
 598   if(NOT CPACK_DEBIAN_PACKAGE_PRIORITY)
 599     set(CPACK_DEBIAN_PACKAGE_PRIORITY "optional")
 600   endif()
 601
 602   if(CPACK_DEBIAN_ARCHIVE_TYPE)
 603     if(CPACK_DEBIAN_ARCHIVE_TYPE STREQUAL "paxr")
 604       message(DEPRECATION "CPACK_DEBIAN_ARCHIVE_TYPE set to old and invalid "
 605         "type 'paxr', mapping to 'gnutar'")
 606       set(CPACK_DEBIAN_ARCHIVE_TYPE "gnutar")
 607     elseif(NOT CPACK_DEBIAN_ARCHIVE_TYPE STREQUAL "gnutar")
 608       message(FATAL_ERROR "CPACK_DEBIAN_ARCHIVE_TYPE set to unsupported"
 609         "type ${CPACK_DEBIAN_ARCHIVE_TYPE}")
 610     endif()
 611   else()
 612     set(CPACK_DEBIAN_ARCHIVE_TYPE "gnutar")
 613   endif()
 614
 615   # Compression: (recommended)
 616   if(NOT CPACK_DEBIAN_COMPRESSION_TYPE)
 617     set(CPACK_DEBIAN_COMPRESSION_TYPE "gzip")
 618   endif()
 619
 620   # Recommends:
 621   # You should set: CPACK_DEBIAN_PACKAGE_RECOMMENDS
 622
 623   # Suggests:
 624   # You should set: CPACK_DEBIAN_PACKAGE_SUGGESTS
 625
 626   # CPACK_DEBIAN_PACKAGE_CONTROL_EXTRA
 627   # This variable allow advanced user to add custom script to the control.tar.gz (inside the .deb archive)
 628   # Typical examples are:
 629   # - conffiles
 630   # - postinst
 631   # - postrm
 632   # - prerm
 633   # Usage:
 634   # set(CPACK_DEBIAN_PACKAGE_CONTROL_EXTRA
 635   #    "${CMAKE_CURRENT_SOURCE_DIR}/prerm;${CMAKE_CURRENT_SOURCE_DIR}/postrm")
 636
 637   # Are we packaging components ?
 638   if(CPACK_DEB_PACKAGE_COMPONENT)
 639     # override values with per component version if set
 640     foreach(VAR_NAME_ IN ITEMS PACKAGE_CONTROL_EXTRA PACKAGE_CONTROL_STRICT_PERMISSION)
 641       if(CPACK_DEBIAN_${_local_component_name}_${VAR_NAME_})
 642         set(CPACK_DEBIAN_${VAR_NAME_} "${CPACK_DEBIAN_${_local_component_name}_${VAR_NAME_}}")
 643       endif()
 644     endforeach()
 645     get_component_package_name(CPACK_DEBIAN_PACKAGE_NAME ${_local_component_name})
 646   endif()
 647
 648   if(NOT CPACK_DEBIAN_PACKAGE_GENERATE_SHLIBS_POLICY)
 649     set(CPACK_DEBIAN_PACKAGE_GENERATE_SHLIBS_POLICY "=")
 650   endif()
 651
 652   unset(CPACK_DEBIAN_PACKAGE_SHLIBS_LIST)
 653
 654   if(CPACK_DEBIAN_PACKAGE_GENERATE_SHLIBS)
 655     if(READELF_EXECUTABLE)
 656       foreach(_FILE IN LISTS CPACK_DEB_SHARED_OBJECT_FILES)
 657         extract_so_info("${_FILE}" libname soversion)
 658         if(libname AND DEFINED soversion)
 659           list(APPEND CPACK_DEBIAN_PACKAGE_SHLIBS_LIST
 660                "${libname} ${soversion} ${CPACK_DEBIAN_PACKAGE_NAME} (${CPACK_DEBIAN_PACKAGE_GENERATE_SHLIBS_POLICY} ${CPACK_DEBIAN_PACKAGE_VERSION})")
 661         else()
 662           message(AUTHOR_WARNING "Shared library '${_FILE}' is missing soname or soversion. Library will not be added to DEBIAN/shlibs control file.")
 663         endif()
 664       endforeach()
 665       list(JOIN CPACK_DEBIAN_PACKAGE_SHLIBS_LIST "\n" CPACK_DEBIAN_PACKAGE_SHLIBS_LIST)
 666     else()
 667       message(FATAL_ERROR "Readelf utility is not available. CPACK_DEBIAN_PACKAGE_GENERATE_SHLIBS option is not available.")
 668     endif()
 669   endif()
 670
 671   # add ldconfig call in default postrm and postint
 672   set(CPACK_ADD_LDCONFIG_CALL 0)
 673   # all files in CPACK_DEB_SHARED_OBJECT_FILES have dot at the beginning
 674   set(_LDCONF_DEFAULTS "./lib" "./usr/lib")
 675   foreach(_FILE IN LISTS CPACK_DEB_SHARED_OBJECT_FILES)
 676     get_filename_component(_DIR ${_FILE} DIRECTORY)
 677     get_filename_component(_PARENT_DIR ${_DIR} DIRECTORY)
 678     if(_DIR IN_LIST _LDCONF_DEFAULTS OR _PARENT_DIR IN_LIST _LDCONF_DEFAULTS)
 679       set(CPACK_ADD_LDCONFIG_CALL 1)
 680     endif()
 681   endforeach()
 682
 683   if(CPACK_ADD_LDCONFIG_CALL)
 684     set(CPACK_DEBIAN_GENERATE_POSTINST 1)
 685     set(CPACK_DEBIAN_GENERATE_POSTRM 1)
 686     foreach(f IN LISTS CPACK_DEBIAN_PACKAGE_CONTROL_EXTRA)
 687       get_filename_component(n "${f}" NAME)
 688       if(n STREQUAL "postinst")
 689         set(CPACK_DEBIAN_GENERATE_POSTINST 0)
 690       endif()
 691       if(n STREQUAL "postrm")
 692         set(CPACK_DEBIAN_GENERATE_POSTRM 0)
 693       endif()
 694     endforeach()
 695   else()
 696     set(CPACK_DEBIAN_GENERATE_POSTINST 0)
 697     set(CPACK_DEBIAN_GENERATE_POSTRM 0)
 698   endif()
 699
 700   cpack_deb_variable_fallback("CPACK_DEBIAN_FILE_NAME"
 701     "CPACK_DEBIAN_${_local_component_name}_FILE_NAME"
 702     "CPACK_DEBIAN_FILE_NAME")
 703   if(CPACK_DEBIAN_FILE_NAME)
 704     if(CPACK_DEBIAN_FILE_NAME STREQUAL "DEB-DEFAULT")
 705       # Patch package file name to be in correct debian format:
 706       # <foo>_<VersionNumber>-<DebianRevisionNumber>_<DebianArchitecture>.deb
 707       set(CPACK_OUTPUT_FILE_NAME
 708         "${CPACK_DEBIAN_PACKAGE_NAME}_${CPACK_DEBIAN_PACKAGE_VERSION}_${CPACK_DEBIAN_PACKAGE_ARCHITECTURE}.deb")
 709       set(CPACK_DBGSYM_OUTPUT_FILE_NAME
 710         "${CPACK_DEBIAN_PACKAGE_NAME}-dbgsym_${CPACK_DEBIAN_PACKAGE_VERSION}_${CPACK_DEBIAN_PACKAGE_ARCHITECTURE}.ddeb")
 711     else()
 712       if(NOT CPACK_DEBIAN_FILE_NAME MATCHES ".*\\.(deb|ipk)")
 713         message(FATAL_ERROR "'${CPACK_DEBIAN_FILE_NAME}' is not a valid DEB package file name as it must end with '.deb' or '.ipk'!")
 714       endif()
 715
 716       set(CPACK_OUTPUT_FILE_NAME "${CPACK_DEBIAN_FILE_NAME}")
 717       string(REGEX REPLACE "\.deb$" "-dbgsym.ddeb" CPACK_DBGSYM_OUTPUT_FILE_NAME "${CPACK_DEBIAN_FILE_NAME}")
 718     endif()
 719
 720     set(CPACK_TEMPORARY_PACKAGE_FILE_NAME "${CPACK_TOPLEVEL_DIRECTORY}/${CPACK_OUTPUT_FILE_NAME}")
 721     get_filename_component(BINARY_DIR "${CPACK_OUTPUT_FILE_PATH}" DIRECTORY)
 722     set(CPACK_OUTPUT_FILE_PATH "${BINARY_DIR}/${CPACK_OUTPUT_FILE_NAME}")
 723   else()
 724     # back compatibility - don't change the name
 725     string(REGEX REPLACE "\.deb$" "-dbgsym.ddeb" CPACK_DBGSYM_OUTPUT_FILE_NAME "${CPACK_OUTPUT_FILE_NAME}")
 726   endif()
 727
 728   # Print out some debug information if we were asked for that
 729   if(CPACK_DEBIAN_PACKAGE_DEBUG)
 730      message("CPackDeb:Debug: CPACK_TOPLEVEL_DIRECTORY          = '${CPACK_TOPLEVEL_DIRECTORY}'")
 731      message("CPackDeb:Debug: CPACK_TOPLEVEL_TAG                = '${CPACK_TOPLEVEL_TAG}'")
 732      message("CPackDeb:Debug: CPACK_TEMPORARY_DIRECTORY         = '${CPACK_TEMPORARY_DIRECTORY}'")
 733      message("CPackDeb:Debug: CPACK_OUTPUT_FILE_NAME            = '${CPACK_OUTPUT_FILE_NAME}'")
 734      message("CPackDeb:Debug: CPACK_OUTPUT_FILE_PATH            = '${CPACK_OUTPUT_FILE_PATH}'")
 735      message("CPackDeb:Debug: CPACK_PACKAGE_FILE_NAME           = '${CPACK_PACKAGE_FILE_NAME}'")
 736      message("CPackDeb:Debug: CPACK_PACKAGE_INSTALL_DIRECTORY   = '${CPACK_PACKAGE_INSTALL_DIRECTORY}'")
 737      message("CPackDeb:Debug: CPACK_TEMPORARY_PACKAGE_FILE_NAME = '${CPACK_TEMPORARY_PACKAGE_FILE_NAME}'")
 738      message("CPackDeb:Debug: CPACK_DEBIAN_PACKAGE_CONTROL_STRICT_PERMISSION = '${CPACK_DEBIAN_PACKAGE_CONTROL_STRICT_PERMISSION}'")
 739      message("CPackDeb:Debug: CPACK_DEBIAN_PACKAGE_SOURCE       = '${CPACK_DEBIAN_PACKAGE_SOURCE}'")
 740   endif()
 741
 742   # For debian source packages:
 743   # debian/control
 744   # http://www.debian.org/doc/debian-policy/ch-controlfields.html#s-sourcecontrolfiles
 745
 746   # .dsc
 747   # http://www.debian.org/doc/debian-policy/ch-controlfields.html#s-debiansourcecontrolfiles
 748
 749   # Builds-Depends:
 750   #if(NOT CPACK_DEBIAN_PACKAGE_BUILDS_DEPENDS)
 751   #  set(CPACK_DEBIAN_PACKAGE_BUILDS_DEPENDS
 752   #    "debhelper (>> 5.0.0), libncurses5-dev, tcl8.4"
 753   #  )
 754   #endif()
 755
 756   # move variables to parent scope so that they may be used to create debian package
 757   set(GEN_CPACK_OUTPUT_FILE_NAME "${CPACK_OUTPUT_FILE_NAME}" PARENT_SCOPE)
 758   set(GEN_CPACK_TEMPORARY_PACKAGE_FILE_NAME "${CPACK_TEMPORARY_PACKAGE_FILE_NAME}" PARENT_SCOPE)
 759   set(GEN_CPACK_DEBIAN_PACKAGE_NAME "${CPACK_DEBIAN_PACKAGE_NAME}" PARENT_SCOPE)
 760   set(GEN_CPACK_DEBIAN_PACKAGE_VERSION "${CPACK_DEBIAN_PACKAGE_VERSION}" PARENT_SCOPE)
 761   set(GEN_CPACK_DEBIAN_PACKAGE_SECTION "${CPACK_DEBIAN_PACKAGE_SECTION}" PARENT_SCOPE)
 762   set(GEN_CPACK_DEBIAN_PACKAGE_PRIORITY "${CPACK_DEBIAN_PACKAGE_PRIORITY}" PARENT_SCOPE)
 763   set(GEN_CPACK_DEBIAN_PACKAGE_ARCHITECTURE "${CPACK_DEBIAN_PACKAGE_ARCHITECTURE}" PARENT_SCOPE)
 764   set(GEN_CPACK_DEBIAN_PACKAGE_MAINTAINER "${CPACK_DEBIAN_PACKAGE_MAINTAINER}" PARENT_SCOPE)
 765   set(GEN_CPACK_DEBIAN_PACKAGE_DESCRIPTION "${CPACK_DEBIAN_PACKAGE_DESCRIPTION}" PARENT_SCOPE)
 766   set(GEN_CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS}" PARENT_SCOPE)
 767   set(GEN_CPACK_DEBIAN_ARCHIVE_TYPE "${CPACK_DEBIAN_ARCHIVE_TYPE}" PARENT_SCOPE)
 768   set(GEN_CPACK_DEBIAN_COMPRESSION_TYPE "${CPACK_DEBIAN_COMPRESSION_TYPE}" PARENT_SCOPE)
 769   set(GEN_CPACK_DEBIAN_PACKAGE_RECOMMENDS "${CPACK_DEBIAN_PACKAGE_RECOMMENDS}" PARENT_SCOPE)
 770   set(GEN_CPACK_DEBIAN_PACKAGE_SUGGESTS "${CPACK_DEBIAN_PACKAGE_SUGGESTS}" PARENT_SCOPE)
 771   set(GEN_CPACK_DEBIAN_PACKAGE_HOMEPAGE "${CPACK_DEBIAN_PACKAGE_HOMEPAGE}" PARENT_SCOPE)
 772   set(GEN_CPACK_DEBIAN_PACKAGE_PREDEPENDS "${CPACK_DEBIAN_PACKAGE_PREDEPENDS}" PARENT_SCOPE)
 773   set(GEN_CPACK_DEBIAN_PACKAGE_ENHANCES "${CPACK_DEBIAN_PACKAGE_ENHANCES}" PARENT_SCOPE)
 774   set(GEN_CPACK_DEBIAN_PACKAGE_BREAKS "${CPACK_DEBIAN_PACKAGE_BREAKS}" PARENT_SCOPE)
 775   set(GEN_CPACK_DEBIAN_PACKAGE_CONFLICTS "${CPACK_DEBIAN_PACKAGE_CONFLICTS}" PARENT_SCOPE)
 776   set(GEN_CPACK_DEBIAN_PACKAGE_PROVIDES "${CPACK_DEBIAN_PACKAGE_PROVIDES}" PARENT_SCOPE)
 777   set(GEN_CPACK_DEBIAN_PACKAGE_REPLACES "${CPACK_DEBIAN_PACKAGE_REPLACES}" PARENT_SCOPE)
 778   set(GEN_CPACK_DEBIAN_PACKAGE_SHLIBS "${CPACK_DEBIAN_PACKAGE_SHLIBS_LIST}" PARENT_SCOPE)
 779   set(GEN_CPACK_DEBIAN_PACKAGE_CONTROL_EXTRA "${CPACK_DEBIAN_PACKAGE_CONTROL_EXTRA}" PARENT_SCOPE)
 780   set(GEN_CPACK_DEBIAN_PACKAGE_CONTROL_STRICT_PERMISSION
 781       "${CPACK_DEBIAN_PACKAGE_CONTROL_STRICT_PERMISSION}" PARENT_SCOPE)
 782   set(GEN_CPACK_DEBIAN_PACKAGE_SOURCE
 783      "${CPACK_DEBIAN_PACKAGE_SOURCE}" PARENT_SCOPE)
 784   set(GEN_CPACK_DEBIAN_GENERATE_POSTINST "${CPACK_DEBIAN_GENERATE_POSTINST}" PARENT_SCOPE)
 785   set(GEN_CPACK_DEBIAN_GENERATE_POSTRM "${CPACK_DEBIAN_GENERATE_POSTRM}" PARENT_SCOPE)
 786   set(GEN_WDIR "${WDIR}" PARENT_SCOPE)
 787
 788   set(GEN_CPACK_DEBIAN_DEBUGINFO_PACKAGE "${CPACK_DEBIAN_DEBUGINFO_PACKAGE}" PARENT_SCOPE)
 789   if(BUILD_IDS)
 790     set(GEN_DBGSYMDIR "${DBGSYMDIR}" PARENT_SCOPE)
 791     set(GEN_CPACK_DBGSYM_OUTPUT_FILE_NAME "${CPACK_DBGSYM_OUTPUT_FILE_NAME}" PARENT_SCOPE)
 792     list(JOIN BUILD_IDS " " BUILD_IDS)
 793     set(GEN_BUILD_IDS "${BUILD_IDS}" PARENT_SCOPE)
 794   else()
 795     unset(GEN_DBGSYMDIR PARENT_SCOPE)
 796     unset(GEN_CPACK_DBGSYM_OUTPUT_FILE_NAME PARENT_SCOPE)
 797     unset(GEN_BUILD_IDS PARENT_SCOPE)
 798   endif()
 799 endfunction()
 800
 801 cpack_deb_prepare_package_vars()
 802
 803 cmake_policy(POP)