Modules/FindSDL_mixer.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 #[=======================================================================[.rst:
   5 FindSDL_mixer
   6 -------------
   7
   8 Locate SDL_mixer library
   9
  10 This module defines:
  11
  12 ::
  13
  14   SDL_MIXER_LIBRARIES, the name of the library to link against
  15   SDL_MIXER_INCLUDE_DIRS, where to find the headers
  16   SDL_MIXER_FOUND, if false, do not try to link against
  17   SDL_MIXER_VERSION_STRING - human-readable string containing the
  18                              version of SDL_mixer
  19
  20
  21
  22 For backward compatibility the following variables are also set:
  23
  24 ::
  25
  26   SDLMIXER_LIBRARY (same value as SDL_MIXER_LIBRARIES)
  27   SDLMIXER_INCLUDE_DIR (same value as SDL_MIXER_INCLUDE_DIRS)
  28   SDLMIXER_FOUND (same value as SDL_MIXER_FOUND)
  29
  30
  31
  32 $SDLDIR is an environment variable that would correspond to the
  33 ./configure --prefix=$SDLDIR used in building SDL.
  34 #]=======================================================================]
  35
  36 if(NOT SDL_MIXER_INCLUDE_DIR AND SDLMIXER_INCLUDE_DIR)
  37   set(SDL_MIXER_INCLUDE_DIR ${SDLMIXER_INCLUDE_DIR} CACHE PATH "directory cache
  38 entry initialized from old variable name")
  39 endif()
  40 find_path(SDL_MIXER_INCLUDE_DIR SDL_mixer.h
  41   HINTS
  42     ENV SDLMIXERDIR
  43     ENV SDLDIR
  44   PATH_SUFFIXES SDL
  45                 # path suffixes to search inside ENV{SDLDIR}
  46                 include/SDL include/SDL12 include/SDL11 include
  47 )
  48
  49 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
  50   set(VC_LIB_PATH_SUFFIX lib/x64)
  51 else()
  52   set(VC_LIB_PATH_SUFFIX lib/x86)
  53 endif()
  54
  55 if(NOT SDL_MIXER_LIBRARY AND SDLMIXER_LIBRARY)
  56   set(SDL_MIXER_LIBRARY ${SDLMIXER_LIBRARY} CACHE FILEPATH "file cache entry
  57 initialized from old variable name")
  58 endif()
  59 find_library(SDL_MIXER_LIBRARY
  60   NAMES SDL_mixer
  61   HINTS
  62     ENV SDLMIXERDIR
  63     ENV SDLDIR
  64   PATH_SUFFIXES lib ${VC_LIB_PATH_SUFFIX}
  65 )
  66
  67 if(SDL_MIXER_INCLUDE_DIR AND EXISTS "${SDL_MIXER_INCLUDE_DIR}/SDL_mixer.h")
  68   file(STRINGS "${SDL_MIXER_INCLUDE_DIR}/SDL_mixer.h" SDL_MIXER_VERSION_MAJOR_LINE REGEX "^#define[ \t]+SDL_MIXER_MAJOR_VERSION[ \t]+[0-9]+$")
  69   file(STRINGS "${SDL_MIXER_INCLUDE_DIR}/SDL_mixer.h" SDL_MIXER_VERSION_MINOR_LINE REGEX "^#define[ \t]+SDL_MIXER_MINOR_VERSION[ \t]+[0-9]+$")
  70   file(STRINGS "${SDL_MIXER_INCLUDE_DIR}/SDL_mixer.h" SDL_MIXER_VERSION_PATCH_LINE REGEX "^#define[ \t]+SDL_MIXER_PATCHLEVEL[ \t]+[0-9]+$")
  71   string(REGEX REPLACE "^#define[ \t]+SDL_MIXER_MAJOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL_MIXER_VERSION_MAJOR "${SDL_MIXER_VERSION_MAJOR_LINE}")
  72   string(REGEX REPLACE "^#define[ \t]+SDL_MIXER_MINOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL_MIXER_VERSION_MINOR "${SDL_MIXER_VERSION_MINOR_LINE}")
  73   string(REGEX REPLACE "^#define[ \t]+SDL_MIXER_PATCHLEVEL[ \t]+([0-9]+)$" "\\1" SDL_MIXER_VERSION_PATCH "${SDL_MIXER_VERSION_PATCH_LINE}")
  74   set(SDL_MIXER_VERSION_STRING ${SDL_MIXER_VERSION_MAJOR}.${SDL_MIXER_VERSION_MINOR}.${SDL_MIXER_VERSION_PATCH})
  75   unset(SDL_MIXER_VERSION_MAJOR_LINE)
  76   unset(SDL_MIXER_VERSION_MINOR_LINE)
  77   unset(SDL_MIXER_VERSION_PATCH_LINE)
  78   unset(SDL_MIXER_VERSION_MAJOR)
  79   unset(SDL_MIXER_VERSION_MINOR)
  80   unset(SDL_MIXER_VERSION_PATCH)
  81 endif()
  82
  83 set(SDL_MIXER_LIBRARIES ${SDL_MIXER_LIBRARY})
  84 set(SDL_MIXER_INCLUDE_DIRS ${SDL_MIXER_INCLUDE_DIR})
  85
  86 include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
  87
  88 FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL_mixer
  89                                   REQUIRED_VARS SDL_MIXER_LIBRARIES SDL_MIXER_INCLUDE_DIRS
  90                                   VERSION_VAR SDL_MIXER_VERSION_STRING)
  91
  92 # for backward compatibility
  93 set(SDLMIXER_LIBRARY ${SDL_MIXER_LIBRARIES})
  94 set(SDLMIXER_INCLUDE_DIR ${SDL_MIXER_INCLUDE_DIRS})
  95 set(SDLMIXER_FOUND ${SDL_MIXER_FOUND})
  96
  97 mark_as_advanced(SDL_MIXER_LIBRARY SDL_MIXER_INCLUDE_DIR)