Modules/FindJava.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 #.rst:
   5 # FindJava
   6 # --------
   7 #
   8 # Find Java
   9 #
  10 # This module finds if Java is installed and determines where the
  11 # include files and libraries are.  The caller may set variable JAVA_HOME
  12 # to specify a Java installation prefix explicitly.
  13 #
  14 # See also the :module:`FindJNI` module to find Java development tools.
  15 #
  16 # Specify one or more of the following components as you call this find module. See example below.
  17 #
  18 # ::
  19 #
  20 #   Runtime     = User just want to execute some Java byte-compiled
  21 #   Development = Development tools (java, javac, javah and javadoc), includes Runtime component
  22 #   IdlJ        = idl compiler for Java
  23 #   JarSigner   = signer tool for jar
  24 #
  25 #
  26 # This module sets the following result variables:
  27 #
  28 # ::
  29 #
  30 #   Java_JAVA_EXECUTABLE      = the full path to the Java runtime
  31 #   Java_JAVAC_EXECUTABLE     = the full path to the Java compiler
  32 #   Java_JAVAH_EXECUTABLE     = the full path to the Java header generator
  33 #   Java_JAVADOC_EXECUTABLE   = the full path to the Java documentation generator
  34 #   Java_IDLJ_EXECUTABLE      = the full path to the Java idl compiler
  35 #   Java_JAR_EXECUTABLE       = the full path to the Java archiver
  36 #   Java_JARSIGNER_EXECUTABLE = the full path to the Java jar signer
  37 #   Java_VERSION_STRING       = Version of java found, eg. 1.6.0_12
  38 #   Java_VERSION_MAJOR        = The major version of the package found.
  39 #   Java_VERSION_MINOR        = The minor version of the package found.
  40 #   Java_VERSION_PATCH        = The patch version of the package found.
  41 #   Java_VERSION_TWEAK        = The tweak version of the package found (after '_')
  42 #   Java_VERSION              = This is set to: $major[.$minor[.$patch[.$tweak]]]
  43 #
  44 #
  45 #
  46 # The minimum required version of Java can be specified using the
  47 # standard CMake syntax, e.g.  find_package(Java 1.5)
  48 #
  49 # NOTE: ${Java_VERSION} and ${Java_VERSION_STRING} are not guaranteed to
  50 # be identical.  For example some java version may return:
  51 # Java_VERSION_STRING = 1.5.0_17 and Java_VERSION = 1.5.0.17
  52 #
  53 # another example is the Java OEM, with: Java_VERSION_STRING = 1.6.0-oem
  54 # and Java_VERSION = 1.6.0
  55 #
  56 # For these components the following variables are set:
  57 #
  58 # ::
  59 #
  60 #   Java_FOUND                    - TRUE if all components are found.
  61 #   Java_<component>_FOUND        - TRUE if <component> is found.
  62 #
  63 #
  64 #
  65 # Example Usages:
  66 #
  67 # ::
  68 #
  69 #   find_package(Java)
  70 #   find_package(Java COMPONENTS Runtime)
  71 #   find_package(Java COMPONENTS Development)
  72
  73 include(${CMAKE_CURRENT_LIST_DIR}/CMakeFindJavaCommon.cmake)
  74
  75 # The HINTS option should only be used for values computed from the system.
  76 set(_JAVA_HINTS)
  77 if(_JAVA_HOME)
  78   list(APPEND _JAVA_HINTS ${_JAVA_HOME}/bin)
  79 endif()
  80 list(APPEND _JAVA_HINTS
  81   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Development Kit\\2.0;JavaHome]/bin"
  82   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Development Kit\\1.9;JavaHome]/bin"
  83   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Development Kit\\1.8;JavaHome]/bin"
  84   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Development Kit\\1.7;JavaHome]/bin"
  85   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Development Kit\\1.6;JavaHome]/bin"
  86   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Development Kit\\1.5;JavaHome]/bin"
  87   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Development Kit\\1.4;JavaHome]/bin"
  88   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Development Kit\\1.3;JavaHome]/bin"
  89   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Runtime Environment\\2.0;JavaHome]/bin"
  90   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Runtime Environment\\1.9;JavaHome]/bin"
  91   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Runtime Environment\\1.8;JavaHome]/bin"
  92   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Runtime Environment\\1.7;JavaHome]/bin"
  93   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Runtime Environment\\1.6;JavaHome]/bin"
  94   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Runtime Environment\\1.5;JavaHome]/bin"
  95   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Runtime Environment\\1.4;JavaHome]/bin"
  96   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\JavaSoft\\Java Runtime Environment\\1.3;JavaHome]/bin"
  97   )
  98 # Hard-coded guesses should still go in PATHS. This ensures that the user
  99 # environment can always override hard guesses.
 100 set(_JAVA_PATHS
 101   /usr/lib/java/bin
 102   /usr/share/java/bin
 103   /usr/local/java/bin
 104   /usr/local/java/share/bin
 105   /usr/java/j2sdk1.4.2_04
 106   /usr/lib/j2sdk1.4-sun/bin
 107   /usr/java/j2sdk1.4.2_09/bin
 108   /usr/lib/j2sdk1.5-sun/bin
 109   /opt/sun-jdk-1.5.0.04/bin
 110   /usr/local/jdk-1.7.0/bin
 111   /usr/local/jdk-1.6.0/bin
 112   )
 113 find_program(Java_JAVA_EXECUTABLE
 114   NAMES java
 115   HINTS ${_JAVA_HINTS}
 116   PATHS ${_JAVA_PATHS}
 117 )
 118
 119 if(Java_JAVA_EXECUTABLE)
 120     execute_process(COMMAND ${Java_JAVA_EXECUTABLE} -version
 121       RESULT_VARIABLE res
 122       OUTPUT_VARIABLE var
 123       ERROR_VARIABLE var # sun-java output to stderr
 124       OUTPUT_STRIP_TRAILING_WHITESPACE
 125       ERROR_STRIP_TRAILING_WHITESPACE)
 126     if( res )
 127       if(var MATCHES "No Java runtime present, requesting install")
 128         set_property(CACHE Java_JAVA_EXECUTABLE
 129           PROPERTY VALUE "Java_JAVA_EXECUTABLE-NOTFOUND")
 130       elseif(${Java_FIND_REQUIRED})
 131         message( FATAL_ERROR "Error executing java -version" )
 132       else()
 133         message( STATUS "Warning, could not run java -version")
 134       endif()
 135     else()
 136       # Extract version components (up to 4 levels) from "java -version" output.
 137       set(_java_version_regex [[(([0-9]+)(\.([0-9]+)(\.([0-9]+)(_([0-9]+))?)?)?.*)]])
 138       if(var MATCHES "java version \"${_java_version_regex}\"")
 139         # Sun, GCJ, older OpenJDK
 140         set(Java_VERSION_STRING "${CMAKE_MATCH_1}")
 141         set(Java_VERSION_MAJOR "${CMAKE_MATCH_2}")
 142         set(Java_VERSION_MINOR "${CMAKE_MATCH_4}")
 143         set(Java_VERSION_PATCH "${CMAKE_MATCH_6}")
 144         set(Java_VERSION_TWEAK "${CMAKE_MATCH_8}")
 145       elseif(var MATCHES "openjdk version \"${_java_version_regex}\"")
 146         # OpenJDK
 147         set(Java_VERSION_STRING "${CMAKE_MATCH_1}")
 148         set(Java_VERSION_MAJOR "${CMAKE_MATCH_2}")
 149         set(Java_VERSION_MINOR "${CMAKE_MATCH_4}")
 150         set(Java_VERSION_PATCH "${CMAKE_MATCH_6}")
 151         set(Java_VERSION_TWEAK "${CMAKE_MATCH_8}")
 152       elseif(var MATCHES "openjdk version \"([0-9]+)-[A-Za-z]+\"")
 153         # OpenJDK 9 early access builds or locally built
 154         set(Java_VERSION_STRING "1.${CMAKE_MATCH_1}.0")
 155         set(Java_VERSION_MAJOR "1")
 156         set(Java_VERSION_MINOR "${CMAKE_MATCH_1}")
 157         set(Java_VERSION_PATCH "0")
 158         set(Java_VERSION_TWEAK "")
 159       elseif(var MATCHES "java full version \"kaffe-${_java_version_regex}\"")
 160         # Kaffe style
 161         set(Java_VERSION_STRING "${CMAKE_MATCH_1}")
 162         set(Java_VERSION_MAJOR "${CMAKE_MATCH_2}")
 163         set(Java_VERSION_MINOR "${CMAKE_MATCH_4}")
 164         set(Java_VERSION_PATCH "${CMAKE_MATCH_6}")
 165         set(Java_VERSION_TWEAK "${CMAKE_MATCH_8}")
 166       else()
 167         if(NOT Java_FIND_QUIETLY)
 168           string(REPLACE "\n" "\n  " ver_msg "\n${var}")
 169           message(WARNING "Java version not recognized:${ver_msg}\nPlease report.")
 170         endif()
 171         set(Java_VERSION_STRING "")
 172         set(Java_VERSION_MAJOR "")
 173         set(Java_VERSION_MINOR "")
 174         set(Java_VERSION_PATCH "")
 175         set(Java_VERSION_TWEAK "")
 176       endif()
 177       set(Java_VERSION "${Java_VERSION_MAJOR}")
 178       if(NOT "x${Java_VERSION}" STREQUAL "x")
 179         foreach(c MINOR PATCH TWEAK)
 180           if(NOT "x${Java_VERSION_${c}}" STREQUAL "x")
 181             string(APPEND Java_VERSION ".${Java_VERSION_${c}}")
 182           else()
 183             break()
 184           endif()
 185         endforeach()
 186       endif()
 187     endif()
 188
 189 endif()
 190
 191
 192 find_program(Java_JAR_EXECUTABLE
 193   NAMES jar
 194   HINTS ${_JAVA_HINTS}
 195   PATHS ${_JAVA_PATHS}
 196 )
 197
 198 find_program(Java_JAVAC_EXECUTABLE
 199   NAMES javac
 200   HINTS ${_JAVA_HINTS}
 201   PATHS ${_JAVA_PATHS}
 202 )
 203
 204 find_program(Java_JAVAH_EXECUTABLE
 205   NAMES javah
 206   HINTS ${_JAVA_HINTS}
 207   PATHS ${_JAVA_PATHS}
 208 )
 209
 210 find_program(Java_JAVADOC_EXECUTABLE
 211   NAMES javadoc
 212   HINTS ${_JAVA_HINTS}
 213   PATHS ${_JAVA_PATHS}
 214 )
 215
 216 find_program(Java_IDLJ_EXECUTABLE
 217   NAMES idlj
 218   HINTS ${_JAVA_HINTS}
 219   PATHS ${_JAVA_PATHS}
 220 )
 221
 222 find_program(Java_JARSIGNER_EXECUTABLE
 223   NAMES jarsigner
 224   HINTS ${_JAVA_HINTS}
 225   PATHS ${_JAVA_PATHS}
 226 )
 227
 228 include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
 229 if(Java_FIND_COMPONENTS)
 230   set(_JAVA_REQUIRED_VARS)
 231   foreach(component ${Java_FIND_COMPONENTS})
 232     # User just want to execute some Java byte-compiled
 233     If(component STREQUAL "Runtime")
 234       list(APPEND _JAVA_REQUIRED_VARS Java_JAVA_EXECUTABLE)
 235       if(Java_JAVA_EXECUTABLE)
 236         set(Java_Runtime_FOUND TRUE)
 237       endif()
 238     elseif(component STREQUAL "Development")
 239       list(APPEND _JAVA_REQUIRED_VARS Java_JAVA_EXECUTABLE Java_JAVAC_EXECUTABLE
 240                                       Java_JAVADOC_EXECUTABLE)
 241       if(Java_VERSION VERSION_LESS "1.10")
 242         list(APPEND _JAVA_REQUIRED_VARS Java_JAVAH_EXECUTABLE)
 243         if(Java_JAVA_EXECUTABLE AND Java_JAVAC_EXECUTABLE
 244             AND Java_JAVAH_EXECUTABLE AND Java_JAVADOC_EXECUTABLE)
 245           set(Java_Development_FOUND TRUE)
 246         endif()
 247       else()
 248         if(Java_JAVA_EXECUTABLE AND Java_JAVAC_EXECUTABLE
 249             AND Java_JAVADOC_EXECUTABLE)
 250           set(Java_Development_FOUND TRUE)
 251         endif()
 252       endif()
 253     elseif(component STREQUAL "IdlJ")
 254       list(APPEND _JAVA_REQUIRED_VARS Java_IDLJ_EXECUTABLE)
 255       if(Java_IDLJ_EXECUTABLE)
 256         set(Java_IdlJ_FOUND TRUE)
 257       endif()
 258     elseif(component STREQUAL "JarSigner")
 259       list(APPEND _JAVA_REQUIRED_VARS Java_JARSIGNER_EXECUTABLE)
 260       if(Java_JARSIGNER_EXECUTABLE)
 261         set(Java_JarSigner_FOUND TRUE)
 262       endif()
 263     else()
 264       message(FATAL_ERROR "Comp: ${component} is not handled")
 265     endif()
 266   endforeach()
 267   list (REMOVE_DUPLICATES _JAVA_REQUIRED_VARS)
 268   find_package_handle_standard_args(Java
 269     REQUIRED_VARS ${_JAVA_REQUIRED_VARS} HANDLE_COMPONENTS
 270     VERSION_VAR Java_VERSION
 271     )
 272   if(Java_FOUND)
 273     foreach(component ${Java_FIND_COMPONENTS})
 274       set(Java_${component}_FOUND TRUE)
 275     endforeach()
 276   endif()
 277 else()
 278   # Check for Development
 279   if(Java_VERSION VERSION_LESS "1.10")
 280     find_package_handle_standard_args(Java
 281       REQUIRED_VARS Java_JAVA_EXECUTABLE Java_JAR_EXECUTABLE Java_JAVAC_EXECUTABLE
 282                     Java_JAVAH_EXECUTABLE Java_JAVADOC_EXECUTABLE
 283       VERSION_VAR Java_VERSION_STRING
 284       )
 285   else()
 286     find_package_handle_standard_args(Java
 287       REQUIRED_VARS Java_JAVA_EXECUTABLE Java_JAR_EXECUTABLE Java_JAVAC_EXECUTABLE
 288                     Java_JAVADOC_EXECUTABLE
 289       VERSION_VAR Java_VERSION_STRING
 290       )
 291   endif()
 292 endif()
 293
 294
 295 mark_as_advanced(
 296   Java_JAVA_EXECUTABLE
 297   Java_JAR_EXECUTABLE
 298   Java_JAVAC_EXECUTABLE
 299   Java_JAVAH_EXECUTABLE
 300   Java_JAVADOC_EXECUTABLE
 301   Java_IDLJ_EXECUTABLE
 302   Java_JARSIGNER_EXECUTABLE
 303   )
 304
 305 # LEGACY
 306 set(JAVA_RUNTIME ${Java_JAVA_EXECUTABLE})
 307 set(JAVA_ARCHIVE ${Java_JAR_EXECUTABLE})
 308 set(JAVA_COMPILE ${Java_JAVAC_EXECUTABLE})