Modules/FindQt3.cmake

   1 # - Locate Qt include paths and libraries
   2 # This module defines:
   3 #  QT_INCLUDE_DIR    - where to find qt.h, etc.
   4 #  QT_LIBRARIES      - the libraries to link against to use Qt.
   5 #  QT_DEFINITIONS    - definitions to use when
   6 #                      compiling code that uses Qt.
   7 #  QT_FOUND          - If false, don't try to use Qt.
   8 #  QT_VERSION_STRING - the version of Qt found
   9 #
  10 # If you need the multithreaded version of Qt, set QT_MT_REQUIRED to TRUE
  11 #
  12 # Also defined, but not for general use are:
  13 #  QT_MOC_EXECUTABLE, where to find the moc tool.
  14 #  QT_UIC_EXECUTABLE, where to find the uic tool.
  15 #  QT_QT_LIBRARY, where to find the Qt library.
  16 #  QT_QTMAIN_LIBRARY, where to find the qtmain
  17 #   library. This is only required by Qt3 on Windows.
  18
  19 # These are around for backwards compatibility
  20 # they will be set
  21 #  QT_WRAP_CPP, set true if QT_MOC_EXECUTABLE is found
  22 #  QT_WRAP_UI set true if QT_UIC_EXECUTABLE is found
  23
  24 #=============================================================================
  25 # Copyright 2005-2009 Kitware, Inc.
  26 #
  27 # Distributed under the OSI-approved BSD License (the "License");
  28 # see accompanying file Copyright.txt for details.
  29 #
  30 # This software is distributed WITHOUT ANY WARRANTY; without even the
  31 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  32 # See the License for more information.
  33 #=============================================================================
  34 # (To distribute this file outside of CMake, substitute the full
  35 #  License text for the above reference.)
  36
  37 # If Qt4 has already been found, fail.
  38 if(QT4_FOUND)
  39   if(Qt3_FIND_REQUIRED)
  40     message( FATAL_ERROR "Qt3 and Qt4 cannot be used together in one project.")
  41   else()
  42     if(NOT Qt3_FIND_QUIETLY)
  43       message( STATUS    "Qt3 and Qt4 cannot be used together in one project.")
  44     endif()
  45     return()
  46   endif()
  47 endif()
  48
  49
  50 file(GLOB GLOB_PATHS /usr/lib/qt-3*)
  51 foreach(GLOB_PATH ${GLOB_PATHS})
  52   list(APPEND GLOB_PATHS_BIN "${GLOB_PATH}/bin")
  53 endforeach()
  54 find_path(QT_INCLUDE_DIR qt.h
  55   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]/include/Qt"
  56   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]/include/Qt"
  57   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]/include/Qt"
  58   $ENV{QTDIR}/include
  59   ${GLOB_PATHS}
  60   /usr/local/qt/include
  61   /usr/lib/qt/include
  62   /usr/lib/qt3/include
  63   /usr/include/qt
  64   /usr/share/qt3/include
  65   C:/Progra~1/qt/include
  66   /usr/include/qt3
  67   )
  68
  69 # if qglobal.h is not in the qt_include_dir then set
  70 # QT_INCLUDE_DIR to NOTFOUND
  71 if(NOT EXISTS ${QT_INCLUDE_DIR}/qglobal.h)
  72   set(QT_INCLUDE_DIR QT_INCLUDE_DIR-NOTFOUND CACHE PATH "path to Qt3 include directory" FORCE)
  73 endif()
  74
  75 if(QT_INCLUDE_DIR)
  76   #extract the version string from qglobal.h
  77   file(STRINGS ${QT_INCLUDE_DIR}/qglobal.h QGLOBAL_H REGEX "#define[\t ]+QT_VERSION_STR[\t ]+\"[0-9]+.[0-9]+.[0-9]+[a-z]*\"")
  78   string(REGEX REPLACE ".*\"([0-9]+.[0-9]+.[0-9]+[a-z]*)\".*" "\\1" qt_version_str "${QGLOBAL_H}")
  79   unset(QGLOBAL_H)
  80
  81   # Under windows the qt library (MSVC) has the format qt-mtXYZ where XYZ is the
  82   # version X.Y.Z, so we need to remove the dots from version
  83   string(REGEX REPLACE "\\." "" qt_version_str_lib "${qt_version_str}")
  84   set(QT_VERSION_STRING "${qt_version_str}")
  85 endif()
  86
  87 file(GLOB GLOB_PATHS_LIB /usr/lib/qt-3*/lib/)
  88 if (QT_MT_REQUIRED)
  89   find_library(QT_QT_LIBRARY
  90     NAMES
  91     qt-mt qt-mt${qt_version_str_lib} qt-mtnc${qt_version_str_lib}
  92     qt-mtedu${qt_version_str_lib} qt-mt230nc qt-mtnc321 qt-mt3
  93     PATHS
  94       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
  95       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
  96       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
  97       ENV QTDIR
  98       ${GLOB_PATHS_LIB}
  99       /usr/local/qt
 100       /usr/lib/qt
 101       /usr/lib/qt3
 102       /usr/share/qt3
 103       C:/Progra~1/qt
 104     PATH_SUFFIXES
 105       lib
 106     )
 107
 108 else ()
 109   find_library(QT_QT_LIBRARY
 110     NAMES
 111     qt qt-${qt_version_str_lib} qt-edu${qt_version_str_lib}
 112     qt-mt qt-mt${qt_version_str_lib} qt-mtnc${qt_version_str_lib}
 113     qt-mtedu${qt_version_str_lib} qt-mt230nc qt-mtnc321 qt-mt3
 114     PATHS
 115       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
 116       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
 117       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
 118       ENV QTDIR
 119       ${GLOB_PATHS_LIB}
 120       /usr/local/qt
 121       /usr/lib/qt
 122       /usr/lib/qt3
 123       /usr/share/qt3
 124       C:/Progra~1/qt/lib
 125     PATH_SUFFIXES
 126       lib
 127     )
 128 endif ()
 129
 130
 131 find_library(QT_QASSISTANTCLIENT_LIBRARY
 132   NAMES qassistantclient
 133   PATHS
 134     "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
 135     "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
 136     "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
 137     ENV QTDIR
 138     ${GLOB_PATHS_LIB}
 139     /usr/local/qt
 140     /usr/lib/qt3
 141     /usr/share/qt3
 142     C:/Progra~1/qt
 143   PATH_SUFFIXES
 144     lib
 145   )
 146
 147 # Qt 3 should prefer QTDIR over the PATH
 148 find_program(QT_MOC_EXECUTABLE
 149   NAMES moc-qt3 moc
 150   HINTS
 151     ENV QTDIR
 152   PATHS
 153   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]/include/Qt"
 154   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]/include/Qt"
 155   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]/include/Qt"
 156   ${GLOB_PATHS_BIN}
 157     /usr/local/qt
 158     /usr/lib/qt
 159     /usr/lib/qt3
 160     /usr/share/qt3
 161     C:/Progra~1/qt
 162     /usr/X11R6
 163   PATH_SUFFIXES
 164     bin
 165   )
 166
 167 if(QT_MOC_EXECUTABLE)
 168   set ( QT_WRAP_CPP "YES")
 169 endif()
 170
 171 # Qt 3 should prefer QTDIR over the PATH
 172 find_program(QT_UIC_EXECUTABLE
 173   NAMES uic-qt3 uic
 174   HINTS
 175     ENV QTDIR
 176   PATHS
 177   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]/include/Qt"
 178   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]/include/Qt"
 179   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]/include/Qt"
 180   ${GLOB_PATHS_BIN}
 181     /usr/local/qt
 182     /usr/lib/qt
 183     /usr/lib/qt3
 184     /usr/share/qt3
 185     C:/Progra~1/qt
 186     /usr/X11R6
 187   PATH_SUFFIXES
 188     bin
 189   )
 190
 191 if(QT_UIC_EXECUTABLE)
 192   set ( QT_WRAP_UI "YES")
 193 endif()
 194
 195 if (WIN32)
 196   find_library(QT_QTMAIN_LIBRARY qtmain
 197     HINTS
 198       ENV QTDIR
 199       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
 200       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
 201       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
 202     PATHS
 203       "$ENV{ProgramFiles}/qt"
 204       "C:/Program Files/qt"
 205     PATH_SUFFIXES
 206       lib
 207     DOC "This Library is only needed by and included with Qt3 on MSWindows. It should be NOTFOUND, undefined or IGNORE otherwise."
 208     )
 209 endif ()
 210
 211 #support old QT_MIN_VERSION if set, but not if version is supplied by find_package()
 212 if(NOT Qt3_FIND_VERSION AND QT_MIN_VERSION)
 213   set(Qt3_FIND_VERSION ${QT_MIN_VERSION})
 214 endif()
 215
 216 # if the include a library are found then we have it
 217 include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
 218 FIND_PACKAGE_HANDLE_STANDARD_ARGS(Qt3
 219                                   REQUIRED_VARS QT_QT_LIBRARY QT_INCLUDE_DIR QT_MOC_EXECUTABLE
 220                                   VERSION_VAR QT_VERSION_STRING)
 221 set(QT_FOUND ${QT3_FOUND} )
 222
 223 if(QT_FOUND)
 224   set( QT_LIBRARIES ${QT_LIBRARIES} ${QT_QT_LIBRARY} )
 225   set( QT_DEFINITIONS "")
 226
 227   if (WIN32 AND NOT CYGWIN)
 228     if (QT_QTMAIN_LIBRARY)
 229       # for version 3
 230       set (QT_DEFINITIONS -DQT_DLL -DQT_THREAD_SUPPORT -DNO_DEBUG)
 231       set (QT_LIBRARIES imm32.lib ${QT_QT_LIBRARY} ${QT_QTMAIN_LIBRARY} )
 232       set (QT_LIBRARIES ${QT_LIBRARIES} winmm wsock32)
 233     else ()
 234       # for version 2
 235       set (QT_LIBRARIES imm32.lib ws2_32.lib ${QT_QT_LIBRARY} )
 236     endif ()
 237   else ()
 238     set (QT_LIBRARIES ${QT_QT_LIBRARY} )
 239
 240     set (QT_DEFINITIONS -DQT_SHARED -DQT_NO_DEBUG)
 241     if(QT_QT_LIBRARY MATCHES "qt-mt")
 242       set (QT_DEFINITIONS ${QT_DEFINITIONS} -DQT_THREAD_SUPPORT -D_REENTRANT)
 243     endif()
 244
 245   endif ()
 246
 247   if (QT_QASSISTANTCLIENT_LIBRARY)
 248     set (QT_LIBRARIES ${QT_QASSISTANTCLIENT_LIBRARY} ${QT_LIBRARIES})
 249   endif ()
 250
 251   # Backwards compatibility for CMake1.4 and 1.2
 252   set (QT_MOC_EXE ${QT_MOC_EXECUTABLE} )
 253   set (QT_UIC_EXE ${QT_UIC_EXECUTABLE} )
 254   # for unix add X11 stuff
 255   if(UNIX)
 256     find_package(X11)
 257     if (X11_FOUND)
 258       set (QT_LIBRARIES ${QT_LIBRARIES} ${X11_LIBRARIES})
 259     endif ()
 260     if (CMAKE_DL_LIBS)
 261       set (QT_LIBRARIES ${QT_LIBRARIES} ${CMAKE_DL_LIBS})
 262     endif ()
 263   endif()
 264   if(QT_QT_LIBRARY MATCHES "qt-mt")
 265     find_package(Threads)
 266     set(QT_LIBRARIES ${QT_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})
 267   endif()
 268 endif()
 269
 270 if(QT_MOC_EXECUTABLE)
 271   execute_process(COMMAND ${QT_MOC_EXECUTABLE} "-v"
 272                   OUTPUT_VARIABLE QTVERSION_MOC
 273                   ERROR_QUIET)
 274 endif()
 275 if(QT_UIC_EXECUTABLE)
 276   execute_process(COMMAND ${QT_UIC_EXECUTABLE} "-version"
 277                   OUTPUT_VARIABLE QTVERSION_UIC
 278                   ERROR_QUIET)
 279 endif()
 280
 281 set(_QT_UIC_VERSION_3 FALSE)
 282 if("${QTVERSION_UIC}" MATCHES ".* 3..*")
 283   set(_QT_UIC_VERSION_3 TRUE)
 284 endif()
 285
 286 set(_QT_MOC_VERSION_3 FALSE)
 287 if("${QTVERSION_MOC}" MATCHES ".* 3..*")
 288   set(_QT_MOC_VERSION_3 TRUE)
 289 endif()
 290
 291 set(QT_WRAP_CPP FALSE)
 292 if (QT_MOC_EXECUTABLE AND _QT_MOC_VERSION_3)
 293   set ( QT_WRAP_CPP TRUE)
 294 endif ()
 295
 296 set(QT_WRAP_UI FALSE)
 297 if (QT_UIC_EXECUTABLE AND _QT_UIC_VERSION_3)
 298   set ( QT_WRAP_UI TRUE)
 299 endif ()
 300
 301 mark_as_advanced(
 302   QT_INCLUDE_DIR
 303   QT_QT_LIBRARY
 304   QT_QTMAIN_LIBRARY
 305   QT_QASSISTANTCLIENT_LIBRARY
 306   QT_UIC_EXECUTABLE
 307   QT_MOC_EXECUTABLE
 308   QT_WRAP_CPP
 309   QT_WRAP_UI
 310   )