Modules/FindQt3.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 #[=======================================================================[.rst:
   5 FindQt3
   6 -------
   7
   8 Locate Qt include paths and libraries
   9
  10 This module defines:
  11
  12 ::
  13
  14   QT_INCLUDE_DIR    - where to find qt.h, etc.
  15   QT_LIBRARIES      - the libraries to link against to use Qt.
  16   QT_DEFINITIONS    - definitions to use when
  17                       compiling code that uses Qt.
  18   QT_FOUND          - If false, don't try to use Qt.
  19   QT_VERSION_STRING - the version of Qt found
  20
  21
  22
  23 If you need the multithreaded version of Qt, set QT_MT_REQUIRED to
  24 TRUE
  25
  26 Also defined, but not for general use are:
  27
  28 ::
  29
  30   QT_MOC_EXECUTABLE, where to find the moc tool.
  31   QT_UIC_EXECUTABLE, where to find the uic tool.
  32   QT_QT_LIBRARY, where to find the Qt library.
  33   QT_QTMAIN_LIBRARY, where to find the qtmain
  34    library. This is only required by Qt3 on Windows.
  35 #]=======================================================================]
  36
  37 # These are around for backwards compatibility
  38 # they will be set
  39 #  QT_WRAP_CPP, set true if QT_MOC_EXECUTABLE is found
  40 #  QT_WRAP_UI set true if QT_UIC_EXECUTABLE is found
  41
  42 # If Qt4 has already been found, fail.
  43 if(QT4_FOUND)
  44   if(Qt3_FIND_REQUIRED)
  45     message( FATAL_ERROR "Qt3 and Qt4 cannot be used together in one project.")
  46   else()
  47     if(NOT Qt3_FIND_QUIETLY)
  48       message( STATUS    "Qt3 and Qt4 cannot be used together in one project.")
  49     endif()
  50     return()
  51   endif()
  52 endif()
  53
  54
  55 file(GLOB GLOB_PATHS /usr/lib/qt-3*)
  56 foreach(GLOB_PATH ${GLOB_PATHS})
  57   list(APPEND GLOB_PATHS_BIN "${GLOB_PATH}/bin")
  58 endforeach()
  59 find_path(QT_INCLUDE_DIR qt.h
  60   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]/include/Qt"
  61   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]/include/Qt"
  62   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]/include/Qt"
  63   $ENV{QTDIR}/include
  64   ${GLOB_PATHS}
  65   /usr/share/qt3/include
  66   C:/Progra~1/qt/include
  67   /usr/local/include/X11/qt3
  68   PATH_SUFFIXES lib/qt/include lib/qt3/include include/qt include/qt3 qt/include qt3/include
  69   )
  70
  71 # if qglobal.h is not in the qt_include_dir then set
  72 # QT_INCLUDE_DIR to NOTFOUND
  73 if(NOT EXISTS ${QT_INCLUDE_DIR}/qglobal.h)
  74   set(QT_INCLUDE_DIR QT_INCLUDE_DIR-NOTFOUND CACHE PATH "path to Qt3 include directory" FORCE)
  75 endif()
  76
  77 if(QT_INCLUDE_DIR)
  78   #extract the version string from qglobal.h
  79   file(STRINGS ${QT_INCLUDE_DIR}/qglobal.h QGLOBAL_H REGEX "#define[\t ]+QT_VERSION_STR[\t ]+\"[0-9]+.[0-9]+.[0-9]+[a-z]*\"")
  80   string(REGEX REPLACE ".*\"([0-9]+.[0-9]+.[0-9]+[a-z]*)\".*" "\\1" qt_version_str "${QGLOBAL_H}")
  81   unset(QGLOBAL_H)
  82
  83   # Under windows the qt library (MSVC) has the format qt-mtXYZ where XYZ is the
  84   # version X.Y.Z, so we need to remove the dots from version
  85   string(REGEX REPLACE "\\." "" qt_version_str_lib "${qt_version_str}")
  86   set(QT_VERSION_STRING "${qt_version_str}")
  87 endif()
  88
  89 file(GLOB GLOB_PATHS_LIB /usr/lib/qt-3*/lib/)
  90 if (QT_MT_REQUIRED)
  91   find_library(QT_QT_LIBRARY
  92     NAMES
  93     qt-mt qt-mt${qt_version_str_lib} qt-mtnc${qt_version_str_lib}
  94     qt-mtedu${qt_version_str_lib} qt-mt230nc qt-mtnc321 qt-mt3
  95     PATHS
  96       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
  97       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
  98       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
  99       ENV QTDIR
 100       ${GLOB_PATHS_LIB}
 101       /usr/share/qt3
 102       C:/Progra~1/qt
 103     PATH_SUFFIXES
 104       lib lib/qt lib/qt3 qt qt3 qt/lib qt3/lib
 105     )
 106
 107 else ()
 108   find_library(QT_QT_LIBRARY
 109     NAMES
 110     qt qt-${qt_version_str_lib} qt-edu${qt_version_str_lib}
 111     qt-mt qt-mt${qt_version_str_lib} qt-mtnc${qt_version_str_lib}
 112     qt-mtedu${qt_version_str_lib} qt-mt230nc qt-mtnc321 qt-mt3
 113     PATHS
 114       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
 115       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
 116       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
 117       ENV QTDIR
 118       ${GLOB_PATHS_LIB}
 119       /usr/share/qt3
 120       C:/Progra~1/qt/lib
 121     PATH_SUFFIXES
 122       lib lib/qt lib/qt3 qt qt3 qt/lib qt3/lib
 123     )
 124 endif ()
 125
 126
 127 find_library(QT_QASSISTANTCLIENT_LIBRARY
 128   NAMES qassistantclient
 129   PATHS
 130     "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
 131     "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
 132     "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
 133     ENV QTDIR
 134     ${GLOB_PATHS_LIB}
 135     /usr/share/qt3
 136     C:/Progra~1/qt
 137   PATH_SUFFIXES
 138     lib lib/qt lib/qt3 qt qt3 qt/lib qt3/lib
 139   )
 140
 141 # Qt 3 should prefer QTDIR over the PATH
 142 find_program(QT_MOC_EXECUTABLE
 143   NAMES moc-qt3 moc3 moc3-mt moc
 144   HINTS
 145     ENV QTDIR
 146   PATHS
 147   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]/include/Qt"
 148   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]/include/Qt"
 149   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]/include/Qt"
 150   ${GLOB_PATHS_BIN}
 151     /usr/share/qt3
 152     C:/Progra~1/qt
 153   PATH_SUFFIXES
 154     bin lib/qt lib/qt3 qt qt3 qt/bin qt3/bin lib/qt/bin lib/qt3/bin
 155   )
 156
 157 if(QT_MOC_EXECUTABLE)
 158   set ( QT_WRAP_CPP "YES")
 159 endif()
 160
 161 # Qt 3 should prefer QTDIR over the PATH
 162 find_program(QT_UIC_EXECUTABLE
 163   NAMES uic-qt3 uic3 uic3-mt uic
 164   HINTS
 165     ENV QTDIR
 166   PATHS
 167   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]/include/Qt"
 168   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]/include/Qt"
 169   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]/include/Qt"
 170   ${GLOB_PATHS_BIN}
 171     /usr/share/qt3
 172     C:/Progra~1/qt
 173   PATH_SUFFIXES
 174     bin lib/qt lib/qt3 qt qt3 qt/bin qt3/bin lib/qt/bin lib/qt3/bin
 175   )
 176
 177 if(QT_UIC_EXECUTABLE)
 178   set ( QT_WRAP_UI "YES")
 179 endif()
 180
 181 if (WIN32)
 182   find_library(QT_QTMAIN_LIBRARY qtmain
 183     HINTS
 184       ENV QTDIR
 185       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
 186       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
 187       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
 188     PATHS
 189       "$ENV{ProgramFiles}/qt"
 190       "C:/Program Files/qt"
 191     PATH_SUFFIXES
 192       lib
 193     DOC "This Library is only needed by and included with Qt3 on MSWindows. It should be NOTFOUND, undefined or IGNORE otherwise."
 194     )
 195 endif ()
 196
 197 #support old QT_MIN_VERSION if set, but not if version is supplied by find_package()
 198 if(NOT Qt3_FIND_VERSION AND QT_MIN_VERSION)
 199   set(Qt3_FIND_VERSION ${QT_MIN_VERSION})
 200 endif()
 201
 202 # if the include a library are found then we have it
 203 include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
 204 FIND_PACKAGE_HANDLE_STANDARD_ARGS(Qt3
 205                                   REQUIRED_VARS QT_QT_LIBRARY QT_INCLUDE_DIR QT_MOC_EXECUTABLE
 206                                   VERSION_VAR QT_VERSION_STRING)
 207 set(QT_FOUND ${QT3_FOUND} )
 208
 209 if(QT_FOUND)
 210   set( QT_LIBRARIES ${QT_LIBRARIES} ${QT_QT_LIBRARY} )
 211   set( QT_DEFINITIONS "")
 212
 213   if (WIN32 AND NOT CYGWIN)
 214     if (QT_QTMAIN_LIBRARY)
 215       # for version 3
 216       set (QT_DEFINITIONS -DQT_DLL -DQT_THREAD_SUPPORT -DNO_DEBUG)
 217       set (QT_LIBRARIES imm32.lib ${QT_QT_LIBRARY} ${QT_QTMAIN_LIBRARY} )
 218       set (QT_LIBRARIES ${QT_LIBRARIES} winmm wsock32)
 219     else ()
 220       # for version 2
 221       set (QT_LIBRARIES imm32.lib ws2_32.lib ${QT_QT_LIBRARY} )
 222     endif ()
 223   else ()
 224     set (QT_LIBRARIES ${QT_QT_LIBRARY} )
 225
 226     set (QT_DEFINITIONS -DQT_SHARED -DQT_NO_DEBUG)
 227     if(QT_QT_LIBRARY MATCHES "qt-mt")
 228       set (QT_DEFINITIONS ${QT_DEFINITIONS} -DQT_THREAD_SUPPORT -D_REENTRANT)
 229     endif()
 230
 231   endif ()
 232
 233   if (QT_QASSISTANTCLIENT_LIBRARY)
 234     set (QT_LIBRARIES ${QT_QASSISTANTCLIENT_LIBRARY} ${QT_LIBRARIES})
 235   endif ()
 236
 237   # Backwards compatibility for CMake1.4 and 1.2
 238   set (QT_MOC_EXE ${QT_MOC_EXECUTABLE} )
 239   set (QT_UIC_EXE ${QT_UIC_EXECUTABLE} )
 240   # for unix add X11 stuff
 241   if(UNIX)
 242     find_package(X11)
 243     if (X11_FOUND)
 244       set (QT_LIBRARIES ${QT_LIBRARIES} ${X11_LIBRARIES})
 245     endif ()
 246     if (CMAKE_DL_LIBS)
 247       set (QT_LIBRARIES ${QT_LIBRARIES} ${CMAKE_DL_LIBS})
 248     endif ()
 249   endif()
 250   if(QT_QT_LIBRARY MATCHES "qt-mt")
 251     find_package(Threads)
 252     set(QT_LIBRARIES ${QT_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})
 253   endif()
 254 endif()
 255
 256 if(QT_MOC_EXECUTABLE)
 257   execute_process(COMMAND ${QT_MOC_EXECUTABLE} "-v"
 258                   OUTPUT_VARIABLE QTVERSION_MOC
 259                   ERROR_QUIET)
 260 endif()
 261 if(QT_UIC_EXECUTABLE)
 262   execute_process(COMMAND ${QT_UIC_EXECUTABLE} "-version"
 263                   OUTPUT_VARIABLE QTVERSION_UIC
 264                   ERROR_QUIET)
 265 endif()
 266
 267 set(_QT_UIC_VERSION_3 FALSE)
 268 if("${QTVERSION_UIC}" MATCHES " 3.")
 269   set(_QT_UIC_VERSION_3 TRUE)
 270 endif()
 271
 272 set(_QT_MOC_VERSION_3 FALSE)
 273 if("${QTVERSION_MOC}" MATCHES " 3.")
 274   set(_QT_MOC_VERSION_3 TRUE)
 275 endif()
 276
 277 set(QT_WRAP_CPP FALSE)
 278 if (QT_MOC_EXECUTABLE AND _QT_MOC_VERSION_3)
 279   set ( QT_WRAP_CPP TRUE)
 280 endif ()
 281
 282 set(QT_WRAP_UI FALSE)
 283 if (QT_UIC_EXECUTABLE AND _QT_UIC_VERSION_3)
 284   set ( QT_WRAP_UI TRUE)
 285 endif ()
 286
 287 mark_as_advanced(
 288   QT_INCLUDE_DIR
 289   QT_QT_LIBRARY
 290   QT_QTMAIN_LIBRARY
 291   QT_QASSISTANTCLIENT_LIBRARY
 292   QT_UIC_EXECUTABLE
 293   QT_MOC_EXECUTABLE
 294   QT_WRAP_CPP
 295   QT_WRAP_UI
 296   )