Modules/Compiler/Clang.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4
   5 # This module is shared by multiple languages; use include blocker.
   6 if(__COMPILER_CLANG)
   7   return()
   8 endif()
   9 set(__COMPILER_CLANG 1)
  10
  11 include(Compiler/CMakeCommonCompilerMacros)
  12
  13 set(__pch_header_C "c-header")
  14 set(__pch_header_CXX "c++-header")
  15 set(__pch_header_OBJC "objective-c-header")
  16 set(__pch_header_OBJCXX "objective-c++-header")
  17
  18 if("x${CMAKE_C_SIMULATE_ID}" STREQUAL "xMSVC"
  19     OR "x${CMAKE_CXX_SIMULATE_ID}" STREQUAL "xMSVC"
  20     OR "x${CMAKE_Fortran_SIMULATE_ID}" STREQUAL "xMSVC")
  21   macro(__compiler_clang lang)
  22   endmacro()
  23 else()
  24   include(Compiler/GNU)
  25
  26   macro(__compiler_clang lang)
  27     __compiler_gnu(${lang})
  28     set(CMAKE_${lang}_COMPILE_OPTIONS_PIE "-fPIE")
  29     # Link options for PIE are already set in 'Compiler/GNU.cmake'
  30     # but clang may require alternate syntax on some platforms
  31     if (APPLE)
  32       set(CMAKE_${lang}_LINK_OPTIONS_PIE ${CMAKE_${lang}_COMPILE_OPTIONS_PIE} -Xlinker -pie)
  33       set(CMAKE_${lang}_LINK_OPTIONS_NO_PIE -Xlinker -no_pie)
  34     endif()
  35     set(CMAKE_INCLUDE_SYSTEM_FLAG_${lang} "-isystem ")
  36     set(CMAKE_${lang}_COMPILE_OPTIONS_VISIBILITY "-fvisibility=")
  37     if(CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.4.0)
  38       set(CMAKE_${lang}_COMPILE_OPTIONS_TARGET "-target ")
  39       set(CMAKE_${lang}_COMPILE_OPTIONS_EXTERNAL_TOOLCHAIN "-gcc-toolchain ")
  40     else()
  41       set(CMAKE_${lang}_COMPILE_OPTIONS_TARGET "--target=")
  42       set(CMAKE_${lang}_COMPILE_OPTIONS_EXTERNAL_TOOLCHAIN "--gcc-toolchain=")
  43     endif()
  44     set(CMAKE_${lang}_LINKER_WRAPPER_FLAG "-Xlinker" " ")
  45     set(CMAKE_${lang}_LINKER_WRAPPER_FLAG_SEP)
  46
  47     if(CMAKE_${lang}_COMPILER_TARGET)
  48       if(CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.4.0)
  49         list(APPEND CMAKE_${lang}_COMPILER_PREDEFINES_COMMAND "-target" "${CMAKE_${lang}_COMPILER_TARGET}")
  50       else()
  51         list(APPEND CMAKE_${lang}_COMPILER_PREDEFINES_COMMAND "--target=${CMAKE_${lang}_COMPILER_TARGET}")
  52       endif()
  53     endif()
  54
  55     set(_CMAKE_${lang}_IPO_SUPPORTED_BY_CMAKE YES)
  56     set(_CMAKE_${lang}_IPO_MAY_BE_SUPPORTED_BY_COMPILER YES)
  57
  58     string(COMPARE EQUAL "${CMAKE_${lang}_COMPILER_ID}" "AppleClang" __is_apple_clang)
  59     string(COMPARE EQUAL "${CMAKE_${lang}_COMPILER_ID}" "FujitsuClang" __is_fujitsu_clang)
  60
  61     # '-flto=thin' available since Clang 3.9 and Xcode 8
  62     # * http://clang.llvm.org/docs/ThinLTO.html#clang-llvm
  63     # * https://trac.macports.org/wiki/XcodeVersionInfo
  64     set(_CMAKE_LTO_THIN TRUE)
  65     if(__is_apple_clang)
  66       if(CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 8.0)
  67         set(_CMAKE_LTO_THIN FALSE)
  68       endif()
  69     elseif(__is_fujitsu_clang)
  70       set(_CMAKE_LTO_THIN FALSE)
  71     else()
  72       if(CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.9)
  73         set(_CMAKE_LTO_THIN FALSE)
  74       endif()
  75     endif()
  76
  77     if(_CMAKE_LTO_THIN)
  78       set(CMAKE_${lang}_COMPILE_OPTIONS_IPO "-flto=thin")
  79     else()
  80       set(CMAKE_${lang}_COMPILE_OPTIONS_IPO "-flto")
  81     endif()
  82
  83     if(ANDROID AND NOT CMAKE_ANDROID_NDK_VERSION VERSION_GREATER_EQUAL "22")
  84       # https://github.com/android-ndk/ndk/issues/242
  85       set(CMAKE_${lang}_LINK_OPTIONS_IPO "-fuse-ld=gold")
  86     endif()
  87
  88     if(ANDROID OR __is_apple_clang)
  89       set(__ar "${CMAKE_AR}")
  90       set(__ranlib "${CMAKE_RANLIB}")
  91     else()
  92       set(__ar "${CMAKE_${lang}_COMPILER_AR}")
  93       set(__ranlib "${CMAKE_${lang}_COMPILER_RANLIB}")
  94     endif()
  95
  96     set(CMAKE_${lang}_ARCHIVE_CREATE_IPO
  97       "\"${__ar}\" cr <TARGET> <LINK_FLAGS> <OBJECTS>"
  98     )
  99
 100     set(CMAKE_${lang}_ARCHIVE_APPEND_IPO
 101       "\"${__ar}\" r <TARGET> <LINK_FLAGS> <OBJECTS>"
 102     )
 103
 104     set(CMAKE_${lang}_ARCHIVE_FINISH_IPO
 105       "\"${__ranlib}\" <TARGET>"
 106     )
 107
 108     set(CMAKE_PCH_EXTENSION .pch)
 109     if (NOT CMAKE_GENERATOR MATCHES "Xcode")
 110       set(CMAKE_PCH_PROLOGUE "#pragma clang system_header")
 111     endif()
 112     if(CMAKE_${lang}_COMPILER_VERSION VERSION_GREATER_EQUAL 11.0.0 AND NOT __is_apple_clang)
 113       set(CMAKE_${lang}_COMPILE_OPTIONS_INSTANTIATE_TEMPLATES_PCH -fpch-instantiate-templates)
 114     endif()
 115     set(CMAKE_${lang}_COMPILE_OPTIONS_USE_PCH -Xclang -include-pch -Xclang <PCH_FILE> -Xclang -include -Xclang <PCH_HEADER>)
 116     set(CMAKE_${lang}_COMPILE_OPTIONS_CREATE_PCH -Xclang -emit-pch -Xclang -include -Xclang <PCH_HEADER> -x ${__pch_header_${lang}})
 117
 118     # '-fcolor-diagnostics' introduced since Clang 2.6
 119     if(CMAKE_${lang}_COMPILER_VERSION VERSION_GREATER_EQUAL 2.6)
 120       set(CMAKE_${lang}_COMPILE_OPTIONS_COLOR_DIAGNOSTICS "-fcolor-diagnostics")
 121       set(CMAKE_${lang}_COMPILE_OPTIONS_COLOR_DIAGNOSTICS_OFF "-fno-color-diagnostics")
 122     endif()
 123   endmacro()
 124 endif()
 125
 126 macro(__compiler_clang_cxx_standards lang)
 127   if("x${CMAKE_${lang}_COMPILER_FRONTEND_VARIANT}" STREQUAL "xGNU")
 128     if(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 2.1)
 129       set(CMAKE_${lang}98_STANDARD_COMPILE_OPTION "-std=c++98")
 130       set(CMAKE_${lang}98_EXTENSION_COMPILE_OPTION "-std=gnu++98")
 131     endif()
 132
 133     if(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.1)
 134       set(CMAKE_${lang}98_STANDARD__HAS_FULL_SUPPORT ON)
 135       set(CMAKE_${lang}11_STANDARD_COMPILE_OPTION "-std=c++11")
 136       set(CMAKE_${lang}11_EXTENSION_COMPILE_OPTION "-std=gnu++11")
 137       set(CMAKE_${lang}11_STANDARD__HAS_FULL_SUPPORT ON)
 138     elseif(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 2.1)
 139       set(CMAKE_${lang}11_STANDARD_COMPILE_OPTION "-std=c++0x")
 140       set(CMAKE_${lang}11_EXTENSION_COMPILE_OPTION "-std=gnu++0x")
 141     endif()
 142
 143     if(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.5)
 144       set(CMAKE_${lang}14_STANDARD_COMPILE_OPTION "-std=c++14")
 145       set(CMAKE_${lang}14_EXTENSION_COMPILE_OPTION "-std=gnu++14")
 146       set(CMAKE_${lang}14_STANDARD__HAS_FULL_SUPPORT ON)
 147     elseif(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.4)
 148       set(CMAKE_${lang}14_STANDARD_COMPILE_OPTION "-std=c++1y")
 149       set(CMAKE_${lang}14_EXTENSION_COMPILE_OPTION "-std=gnu++1y")
 150       set(CMAKE_${lang}14_STANDARD__HAS_FULL_SUPPORT ON)
 151     endif()
 152
 153     set(_clang_version_std17 5.0)
 154     if(CMAKE_SYSTEM_NAME STREQUAL "Android")
 155       set(_clang_version_std17 6.0)
 156     endif()
 157
 158     if (NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS "${_clang_version_std17}")
 159       set(CMAKE_${lang}17_STANDARD_COMPILE_OPTION "-std=c++17")
 160       set(CMAKE_${lang}17_EXTENSION_COMPILE_OPTION "-std=gnu++17")
 161     elseif (NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.5)
 162       set(CMAKE_${lang}17_STANDARD_COMPILE_OPTION "-std=c++1z")
 163       set(CMAKE_${lang}17_EXTENSION_COMPILE_OPTION "-std=gnu++1z")
 164     endif()
 165
 166     if(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 11.0)
 167       set(CMAKE_${lang}20_STANDARD_COMPILE_OPTION "-std=c++20")
 168       set(CMAKE_${lang}20_EXTENSION_COMPILE_OPTION "-std=gnu++20")
 169     elseif(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS "${_clang_version_std17}")
 170       set(CMAKE_${lang}20_STANDARD_COMPILE_OPTION "-std=c++2a")
 171       set(CMAKE_${lang}20_EXTENSION_COMPILE_OPTION "-std=gnu++2a")
 172     endif()
 173
 174     unset(_clang_version_std17)
 175
 176     if(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 12.0)
 177       set(CMAKE_${lang}23_STANDARD_COMPILE_OPTION "-std=c++2b")
 178       set(CMAKE_${lang}23_EXTENSION_COMPILE_OPTION "-std=gnu++2b")
 179     endif()
 180
 181     if("x${CMAKE_${lang}_SIMULATE_ID}" STREQUAL "xMSVC")
 182       # The MSVC standard library requires C++14, and MSVC itself has no
 183       # notion of operating in a mode not aware of at least that standard.
 184       set(CMAKE_${lang}98_STANDARD_COMPILE_OPTION "-std=c++14")
 185       set(CMAKE_${lang}98_EXTENSION_COMPILE_OPTION "-std=gnu++14")
 186       set(CMAKE_${lang}11_STANDARD_COMPILE_OPTION "-std=c++14")
 187       set(CMAKE_${lang}11_EXTENSION_COMPILE_OPTION "-std=gnu++14")
 188
 189       # This clang++ is missing some features because of MSVC compatibility.
 190       unset(CMAKE_${lang}11_STANDARD__HAS_FULL_SUPPORT)
 191       unset(CMAKE_${lang}14_STANDARD__HAS_FULL_SUPPORT)
 192     endif()
 193
 194     __compiler_check_default_language_standard(${lang} 2.1 98)
 195   elseif(CMAKE_${lang}_COMPILER_VERSION VERSION_GREATER_EQUAL 3.9
 196       AND CMAKE_${lang}_SIMULATE_VERSION VERSION_GREATER_EQUAL 19.0)
 197     # This version of clang-cl and the MSVC version it simulates have
 198     # support for -std: flags.
 199     set(CMAKE_${lang}98_STANDARD_COMPILE_OPTION "")
 200     set(CMAKE_${lang}98_EXTENSION_COMPILE_OPTION "")
 201     set(CMAKE_${lang}98_STANDARD__HAS_FULL_SUPPORT ON)
 202     set(CMAKE_${lang}11_STANDARD_COMPILE_OPTION "")
 203     set(CMAKE_${lang}11_EXTENSION_COMPILE_OPTION "")
 204     set(CMAKE_${lang}14_STANDARD_COMPILE_OPTION "-std:c++14")
 205     set(CMAKE_${lang}14_EXTENSION_COMPILE_OPTION "-std:c++14")
 206
 207     if(CMAKE_${lang}_COMPILER_VERSION VERSION_GREATER_EQUAL 6.0)
 208       set(CMAKE_${lang}17_STANDARD_COMPILE_OPTION "-std:c++17")
 209       set(CMAKE_${lang}17_EXTENSION_COMPILE_OPTION "-std:c++17")
 210     else()
 211       set(CMAKE_${lang}17_STANDARD_COMPILE_OPTION "-std:c++latest")
 212       set(CMAKE_${lang}17_EXTENSION_COMPILE_OPTION "-std:c++latest")
 213     endif()
 214
 215     if(CMAKE_${lang}_COMPILER_VERSION VERSION_GREATER_EQUAL 13.0)
 216       set(CMAKE_${lang}23_STANDARD_COMPILE_OPTION "-std:c++latest")
 217       set(CMAKE_${lang}23_EXTENSION_COMPILE_OPTION "-std:c++latest")
 218       set(CMAKE_${lang}20_STANDARD_COMPILE_OPTION "-std:c++20")
 219       set(CMAKE_${lang}20_EXTENSION_COMPILE_OPTION "-std:c++20")
 220     elseif(CMAKE_${lang}_COMPILER_VERSION VERSION_GREATER_EQUAL 6.0)
 221       set(CMAKE_${lang}20_STANDARD_COMPILE_OPTION "-std:c++latest")
 222       set(CMAKE_${lang}20_EXTENSION_COMPILE_OPTION "-std:c++latest")
 223     endif()
 224
 225     __compiler_check_default_language_standard(${lang} 3.9 14)
 226   else()
 227     # This version of clang-cl, or the MSVC version it simulates, does not have
 228     # language standards.  Set these options as empty strings so the feature
 229     # test infrastructure can at least check to see if they are defined.
 230     set(CMAKE_${lang}98_STANDARD_COMPILE_OPTION "")
 231     set(CMAKE_${lang}98_EXTENSION_COMPILE_OPTION "")
 232     set(CMAKE_${lang}11_STANDARD_COMPILE_OPTION "")
 233     set(CMAKE_${lang}11_EXTENSION_COMPILE_OPTION "")
 234     set(CMAKE_${lang}14_STANDARD_COMPILE_OPTION "")
 235     set(CMAKE_${lang}14_EXTENSION_COMPILE_OPTION "")
 236     set(CMAKE_${lang}17_STANDARD_COMPILE_OPTION "")
 237     set(CMAKE_${lang}17_EXTENSION_COMPILE_OPTION "")
 238     set(CMAKE_${lang}20_STANDARD_COMPILE_OPTION "")
 239     set(CMAKE_${lang}20_EXTENSION_COMPILE_OPTION "")
 240     set(CMAKE_${lang}23_STANDARD_COMPILE_OPTION "")
 241     set(CMAKE_${lang}23_EXTENSION_COMPILE_OPTION "")
 242
 243     # There is no meaningful default for this
 244     set(CMAKE_${lang}_STANDARD_DEFAULT "")
 245
 246     # There are no compiler modes so we only need to test features once.
 247     # Override the default macro for this special case.  Pretend that
 248     # all language standards are available so that at least compilation
 249     # can be attempted.
 250     macro(cmake_record_${lang}_compile_features)
 251       list(APPEND CMAKE_${lang}_COMPILE_FEATURES
 252         cxx_std_98
 253         cxx_std_11
 254         cxx_std_14
 255         cxx_std_17
 256         cxx_std_20
 257         cxx_std_23
 258         )
 259       _record_compiler_features(${lang} "" CMAKE_${lang}_COMPILE_FEATURES)
 260     endmacro()
 261   endif()
 262 endmacro()