Modules/FindLibLZMA.cmake

   1 # - Find LibLZMA
   2 # Find LibLZMA headers and library
   3 #
   4 #  LIBLZMA_FOUND             - True if liblzma is found.
   5 #  LIBLZMA_INCLUDE_DIRS      - Directory where liblzma headers are located.
   6 #  LIBLZMA_LIBRARIES         - Lzma libraries to link against.
   7 #  LIBLZMA_HAS_AUTO_DECODER  - True if lzma_auto_decoder() is found (required).
   8 #  LIBLZMA_HAS_EASY_ENCODER  - True if lzma_easy_encoder() is found (required).
   9 #  LIBLZMA_HAS_LZMA_PRESET   - True if lzma_lzma_preset() is found (required).
  10 #  LIBLZMA_VERSION_MAJOR     - The major version of lzma
  11 #  LIBLZMA_VERSION_MINOR     - The minor version of lzma
  12 #  LIBLZMA_VERSION_PATCH     - The patch version of lzma
  13 #  LIBLZMA_VERSION_STRING    - version number as a string (ex: "5.0.3")
  14
  15 #=============================================================================
  16 # Copyright 2008 Per Øyvind Karlsen <peroyvind@mandriva.org>
  17 # Copyright 2009 Alexander Neundorf <neundorf@kde.org>
  18 # Copyright 2009 Helio Chissini de Castro <helio@kde.org>
  19 # Copyright 2012 Mario Bensi <mbensi@ipsquad.net>
  20 #
  21 # Distributed under the OSI-approved BSD License (the "License");
  22 # see accompanying file Copyright.txt for details.
  23 #
  24 # This software is distributed WITHOUT ANY WARRANTY; without even the
  25 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  26 # See the License for more information.
  27 #=============================================================================
  28 # (To distribute this file outside of CMake, substitute the full
  29 #  License text for the above reference.)
  30
  31
  32 find_path(LIBLZMA_INCLUDE_DIR lzma.h )
  33 find_library(LIBLZMA_LIBRARY lzma)
  34
  35 if(LIBLZMA_INCLUDE_DIR AND EXISTS "${LIBLZMA_INCLUDE_DIR}/lzma/version.h")
  36     file(STRINGS "${LIBLZMA_INCLUDE_DIR}/lzma/version.h" LIBLZMA_HEADER_CONTENTS REGEX "#define LZMA_VERSION_[A-Z]+ [0-9]+")
  37
  38     string(REGEX REPLACE ".*#define LZMA_VERSION_MAJOR ([0-9]+).*" "\\1" LIBLZMA_VERSION_MAJOR "${LIBLZMA_HEADER_CONTENTS}")
  39     string(REGEX REPLACE ".*#define LZMA_VERSION_MINOR ([0-9]+).*" "\\1" LIBLZMA_VERSION_MINOR "${LIBLZMA_HEADER_CONTENTS}")
  40     string(REGEX REPLACE ".*#define LZMA_VERSION_PATCH ([0-9]+).*" "\\1" LIBLZMA_VERSION_PATCH "${LIBLZMA_HEADER_CONTENTS}")
  41
  42     set(LIBLZMA_VERSION_STRING "${LIBLZMA_VERSION_MAJOR}.${LIBLZMA_VERSION_MINOR}.${LIBLZMA_VERSION_PATCH}")
  43     unset(LIBLZMA_HEADER_CONTENTS)
  44 endif()
  45
  46 # We're using new code known now as XZ, even library still been called LZMA
  47 # it can be found in http://tukaani.org/xz/
  48 # Avoid using old codebase
  49 if (LIBLZMA_LIBRARY)
  50    include(${CMAKE_CURRENT_LIST_DIR}/CheckLibraryExists.cmake)
  51    CHECK_LIBRARY_EXISTS(${LIBLZMA_LIBRARY} lzma_auto_decoder "" LIBLZMA_HAS_AUTO_DECODER)
  52    CHECK_LIBRARY_EXISTS(${LIBLZMA_LIBRARY} lzma_easy_encoder "" LIBLZMA_HAS_EASY_ENCODER)
  53    CHECK_LIBRARY_EXISTS(${LIBLZMA_LIBRARY} lzma_lzma_preset "" LIBLZMA_HAS_LZMA_PRESET)
  54 endif ()
  55
  56 include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
  57 FIND_PACKAGE_HANDLE_STANDARD_ARGS(LibLZMA  REQUIRED_VARS  LIBLZMA_INCLUDE_DIR
  58                                                           LIBLZMA_LIBRARY
  59                                                           LIBLZMA_HAS_AUTO_DECODER
  60                                                           LIBLZMA_HAS_EASY_ENCODER
  61                                                           LIBLZMA_HAS_LZMA_PRESET
  62                                            VERSION_VAR    LIBLZMA_VERSION_STRING
  63                                  )
  64
  65 if (LIBLZMA_FOUND)
  66     set(LIBLZMA_LIBRARIES ${LIBLZMA_LIBRARY})
  67     set(LIBLZMA_INCLUDE_DIRS ${LIBLZMA_INCLUDE_DIR})
  68 endif ()
  69
  70 mark_as_advanced( LIBLZMA_INCLUDE_DIR LIBLZMA_LIBRARY )