Modules/FindTCL.cmake

   1 # - Find Tcl includes and libraries.
   2 # This module finds if Tcl is installed and determines where the
   3 # include files and libraries are. It also determines what the name of
   4 # the library is. This code sets the following variables:
   5 #  TCL_FOUND              = Tcl was found
   6 #  TK_FOUND               = Tk was found
   7 #  TCLTK_FOUND            = Tcl and Tk were found
   8 #  TCL_LIBRARY            = path to Tcl library (tcl tcl80)
   9 #  TCL_INCLUDE_PATH       = path to where tcl.h can be found
  10 #  TCL_TCLSH              = path to tclsh binary (tcl tcl80)
  11 #  TK_LIBRARY             = path to Tk library (tk tk80 etc)
  12 #  TK_INCLUDE_PATH        = path to where tk.h can be found
  13 #  TK_WISH                = full path to the wish executable
  14 #
  15 # In an effort to remove some clutter and clear up some issues for people
  16 # who are not necessarily Tcl/Tk gurus/developpers, some variables were
  17 # moved or removed. Changes compared to CMake 2.4 are:
  18 # - The stub libraries are now found in FindTclStub.cmake
  19 #   => they were only useful for people writing Tcl/Tk extensions.
  20 # - TCL_LIBRARY_DEBUG and TK_LIBRARY_DEBUG were removed.
  21 #   => these libs are not packaged by default with Tcl/Tk distributions.
  22 #      Even when Tcl/Tk is built from source, several flavors of debug libs
  23 #      are created and there is no real reason to pick a single one
  24 #      specifically (say, amongst tcl84g, tcl84gs, or tcl84sgx).
  25 #      Let's leave that choice to the user by allowing him to assign
  26 #      TCL_LIBRARY to any Tcl library, debug or not.
  27 # - TK_INTERNAL_PATH was removed.
  28 #   => this ended up being only a Win32 variable, and there is a lot of
  29 #      confusion regarding the location of this file in an installed Tcl/Tk
  30 #      tree anyway (see 8.5 for example). If you need the internal path at
  31 #      this point it is safer you ask directly where the *source* tree is
  32 #      and dig from there.
  33
  34 #=============================================================================
  35 # Copyright 2001-2009 Kitware, Inc.
  36 #
  37 # Distributed under the OSI-approved BSD License (the "License");
  38 # see accompanying file Copyright.txt for details.
  39 #
  40 # This software is distributed WITHOUT ANY WARRANTY; without even the
  41 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  42 # See the License for more information.
  43 #=============================================================================
  44 # (To distribute this file outside of CMake, substitute the full
  45 #  License text for the above reference.)
  46
  47 include(${CMAKE_CURRENT_LIST_DIR}/CMakeFindFrameworks.cmake)
  48 include(${CMAKE_CURRENT_LIST_DIR}/FindTclsh.cmake)
  49 include(${CMAKE_CURRENT_LIST_DIR}/FindWish.cmake)
  50
  51 if(TCLSH_VERSION_STRING)
  52   set(TCL_TCLSH_VERSION "${TCLSH_VERSION_STRING}")
  53 else()
  54   get_filename_component(TCL_TCLSH_PATH "${TCL_TCLSH}" PATH)
  55   get_filename_component(TCL_TCLSH_PATH_PARENT "${TCL_TCLSH_PATH}" PATH)
  56   string(REGEX REPLACE
  57     "^.*tclsh([0-9]\\.*[0-9]).*$" "\\1" TCL_TCLSH_VERSION "${TCL_TCLSH}")
  58 endif()
  59
  60 get_filename_component(TK_WISH_PATH "${TK_WISH}" PATH)
  61 get_filename_component(TK_WISH_PATH_PARENT "${TK_WISH_PATH}" PATH)
  62 string(REGEX REPLACE
  63   "^.*wish([0-9]\\.*[0-9]).*$" "\\1" TK_WISH_VERSION "${TK_WISH}")
  64
  65 get_filename_component(TCL_INCLUDE_PATH_PARENT "${TCL_INCLUDE_PATH}" PATH)
  66 get_filename_component(TK_INCLUDE_PATH_PARENT "${TK_INCLUDE_PATH}" PATH)
  67
  68 get_filename_component(TCL_LIBRARY_PATH "${TCL_LIBRARY}" PATH)
  69 get_filename_component(TCL_LIBRARY_PATH_PARENT "${TCL_LIBRARY_PATH}" PATH)
  70 string(REGEX REPLACE
  71   "^.*tcl([0-9]\\.*[0-9]).*$" "\\1" TCL_LIBRARY_VERSION "${TCL_LIBRARY}")
  72
  73 get_filename_component(TK_LIBRARY_PATH "${TK_LIBRARY}" PATH)
  74 get_filename_component(TK_LIBRARY_PATH_PARENT "${TK_LIBRARY_PATH}" PATH)
  75 string(REGEX REPLACE
  76   "^.*tk([0-9]\\.*[0-9]).*$" "\\1" TK_LIBRARY_VERSION "${TK_LIBRARY}")
  77
  78 set(TCLTK_POSSIBLE_LIB_PATHS
  79   "${TCL_INCLUDE_PATH_PARENT}/lib"
  80   "${TK_INCLUDE_PATH_PARENT}/lib"
  81   "${TCL_LIBRARY_PATH}"
  82   "${TK_LIBRARY_PATH}"
  83   "${TCL_TCLSH_PATH_PARENT}/lib"
  84   "${TK_WISH_PATH_PARENT}/lib"
  85   /usr/local/lib/tcl/tcl8.5
  86   /usr/local/lib/tcl/tk8.5
  87   /usr/local/lib/tcl/tcl8.4
  88   /usr/local/lib/tcl/tk8.4
  89   )
  90
  91 if(WIN32)
  92   get_filename_component(
  93     ActiveTcl_CurrentVersion
  94     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\ActiveState\\ActiveTcl;CurrentVersion]"
  95     NAME)
  96   set(TCLTK_POSSIBLE_LIB_PATHS ${TCLTK_POSSIBLE_LIB_PATHS}
  97     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\ActiveState\\ActiveTcl\\${ActiveTcl_CurrentVersion}]/lib"
  98     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.6;Root]/lib"
  99     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.5;Root]/lib"
 100     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.4;Root]/lib"
 101     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.3;Root]/lib"
 102     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.2;Root]/lib"
 103     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.0;Root]/lib"
 104     "$ENV{ProgramFiles}/Tcl/Lib"
 105     "C:/Program Files/Tcl/lib"
 106     "C:/Tcl/lib"
 107     )
 108 endif()
 109
 110 find_library(TCL_LIBRARY
 111   NAMES
 112   tcl
 113   tcl${TCL_LIBRARY_VERSION} tcl${TCL_TCLSH_VERSION} tcl${TK_WISH_VERSION}
 114   tcl86 tcl8.6
 115   tcl85 tcl8.5
 116   tcl84 tcl8.4
 117   tcl83 tcl8.3
 118   tcl82 tcl8.2
 119   tcl80 tcl8.0
 120   PATHS ${TCLTK_POSSIBLE_LIB_PATHS}
 121   )
 122
 123 find_library(TK_LIBRARY
 124   NAMES
 125   tk
 126   tk${TK_LIBRARY_VERSION} tk${TCL_TCLSH_VERSION} tk${TK_WISH_VERSION}
 127   tk86 tk8.6
 128   tk85 tk8.5
 129   tk84 tk8.4
 130   tk83 tk8.3
 131   tk82 tk8.2
 132   tk80 tk8.0
 133   PATHS ${TCLTK_POSSIBLE_LIB_PATHS}
 134   )
 135
 136 CMAKE_FIND_FRAMEWORKS(Tcl)
 137 CMAKE_FIND_FRAMEWORKS(Tk)
 138
 139 set(TCL_FRAMEWORK_INCLUDES)
 140 if(Tcl_FRAMEWORKS)
 141   if(NOT TCL_INCLUDE_PATH)
 142     foreach(dir ${Tcl_FRAMEWORKS})
 143       set(TCL_FRAMEWORK_INCLUDES ${TCL_FRAMEWORK_INCLUDES} ${dir}/Headers)
 144     endforeach()
 145   endif()
 146 endif()
 147
 148 set(TK_FRAMEWORK_INCLUDES)
 149 if(Tk_FRAMEWORKS)
 150   if(NOT TK_INCLUDE_PATH)
 151     foreach(dir ${Tk_FRAMEWORKS})
 152       set(TK_FRAMEWORK_INCLUDES ${TK_FRAMEWORK_INCLUDES}
 153         ${dir}/Headers ${dir}/PrivateHeaders)
 154     endforeach()
 155   endif()
 156 endif()
 157
 158 set(TCLTK_POSSIBLE_INCLUDE_PATHS
 159   "${TCL_LIBRARY_PATH_PARENT}/include"
 160   "${TK_LIBRARY_PATH_PARENT}/include"
 161   "${TCL_INCLUDE_PATH}"
 162   "${TK_INCLUDE_PATH}"
 163   ${TCL_FRAMEWORK_INCLUDES}
 164   ${TK_FRAMEWORK_INCLUDES}
 165   "${TCL_TCLSH_PATH_PARENT}/include"
 166   "${TK_WISH_PATH_PARENT}/include"
 167   /usr/include/tcl${TK_LIBRARY_VERSION}
 168   /usr/include/tcl${TCL_LIBRARY_VERSION}
 169   /usr/include/tcl8.6
 170   /usr/include/tcl8.5
 171   /usr/include/tcl8.4
 172   /usr/include/tcl8.3
 173   /usr/include/tcl8.2
 174   /usr/include/tcl8.0
 175   /usr/local/include/tcl8.5
 176   /usr/local/include/tk8.5
 177   /usr/local/include/tcl8.4
 178   /usr/local/include/tk8.4
 179   )
 180
 181 if(WIN32)
 182   set(TCLTK_POSSIBLE_INCLUDE_PATHS ${TCLTK_POSSIBLE_INCLUDE_PATHS}
 183     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\ActiveState\\ActiveTcl\\${ActiveTcl_CurrentVersion}]/include"
 184     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.6;Root]/include"
 185     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.5;Root]/include"
 186     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.4;Root]/include"
 187     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.3;Root]/include"
 188     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.2;Root]/include"
 189     "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.0;Root]/include"
 190     "$ENV{ProgramFiles}/Tcl/include"
 191     "C:/Program Files/Tcl/include"
 192     "C:/Tcl/include"
 193     )
 194 endif()
 195
 196 find_path(TCL_INCLUDE_PATH
 197   NAMES tcl.h
 198   HINTS ${TCLTK_POSSIBLE_INCLUDE_PATHS}
 199   )
 200
 201 find_path(TK_INCLUDE_PATH
 202   NAMES tk.h
 203   HINTS ${TCLTK_POSSIBLE_INCLUDE_PATHS}
 204   )
 205
 206 # handle the QUIETLY and REQUIRED arguments and set TCL_FOUND to TRUE if
 207 # all listed variables are TRUE
 208 include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
 209
 210 FIND_PACKAGE_HANDLE_STANDARD_ARGS(TCL DEFAULT_MSG TCL_LIBRARY TCL_INCLUDE_PATH)
 211 set(TCLTK_FIND_REQUIRED ${TCL_FIND_REQUIRED})
 212 set(TCLTK_FIND_QUIETLY  ${TCL_FIND_QUIETLY})
 213 FIND_PACKAGE_HANDLE_STANDARD_ARGS(TCLTK DEFAULT_MSG TCL_LIBRARY TCL_INCLUDE_PATH TK_LIBRARY TK_INCLUDE_PATH)
 214 set(TK_FIND_REQUIRED ${TCL_FIND_REQUIRED})
 215 set(TK_FIND_QUIETLY  ${TCL_FIND_QUIETLY})
 216 FIND_PACKAGE_HANDLE_STANDARD_ARGS(TK DEFAULT_MSG TK_LIBRARY TK_INCLUDE_PATH)
 217
 218 mark_as_advanced(
 219   TCL_INCLUDE_PATH
 220   TK_INCLUDE_PATH
 221   TCL_LIBRARY
 222   TK_LIBRARY
 223   )