Modules/FindSDL_mixer.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 #[=======================================================================[.rst:
   5 FindSDL_mixer
   6 -------------
   7
   8 Locate SDL_mixer library
   9
  10 This module defines:
  11
  12 ::
  13
  14   SDL_MIXER_LIBRARIES, the name of the library to link against
  15   SDL_MIXER_INCLUDE_DIRS, where to find the headers
  16   SDL_MIXER_FOUND, if false, do not try to link against
  17   SDL_MIXER_VERSION_STRING - human-readable string containing the
  18                              version of SDL_mixer
  19
  20
  21
  22 For backward compatibility the following variables are also set:
  23
  24 ::
  25
  26   SDLMIXER_LIBRARY (same value as SDL_MIXER_LIBRARIES)
  27   SDLMIXER_INCLUDE_DIR (same value as SDL_MIXER_INCLUDE_DIRS)
  28   SDLMIXER_FOUND (same value as SDL_MIXER_FOUND)
  29
  30
  31
  32 $SDLDIR is an environment variable that would correspond to the
  33 ./configure --prefix=$SDLDIR used in building SDL.
  34
  35 Created by Eric Wing.  This was influenced by the FindSDL.cmake
  36 module, but with modifications to recognize OS X frameworks and
  37 additional Unix paths (FreeBSD, etc).
  38 #]=======================================================================]
  39
  40 if(NOT SDL_MIXER_INCLUDE_DIR AND SDLMIXER_INCLUDE_DIR)
  41   set(SDL_MIXER_INCLUDE_DIR ${SDLMIXER_INCLUDE_DIR} CACHE PATH "directory cache
  42 entry initialized from old variable name")
  43 endif()
  44 find_path(SDL_MIXER_INCLUDE_DIR SDL_mixer.h
  45   HINTS
  46     ENV SDLMIXERDIR
  47     ENV SDLDIR
  48   PATH_SUFFIXES SDL
  49                 # path suffixes to search inside ENV{SDLDIR}
  50                 include/SDL include/SDL12 include/SDL11 include
  51 )
  52
  53 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
  54   set(VC_LIB_PATH_SUFFIX lib/x64)
  55 else()
  56   set(VC_LIB_PATH_SUFFIX lib/x86)
  57 endif()
  58
  59 if(NOT SDL_MIXER_LIBRARY AND SDLMIXER_LIBRARY)
  60   set(SDL_MIXER_LIBRARY ${SDLMIXER_LIBRARY} CACHE FILEPATH "file cache entry
  61 initialized from old variable name")
  62 endif()
  63 find_library(SDL_MIXER_LIBRARY
  64   NAMES SDL_mixer
  65   HINTS
  66     ENV SDLMIXERDIR
  67     ENV SDLDIR
  68   PATH_SUFFIXES lib ${VC_LIB_PATH_SUFFIX}
  69 )
  70
  71 if(SDL_MIXER_INCLUDE_DIR AND EXISTS "${SDL_MIXER_INCLUDE_DIR}/SDL_mixer.h")
  72   file(STRINGS "${SDL_MIXER_INCLUDE_DIR}/SDL_mixer.h" SDL_MIXER_VERSION_MAJOR_LINE REGEX "^#define[ \t]+SDL_MIXER_MAJOR_VERSION[ \t]+[0-9]+$")
  73   file(STRINGS "${SDL_MIXER_INCLUDE_DIR}/SDL_mixer.h" SDL_MIXER_VERSION_MINOR_LINE REGEX "^#define[ \t]+SDL_MIXER_MINOR_VERSION[ \t]+[0-9]+$")
  74   file(STRINGS "${SDL_MIXER_INCLUDE_DIR}/SDL_mixer.h" SDL_MIXER_VERSION_PATCH_LINE REGEX "^#define[ \t]+SDL_MIXER_PATCHLEVEL[ \t]+[0-9]+$")
  75   string(REGEX REPLACE "^#define[ \t]+SDL_MIXER_MAJOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL_MIXER_VERSION_MAJOR "${SDL_MIXER_VERSION_MAJOR_LINE}")
  76   string(REGEX REPLACE "^#define[ \t]+SDL_MIXER_MINOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL_MIXER_VERSION_MINOR "${SDL_MIXER_VERSION_MINOR_LINE}")
  77   string(REGEX REPLACE "^#define[ \t]+SDL_MIXER_PATCHLEVEL[ \t]+([0-9]+)$" "\\1" SDL_MIXER_VERSION_PATCH "${SDL_MIXER_VERSION_PATCH_LINE}")
  78   set(SDL_MIXER_VERSION_STRING ${SDL_MIXER_VERSION_MAJOR}.${SDL_MIXER_VERSION_MINOR}.${SDL_MIXER_VERSION_PATCH})
  79   unset(SDL_MIXER_VERSION_MAJOR_LINE)
  80   unset(SDL_MIXER_VERSION_MINOR_LINE)
  81   unset(SDL_MIXER_VERSION_PATCH_LINE)
  82   unset(SDL_MIXER_VERSION_MAJOR)
  83   unset(SDL_MIXER_VERSION_MINOR)
  84   unset(SDL_MIXER_VERSION_PATCH)
  85 endif()
  86
  87 set(SDL_MIXER_LIBRARIES ${SDL_MIXER_LIBRARY})
  88 set(SDL_MIXER_INCLUDE_DIRS ${SDL_MIXER_INCLUDE_DIR})
  89
  90 include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
  91
  92 FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL_mixer
  93                                   REQUIRED_VARS SDL_MIXER_LIBRARIES SDL_MIXER_INCLUDE_DIRS
  94                                   VERSION_VAR SDL_MIXER_VERSION_STRING)
  95
  96 # for backward compatibility
  97 set(SDLMIXER_LIBRARY ${SDL_MIXER_LIBRARIES})
  98 set(SDLMIXER_INCLUDE_DIR ${SDL_MIXER_INCLUDE_DIRS})
  99 set(SDLMIXER_FOUND ${SDL_MIXER_FOUND})
 100
 101 mark_as_advanced(SDL_MIXER_LIBRARY SDL_MIXER_INCLUDE_DIR)