Modules/Compiler/IAR-CXX.cmake

   1 # This file is processed when the IAR C++ Compiler is used
   2 #
   3 # C++ Language Specification support
   4 #  - Newer versions of the IAR C++ Compiler require the --c++ flag to build a C++ file.
   5 #    Earlier versions for non-ARM architectures provided Embedded C++, enabled with the --eec++ flag.
   6 #
   7 # The IAR Language Extensions
   8 #  - The IAR Language Extensions can be enabled by -e flag
   9 #
  10 include(Compiler/IAR)
  11 include(Compiler/CMakeCommonCompilerMacros)
  12
  13 if(NOT DEFINED CMAKE_CXX_COMPILER_VERSION)
  14   message(FATAL_ERROR "CMAKE_CXX_COMPILER_VERSION not detected. This should be automatic.")
  15 endif()
  16
  17 # Whenever needed, override this default behavior using CMAKE_IAR_CXX_FLAG in your toolchain file.
  18 if(NOT CMAKE_IAR_CXX_FLAG)
  19   cmake_policy(PUSH)
  20   cmake_policy(SET CMP0057 NEW) # if IN_LIST
  21
  22   set(_CMAKE_IAR_MODERNCXX_LIST 14 17)
  23   if(${CMAKE_CXX_STANDARD_COMPUTED_DEFAULT} IN_LIST _CMAKE_IAR_MODERNCXX_LIST OR
  24      ("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "ARM" AND ${CMAKE_CXX_STANDARD_COMPUTED_DEFAULT} EQUAL 98))
  25     string(PREPEND CMAKE_CXX_FLAGS "--c++ ")
  26   else()
  27     string(PREPEND CMAKE_CXX_FLAGS "--eec++ ")
  28   endif()
  29   unset(_CMAKE_IAR_MODERNCXX_LIST)
  30
  31   cmake_policy(POP)
  32 endif()
  33
  34 set(CMAKE_CXX_STANDARD_COMPILE_OPTION "")
  35 set(CMAKE_CXX_EXTENSION_COMPILE_OPTION -e) # Unused after CMP0128
  36
  37 set(CMAKE_CXX${CMAKE_CXX_STANDARD_COMPUTED_DEFAULT}_STANDARD_COMPILE_OPTION "")
  38 set(CMAKE_CXX${CMAKE_CXX_STANDARD_COMPUTED_DEFAULT}_EXTENSION_COMPILE_OPTION -e)
  39
  40 # Architecture specific
  41 if("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "ARM")
  42   if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5)
  43     # IAR C++ Compiler for Arm prior version 5.xx uses XLINK. Support in CMake is not implemented.
  44     message(FATAL_ERROR "IAR C++ Compiler for Arm version ${CMAKE_CXX_COMPILER_VERSION} not supported by CMake.")
  45   endif()
  46   __compiler_iar_ilink(CXX)
  47   __compiler_check_default_language_standard(CXX 5.10 98 8.10 14 8.40 17)
  48
  49 elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "RX")
  50   __compiler_iar_ilink(CXX)
  51   __compiler_check_default_language_standard(CXX 2.10 98 4.10 14 4.20 17)
  52
  53 elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "RH850")
  54   __compiler_iar_ilink(CXX)
  55   __compiler_check_default_language_standard(CXX 1.10 98 2.10 14 2.21 17)
  56
  57 elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "RL78")
  58   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 2)
  59     # # IAR C++ Compiler for RL78 prior version 2.xx uses XLINK. Support in CMake is not implemented.
  60     message(FATAL_ERROR "IAR C++ Compiler for RL78 version ${CMAKE_CXX_COMPILER_VERSION} not supported by CMake.")
  61   endif()
  62   __compiler_iar_ilink(CXX)
  63   __compiler_check_default_language_standard(CXX 2.10 98 4.10 14 4.20 17)
  64
  65 elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "RISCV")
  66   __compiler_iar_ilink(CXX)
  67   __compiler_check_default_language_standard(CXX 1.10 98 1.10 14 1.21 17)
  68
  69 elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "AVR")
  70   __compiler_iar_xlink(CXX)
  71   __compiler_check_default_language_standard(CXX 7.10 98)
  72
  73 elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "MSP430")
  74   __compiler_iar_xlink(CXX)
  75   __compiler_check_default_language_standard(CXX 5.10 98)
  76   set(CMAKE_CXX_OUTPUT_EXTENSION ".r43")
  77
  78 elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "V850")
  79   __compiler_iar_xlink(CXX)
  80   __compiler_check_default_language_standard(CXX 1.10 98)
  81   set(CMAKE_C_OUTPUT_EXTENSION ".r85")
  82
  83 elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "8051")
  84   __compiler_iar_xlink(CXX)
  85   __compiler_check_default_language_standard(CXX 6.10 98)
  86   set(CMAKE_C_OUTPUT_EXTENSION ".r51")
  87
  88 elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "STM8")
  89   __compiler_iar_ilink(CXX)
  90   __compiler_check_default_language_standard(CXX 3.11 98)
  91
  92 else()
  93   message(FATAL_ERROR "CMAKE_CXX_COMPILER_ARCHITECTURE_ID not detected. This should be automatic." )
  94 endif()