Modules/FindLibArchive.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 #[=======================================================================[.rst:
   5 FindLibArchive
   6 --------------
   7
   8 Find libarchive library and headers.
   9 Libarchive is multi-format archive and compression library.
  10
  11 The module defines the following variables:
  12
  13 ::
  14
  15   LibArchive_FOUND        - true if libarchive was found
  16   LibArchive_INCLUDE_DIRS - include search path
  17   LibArchive_LIBRARIES    - libraries to link
  18   LibArchive_VERSION      - libarchive 3-component version number
  19
  20 The module defines the following ``IMPORTED`` targets:
  21
  22 ::
  23
  24   LibArchive::LibArchive  - target for linking against libarchive
  25
  26 .. versionadded:: 3.6
  27   Support for new libarchive 3.2 version string format.
  28
  29 #]=======================================================================]
  30
  31 find_path(LibArchive_INCLUDE_DIR
  32   NAMES archive.h
  33   PATHS
  34   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\GnuWin32\\LibArchive;InstallPath]/include"
  35   DOC "libarchive include directory"
  36   )
  37
  38 find_library(LibArchive_LIBRARY
  39   NAMES archive libarchive
  40   PATHS
  41   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\GnuWin32\\LibArchive;InstallPath]/lib"
  42   DOC "libarchive library"
  43   )
  44
  45 mark_as_advanced(LibArchive_INCLUDE_DIR LibArchive_LIBRARY)
  46
  47 # Extract the version number from the header.
  48 if(LibArchive_INCLUDE_DIR AND EXISTS "${LibArchive_INCLUDE_DIR}/archive.h")
  49   # The version string appears in one of three known formats in the header:
  50   #  #define ARCHIVE_LIBRARY_VERSION "libarchive 2.4.12"
  51   #  #define ARCHIVE_VERSION_STRING "libarchive 2.8.4"
  52   #  #define ARCHIVE_VERSION_ONLY_STRING "3.2.0"
  53   # Match any format.
  54   set(_LibArchive_VERSION_REGEX "^#define[ \t]+ARCHIVE[_A-Z]+VERSION[_A-Z]*[ \t]+\"(libarchive +)?([0-9]+)\\.([0-9]+)\\.([0-9]+)[^\"]*\".*$")
  55   file(STRINGS "${LibArchive_INCLUDE_DIR}/archive.h" _LibArchive_VERSION_STRING LIMIT_COUNT 1 REGEX "${_LibArchive_VERSION_REGEX}")
  56   if(_LibArchive_VERSION_STRING)
  57     string(REGEX REPLACE "${_LibArchive_VERSION_REGEX}" "\\2.\\3.\\4" LibArchive_VERSION "${_LibArchive_VERSION_STRING}")
  58   endif()
  59   unset(_LibArchive_VERSION_REGEX)
  60   unset(_LibArchive_VERSION_STRING)
  61 endif()
  62
  63 include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
  64 find_package_handle_standard_args(LibArchive
  65                                   REQUIRED_VARS LibArchive_LIBRARY LibArchive_INCLUDE_DIR
  66                                   VERSION_VAR LibArchive_VERSION
  67   )
  68 unset(LIBARCHIVE_FOUND)
  69
  70 if(LibArchive_FOUND)
  71   set(LibArchive_INCLUDE_DIRS ${LibArchive_INCLUDE_DIR})
  72   set(LibArchive_LIBRARIES    ${LibArchive_LIBRARY})
  73
  74   if (NOT TARGET LibArchive::LibArchive)
  75     add_library(LibArchive::LibArchive UNKNOWN IMPORTED)
  76     set_target_properties(LibArchive::LibArchive PROPERTIES
  77       IMPORTED_LOCATION "${LibArchive_LIBRARY}"
  78       INTERFACE_INCLUDE_DIRECTORIES "${LibArchive_INCLUDE_DIR}")
  79   endif ()
  80 endif()