Modules/CMakeTestCXXCompiler.cmake

   1
   2 #=============================================================================
   3 # Copyright 2003-2012 Kitware, Inc.
   4 #
   5 # Distributed under the OSI-approved BSD License (the "License");
   6 # see accompanying file Copyright.txt for details.
   7 #
   8 # This software is distributed WITHOUT ANY WARRANTY; without even the
   9 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  10 # See the License for more information.
  11 #=============================================================================
  12 # (To distribute this file outside of CMake, substitute the full
  13 #  License text for the above reference.)
  14
  15 if(CMAKE_CXX_COMPILER_FORCED)
  16   # The compiler configuration was forced by the user.
  17   # Assume the user has configured all compiler information.
  18   set(CMAKE_CXX_COMPILER_WORKS TRUE)
  19   return()
  20 endif()
  21
  22 include(CMakeTestCompilerCommon)
  23
  24 # Remove any cached result from an older CMake version.
  25 # We now store this in CMakeCXXCompiler.cmake.
  26 unset(CMAKE_CXX_COMPILER_WORKS CACHE)
  27
  28 # This file is used by EnableLanguage in cmGlobalGenerator to
  29 # determine that that selected C++ compiler can actually compile
  30 # and link the most basic of programs.   If not, a fatal error
  31 # is set and cmake stops processing commands and will not generate
  32 # any makefiles or projects.
  33 if(NOT CMAKE_CXX_COMPILER_WORKS)
  34   PrintTestCompilerStatus("CXX" "")
  35   file(WRITE ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/testCXXCompiler.cxx
  36     "#ifndef __cplusplus\n"
  37     "# error \"The CMAKE_CXX_COMPILER is set to a C compiler\"\n"
  38     "#endif\n"
  39     "int main(){return 0;}\n")
  40   try_compile(CMAKE_CXX_COMPILER_WORKS ${CMAKE_BINARY_DIR}
  41     ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/testCXXCompiler.cxx
  42     OUTPUT_VARIABLE __CMAKE_CXX_COMPILER_OUTPUT)
  43   # Move result from cache to normal variable.
  44   set(CMAKE_CXX_COMPILER_WORKS ${CMAKE_CXX_COMPILER_WORKS})
  45   unset(CMAKE_CXX_COMPILER_WORKS CACHE)
  46   set(CXX_TEST_WAS_RUN 1)
  47 endif()
  48
  49 if(NOT CMAKE_CXX_COMPILER_WORKS)
  50   PrintTestCompilerStatus("CXX" " -- broken")
  51   file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
  52     "Determining if the CXX compiler works failed with "
  53     "the following output:\n${__CMAKE_CXX_COMPILER_OUTPUT}\n\n")
  54   message(FATAL_ERROR "The C++ compiler \"${CMAKE_CXX_COMPILER}\" "
  55     "is not able to compile a simple test program.\nIt fails "
  56     "with the following output:\n ${__CMAKE_CXX_COMPILER_OUTPUT}\n\n"
  57     "CMake will not be able to correctly generate this project.")
  58 else()
  59   if(CXX_TEST_WAS_RUN)
  60     PrintTestCompilerStatus("CXX" " -- works")
  61     file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
  62       "Determining if the CXX compiler works passed with "
  63       "the following output:\n${__CMAKE_CXX_COMPILER_OUTPUT}\n\n")
  64   endif()
  65
  66   # Try to identify the ABI and configure it into CMakeCXXCompiler.cmake
  67   include(${CMAKE_ROOT}/Modules/CMakeDetermineCompilerABI.cmake)
  68   CMAKE_DETERMINE_COMPILER_ABI(CXX ${CMAKE_ROOT}/Modules/CMakeCXXCompilerABI.cpp)
  69
  70   # Re-configure to save learned information.
  71   configure_file(
  72     ${CMAKE_ROOT}/Modules/CMakeCXXCompiler.cmake.in
  73     ${CMAKE_PLATFORM_INFO_DIR}/CMakeCXXCompiler.cmake
  74     @ONLY IMMEDIATE # IMMEDIATE must be here for compatibility mode <= 2.0
  75     )
  76   include(${CMAKE_PLATFORM_INFO_DIR}/CMakeCXXCompiler.cmake)
  77
  78   if(CMAKE_CXX_SIZEOF_DATA_PTR)
  79     foreach(f ${CMAKE_CXX_ABI_FILES})
  80       include(${f})
  81     endforeach()
  82     unset(CMAKE_CXX_ABI_FILES)
  83   endif()
  84 endif()
  85
  86 unset(__CMAKE_CXX_COMPILER_OUTPUT)