Modules/CheckVariableExists.cmake

   1 # - Check if the variable exists.
   2 #  CHECK_VARIABLE_EXISTS(VAR VARIABLE)
   3 #
   4 #  VAR      - the name of the variable
   5 #  VARIABLE - variable to store the result
   6 #
   7 # This macro is only for C variables.
   8 #
   9 # The following variables may be set before calling this macro to
  10 # modify the way the check is run:
  11 #
  12 #  CMAKE_REQUIRED_FLAGS = string of compile command line flags
  13 #  CMAKE_REQUIRED_DEFINITIONS = list of macros to define (-DFOO=bar)
  14 #  CMAKE_REQUIRED_LIBRARIES = list of libraries to link
  15
  16 #=============================================================================
  17 # Copyright 2002-2009 Kitware, Inc.
  18 #
  19 # Distributed under the OSI-approved BSD License (the "License");
  20 # see accompanying file Copyright.txt for details.
  21 #
  22 # This software is distributed WITHOUT ANY WARRANTY; without even the
  23 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  24 # See the License for more information.
  25 #=============================================================================
  26 # (To distribute this file outside of CMake, substitute the full
  27 #  License text for the above reference.)
  28
  29 include("${CMAKE_CURRENT_LIST_DIR}/CMakeExpandImportedTargets.cmake")
  30
  31
  32 macro(CHECK_VARIABLE_EXISTS VAR VARIABLE)
  33   if("${VARIABLE}" MATCHES "^${VARIABLE}$")
  34     set(MACRO_CHECK_VARIABLE_DEFINITIONS
  35       "-DCHECK_VARIABLE_EXISTS=${VAR} ${CMAKE_REQUIRED_FLAGS}")
  36     message(STATUS "Looking for ${VAR}")
  37     if(CMAKE_REQUIRED_LIBRARIES)
  38       # this one translates potentially used imported library targets to their files on disk
  39       CMAKE_EXPAND_IMPORTED_TARGETS(_ADJUSTED_CMAKE_REQUIRED_LIBRARIES  LIBRARIES  ${CMAKE_REQUIRED_LIBRARIES} CONFIGURATION "${CMAKE_TRY_COMPILE_CONFIGURATION}")
  40       set(CHECK_VARIABLE_EXISTS_ADD_LIBRARIES
  41         "-DLINK_LIBRARIES:STRING=${_ADJUSTED_CMAKE_REQUIRED_LIBRARIES}")
  42     else()
  43       set(CHECK_VARIABLE_EXISTS_ADD_LIBRARIES)
  44     endif()
  45     try_compile(${VARIABLE}
  46       ${CMAKE_BINARY_DIR}
  47       ${CMAKE_ROOT}/Modules/CheckVariableExists.c
  48       COMPILE_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS}
  49       CMAKE_FLAGS -DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_VARIABLE_DEFINITIONS}
  50       "${CHECK_VARIABLE_EXISTS_ADD_LIBRARIES}"
  51       OUTPUT_VARIABLE OUTPUT)
  52     if(${VARIABLE})
  53       set(${VARIABLE} 1 CACHE INTERNAL "Have variable ${VAR}")
  54       message(STATUS "Looking for ${VAR} - found")
  55       file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
  56         "Determining if the variable ${VAR} exists passed with the following output:\n"
  57         "${OUTPUT}\n\n")
  58     else()
  59       set(${VARIABLE} "" CACHE INTERNAL "Have variable ${VAR}")
  60       message(STATUS "Looking for ${VAR} - not found")
  61       file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
  62         "Determining if the variable ${VAR} exists failed with the following output:\n"
  63         "${OUTPUT}\n\n")
  64     endif()
  65   endif()
  66 endmacro()