Modules/FindSDL_image.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 #[=======================================================================[.rst:
   5 FindSDL_image
   6 -------------
   7
   8 Locate SDL_image library
   9
  10 This module defines:
  11
  12 ::
  13
  14   SDL_IMAGE_LIBRARIES, the name of the library to link against
  15   SDL_IMAGE_INCLUDE_DIRS, where to find the headers
  16   SDL_IMAGE_FOUND, if false, do not try to link against
  17   SDL_IMAGE_VERSION_STRING - human-readable string containing the
  18                              version of SDL_image
  19
  20
  21
  22 For backward compatibility the following variables are also set:
  23
  24 ::
  25
  26   SDLIMAGE_LIBRARY (same value as SDL_IMAGE_LIBRARIES)
  27   SDLIMAGE_INCLUDE_DIR (same value as SDL_IMAGE_INCLUDE_DIRS)
  28   SDLIMAGE_FOUND (same value as SDL_IMAGE_FOUND)
  29
  30
  31
  32 $SDLDIR is an environment variable that would correspond to the
  33 ./configure --prefix=$SDLDIR used in building SDL.
  34 #]=======================================================================]
  35
  36 if(NOT SDL_IMAGE_INCLUDE_DIR AND SDLIMAGE_INCLUDE_DIR)
  37   set(SDL_IMAGE_INCLUDE_DIR ${SDLIMAGE_INCLUDE_DIR} CACHE PATH "directory cache
  38 entry initialized from old variable name")
  39 endif()
  40 find_path(SDL_IMAGE_INCLUDE_DIR SDL_image.h
  41   HINTS
  42     ENV SDLIMAGEDIR
  43     ENV SDLDIR
  44   PATH_SUFFIXES SDL
  45                 # path suffixes to search inside ENV{SDLDIR}
  46                 include/SDL include/SDL12 include/SDL11 include
  47 )
  48
  49 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
  50   set(VC_LIB_PATH_SUFFIX lib/x64)
  51 else()
  52   set(VC_LIB_PATH_SUFFIX lib/x86)
  53 endif()
  54
  55 if(NOT SDL_IMAGE_LIBRARY AND SDLIMAGE_LIBRARY)
  56   set(SDL_IMAGE_LIBRARY ${SDLIMAGE_LIBRARY} CACHE FILEPATH "file cache entry
  57 initialized from old variable name")
  58 endif()
  59 find_library(SDL_IMAGE_LIBRARY
  60   NAMES SDL_image
  61   HINTS
  62     ENV SDLIMAGEDIR
  63     ENV SDLDIR
  64   PATH_SUFFIXES lib ${VC_LIB_PATH_SUFFIX}
  65 )
  66
  67 if(SDL_IMAGE_INCLUDE_DIR AND EXISTS "${SDL_IMAGE_INCLUDE_DIR}/SDL_image.h")
  68   file(STRINGS "${SDL_IMAGE_INCLUDE_DIR}/SDL_image.h" SDL_IMAGE_VERSION_MAJOR_LINE REGEX "^#define[ \t]+SDL_IMAGE_MAJOR_VERSION[ \t]+[0-9]+$")
  69   file(STRINGS "${SDL_IMAGE_INCLUDE_DIR}/SDL_image.h" SDL_IMAGE_VERSION_MINOR_LINE REGEX "^#define[ \t]+SDL_IMAGE_MINOR_VERSION[ \t]+[0-9]+$")
  70   file(STRINGS "${SDL_IMAGE_INCLUDE_DIR}/SDL_image.h" SDL_IMAGE_VERSION_PATCH_LINE REGEX "^#define[ \t]+SDL_IMAGE_PATCHLEVEL[ \t]+[0-9]+$")
  71   string(REGEX REPLACE "^#define[ \t]+SDL_IMAGE_MAJOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL_IMAGE_VERSION_MAJOR "${SDL_IMAGE_VERSION_MAJOR_LINE}")
  72   string(REGEX REPLACE "^#define[ \t]+SDL_IMAGE_MINOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL_IMAGE_VERSION_MINOR "${SDL_IMAGE_VERSION_MINOR_LINE}")
  73   string(REGEX REPLACE "^#define[ \t]+SDL_IMAGE_PATCHLEVEL[ \t]+([0-9]+)$" "\\1" SDL_IMAGE_VERSION_PATCH "${SDL_IMAGE_VERSION_PATCH_LINE}")
  74   set(SDL_IMAGE_VERSION_STRING ${SDL_IMAGE_VERSION_MAJOR}.${SDL_IMAGE_VERSION_MINOR}.${SDL_IMAGE_VERSION_PATCH})
  75   unset(SDL_IMAGE_VERSION_MAJOR_LINE)
  76   unset(SDL_IMAGE_VERSION_MINOR_LINE)
  77   unset(SDL_IMAGE_VERSION_PATCH_LINE)
  78   unset(SDL_IMAGE_VERSION_MAJOR)
  79   unset(SDL_IMAGE_VERSION_MINOR)
  80   unset(SDL_IMAGE_VERSION_PATCH)
  81 endif()
  82
  83 set(SDL_IMAGE_LIBRARIES ${SDL_IMAGE_LIBRARY})
  84 set(SDL_IMAGE_INCLUDE_DIRS ${SDL_IMAGE_INCLUDE_DIR})
  85
  86 include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
  87
  88 FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL_image
  89                                   REQUIRED_VARS SDL_IMAGE_LIBRARIES SDL_IMAGE_INCLUDE_DIRS
  90                                   VERSION_VAR SDL_IMAGE_VERSION_STRING)
  91
  92 # for backward compatibility
  93 set(SDLIMAGE_LIBRARY ${SDL_IMAGE_LIBRARIES})
  94 set(SDLIMAGE_INCLUDE_DIR ${SDL_IMAGE_INCLUDE_DIRS})
  95 set(SDLIMAGE_FOUND ${SDL_IMAGE_FOUND})
  96
  97 mark_as_advanced(SDL_IMAGE_LIBRARY SDL_IMAGE_INCLUDE_DIR)