Modules/FindKDE4.cmake

   1 # Find KDE4 and provide all necessary variables and macros to compile software for it.
   2 # It looks for KDE 4 in the following directories in the given order:
   3 #  CMAKE_INSTALL_PREFIX
   4 #  KDEDIRS
   5 #  /opt/kde4
   6 #
   7 # Please look in FindKDE4Internal.cmake and KDE4Macros.cmake for more information.
   8 # They are installed with the KDE 4 libraries in $KDEDIRS/share/apps/cmake/modules/.
   9 #
  10 # Author: Alexander Neundorf <neundorf@kde.org>
  11
  12 #=============================================================================
  13 # Copyright 2006-2009 Kitware, Inc.
  14 # Copyright 2006 Alexander Neundorf <neundorf@kde.org>
  15 #
  16 # Distributed under the OSI-approved BSD License (the "License");
  17 # see accompanying file Copyright.txt for details.
  18 #
  19 # This software is distributed WITHOUT ANY WARRANTY; without even the
  20 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  21 # See the License for more information.
  22 #=============================================================================
  23 # (To distribute this file outside of CMake, substitute the full
  24 #  License text for the above reference.)
  25
  26 # If Qt3 has already been found, fail.
  27 if(QT_QT_LIBRARY)
  28   if(KDE4_FIND_REQUIRED)
  29     message( FATAL_ERROR "KDE4/Qt4 and Qt3 cannot be used together in one project.")
  30   else()
  31     if(NOT KDE4_FIND_QUIETLY)
  32       message( STATUS    "KDE4/Qt4 and Qt3 cannot be used together in one project.")
  33     endif()
  34     return()
  35   endif()
  36 endif()
  37
  38 file(TO_CMAKE_PATH "$ENV{KDEDIRS}" _KDEDIRS)
  39
  40 # when cross compiling, searching kde4-config in order to run it later on
  41 # doesn't make a lot of sense. We'll have to do something about this.
  42 # Searching always in the target environment ? Then we get at least the correct one,
  43 # still it can't be used to run it. Alex
  44
  45 # For KDE4 kde-config has been renamed to kde4-config
  46 find_program(KDE4_KDECONFIG_EXECUTABLE NAMES kde4-config
  47    # the suffix must be used since KDEDIRS can be a list of directories which don't have bin/ appended
  48    PATH_SUFFIXES bin
  49    HINTS
  50    ${CMAKE_INSTALL_PREFIX}
  51    ${_KDEDIRS}
  52    /opt/kde4
  53    ONLY_CMAKE_FIND_ROOT_PATH
  54    )
  55
  56 if (NOT KDE4_KDECONFIG_EXECUTABLE)
  57    if (KDE4_FIND_REQUIRED)
  58       message(FATAL_ERROR "ERROR: Could not find KDE4 kde4-config")
  59    endif ()
  60 endif ()
  61
  62
  63 # when cross compiling, KDE4_DATA_DIR may be already preset
  64 if(NOT KDE4_DATA_DIR)
  65    if(CMAKE_CROSSCOMPILING)
  66       # when cross compiling, don't run kde4-config but use its location as install dir
  67       get_filename_component(KDE4_DATA_DIR "${KDE4_KDECONFIG_EXECUTABLE}" PATH)
  68       get_filename_component(KDE4_DATA_DIR "${KDE4_DATA_DIR}" PATH)
  69    else()
  70       # then ask kde4-config for the kde data dirs
  71
  72       if(KDE4_KDECONFIG_EXECUTABLE)
  73         execute_process(COMMAND "${KDE4_KDECONFIG_EXECUTABLE}" --path data OUTPUT_VARIABLE _data_DIR ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
  74         file(TO_CMAKE_PATH "${_data_DIR}" _data_DIR)
  75         # then check the data dirs for FindKDE4Internal.cmake
  76         find_path(KDE4_DATA_DIR cmake/modules/FindKDE4Internal.cmake HINTS ${_data_DIR})
  77       endif()
  78    endif()
  79 endif()
  80
  81 # if it has been found...
  82 if (KDE4_DATA_DIR)
  83
  84    set(CMAKE_MODULE_PATH  ${CMAKE_MODULE_PATH} ${KDE4_DATA_DIR}/cmake/modules)
  85
  86    if (KDE4_FIND_QUIETLY)
  87       set(_quiet QUIET)
  88    endif ()
  89
  90    if (KDE4_FIND_REQUIRED)
  91       set(_req REQUIRED)
  92    endif ()
  93
  94    # use FindKDE4Internal.cmake to do the rest
  95    find_package(KDE4Internal ${_req} ${_quiet})
  96 else ()
  97    if (KDE4_FIND_REQUIRED)
  98       message(FATAL_ERROR "ERROR: cmake/modules/FindKDE4Internal.cmake not found in ${_data_DIR}")
  99    endif ()
 100 endif ()