Modules/FindLibArchive.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 #[=======================================================================[.rst:
   5 FindLibArchive
   6 --------------
   7
   8 Find libarchive library and headers.
   9 Libarchive is multi-format archive and compression library.
  10
  11 The module defines the following variables:
  12
  13 ::
  14
  15   LibArchive_FOUND        - true if libarchive was found
  16   LibArchive_INCLUDE_DIRS - include search path
  17   LibArchive_LIBRARIES    - libraries to link
  18   LibArchive_VERSION      - libarchive 3-component version number
  19
  20 The module defines the following ``IMPORTED`` targets:
  21
  22 ::
  23
  24   LibArchive::LibArchive  - target for linking against libarchive
  25
  26 .. versionadded:: 3.6
  27   Support for new libarchive 3.2 version string format.
  28
  29 .. versionadded:: 3.17
  30   Provides an imported target.
  31
  32 #]=======================================================================]
  33
  34 find_path(LibArchive_INCLUDE_DIR
  35   NAMES archive.h
  36   PATHS
  37   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\GnuWin32\\LibArchive;InstallPath]/include"
  38   DOC "libarchive include directory"
  39   )
  40
  41 find_library(LibArchive_LIBRARY
  42   NAMES archive libarchive
  43   PATHS
  44   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\GnuWin32\\LibArchive;InstallPath]/lib"
  45   DOC "libarchive library"
  46   )
  47
  48 mark_as_advanced(LibArchive_INCLUDE_DIR LibArchive_LIBRARY)
  49
  50 # Extract the version number from the header.
  51 if(LibArchive_INCLUDE_DIR AND EXISTS "${LibArchive_INCLUDE_DIR}/archive.h")
  52   # The version string appears in one of three known formats in the header:
  53   #  #define ARCHIVE_LIBRARY_VERSION "libarchive 2.4.12"
  54   #  #define ARCHIVE_VERSION_STRING "libarchive 2.8.4"
  55   #  #define ARCHIVE_VERSION_ONLY_STRING "3.2.0"
  56   # Match any format.
  57   set(_LibArchive_VERSION_REGEX "^#define[ \t]+ARCHIVE[_A-Z]+VERSION[_A-Z]*[ \t]+\"(libarchive +)?([0-9]+)\\.([0-9]+)\\.([0-9]+)[^\"]*\".*$")
  58   file(STRINGS "${LibArchive_INCLUDE_DIR}/archive.h" _LibArchive_VERSION_STRING LIMIT_COUNT 1 REGEX "${_LibArchive_VERSION_REGEX}")
  59   if(_LibArchive_VERSION_STRING)
  60     string(REGEX REPLACE "${_LibArchive_VERSION_REGEX}" "\\2.\\3.\\4" LibArchive_VERSION "${_LibArchive_VERSION_STRING}")
  61   endif()
  62   unset(_LibArchive_VERSION_REGEX)
  63   unset(_LibArchive_VERSION_STRING)
  64 endif()
  65
  66 include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
  67 find_package_handle_standard_args(LibArchive
  68                                   REQUIRED_VARS LibArchive_LIBRARY LibArchive_INCLUDE_DIR
  69                                   VERSION_VAR LibArchive_VERSION
  70   )
  71 unset(LIBARCHIVE_FOUND)
  72
  73 if(LibArchive_FOUND)
  74   set(LibArchive_INCLUDE_DIRS ${LibArchive_INCLUDE_DIR})
  75   set(LibArchive_LIBRARIES    ${LibArchive_LIBRARY})
  76
  77   if (NOT TARGET LibArchive::LibArchive)
  78     add_library(LibArchive::LibArchive UNKNOWN IMPORTED)
  79     set_target_properties(LibArchive::LibArchive PROPERTIES
  80       IMPORTED_LOCATION "${LibArchive_LIBRARY}"
  81       INTERFACE_INCLUDE_DIRECTORIES "${LibArchive_INCLUDE_DIR}")
  82   endif ()
  83 endif()