Modules/Compiler/NVIDIA-CUDA.cmake

   1 include(Compiler/CMakeCommonCompilerMacros)
   2
   3 set(CMAKE_CUDA_COMPILER_HAS_DEVICE_LINK_PHASE True)
   4 set(CMAKE_CUDA_VERBOSE_FLAG "-v")
   5 set(CMAKE_CUDA_VERBOSE_COMPILE_FLAG "-Xcompiler=-v")
   6
   7 set(_CMAKE_COMPILE_AS_CUDA_FLAG "-x cu")
   8 set(_CMAKE_CUDA_WHOLE_FLAG "-c")
   9 set(_CMAKE_CUDA_RDC_FLAG "-rdc=true")
  10 set(_CMAKE_CUDA_PTX_FLAG "-ptx")
  11
  12 if (CMAKE_CUDA_COMPILER_VERSION VERSION_GREATER_EQUAL 10.2.89)
  13   # The -forward-unknown-to-host-compiler flag was only
  14   # added to nvcc in 10.2 so before that we had no good
  15   # way to invoke the CUDA compiler and propagate unknown
  16   # flags such as -pthread to the host compiler
  17   set(_CMAKE_CUDA_EXTRA_FLAGS "-forward-unknown-to-host-compiler")
  18 else()
  19   set(_CMAKE_CUDA_EXTRA_FLAGS "")
  20 endif()
  21
  22 if(CMAKE_CUDA_COMPILER_VERSION VERSION_GREATER_EQUAL "8.0.0")
  23   set(_CMAKE_CUDA_EXTRA_DEVICE_LINK_FLAGS "-Wno-deprecated-gpu-targets")
  24 else()
  25   set(_CMAKE_CUDA_EXTRA_DEVICE_LINK_FLAGS "")
  26 endif()
  27
  28 if(CMAKE_CUDA_HOST_COMPILER AND NOT CMAKE_GENERATOR MATCHES "Visual Studio")
  29   string(APPEND _CMAKE_CUDA_EXTRA_FLAGS " -ccbin=<CMAKE_CUDA_HOST_COMPILER>")
  30 endif()
  31
  32 if (CMAKE_CUDA_COMPILER_VERSION VERSION_GREATER_EQUAL 10.2.89)
  33   # Starting in 10.2, nvcc supported treating all warnings as errors
  34   set(CMAKE_CUDA_COMPILE_OPTIONS_WARNING_AS_ERROR "-Werror" "all-warnings")
  35 endif()
  36
  37 if (CMAKE_CUDA_COMPILER_VERSION VERSION_GREATER_EQUAL 10.2.89)
  38   # The -MD flag was only added to nvcc in 10.2 so
  39   # before that we had to invoke the compiler twice
  40   # to get header dependency information
  41   set(CMAKE_DEPFILE_FLAGS_CUDA "-MD -MT <DEP_TARGET> -MF <DEP_FILE>")
  42 else()
  43   set(CMAKE_CUDA_DEPENDS_EXTRA_COMMANDS "<CMAKE_CUDA_COMPILER> ${_CMAKE_CUDA_EXTRA_FLAGS} <DEFINES> <INCLUDES> <FLAGS> ${_CMAKE_COMPILE_AS_CUDA_FLAG} -M <SOURCE> -MT <OBJECT> -o <DEP_FILE>")
  44 endif()
  45 set(CMAKE_CUDA_DEPFILE_FORMAT gcc)
  46 if((NOT DEFINED CMAKE_DEPENDS_USE_COMPILER OR CMAKE_DEPENDS_USE_COMPILER)
  47     AND CMAKE_GENERATOR MATCHES "Makefiles|WMake")
  48   set(CMAKE_CUDA_DEPENDS_USE_COMPILER TRUE)
  49 endif()
  50
  51 if(NOT "x${CMAKE_CUDA_SIMULATE_ID}" STREQUAL "xMSVC")
  52   set(CMAKE_CUDA_COMPILE_OPTIONS_PIE -Xcompiler=-fPIE)
  53   set(CMAKE_CUDA_COMPILE_OPTIONS_PIC -Xcompiler=-fPIC)
  54   set(CMAKE_CUDA_COMPILE_OPTIONS_VISIBILITY -Xcompiler=-fvisibility=)
  55   # CMAKE_SHARED_LIBRARY_CUDA_FLAGS is sent to the host linker so we
  56   # don't need to forward it through nvcc.
  57   set(CMAKE_SHARED_LIBRARY_CUDA_FLAGS -fPIC)
  58   string(APPEND CMAKE_CUDA_FLAGS_INIT " ")
  59   string(APPEND CMAKE_CUDA_FLAGS_DEBUG_INIT " -g")
  60   string(APPEND CMAKE_CUDA_FLAGS_RELEASE_INIT " -O3 -DNDEBUG")
  61   string(APPEND CMAKE_CUDA_FLAGS_MINSIZEREL_INIT " -O1 -DNDEBUG")
  62   string(APPEND CMAKE_CUDA_FLAGS_RELWITHDEBINFO_INIT " -O2 -g -DNDEBUG")
  63 endif()
  64 set(CMAKE_SHARED_LIBRARY_CREATE_CUDA_FLAGS -shared)
  65 set(CMAKE_INCLUDE_SYSTEM_FLAG_CUDA -isystem=)
  66
  67 if (CMAKE_CUDA_SIMULATE_ID STREQUAL "GNU")
  68   set(CMAKE_CUDA_LINKER_WRAPPER_FLAG "-Wl,")
  69   set(CMAKE_CUDA_LINKER_WRAPPER_FLAG_SEP ",")
  70 elseif(CMAKE_CUDA_SIMULATE_ID STREQUAL "Clang")
  71   set(CMAKE_CUDA_LINKER_WRAPPER_FLAG "-Xlinker" " ")
  72   set(CMAKE_CUDA_LINKER_WRAPPER_FLAG_SEP)
  73 endif()
  74
  75 set(CMAKE_CUDA_DEVICE_COMPILER_WRAPPER_FLAG "-Xcompiler=")
  76 set(CMAKE_CUDA_DEVICE_COMPILER_WRAPPER_FLAG_SEP ",")
  77 set(CMAKE_CUDA_DEVICE_LINKER_WRAPPER_FLAG "-Xlinker=")
  78 set(CMAKE_CUDA_DEVICE_LINKER_WRAPPER_FLAG_SEP ",")
  79
  80 set(CMAKE_CUDA_RUNTIME_LIBRARY_LINK_OPTIONS_STATIC  "cudadevrt;cudart_static")
  81 set(CMAKE_CUDA_RUNTIME_LIBRARY_LINK_OPTIONS_SHARED  "cudadevrt;cudart")
  82 set(CMAKE_CUDA_RUNTIME_LIBRARY_LINK_OPTIONS_NONE    "")
  83
  84 if(UNIX AND NOT (CMAKE_SYSTEM_NAME STREQUAL "QNX"))
  85   list(APPEND CMAKE_CUDA_RUNTIME_LIBRARY_LINK_OPTIONS_STATIC "rt" "pthread" "dl")
  86 endif()
  87
  88 if("x${CMAKE_CUDA_SIMULATE_ID}" STREQUAL "xMSVC")
  89   # MSVC requires c++14 as the minimum level
  90   set(CMAKE_CUDA03_STANDARD_COMPILE_OPTION "")
  91   set(CMAKE_CUDA03_EXTENSION_COMPILE_OPTION "")
  92
  93   # MSVC requires c++14 as the minimum level
  94   set(CMAKE_CUDA11_STANDARD_COMPILE_OPTION "")
  95   set(CMAKE_CUDA11_EXTENSION_COMPILE_OPTION "")
  96
  97   if (NOT CMAKE_CUDA_COMPILER_VERSION VERSION_LESS 9.0)
  98     if(CMAKE_CUDA_SIMULATE_VERSION VERSION_GREATER_EQUAL 19.10.25017)
  99       set(CMAKE_CUDA14_STANDARD_COMPILE_OPTION "-std=c++14")
 100       set(CMAKE_CUDA14_EXTENSION_COMPILE_OPTION "-std=c++14")
 101     else()
 102       set(CMAKE_CUDA14_STANDARD_COMPILE_OPTION "")
 103       set(CMAKE_CUDA14_EXTENSION_COMPILE_OPTION "")
 104     endif()
 105   endif()
 106
 107   if (NOT CMAKE_CUDA_COMPILER_VERSION VERSION_LESS 11.0)
 108     if(CMAKE_CUDA_SIMULATE_VERSION VERSION_GREATER_EQUAL 19.11.25505)
 109       set(CMAKE_CUDA17_STANDARD_COMPILE_OPTION "-std=c++17")
 110       set(CMAKE_CUDA17_EXTENSION_COMPILE_OPTION "-std=c++17")
 111     endif()
 112   endif()
 113
 114 else()
 115   set(CMAKE_CUDA03_STANDARD_COMPILE_OPTION "")
 116   set(CMAKE_CUDA03_EXTENSION_COMPILE_OPTION "")
 117
 118   set(CMAKE_CUDA11_STANDARD_COMPILE_OPTION "-std=c++11")
 119   set(CMAKE_CUDA11_EXTENSION_COMPILE_OPTION "-std=c++11")
 120
 121   if (NOT CMAKE_CUDA_COMPILER_VERSION VERSION_LESS 9.0)
 122     set(CMAKE_CUDA03_STANDARD_COMPILE_OPTION "-std=c++03")
 123     set(CMAKE_CUDA03_EXTENSION_COMPILE_OPTION "-std=c++03")
 124     set(CMAKE_CUDA14_STANDARD_COMPILE_OPTION "-std=c++14")
 125     set(CMAKE_CUDA14_EXTENSION_COMPILE_OPTION "-std=c++14")
 126   endif()
 127
 128   if (NOT CMAKE_CUDA_COMPILER_VERSION VERSION_LESS 11.0)
 129     set(CMAKE_CUDA17_STANDARD_COMPILE_OPTION "-std=c++17")
 130     set(CMAKE_CUDA17_EXTENSION_COMPILE_OPTION "-std=c++17")
 131   endif()
 132
 133 endif()
 134
 135 # FIXME: investigate use of --options-file.
 136 # Tell Makefile generator that nvcc does not support @<rspfile> syntax.
 137 set(CMAKE_CUDA_USE_RESPONSE_FILE_FOR_INCLUDES 0)
 138 set(CMAKE_CUDA_USE_RESPONSE_FILE_FOR_LIBRARIES 0)
 139 set(CMAKE_CUDA_USE_RESPONSE_FILE_FOR_OBJECTS 0)
 140
 141 if (CMAKE_CUDA_COMPILER_VERSION VERSION_GREATER_EQUAL "9.0")
 142   set(CMAKE_CUDA_RESPONSE_FILE_DEVICE_LINK_FLAG "--options-file ")
 143   set(CMAKE_CUDA_RESPONSE_FILE_FLAG "--options-file ")
 144 endif()
 145
 146 __compiler_check_default_language_standard(CUDA 6.0 03)