Modules/CMakeTestCXXCompiler.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4
   5 if(CMAKE_CXX_COMPILER_FORCED)
   6   # The compiler configuration was forced by the user.
   7   # Assume the user has configured all compiler information.
   8   set(CMAKE_CXX_COMPILER_WORKS TRUE)
   9   return()
  10 endif()
  11
  12 include(CMakeTestCompilerCommon)
  13
  14 # work around enforced code signing and / or missing executable target type
  15 set(__CMAKE_SAVED_TRY_COMPILE_TARGET_TYPE ${CMAKE_TRY_COMPILE_TARGET_TYPE})
  16 if(_CMAKE_FEATURE_DETECTION_TARGET_TYPE)
  17   set(CMAKE_TRY_COMPILE_TARGET_TYPE ${_CMAKE_FEATURE_DETECTION_TARGET_TYPE})
  18 endif()
  19
  20 # Remove any cached result from an older CMake version.
  21 # We now store this in CMakeCXXCompiler.cmake.
  22 unset(CMAKE_CXX_COMPILER_WORKS CACHE)
  23
  24 # Try to identify the ABI and configure it into CMakeCXXCompiler.cmake
  25 include(${CMAKE_ROOT}/Modules/CMakeDetermineCompilerABI.cmake)
  26 CMAKE_DETERMINE_COMPILER_ABI(CXX ${CMAKE_ROOT}/Modules/CMakeCXXCompilerABI.cpp)
  27 if(CMAKE_CXX_ABI_COMPILED)
  28   # The compiler worked so skip dedicated test below.
  29   set(CMAKE_CXX_COMPILER_WORKS TRUE)
  30   message(STATUS "Check for working CXX compiler: ${CMAKE_CXX_COMPILER} - skipped")
  31 endif()
  32
  33 # This file is used by EnableLanguage in cmGlobalGenerator to
  34 # determine that the selected C++ compiler can actually compile
  35 # and link the most basic of programs.   If not, a fatal error
  36 # is set and cmake stops processing commands and will not generate
  37 # any makefiles or projects.
  38 if(NOT CMAKE_CXX_COMPILER_WORKS)
  39   PrintTestCompilerStatus("CXX")
  40   __TestCompiler_setTryCompileTargetType()
  41   file(WRITE ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/testCXXCompiler.cxx
  42     "#ifndef __cplusplus\n"
  43     "# error \"The CMAKE_CXX_COMPILER is set to a C compiler\"\n"
  44     "#endif\n"
  45     "int main(){return 0;}\n")
  46   # Clear result from normal variable.
  47   unset(CMAKE_CXX_COMPILER_WORKS)
  48   # Puts test result in cache variable.
  49   try_compile(CMAKE_CXX_COMPILER_WORKS ${CMAKE_BINARY_DIR}
  50     ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/testCXXCompiler.cxx
  51     OUTPUT_VARIABLE __CMAKE_CXX_COMPILER_OUTPUT)
  52   # Move result from cache to normal variable.
  53   set(CMAKE_CXX_COMPILER_WORKS ${CMAKE_CXX_COMPILER_WORKS})
  54   unset(CMAKE_CXX_COMPILER_WORKS CACHE)
  55   __TestCompiler_restoreTryCompileTargetType()
  56   if(NOT CMAKE_CXX_COMPILER_WORKS)
  57     PrintTestCompilerResult(CHECK_FAIL "broken")
  58     file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
  59       "Determining if the CXX compiler works failed with "
  60       "the following output:\n${__CMAKE_CXX_COMPILER_OUTPUT}\n\n")
  61     string(REPLACE "\n" "\n  " _output "${__CMAKE_CXX_COMPILER_OUTPUT}")
  62     message(FATAL_ERROR "The C++ compiler\n  \"${CMAKE_CXX_COMPILER}\"\n"
  63       "is not able to compile a simple test program.\nIt fails "
  64       "with the following output:\n  ${_output}\n\n"
  65       "CMake will not be able to correctly generate this project.")
  66   endif()
  67   PrintTestCompilerResult(CHECK_PASS "works")
  68   file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
  69     "Determining if the CXX compiler works passed with "
  70     "the following output:\n${__CMAKE_CXX_COMPILER_OUTPUT}\n\n")
  71 endif()
  72
  73 # Try to identify the compiler features
  74 include(${CMAKE_ROOT}/Modules/CMakeDetermineCompileFeatures.cmake)
  75 CMAKE_DETERMINE_COMPILE_FEATURES(CXX)
  76
  77 # Re-configure to save learned information.
  78 configure_file(
  79   ${CMAKE_ROOT}/Modules/CMakeCXXCompiler.cmake.in
  80   ${CMAKE_PLATFORM_INFO_DIR}/CMakeCXXCompiler.cmake
  81   @ONLY
  82   )
  83 include(${CMAKE_PLATFORM_INFO_DIR}/CMakeCXXCompiler.cmake)
  84
  85 if(CMAKE_CXX_SIZEOF_DATA_PTR)
  86   foreach(f ${CMAKE_CXX_ABI_FILES})
  87     include(${f})
  88   endforeach()
  89   unset(CMAKE_CXX_ABI_FILES)
  90 endif()
  91
  92 set(CMAKE_TRY_COMPILE_TARGET_TYPE ${__CMAKE_SAVED_TRY_COMPILE_TARGET_TYPE})
  93 unset(__CMAKE_SAVED_TRY_COMPILE_TARGET_TYPE)
  94 unset(__CMAKE_CXX_COMPILER_OUTPUT)