Modules/Compiler/MSVC-CXX.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 include(Compiler/CMakeCommonCompilerMacros)
   5
   6 set(CMAKE_CXX_CLANG_TIDY_DRIVER_MODE "cl")
   7
   8 if ((CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL 19.0.24215.1 AND
   9      CMAKE_CXX_COMPILER_VERSION VERSION_LESS 19.10) OR
  10    CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL 19.10.25017)
  11
  12   # VS 2015 Update 3 and above support language standard level flags,
  13   # with the default and minimum level being C++14.
  14   set(CMAKE_CXX98_STANDARD_COMPILE_OPTION "")
  15   set(CMAKE_CXX98_EXTENSION_COMPILE_OPTION "")
  16   set(CMAKE_CXX98_STANDARD__HAS_FULL_SUPPORT ON)
  17   set(CMAKE_CXX11_STANDARD_COMPILE_OPTION "")
  18   set(CMAKE_CXX11_EXTENSION_COMPILE_OPTION "")
  19   set(CMAKE_CXX14_STANDARD_COMPILE_OPTION "-std:c++14")
  20   set(CMAKE_CXX14_EXTENSION_COMPILE_OPTION "-std:c++14")
  21
  22   if (CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL 19.11.25505)
  23     set(CMAKE_CXX11_STANDARD__HAS_FULL_SUPPORT ON)
  24     set(CMAKE_CXX14_STANDARD__HAS_FULL_SUPPORT ON)
  25     set(CMAKE_CXX17_STANDARD_COMPILE_OPTION "-std:c++17")
  26     set(CMAKE_CXX17_EXTENSION_COMPILE_OPTION "-std:c++17")
  27   else()
  28     set(CMAKE_CXX17_STANDARD_COMPILE_OPTION "-std:c++latest")
  29     set(CMAKE_CXX17_EXTENSION_COMPILE_OPTION "-std:c++latest")
  30   endif()
  31
  32   if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL 19.29.30129)
  33     set(CMAKE_CXX20_STANDARD_COMPILE_OPTION "-std:c++20")
  34     set(CMAKE_CXX20_EXTENSION_COMPILE_OPTION "-std:c++20")
  35     set(CMAKE_CXX23_STANDARD_COMPILE_OPTION "-std:c++latest")
  36     set(CMAKE_CXX23_EXTENSION_COMPILE_OPTION "-std:c++latest")
  37   elseif(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL 19.12.25835)
  38     set(CMAKE_CXX20_STANDARD_COMPILE_OPTION "-std:c++latest")
  39     set(CMAKE_CXX20_EXTENSION_COMPILE_OPTION "-std:c++latest")
  40   endif()
  41
  42   __compiler_check_default_language_standard(CXX 19.0 14)
  43
  44 elseif (CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL 16.0)
  45   # MSVC has no specific options to set language standards, but set them as
  46   # empty strings anyways so the feature test infrastructure can at least check
  47   # to see if they are defined.
  48   set(CMAKE_CXX98_STANDARD_COMPILE_OPTION "")
  49   set(CMAKE_CXX98_EXTENSION_COMPILE_OPTION "")
  50   set(CMAKE_CXX11_STANDARD_COMPILE_OPTION "")
  51   set(CMAKE_CXX11_EXTENSION_COMPILE_OPTION "")
  52   set(CMAKE_CXX14_STANDARD_COMPILE_OPTION "")
  53   set(CMAKE_CXX14_EXTENSION_COMPILE_OPTION "")
  54   set(CMAKE_CXX17_STANDARD_COMPILE_OPTION "")
  55   set(CMAKE_CXX17_EXTENSION_COMPILE_OPTION "")
  56   set(CMAKE_CXX20_STANDARD_COMPILE_OPTION "")
  57   set(CMAKE_CXX20_EXTENSION_COMPILE_OPTION "")
  58
  59   # There is no meaningful default for this
  60   set(CMAKE_CXX_STANDARD_DEFAULT "")
  61
  62   # There are no compiler modes so we only need to test features once.
  63   # Override the default macro for this special case.  Pretend that
  64   # all language standards are available so that at least compilation
  65   # can be attempted.
  66   macro(cmake_record_cxx_compile_features)
  67     list(APPEND CMAKE_CXX_COMPILE_FEATURES
  68       cxx_std_98
  69       cxx_std_11
  70       cxx_std_14
  71       cxx_std_17
  72       cxx_std_20
  73       cxx_std_23
  74       )
  75     _record_compiler_features(CXX "" CMAKE_CXX_COMPILE_FEATURES)
  76   endmacro()
  77 endif()
  78
  79 # /JMC "Just My Code" is only supported by MSVC 19.05 onward.
  80 if (CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL 19.05)
  81   set(CMAKE_CXX_COMPILE_OPTIONS_JMC "-JMC")
  82 endif()