Modules/FindBLAS.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 #.rst:
   5 # FindBLAS
   6 # --------
   7 #
   8 # Find BLAS library
   9 #
  10 # This module finds an installed fortran library that implements the
  11 # BLAS linear-algebra interface (see http://www.netlib.org/blas/).  The
  12 # list of libraries searched for is taken from the autoconf macro file,
  13 # acx_blas.m4 (distributed at
  14 # http://ac-archive.sourceforge.net/ac-archive/acx_blas.html).
  15 #
  16 # This module sets the following variables:
  17 #
  18 # ::
  19 #
  20 #   BLAS_FOUND - set to true if a library implementing the BLAS interface
  21 #     is found
  22 #   BLAS_LINKER_FLAGS - uncached list of required linker flags (excluding -l
  23 #     and -L).
  24 #   BLAS_LIBRARIES - uncached list of libraries (using full path name) to
  25 #     link against to use BLAS
  26 #   BLAS95_LIBRARIES - uncached list of libraries (using full path name)
  27 #     to link against to use BLAS95 interface
  28 #   BLAS95_FOUND - set to true if a library implementing the BLAS f95 interface
  29 #     is found
  30 #
  31 # The following variables can be used to control this module:
  32 #
  33 # ::
  34 #
  35 #   BLA_STATIC  if set on this determines what kind of linkage we do (static)
  36 #   BLA_VENDOR  if set checks only the specified vendor, if not set checks
  37 #      all the possibilities
  38 #   BLA_F95     if set on tries to find the f95 interfaces for BLAS/LAPACK
  39 #   BLA_PREFER_PKGCONFIG  if set pkg-config will be used to search for a BLAS
  40 #      library first and if one is found that is preferred
  41 #
  42 # List of vendors (BLA_VENDOR) valid in this module:
  43 #
  44 # * Goto
  45 # * OpenBLAS
  46 # * FLAME
  47 # * ATLAS PhiPACK
  48 # * CXML
  49 # * DXML
  50 # * SunPerf
  51 # * SCSL
  52 # * SGIMATH
  53 # * IBMESSL
  54 # * Intel10_32 (intel mkl v10 32 bit)
  55 # * Intel10_64lp (intel mkl v10 64 bit, lp thread model, lp64 model)
  56 # * Intel10_64lp_seq (intel mkl v10 64 bit, sequential code, lp64 model)
  57 # * Intel (older versions of mkl 32 and 64 bit)
  58 # * ACML
  59 # * ACML_MP
  60 # * ACML_GPU
  61 # * Apple
  62 # * NAS
  63 # * Generic
  64 #
  65 # .. note::
  66 #
  67 #   C/CXX should be enabled to use Intel mkl
  68 #
  69
  70 include(${CMAKE_CURRENT_LIST_DIR}/CheckFunctionExists.cmake)
  71 include(${CMAKE_CURRENT_LIST_DIR}/CheckFortranFunctionExists.cmake)
  72 include(${CMAKE_CURRENT_LIST_DIR}/CMakePushCheckState.cmake)
  73 include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
  74 cmake_push_check_state()
  75 set(CMAKE_REQUIRED_QUIET ${BLAS_FIND_QUIETLY})
  76
  77 set(_blas_ORIG_CMAKE_FIND_LIBRARY_SUFFIXES ${CMAKE_FIND_LIBRARY_SUFFIXES})
  78
  79 # Check the language being used
  80 if( NOT (CMAKE_C_COMPILER_LOADED OR CMAKE_CXX_COMPILER_LOADED OR CMAKE_Fortran_COMPILER_LOADED) )
  81   if(BLAS_FIND_REQUIRED)
  82     message(FATAL_ERROR "FindBLAS requires Fortran, C, or C++ to be enabled.")
  83   else()
  84     message(STATUS "Looking for BLAS... - NOT found (Unsupported languages)")
  85     return()
  86   endif()
  87 endif()
  88
  89 if(BLA_PREFER_PKGCONFIG)
  90   find_package(PkgConfig)
  91   pkg_check_modules(PKGC_BLAS IMPORTED_TARGET blas)
  92   if(PKGC_BLAS_FOUND)
  93     set(BLAS_LIBRARIES PkgConfig::PKGC_BLAS)
  94     find_package_handle_standard_args(BLAS
  95                                       REQUIRED_VARS BLAS_LIBRARIES
  96                                       VERSION_VAR PKGC_BLAS_VERSION)
  97     return()
  98   endif()
  99 endif()
 100
 101 macro(Check_Fortran_Libraries LIBRARIES _prefix _name _flags _list _thread)
 102 # This macro checks for the existence of the combination of fortran libraries
 103 # given by _list.  If the combination is found, this macro checks (using the
 104 # Check_Fortran_Function_Exists macro) whether can link against that library
 105 # combination using the name of a routine given by _name using the linker
 106 # flags given by _flags.  If the combination of libraries is found and passes
 107 # the link test, LIBRARIES is set to the list of complete library paths that
 108 # have been found.  Otherwise, LIBRARIES is set to FALSE.
 109
 110 # N.B. _prefix is the prefix applied to the names of all cached variables that
 111 # are generated internally and marked advanced by this macro.
 112
 113 set(_libdir ${ARGN})
 114
 115 set(_libraries_work TRUE)
 116 set(${LIBRARIES})
 117 set(_combined_name)
 118 if (NOT _libdir)
 119   if (WIN32)
 120     set(_libdir ENV LIB)
 121   elseif (APPLE)
 122     set(_libdir ENV DYLD_LIBRARY_PATH)
 123   else ()
 124     set(_libdir ENV LD_LIBRARY_PATH)
 125   endif ()
 126 endif ()
 127
 128 foreach(_library ${_list})
 129   set(_combined_name ${_combined_name}_${_library})
 130
 131   if(_libraries_work)
 132     if (BLA_STATIC)
 133       if (WIN32)
 134         set(CMAKE_FIND_LIBRARY_SUFFIXES .lib ${CMAKE_FIND_LIBRARY_SUFFIXES})
 135       endif ()
 136       if (APPLE)
 137         set(CMAKE_FIND_LIBRARY_SUFFIXES .lib ${CMAKE_FIND_LIBRARY_SUFFIXES})
 138       else ()
 139         set(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 140       endif ()
 141     else ()
 142       if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
 143         # for ubuntu's libblas3gf and liblapack3gf packages
 144         set(CMAKE_FIND_LIBRARY_SUFFIXES ${CMAKE_FIND_LIBRARY_SUFFIXES} .so.3gf)
 145       endif ()
 146     endif ()
 147     find_library(${_prefix}_${_library}_LIBRARY
 148       NAMES ${_library}
 149       PATHS ${_libdir}
 150       )
 151     mark_as_advanced(${_prefix}_${_library}_LIBRARY)
 152     set(${LIBRARIES} ${${LIBRARIES}} ${${_prefix}_${_library}_LIBRARY})
 153     set(_libraries_work ${${_prefix}_${_library}_LIBRARY})
 154   endif()
 155 endforeach()
 156 if(_libraries_work)
 157   # Test this combination of libraries.
 158   set(CMAKE_REQUIRED_LIBRARIES ${_flags} ${${LIBRARIES}} ${_thread})
 159 #  message("DEBUG: CMAKE_REQUIRED_LIBRARIES = ${CMAKE_REQUIRED_LIBRARIES}")
 160   if (CMAKE_Fortran_COMPILER_LOADED)
 161     check_fortran_function_exists("${_name}" ${_prefix}${_combined_name}_WORKS)
 162   else()
 163     check_function_exists("${_name}_" ${_prefix}${_combined_name}_WORKS)
 164   endif()
 165   set(CMAKE_REQUIRED_LIBRARIES)
 166   mark_as_advanced(${_prefix}${_combined_name}_WORKS)
 167   set(_libraries_work ${${_prefix}${_combined_name}_WORKS})
 168 endif()
 169 if(NOT _libraries_work)
 170   set(${LIBRARIES} FALSE)
 171 endif()
 172 #message("DEBUG: ${LIBRARIES} = ${${LIBRARIES}}")
 173 endmacro()
 174
 175 set(BLAS_LINKER_FLAGS)
 176 set(BLAS_LIBRARIES)
 177 set(BLAS95_LIBRARIES)
 178 if (NOT $ENV{BLA_VENDOR} STREQUAL "")
 179   set(BLA_VENDOR $ENV{BLA_VENDOR})
 180 else ()
 181   if(NOT BLA_VENDOR)
 182     set(BLA_VENDOR "All")
 183   endif()
 184 endif ()
 185
 186 if (BLA_VENDOR STREQUAL "Goto" OR BLA_VENDOR STREQUAL "All")
 187  if(NOT BLAS_LIBRARIES)
 188   # gotoblas (http://www.tacc.utexas.edu/tacc-projects/gotoblas2)
 189   check_fortran_libraries(
 190   BLAS_LIBRARIES
 191   BLAS
 192   sgemm
 193   ""
 194   "goto2"
 195   ""
 196   )
 197  endif()
 198 endif ()
 199
 200 if (BLA_VENDOR STREQUAL "OpenBLAS" OR BLA_VENDOR STREQUAL "All")
 201  if(NOT BLAS_LIBRARIES)
 202   # OpenBLAS (http://www.openblas.net)
 203   check_fortran_libraries(
 204   BLAS_LIBRARIES
 205   BLAS
 206   sgemm
 207   ""
 208   "openblas"
 209   ""
 210   )
 211  endif()
 212 endif ()
 213
 214 if (BLA_VENDOR STREQUAL "FLAME" OR BLA_VENDOR STREQUAL "All")
 215  if(NOT BLAS_LIBRARIES)
 216   # FLAME's blis library (https://github.com/flame/blis)
 217   check_fortran_libraries(
 218   BLAS_LIBRARIES
 219   BLAS
 220   sgemm
 221   ""
 222   "blis"
 223   ""
 224   )
 225  endif()
 226 endif ()
 227
 228 if (BLA_VENDOR STREQUAL "ATLAS" OR BLA_VENDOR STREQUAL "All")
 229  if(NOT BLAS_LIBRARIES)
 230   # BLAS in ATLAS library? (http://math-atlas.sourceforge.net/)
 231   check_fortran_libraries(
 232   BLAS_LIBRARIES
 233   BLAS
 234   dgemm
 235   ""
 236   "f77blas;atlas"
 237   ""
 238   )
 239  endif()
 240 endif ()
 241
 242 # BLAS in PhiPACK libraries? (requires generic BLAS lib, too)
 243 if (BLA_VENDOR STREQUAL "PhiPACK" OR BLA_VENDOR STREQUAL "All")
 244  if(NOT BLAS_LIBRARIES)
 245   check_fortran_libraries(
 246   BLAS_LIBRARIES
 247   BLAS
 248   sgemm
 249   ""
 250   "sgemm;dgemm;blas"
 251   ""
 252   )
 253  endif()
 254 endif ()
 255
 256 # BLAS in Alpha CXML library?
 257 if (BLA_VENDOR STREQUAL "CXML" OR BLA_VENDOR STREQUAL "All")
 258  if(NOT BLAS_LIBRARIES)
 259   check_fortran_libraries(
 260   BLAS_LIBRARIES
 261   BLAS
 262   sgemm
 263   ""
 264   "cxml"
 265   ""
 266   )
 267  endif()
 268 endif ()
 269
 270 # BLAS in Alpha DXML library? (now called CXML, see above)
 271 if (BLA_VENDOR STREQUAL "DXML" OR BLA_VENDOR STREQUAL "All")
 272  if(NOT BLAS_LIBRARIES)
 273   check_fortran_libraries(
 274   BLAS_LIBRARIES
 275   BLAS
 276   sgemm
 277   ""
 278   "dxml"
 279   ""
 280   )
 281  endif()
 282 endif ()
 283
 284 # BLAS in Sun Performance library?
 285 if (BLA_VENDOR STREQUAL "SunPerf" OR BLA_VENDOR STREQUAL "All")
 286  if(NOT BLAS_LIBRARIES)
 287   check_fortran_libraries(
 288   BLAS_LIBRARIES
 289   BLAS
 290   sgemm
 291   "-xlic_lib=sunperf"
 292   "sunperf;sunmath"
 293   ""
 294   )
 295   if(BLAS_LIBRARIES)
 296     set(BLAS_LINKER_FLAGS "-xlic_lib=sunperf")
 297   endif()
 298  endif()
 299 endif ()
 300
 301 # BLAS in SCSL library?  (SGI/Cray Scientific Library)
 302 if (BLA_VENDOR STREQUAL "SCSL" OR BLA_VENDOR STREQUAL "All")
 303  if(NOT BLAS_LIBRARIES)
 304   check_fortran_libraries(
 305   BLAS_LIBRARIES
 306   BLAS
 307   sgemm
 308   ""
 309   "scsl"
 310   ""
 311   )
 312  endif()
 313 endif ()
 314
 315 # BLAS in SGIMATH library?
 316 if (BLA_VENDOR STREQUAL "SGIMATH" OR BLA_VENDOR STREQUAL "All")
 317  if(NOT BLAS_LIBRARIES)
 318   check_fortran_libraries(
 319   BLAS_LIBRARIES
 320   BLAS
 321   sgemm
 322   ""
 323   "complib.sgimath"
 324   ""
 325   )
 326  endif()
 327 endif ()
 328
 329 # BLAS in IBM ESSL library? (requires generic BLAS lib, too)
 330 if (BLA_VENDOR STREQUAL "IBMESSL" OR BLA_VENDOR STREQUAL "All")
 331  if(NOT BLAS_LIBRARIES)
 332   check_fortran_libraries(
 333   BLAS_LIBRARIES
 334   BLAS
 335   sgemm
 336   ""
 337   "essl;blas"
 338   ""
 339   )
 340  endif()
 341 endif ()
 342
 343 #BLAS in acml library?
 344 if (BLA_VENDOR MATCHES "ACML" OR BLA_VENDOR STREQUAL "All")
 345  if( ((BLA_VENDOR STREQUAL "ACML") AND (NOT BLAS_ACML_LIB_DIRS)) OR
 346      ((BLA_VENDOR STREQUAL "ACML_MP") AND (NOT BLAS_ACML_MP_LIB_DIRS)) OR
 347      ((BLA_VENDOR STREQUAL "ACML_GPU") AND (NOT BLAS_ACML_GPU_LIB_DIRS))
 348    )
 349    # try to find acml in "standard" paths
 350    if( WIN32 )
 351     file( GLOB _ACML_ROOT "C:/AMD/acml*/ACML-EULA.txt" )
 352    else()
 353     file( GLOB _ACML_ROOT "/opt/acml*/ACML-EULA.txt" )
 354    endif()
 355    if( WIN32 )
 356     file( GLOB _ACML_GPU_ROOT "C:/AMD/acml*/GPGPUexamples" )
 357    else()
 358     file( GLOB _ACML_GPU_ROOT "/opt/acml*/GPGPUexamples" )
 359    endif()
 360    list(GET _ACML_ROOT 0 _ACML_ROOT)
 361    list(GET _ACML_GPU_ROOT 0 _ACML_GPU_ROOT)
 362    if( _ACML_ROOT )
 363     get_filename_component( _ACML_ROOT ${_ACML_ROOT} PATH )
 364     if( SIZEOF_INTEGER EQUAL 8 )
 365      set( _ACML_PATH_SUFFIX "_int64" )
 366     else()
 367     set( _ACML_PATH_SUFFIX "" )
 368    endif()
 369    if( CMAKE_Fortran_COMPILER_ID STREQUAL "Intel" )
 370     set( _ACML_COMPILER32 "ifort32" )
 371     set( _ACML_COMPILER64 "ifort64" )
 372    elseif( CMAKE_Fortran_COMPILER_ID STREQUAL "SunPro" )
 373     set( _ACML_COMPILER32 "sun32" )
 374     set( _ACML_COMPILER64 "sun64" )
 375    elseif( CMAKE_Fortran_COMPILER_ID STREQUAL "PGI" )
 376     set( _ACML_COMPILER32 "pgi32" )
 377     if( WIN32 )
 378      set( _ACML_COMPILER64 "win64" )
 379     else()
 380      set( _ACML_COMPILER64 "pgi64" )
 381     endif()
 382    elseif( CMAKE_Fortran_COMPILER_ID STREQUAL "Open64" )
 383     # 32 bit builds not supported on Open64 but for code simplicity
 384     # We'll just use the same directory twice
 385     set( _ACML_COMPILER32 "open64_64" )
 386     set( _ACML_COMPILER64 "open64_64" )
 387    elseif( CMAKE_Fortran_COMPILER_ID STREQUAL "NAG" )
 388     set( _ACML_COMPILER32 "nag32" )
 389     set( _ACML_COMPILER64 "nag64" )
 390    else()
 391     set( _ACML_COMPILER32 "gfortran32" )
 392     set( _ACML_COMPILER64 "gfortran64" )
 393    endif()
 394
 395    if( BLA_VENDOR STREQUAL "ACML_MP" )
 396     set(_ACML_MP_LIB_DIRS
 397      "${_ACML_ROOT}/${_ACML_COMPILER32}_mp${_ACML_PATH_SUFFIX}/lib"
 398      "${_ACML_ROOT}/${_ACML_COMPILER64}_mp${_ACML_PATH_SUFFIX}/lib" )
 399    else()
 400     set(_ACML_LIB_DIRS
 401      "${_ACML_ROOT}/${_ACML_COMPILER32}${_ACML_PATH_SUFFIX}/lib"
 402      "${_ACML_ROOT}/${_ACML_COMPILER64}${_ACML_PATH_SUFFIX}/lib" )
 403    endif()
 404   endif()
 405  elseif(BLAS_${BLA_VENDOR}_LIB_DIRS)
 406    set(_${BLA_VENDOR}_LIB_DIRS ${BLAS_${BLA_VENDOR}_LIB_DIRS})
 407  endif()
 408
 409  if( BLA_VENDOR STREQUAL "ACML_MP" )
 410   foreach( BLAS_ACML_MP_LIB_DIRS ${_ACML_MP_LIB_DIRS})
 411    check_fortran_libraries (
 412      BLAS_LIBRARIES
 413      BLAS
 414      sgemm
 415      "" "acml_mp;acml_mv" "" ${BLAS_ACML_MP_LIB_DIRS}
 416    )
 417    if( BLAS_LIBRARIES )
 418     break()
 419    endif()
 420   endforeach()
 421  elseif( BLA_VENDOR STREQUAL "ACML_GPU" )
 422   foreach( BLAS_ACML_GPU_LIB_DIRS ${_ACML_GPU_LIB_DIRS})
 423    check_fortran_libraries (
 424      BLAS_LIBRARIES
 425      BLAS
 426      sgemm
 427      "" "acml;acml_mv;CALBLAS" "" ${BLAS_ACML_GPU_LIB_DIRS}
 428    )
 429    if( BLAS_LIBRARIES )
 430     break()
 431    endif()
 432   endforeach()
 433  else()
 434   foreach( BLAS_ACML_LIB_DIRS ${_ACML_LIB_DIRS} )
 435    check_fortran_libraries (
 436      BLAS_LIBRARIES
 437      BLAS
 438      sgemm
 439      "" "acml;acml_mv" "" ${BLAS_ACML_LIB_DIRS}
 440    )
 441    if( BLAS_LIBRARIES )
 442     break()
 443    endif()
 444   endforeach()
 445  endif()
 446
 447  # Either acml or acml_mp should be in LD_LIBRARY_PATH but not both
 448  if(NOT BLAS_LIBRARIES)
 449   check_fortran_libraries(
 450   BLAS_LIBRARIES
 451   BLAS
 452   sgemm
 453   ""
 454   "acml;acml_mv"
 455   ""
 456   )
 457  endif()
 458  if(NOT BLAS_LIBRARIES)
 459   check_fortran_libraries(
 460   BLAS_LIBRARIES
 461   BLAS
 462   sgemm
 463   ""
 464   "acml_mp;acml_mv"
 465   ""
 466   )
 467  endif()
 468  if(NOT BLAS_LIBRARIES)
 469   check_fortran_libraries(
 470   BLAS_LIBRARIES
 471   BLAS
 472   sgemm
 473   ""
 474   "acml;acml_mv;CALBLAS"
 475   ""
 476   )
 477  endif()
 478 endif () # ACML
 479
 480 # Apple BLAS library?
 481 if (BLA_VENDOR STREQUAL "Apple" OR BLA_VENDOR STREQUAL "All")
 482 if(NOT BLAS_LIBRARIES)
 483   check_fortran_libraries(
 484   BLAS_LIBRARIES
 485   BLAS
 486   dgemm
 487   ""
 488   "Accelerate"
 489   ""
 490   )
 491  endif()
 492 endif ()
 493
 494 if (BLA_VENDOR STREQUAL "NAS" OR BLA_VENDOR STREQUAL "All")
 495  if ( NOT BLAS_LIBRARIES )
 496     check_fortran_libraries(
 497     BLAS_LIBRARIES
 498     BLAS
 499     dgemm
 500     ""
 501     "vecLib"
 502     ""
 503     )
 504  endif ()
 505 endif ()
 506 # Generic BLAS library?
 507 if (BLA_VENDOR STREQUAL "Generic" OR BLA_VENDOR STREQUAL "All")
 508  if(NOT BLAS_LIBRARIES)
 509   check_fortran_libraries(
 510   BLAS_LIBRARIES
 511   BLAS
 512   sgemm
 513   ""
 514   "blas"
 515   ""
 516   )
 517  endif()
 518 endif ()
 519
 520 #BLAS in intel mkl 10 library? (em64t 64bit)
 521 if (BLA_VENDOR MATCHES "Intel" OR BLA_VENDOR STREQUAL "All")
 522  if (NOT WIN32)
 523   set(LM "-lm")
 524  endif ()
 525  if (CMAKE_C_COMPILER_LOADED OR CMAKE_CXX_COMPILER_LOADED)
 526   if(BLAS_FIND_QUIETLY OR NOT BLAS_FIND_REQUIRED)
 527     find_package(Threads)
 528   else()
 529     find_package(Threads REQUIRED)
 530   endif()
 531
 532   set(BLAS_SEARCH_LIBS "")
 533
 534   if(BLA_F95)
 535     set(BLAS_mkl_SEARCH_SYMBOL SGEMM)
 536     set(_LIBRARIES BLAS95_LIBRARIES)
 537     if (WIN32)
 538       if (BLA_STATIC)
 539         set(BLAS_mkl_DLL_SUFFIX "")
 540       else()
 541         set(BLAS_mkl_DLL_SUFFIX "_dll")
 542       endif()
 543
 544       # Find the main file (32-bit or 64-bit)
 545       set(BLAS_SEARCH_LIBS_WIN_MAIN "")
 546       if (BLA_VENDOR STREQUAL "Intel10_32" OR BLA_VENDOR STREQUAL "All")
 547         list(APPEND BLAS_SEARCH_LIBS_WIN_MAIN
 548           "mkl_blas95${BLAS_mkl_DLL_SUFFIX} mkl_intel_c${BLAS_mkl_DLL_SUFFIX}")
 549       endif()
 550       if (BLA_VENDOR MATCHES "^Intel10_64lp" OR BLA_VENDOR STREQUAL "All")
 551         list(APPEND BLAS_SEARCH_LIBS_WIN_MAIN
 552           "mkl_blas95_lp64${BLAS_mkl_DLL_SUFFIX} mkl_intel_lp64${BLAS_mkl_DLL_SUFFIX}")
 553       endif ()
 554
 555       # Add threading/sequential libs
 556       set(BLAS_SEARCH_LIBS_WIN_THREAD "")
 557       if (BLA_VENDOR MATCHES "_seq$" OR BLA_VENDOR STREQUAL "All")
 558         list(APPEND BLAS_SEARCH_LIBS_WIN_THREAD
 559           "mkl_sequential${BLAS_mkl_DLL_SUFFIX}")
 560       endif()
 561       if (NOT BLA_VENDOR MATCHES "_seq$" OR BLA_VENDOR STREQUAL "All")
 562         # old version
 563         list(APPEND BLAS_SEARCH_LIBS_WIN_THREAD
 564           "libguide40 mkl_intel_thread${BLAS_mkl_DLL_SUFFIX}")
 565         # mkl >= 10.3
 566         list(APPEND BLAS_SEARCH_LIBS_WIN_THREAD
 567           "libiomp5md mkl_intel_thread${BLAS_mkl_DLL_SUFFIX}")
 568       endif()
 569
 570       # Cartesian product of the above
 571       foreach (MAIN ${BLAS_SEARCH_LIBS_WIN_MAIN})
 572         foreach (THREAD ${BLAS_SEARCH_LIBS_WIN_THREAD})
 573           list(APPEND BLAS_SEARCH_LIBS
 574             "${MAIN} ${THREAD} mkl_core${BLAS_mkl_DLL_SUFFIX}")
 575         endforeach()
 576       endforeach()
 577     else ()
 578       if (BLA_VENDOR STREQUAL "Intel10_32" OR BLA_VENDOR STREQUAL "All")
 579         list(APPEND BLAS_SEARCH_LIBS
 580           "mkl_blas95 mkl_intel mkl_intel_thread mkl_core guide")
 581       endif ()
 582       if (BLA_VENDOR STREQUAL "Intel10_64lp" OR BLA_VENDOR STREQUAL "All")
 583         # old version
 584         list(APPEND BLAS_SEARCH_LIBS
 585           "mkl_blas95 mkl_intel_lp64 mkl_intel_thread mkl_core guide")
 586
 587         # mkl >= 10.3
 588         if (CMAKE_C_COMPILER MATCHES ".+gcc")
 589           list(APPEND BLAS_SEARCH_LIBS
 590             "mkl_blas95_lp64 mkl_intel_lp64 mkl_gnu_thread mkl_core gomp")
 591         else ()
 592           list(APPEND BLAS_SEARCH_LIBS
 593             "mkl_blas95_lp64 mkl_intel_lp64 mkl_intel_thread mkl_core iomp5")
 594         endif ()
 595       endif ()
 596       if (BLA_VENDOR STREQUAL "Intel10_64lp_seq" OR BLA_VENDOR STREQUAL "All")
 597         list(APPEND BLAS_SEARCH_LIBS
 598           "mkl_intel_lp64 mkl_sequential mkl_core")
 599       endif ()
 600     endif ()
 601   else ()
 602     set(BLAS_mkl_SEARCH_SYMBOL sgemm)
 603     set(_LIBRARIES BLAS_LIBRARIES)
 604     if (WIN32)
 605       if (BLA_STATIC)
 606         set(BLAS_mkl_DLL_SUFFIX "")
 607       else()
 608         set(BLAS_mkl_DLL_SUFFIX "_dll")
 609       endif()
 610
 611       # Find the main file (32-bit or 64-bit)
 612       set(BLAS_SEARCH_LIBS_WIN_MAIN "")
 613       if (BLA_VENDOR STREQUAL "Intel10_32" OR BLA_VENDOR STREQUAL "All")
 614         list(APPEND BLAS_SEARCH_LIBS_WIN_MAIN
 615           "mkl_intel_c${BLAS_mkl_DLL_SUFFIX}")
 616       endif()
 617       if (BLA_VENDOR MATCHES "^Intel10_64lp" OR BLA_VENDOR STREQUAL "All")
 618         list(APPEND BLAS_SEARCH_LIBS_WIN_MAIN
 619           "mkl_intel_lp64${BLAS_mkl_DLL_SUFFIX}")
 620       endif ()
 621
 622       # Add threading/sequential libs
 623       set(BLAS_SEARCH_LIBS_WIN_THREAD "")
 624       if (NOT BLA_VENDOR MATCHES "_seq$" OR BLA_VENDOR STREQUAL "All")
 625         # old version
 626         list(APPEND BLAS_SEARCH_LIBS_WIN_THREAD
 627           "libguide40 mkl_intel_thread${BLAS_mkl_DLL_SUFFIX}")
 628         # mkl >= 10.3
 629         list(APPEND BLAS_SEARCH_LIBS_WIN_THREAD
 630           "libiomp5md mkl_intel_thread${BLAS_mkl_DLL_SUFFIX}")
 631       endif()
 632       if (BLA_VENDOR MATCHES "_seq$" OR BLA_VENDOR STREQUAL "All")
 633         list(APPEND BLAS_SEARCH_LIBS_WIN_THREAD
 634           "mkl_sequential${BLAS_mkl_DLL_SUFFIX}")
 635       endif()
 636
 637       # Cartesian product of the above
 638       foreach (MAIN ${BLAS_SEARCH_LIBS_WIN_MAIN})
 639         foreach (THREAD ${BLAS_SEARCH_LIBS_WIN_THREAD})
 640           list(APPEND BLAS_SEARCH_LIBS
 641             "${MAIN} ${THREAD} mkl_core${BLAS_mkl_DLL_SUFFIX}")
 642         endforeach()
 643       endforeach()
 644     else ()
 645       if (BLA_VENDOR STREQUAL "Intel10_32" OR BLA_VENDOR STREQUAL "All")
 646         list(APPEND BLAS_SEARCH_LIBS
 647           "mkl_intel mkl_intel_thread mkl_core guide")
 648       endif ()
 649       if (BLA_VENDOR STREQUAL "Intel10_64lp" OR BLA_VENDOR STREQUAL "All")
 650
 651         # old version
 652         list(APPEND BLAS_SEARCH_LIBS
 653           "mkl_intel_lp64 mkl_intel_thread mkl_core guide")
 654
 655         # mkl >= 10.3
 656         if (CMAKE_C_COMPILER MATCHES ".+gcc")
 657           list(APPEND BLAS_SEARCH_LIBS
 658             "mkl_intel_lp64 mkl_gnu_thread mkl_core gomp")
 659         else ()
 660           list(APPEND BLAS_SEARCH_LIBS
 661             "mkl_intel_lp64 mkl_intel_thread mkl_core iomp5")
 662         endif ()
 663       endif ()
 664       if (BLA_VENDOR STREQUAL "Intel10_64lp_seq" OR BLA_VENDOR STREQUAL "All")
 665         list(APPEND BLAS_SEARCH_LIBS
 666           "mkl_intel_lp64 mkl_sequential mkl_core")
 667       endif ()
 668
 669       #older vesions of intel mkl libs
 670       if (BLA_VENDOR STREQUAL "Intel" OR BLA_VENDOR STREQUAL "All")
 671         list(APPEND BLAS_SEARCH_LIBS
 672           "mkl")
 673         list(APPEND BLAS_SEARCH_LIBS
 674           "mkl_ia32")
 675         list(APPEND BLAS_SEARCH_LIBS
 676           "mkl_em64t")
 677       endif ()
 678     endif ()
 679   endif ()
 680
 681   foreach (IT ${BLAS_SEARCH_LIBS})
 682     string(REPLACE " " ";" SEARCH_LIBS ${IT})
 683     if (NOT ${_LIBRARIES})
 684       check_fortran_libraries(
 685         ${_LIBRARIES}
 686         BLAS
 687         ${BLAS_mkl_SEARCH_SYMBOL}
 688         ""
 689         "${SEARCH_LIBS}"
 690         "${CMAKE_THREAD_LIBS_INIT};${LM}"
 691         )
 692     endif ()
 693   endforeach ()
 694
 695  endif ()
 696 endif ()
 697
 698 if(BLA_F95)
 699   find_package_handle_standard_args(BLAS REQUIRED_VARS BLAS95_LIBRARIES)
 700   set(BLAS95_FOUND ${BLAS_FOUND})
 701   if(BLAS_FOUND)
 702     set(BLAS_LIBRARIES "${BLAS95_LIBRARIES}")
 703   endif()
 704 else()
 705   find_package_handle_standard_args(BLAS REQUIRED_VARS BLAS_LIBRARIES)
 706 endif()
 707
 708 cmake_pop_check_state()
 709 set(CMAKE_FIND_LIBRARY_SUFFIXES ${_blas_ORIG_CMAKE_FIND_LIBRARY_SUFFIXES})