Modules/CMakeTestCCompiler.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4
   5 if(CMAKE_C_COMPILER_FORCED)
   6   # The compiler configuration was forced by the user.
   7   # Assume the user has configured all compiler information.
   8   set(CMAKE_C_COMPILER_WORKS TRUE)
   9   return()
  10 endif()
  11
  12 include(CMakeTestCompilerCommon)
  13
  14 # work around enforced code signing and / or missing executable target type
  15 set(__CMAKE_SAVED_TRY_COMPILE_TARGET_TYPE ${CMAKE_TRY_COMPILE_TARGET_TYPE})
  16 if(_CMAKE_FEATURE_DETECTION_TARGET_TYPE)
  17   set(CMAKE_TRY_COMPILE_TARGET_TYPE ${_CMAKE_FEATURE_DETECTION_TARGET_TYPE})
  18 endif()
  19
  20 # Remove any cached result from an older CMake version.
  21 # We now store this in CMakeCCompiler.cmake.
  22 unset(CMAKE_C_COMPILER_WORKS CACHE)
  23
  24 # Try to identify the ABI and configure it into CMakeCCompiler.cmake
  25 include(${CMAKE_ROOT}/Modules/CMakeDetermineCompilerABI.cmake)
  26 CMAKE_DETERMINE_COMPILER_ABI(C ${CMAKE_ROOT}/Modules/CMakeCCompilerABI.c)
  27 if(CMAKE_C_ABI_COMPILED)
  28   # The compiler worked so skip dedicated test below.
  29   set(CMAKE_C_COMPILER_WORKS TRUE)
  30   message(STATUS "Check for working C compiler: ${CMAKE_C_COMPILER} - skipped")
  31 endif()
  32
  33 # This file is used by EnableLanguage in cmGlobalGenerator to
  34 # determine that that selected C compiler can actually compile
  35 # and link the most basic of programs.   If not, a fatal error
  36 # is set and cmake stops processing commands and will not generate
  37 # any makefiles or projects.
  38 if(NOT CMAKE_C_COMPILER_WORKS)
  39   PrintTestCompilerStatus("C")
  40   __TestCompiler_setTryCompileTargetType()
  41   string(CONCAT __TestCompiler_testCCompilerSource
  42     "#ifdef __cplusplus\n"
  43     "# error \"The CMAKE_C_COMPILER is set to a C++ compiler\"\n"
  44     "#endif\n"
  45     "#if defined(__CLASSIC_C__)\n"
  46     "int main(argc, argv)\n"
  47     "  int argc;\n"
  48     "  char* argv[];\n"
  49     "#else\n"
  50     "int main(int argc, char* argv[])\n"
  51     "#endif\n"
  52     "{ (void)argv; return argc-1;}\n")
  53   # Clear result from normal variable.
  54   unset(CMAKE_C_COMPILER_WORKS)
  55   # Puts test result in cache variable.
  56   try_compile(CMAKE_C_COMPILER_WORKS
  57     SOURCE_FROM_VAR testCCompiler.c __TestCompiler_testCCompilerSource
  58     OUTPUT_VARIABLE __CMAKE_C_COMPILER_OUTPUT)
  59   unset(__TestCompiler_testCCompilerSource)
  60   # Move result from cache to normal variable.
  61   set(CMAKE_C_COMPILER_WORKS ${CMAKE_C_COMPILER_WORKS})
  62   unset(CMAKE_C_COMPILER_WORKS CACHE)
  63   __TestCompiler_restoreTryCompileTargetType()
  64   if(NOT CMAKE_C_COMPILER_WORKS)
  65     PrintTestCompilerResult(CHECK_FAIL "broken")
  66     file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
  67       "Determining if the C compiler works failed with "
  68       "the following output:\n${__CMAKE_C_COMPILER_OUTPUT}\n\n")
  69     string(REPLACE "\n" "\n  " _output "${__CMAKE_C_COMPILER_OUTPUT}")
  70     message(FATAL_ERROR "The C compiler\n  \"${CMAKE_C_COMPILER}\"\n"
  71       "is not able to compile a simple test program.\nIt fails "
  72       "with the following output:\n  ${_output}\n\n"
  73       "CMake will not be able to correctly generate this project.")
  74   endif()
  75   PrintTestCompilerResult(CHECK_PASS "works")
  76   file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
  77     "Determining if the C compiler works passed with "
  78     "the following output:\n${__CMAKE_C_COMPILER_OUTPUT}\n\n")
  79 endif()
  80
  81 # Try to identify the compiler features
  82 include(${CMAKE_ROOT}/Modules/CMakeDetermineCompileFeatures.cmake)
  83 CMAKE_DETERMINE_COMPILE_FEATURES(C)
  84
  85 # Re-configure to save learned information.
  86 configure_file(
  87   ${CMAKE_ROOT}/Modules/CMakeCCompiler.cmake.in
  88   ${CMAKE_PLATFORM_INFO_DIR}/CMakeCCompiler.cmake
  89   @ONLY
  90   )
  91 include(${CMAKE_PLATFORM_INFO_DIR}/CMakeCCompiler.cmake)
  92
  93 if(CMAKE_C_SIZEOF_DATA_PTR)
  94   foreach(f ${CMAKE_C_ABI_FILES})
  95     include(${f})
  96   endforeach()
  97   unset(CMAKE_C_ABI_FILES)
  98 endif()
  99
 100 set(CMAKE_TRY_COMPILE_TARGET_TYPE ${__CMAKE_SAVED_TRY_COMPILE_TARGET_TYPE})
 101 unset(__CMAKE_SAVED_TRY_COMPILE_TARGET_TYPE)
 102 unset(__CMAKE_C_COMPILER_OUTPUT)