Modules/FindQt3.cmake

   1 # - Locate Qt include paths and libraries
   2 # This module defines:
   3 #  QT_INCLUDE_DIR    - where to find qt.h, etc.
   4 #  QT_LIBRARIES      - the libraries to link against to use Qt.
   5 #  QT_DEFINITIONS    - definitions to use when
   6 #                      compiling code that uses Qt.
   7 #  QT_FOUND          - If false, don't try to use Qt.
   8 #  QT_VERSION_STRING - the version of Qt found
   9 #
  10 # If you need the multithreaded version of Qt, set QT_MT_REQUIRED to TRUE
  11 #
  12 # Also defined, but not for general use are:
  13 #  QT_MOC_EXECUTABLE, where to find the moc tool.
  14 #  QT_UIC_EXECUTABLE, where to find the uic tool.
  15 #  QT_QT_LIBRARY, where to find the Qt library.
  16 #  QT_QTMAIN_LIBRARY, where to find the qtmain
  17 #   library. This is only required by Qt3 on Windows.
  18
  19 # These are around for backwards compatibility
  20 # they will be set
  21 #  QT_WRAP_CPP, set true if QT_MOC_EXECUTABLE is found
  22 #  QT_WRAP_UI set true if QT_UIC_EXECUTABLE is found
  23
  24 #=============================================================================
  25 # Copyright 2005-2009 Kitware, Inc.
  26 #
  27 # Distributed under the OSI-approved BSD License (the "License");
  28 # see accompanying file Copyright.txt for details.
  29 #
  30 # This software is distributed WITHOUT ANY WARRANTY; without even the
  31 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  32 # See the License for more information.
  33 #=============================================================================
  34 # (To distribute this file outside of CMake, substitute the full
  35 #  License text for the above reference.)
  36
  37 # If Qt4 has already been found, fail.
  38 if(QT4_FOUND)
  39   if(Qt3_FIND_REQUIRED)
  40     message( FATAL_ERROR "Qt3 and Qt4 cannot be used together in one project.")
  41   else()
  42     if(NOT Qt3_FIND_QUIETLY)
  43       message( STATUS    "Qt3 and Qt4 cannot be used together in one project.")
  44     endif()
  45     return()
  46   endif()
  47 endif()
  48
  49
  50 file(GLOB GLOB_PATHS /usr/lib/qt-3*)
  51 foreach(GLOB_PATH ${GLOB_PATHS})
  52   list(APPEND GLOB_PATHS_BIN "${GLOB_PATH}/bin")
  53 endforeach()
  54 find_path(QT_INCLUDE_DIR qt.h
  55   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]/include/Qt"
  56   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]/include/Qt"
  57   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]/include/Qt"
  58   $ENV{QTDIR}/include
  59   ${GLOB_PATHS}
  60   /usr/local/qt/include
  61   /usr/lib/qt/include
  62   /usr/lib/qt3/include
  63   /usr/include/qt
  64   /usr/share/qt3/include
  65   C:/Progra~1/qt/include
  66   /usr/include/qt3
  67   /usr/local/include/X11/qt3
  68   )
  69
  70 # if qglobal.h is not in the qt_include_dir then set
  71 # QT_INCLUDE_DIR to NOTFOUND
  72 if(NOT EXISTS ${QT_INCLUDE_DIR}/qglobal.h)
  73   set(QT_INCLUDE_DIR QT_INCLUDE_DIR-NOTFOUND CACHE PATH "path to Qt3 include directory" FORCE)
  74 endif()
  75
  76 if(QT_INCLUDE_DIR)
  77   #extract the version string from qglobal.h
  78   file(STRINGS ${QT_INCLUDE_DIR}/qglobal.h QGLOBAL_H REGEX "#define[\t ]+QT_VERSION_STR[\t ]+\"[0-9]+.[0-9]+.[0-9]+[a-z]*\"")
  79   string(REGEX REPLACE ".*\"([0-9]+.[0-9]+.[0-9]+[a-z]*)\".*" "\\1" qt_version_str "${QGLOBAL_H}")
  80   unset(QGLOBAL_H)
  81
  82   # Under windows the qt library (MSVC) has the format qt-mtXYZ where XYZ is the
  83   # version X.Y.Z, so we need to remove the dots from version
  84   string(REGEX REPLACE "\\." "" qt_version_str_lib "${qt_version_str}")
  85   set(QT_VERSION_STRING "${qt_version_str}")
  86 endif()
  87
  88 file(GLOB GLOB_PATHS_LIB /usr/lib/qt-3*/lib/)
  89 if (QT_MT_REQUIRED)
  90   find_library(QT_QT_LIBRARY
  91     NAMES
  92     qt-mt qt-mt${qt_version_str_lib} qt-mtnc${qt_version_str_lib}
  93     qt-mtedu${qt_version_str_lib} qt-mt230nc qt-mtnc321 qt-mt3
  94     PATHS
  95       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
  96       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
  97       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
  98       ENV QTDIR
  99       ${GLOB_PATHS_LIB}
 100       /usr/local/qt
 101       /usr/lib/qt
 102       /usr/lib/qt3
 103       /usr/share/qt3
 104       C:/Progra~1/qt
 105     PATH_SUFFIXES
 106       lib
 107     )
 108
 109 else ()
 110   find_library(QT_QT_LIBRARY
 111     NAMES
 112     qt qt-${qt_version_str_lib} qt-edu${qt_version_str_lib}
 113     qt-mt qt-mt${qt_version_str_lib} qt-mtnc${qt_version_str_lib}
 114     qt-mtedu${qt_version_str_lib} qt-mt230nc qt-mtnc321 qt-mt3
 115     PATHS
 116       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
 117       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
 118       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
 119       ENV QTDIR
 120       ${GLOB_PATHS_LIB}
 121       /usr/local/qt
 122       /usr/lib/qt
 123       /usr/lib/qt3
 124       /usr/share/qt3
 125       C:/Progra~1/qt/lib
 126     PATH_SUFFIXES
 127       lib
 128     )
 129 endif ()
 130
 131
 132 find_library(QT_QASSISTANTCLIENT_LIBRARY
 133   NAMES qassistantclient
 134   PATHS
 135     "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
 136     "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
 137     "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
 138     ENV QTDIR
 139     ${GLOB_PATHS_LIB}
 140     /usr/local/qt
 141     /usr/lib/qt3
 142     /usr/share/qt3
 143     C:/Progra~1/qt
 144   PATH_SUFFIXES
 145     lib
 146   )
 147
 148 # Qt 3 should prefer QTDIR over the PATH
 149 find_program(QT_MOC_EXECUTABLE
 150   NAMES moc-qt3 moc moc3 moc3-mt
 151   HINTS
 152     ENV QTDIR
 153   PATHS
 154   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]/include/Qt"
 155   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]/include/Qt"
 156   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]/include/Qt"
 157   ${GLOB_PATHS_BIN}
 158     /usr/local/lib/qt3
 159     /usr/local/qt
 160     /usr/lib/qt
 161     /usr/lib/qt3
 162     /usr/share/qt3
 163     C:/Progra~1/qt
 164     /usr/X11R6
 165   PATH_SUFFIXES
 166     bin
 167   )
 168
 169 if(QT_MOC_EXECUTABLE)
 170   set ( QT_WRAP_CPP "YES")
 171 endif()
 172
 173 # Qt 3 should prefer QTDIR over the PATH
 174 find_program(QT_UIC_EXECUTABLE
 175   NAMES uic-qt3 uic uic3 uic3-mt
 176   HINTS
 177     ENV QTDIR
 178   PATHS
 179   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]/include/Qt"
 180   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]/include/Qt"
 181   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]/include/Qt"
 182   ${GLOB_PATHS_BIN}
 183     /usr/local/qt
 184     /usr/lib/qt
 185     /usr/lib/qt3
 186     /usr/share/qt3
 187     C:/Progra~1/qt
 188     /usr/X11R6
 189   PATH_SUFFIXES
 190     bin
 191   )
 192
 193 if(QT_UIC_EXECUTABLE)
 194   set ( QT_WRAP_UI "YES")
 195 endif()
 196
 197 if (WIN32)
 198   find_library(QT_QTMAIN_LIBRARY qtmain
 199     HINTS
 200       ENV QTDIR
 201       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
 202       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
 203       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
 204     PATHS
 205       "$ENV{ProgramFiles}/qt"
 206       "C:/Program Files/qt"
 207     PATH_SUFFIXES
 208       lib
 209     DOC "This Library is only needed by and included with Qt3 on MSWindows. It should be NOTFOUND, undefined or IGNORE otherwise."
 210     )
 211 endif ()
 212
 213 #support old QT_MIN_VERSION if set, but not if version is supplied by find_package()
 214 if(NOT Qt3_FIND_VERSION AND QT_MIN_VERSION)
 215   set(Qt3_FIND_VERSION ${QT_MIN_VERSION})
 216 endif()
 217
 218 # if the include a library are found then we have it
 219 include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
 220 FIND_PACKAGE_HANDLE_STANDARD_ARGS(Qt3
 221                                   REQUIRED_VARS QT_QT_LIBRARY QT_INCLUDE_DIR QT_MOC_EXECUTABLE
 222                                   VERSION_VAR QT_VERSION_STRING)
 223 set(QT_FOUND ${QT3_FOUND} )
 224
 225 if(QT_FOUND)
 226   set( QT_LIBRARIES ${QT_LIBRARIES} ${QT_QT_LIBRARY} )
 227   set( QT_DEFINITIONS "")
 228
 229   if (WIN32 AND NOT CYGWIN)
 230     if (QT_QTMAIN_LIBRARY)
 231       # for version 3
 232       set (QT_DEFINITIONS -DQT_DLL -DQT_THREAD_SUPPORT -DNO_DEBUG)
 233       set (QT_LIBRARIES imm32.lib ${QT_QT_LIBRARY} ${QT_QTMAIN_LIBRARY} )
 234       set (QT_LIBRARIES ${QT_LIBRARIES} winmm wsock32)
 235     else ()
 236       # for version 2
 237       set (QT_LIBRARIES imm32.lib ws2_32.lib ${QT_QT_LIBRARY} )
 238     endif ()
 239   else ()
 240     set (QT_LIBRARIES ${QT_QT_LIBRARY} )
 241
 242     set (QT_DEFINITIONS -DQT_SHARED -DQT_NO_DEBUG)
 243     if(QT_QT_LIBRARY MATCHES "qt-mt")
 244       set (QT_DEFINITIONS ${QT_DEFINITIONS} -DQT_THREAD_SUPPORT -D_REENTRANT)
 245     endif()
 246
 247   endif ()
 248
 249   if (QT_QASSISTANTCLIENT_LIBRARY)
 250     set (QT_LIBRARIES ${QT_QASSISTANTCLIENT_LIBRARY} ${QT_LIBRARIES})
 251   endif ()
 252
 253   # Backwards compatibility for CMake1.4 and 1.2
 254   set (QT_MOC_EXE ${QT_MOC_EXECUTABLE} )
 255   set (QT_UIC_EXE ${QT_UIC_EXECUTABLE} )
 256   # for unix add X11 stuff
 257   if(UNIX)
 258     find_package(X11)
 259     if (X11_FOUND)
 260       set (QT_LIBRARIES ${QT_LIBRARIES} ${X11_LIBRARIES})
 261     endif ()
 262     if (CMAKE_DL_LIBS)
 263       set (QT_LIBRARIES ${QT_LIBRARIES} ${CMAKE_DL_LIBS})
 264     endif ()
 265   endif()
 266   if(QT_QT_LIBRARY MATCHES "qt-mt")
 267     find_package(Threads)
 268     set(QT_LIBRARIES ${QT_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})
 269   endif()
 270 endif()
 271
 272 if(QT_MOC_EXECUTABLE)
 273   execute_process(COMMAND ${QT_MOC_EXECUTABLE} "-v"
 274                   OUTPUT_VARIABLE QTVERSION_MOC
 275                   ERROR_QUIET)
 276 endif()
 277 if(QT_UIC_EXECUTABLE)
 278   execute_process(COMMAND ${QT_UIC_EXECUTABLE} "-version"
 279                   OUTPUT_VARIABLE QTVERSION_UIC
 280                   ERROR_QUIET)
 281 endif()
 282
 283 set(_QT_UIC_VERSION_3 FALSE)
 284 if("${QTVERSION_UIC}" MATCHES ".* 3..*")
 285   set(_QT_UIC_VERSION_3 TRUE)
 286 endif()
 287
 288 set(_QT_MOC_VERSION_3 FALSE)
 289 if("${QTVERSION_MOC}" MATCHES ".* 3..*")
 290   set(_QT_MOC_VERSION_3 TRUE)
 291 endif()
 292
 293 set(QT_WRAP_CPP FALSE)
 294 if (QT_MOC_EXECUTABLE AND _QT_MOC_VERSION_3)
 295   set ( QT_WRAP_CPP TRUE)
 296 endif ()
 297
 298 set(QT_WRAP_UI FALSE)
 299 if (QT_UIC_EXECUTABLE AND _QT_UIC_VERSION_3)
 300   set ( QT_WRAP_UI TRUE)
 301 endif ()
 302
 303 mark_as_advanced(
 304   QT_INCLUDE_DIR
 305   QT_QT_LIBRARY
 306   QT_QTMAIN_LIBRARY
 307   QT_QASSISTANTCLIENT_LIBRARY
 308   QT_UIC_EXECUTABLE
 309   QT_MOC_EXECUTABLE
 310   QT_WRAP_CPP
 311   QT_WRAP_UI
 312   )