Modules/CMakeGenericSystem.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 include(CMakeInitializeConfigs)
   5
   6 set(CMAKE_SHARED_LIBRARY_C_FLAGS "")            # -pic
   7 set(CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS "-shared")       # -shared
   8 set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS "")         # +s, flag for exe link to use shared lib
   9 set(CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG "")       # -rpath
  10 set(CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG_SEP "")   # : or empty
  11 set(CMAKE_INCLUDE_FLAG_C "-I")       # -I
  12 set(CMAKE_LIBRARY_PATH_FLAG "-L")
  13 set(CMAKE_LIBRARY_PATH_TERMINATOR "")  # for the Digital Mars D compiler the link paths have to be terminated with a "/"
  14 set(CMAKE_LINK_LIBRARY_FLAG "-l")
  15
  16 set(CMAKE_LINK_LIBRARY_SUFFIX "")
  17 set(CMAKE_STATIC_LIBRARY_PREFIX "lib")
  18 set(CMAKE_STATIC_LIBRARY_SUFFIX ".a")
  19 set(CMAKE_SHARED_LIBRARY_PREFIX "lib")          # lib
  20 set(CMAKE_SHARED_LIBRARY_SUFFIX ".so")          # .so
  21 set(CMAKE_EXECUTABLE_SUFFIX "")          # .exe
  22 set(CMAKE_DL_LIBS "dl")
  23
  24 set(CMAKE_FIND_LIBRARY_PREFIXES "lib")
  25 set(CMAKE_FIND_LIBRARY_SUFFIXES ".so" ".a")
  26
  27 set(CMAKE_AUTOGEN_ORIGIN_DEPENDS ON)
  28 set(CMAKE_AUTOMOC_COMPILER_PREDEFINES ON)
  29 if(NOT DEFINED CMAKE_AUTOMOC_PATH_PREFIX)
  30   set(CMAKE_AUTOMOC_PATH_PREFIX OFF)
  31 endif()
  32 set(CMAKE_AUTOMOC_MACRO_NAMES "Q_OBJECT" "Q_GADGET" "Q_NAMESPACE" "Q_NAMESPACE_EXPORT")
  33
  34 # basically all general purpose OSs support shared libs
  35 set_property(GLOBAL PROPERTY TARGET_SUPPORTS_SHARED_LIBS TRUE)
  36
  37 set (CMAKE_SKIP_RPATH "NO" CACHE BOOL
  38      "If set, runtime paths are not added when using shared libraries.")
  39 set (CMAKE_SKIP_INSTALL_RPATH "NO" CACHE BOOL
  40      "If set, runtime paths are not added when installing shared libraries, but are added when building.")
  41
  42 set(CMAKE_VERBOSE_MAKEFILE FALSE CACHE BOOL "If this value is on, makefiles will be generated without the .SILENT directive, and all commands will be echoed to the console during the make.  This is useful for debugging only. With Visual Studio IDE projects all commands are done without /nologo.")
  43
  44 if(CMAKE_GENERATOR MATCHES "Make")
  45   set(CMAKE_COLOR_MAKEFILE ON CACHE BOOL
  46     "Enable/Disable color output during build."
  47     )
  48   mark_as_advanced(CMAKE_COLOR_MAKEFILE)
  49   if(DEFINED CMAKE_RULE_MESSAGES)
  50     set_property(GLOBAL PROPERTY RULE_MESSAGES ${CMAKE_RULE_MESSAGES})
  51   endif()
  52   if(DEFINED CMAKE_TARGET_MESSAGES)
  53     set_property(GLOBAL PROPERTY TARGET_MESSAGES ${CMAKE_TARGET_MESSAGES})
  54   endif()
  55 endif()
  56
  57 if(NOT DEFINED CMAKE_EXPORT_COMPILE_COMMANDS AND CMAKE_GENERATOR MATCHES "Ninja|Unix Makefiles")
  58   set(CMAKE_EXPORT_COMPILE_COMMANDS "$ENV{CMAKE_EXPORT_COMPILE_COMMANDS}"
  59     CACHE BOOL "Enable/Disable output of compile commands during generation."
  60     )
  61   mark_as_advanced(CMAKE_EXPORT_COMPILE_COMMANDS)
  62 endif()
  63
  64 # GetDefaultWindowsPrefixBase
  65 #
  66 # Compute the base directory for CMAKE_INSTALL_PREFIX based on:
  67 #  - is this 32-bit or 64-bit Windows
  68 #  - is this 32-bit or 64-bit CMake running
  69 #  - what architecture targets will be built
  70 #
  71 function(GetDefaultWindowsPrefixBase var)
  72
  73   # Try to guess what architecture targets will end up being built as,
  74   # even if CMAKE_SIZEOF_VOID_P is not computed yet... We need to know
  75   # the architecture of the targets being built to choose the right
  76   # default value for CMAKE_INSTALL_PREFIX.
  77   #
  78   if("${CMAKE_GENERATOR}" MATCHES "(Win64|IA64)")
  79     set(arch_hint "x64")
  80   elseif("${CMAKE_GENERATOR_PLATFORM}" MATCHES "ARM64")
  81     set(arch_hint "ARM64")
  82   elseif("${CMAKE_GENERATOR}" MATCHES "ARM")
  83     set(arch_hint "ARM")
  84   elseif("${CMAKE_SIZEOF_VOID_P}" STREQUAL "8")
  85     set(arch_hint "x64")
  86   elseif("$ENV{LIB}" MATCHES "(amd64|ia64)")
  87     set(arch_hint "x64")
  88   endif()
  89
  90   if(NOT arch_hint)
  91     set(arch_hint "x86")
  92   endif()
  93
  94   # default env in a 64-bit app on Win64:
  95   # ProgramFiles=C:\Program Files
  96   # ProgramFiles(x86)=C:\Program Files (x86)
  97   # ProgramW6432=C:\Program Files
  98   #
  99   # default env in a 32-bit app on Win64:
 100   # ProgramFiles=C:\Program Files (x86)
 101   # ProgramFiles(x86)=C:\Program Files (x86)
 102   # ProgramW6432=C:\Program Files
 103   #
 104   # default env in a 32-bit app on Win32:
 105   # ProgramFiles=C:\Program Files
 106   # ProgramFiles(x86) NOT DEFINED
 107   # ProgramW6432 NOT DEFINED
 108
 109   # By default, use the ProgramFiles env var as the base value of
 110   # CMAKE_INSTALL_PREFIX:
 111   #
 112   set(_PREFIX_ENV_VAR "ProgramFiles")
 113
 114   if ("$ENV{ProgramW6432}" STREQUAL "")
 115     # running on 32-bit Windows
 116     # must be a 32-bit CMake, too...
 117     #message("guess: this is a 32-bit CMake running on 32-bit Windows")
 118   else()
 119     # running on 64-bit Windows
 120     if ("$ENV{ProgramW6432}" STREQUAL "$ENV{ProgramFiles}")
 121       # 64-bit CMake
 122       #message("guess: this is a 64-bit CMake running on 64-bit Windows")
 123       if(NOT "${arch_hint}" STREQUAL "x64")
 124       # building 32-bit targets
 125         set(_PREFIX_ENV_VAR "ProgramFiles(x86)")
 126       endif()
 127     else()
 128       # 32-bit CMake
 129       #message("guess: this is a 32-bit CMake running on 64-bit Windows")
 130       if("${arch_hint}" STREQUAL "x64")
 131       # building 64-bit targets
 132         set(_PREFIX_ENV_VAR "ProgramW6432")
 133       endif()
 134     endif()
 135   endif()
 136
 137   #if("${arch_hint}" STREQUAL "x64")
 138   #  message("guess: you are building a 64-bit app")
 139   #else()
 140   #  message("guess: you are building a 32-bit app")
 141   #endif()
 142
 143   if(NOT "$ENV{${_PREFIX_ENV_VAR}}" STREQUAL "")
 144     file(TO_CMAKE_PATH "$ENV{${_PREFIX_ENV_VAR}}" _base)
 145   elseif(NOT "$ENV{SystemDrive}" STREQUAL "")
 146     set(_base "$ENV{SystemDrive}/Program Files")
 147   else()
 148     set(_base "C:/Program Files")
 149   endif()
 150
 151   set(${var} "${_base}" PARENT_SCOPE)
 152 endfunction()
 153
 154
 155 # Set a variable to indicate whether the value of CMAKE_INSTALL_PREFIX
 156 # was initialized by the block below.  This is useful for user
 157 # projects to change the default prefix while still allowing the
 158 # command line to override it.
 159 if(NOT DEFINED CMAKE_INSTALL_PREFIX)
 160   set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT 1)
 161 endif()
 162
 163 # Choose a default install prefix for this platform.
 164 if(CMAKE_HOST_UNIX)
 165   set(CMAKE_INSTALL_PREFIX "/usr/local"
 166     CACHE PATH "Install path prefix, prepended onto install directories.")
 167 else()
 168   GetDefaultWindowsPrefixBase(CMAKE_GENERIC_PROGRAM_FILES)
 169   set(CMAKE_INSTALL_PREFIX
 170     "${CMAKE_GENERIC_PROGRAM_FILES}/${PROJECT_NAME}"
 171     CACHE PATH "Install path prefix, prepended onto install directories.")
 172   set(CMAKE_GENERIC_PROGRAM_FILES)
 173 endif()
 174
 175 # Set a variable which will be used as component name in install() commands
 176 # where no COMPONENT has been given:
 177 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "Unspecified")
 178
 179 mark_as_advanced(
 180   CMAKE_SKIP_RPATH
 181   CMAKE_SKIP_INSTALL_RPATH
 182   CMAKE_VERBOSE_MAKEFILE
 183 )