Modules/CMakeFindBinUtils.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4
   5 # search for additional tools required for C/C++ (and other languages ?)
   6 #
   7 # If the internal cmake variable _CMAKE_TOOLCHAIN_PREFIX is set, this is used
   8 # as prefix for the tools (e.g. arm-elf-gcc etc.)
   9 # If the cmake variable _CMAKE_TOOLCHAIN_LOCATION is set, the compiler is
  10 # searched only there. The other tools are at first searched there, then
  11 # also in the default locations.
  12 #
  13 # Sets the following variables:
  14 #   CMAKE_AR
  15 #   CMAKE_RANLIB
  16 #   CMAKE_LINKER
  17 #   CMAKE_MT
  18 #   CMAKE_STRIP
  19 #   CMAKE_INSTALL_NAME_TOOL
  20
  21 # on UNIX, cygwin and mingw
  22
  23 # Resolve full path of CMAKE_TOOL from user-defined name and SEARCH_PATH.
  24 function(__resolve_tool_path CMAKE_TOOL SEARCH_PATH DOCSTRING)
  25
  26   if(${CMAKE_TOOL})
  27     # We only get here if CMAKE_TOOL was
  28     # specified using -D or a pre-made CMakeCache.txt (e.g. via ctest)
  29     # or set in CMAKE_TOOLCHAIN_FILE.
  30
  31     get_filename_component(_CMAKE_USER_TOOL_PATH "${${CMAKE_TOOL}}" DIRECTORY)
  32     # Is CMAKE_TOOL a user-defined name instead of a full path?
  33     if(NOT _CMAKE_USER_TOOL_PATH)
  34
  35       # Find CMAKE_TOOL in the SEARCH_PATH directory by user-defined name.
  36       find_program(_CMAKE_TOOL_WITH_PATH NAMES ${${CMAKE_TOOL}} HINTS ${SEARCH_PATH})
  37       if(_CMAKE_TOOL_WITH_PATH)
  38
  39         # Overwrite CMAKE_TOOL with full path found in SEARCH_PATH.
  40         set(${CMAKE_TOOL} ${_CMAKE_TOOL_WITH_PATH} PARENT_SCOPE)
  41
  42         get_property(_CMAKE_TOOL_CACHED CACHE ${CMAKE_TOOL} PROPERTY TYPE)
  43         # If CMAKE_TOOL is present in the CMake Cache, then overwrit it as well.
  44         if(_CMAKE_TOOL_CACHED)
  45           set(${CMAKE_TOOL} "${_CMAKE_TOOL_WITH_PATH}" CACHE STRING ${DOCSTRING} FORCE)
  46         endif()
  47
  48       endif()
  49       unset(_CMAKE_TOOL_WITH_PATH CACHE)
  50
  51     endif()
  52
  53   endif()
  54
  55 endfunction()
  56
  57 __resolve_tool_path(CMAKE_LINKER "${_CMAKE_TOOLCHAIN_LOCATION}" "Default Linker")
  58 __resolve_tool_path(CMAKE_MT     "${_CMAKE_TOOLCHAIN_LOCATION}" "Default Manifest Tool")
  59
  60 set(_CMAKE_TOOL_VARS "")
  61
  62 # if it's the MS C/CXX compiler, search for link
  63 if(("x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_SIMULATE_ID}" STREQUAL "xMSVC" AND
  64    ("x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_FRONTEND_VARIANT}" STREQUAL "xMSVC"
  65     OR NOT "x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" STREQUAL "xClang"))
  66    OR "x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" STREQUAL "xMSVC"
  67    OR (CMAKE_HOST_WIN32 AND "x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" STREQUAL "xPGI")
  68    OR (CMAKE_HOST_WIN32 AND "x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" STREQUAL "xNVIDIA")
  69    OR (CMAKE_GENERATOR MATCHES "Visual Studio"
  70        AND NOT CMAKE_VS_PLATFORM_NAME STREQUAL "Tegra-Android"))
  71
  72   if("x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" STREQUAL "xClang")
  73     find_program(CMAKE_NM NAMES ${_CMAKE_TOOLCHAIN_PREFIX}nm llvm-nm HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
  74     set(_CMAKE_ADDITIONAL_LINKER_NAMES "lld-link")
  75   endif()
  76
  77   find_program(CMAKE_LINKER NAMES ${_CMAKE_ADDITIONAL_LINKER_NAMES} link HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
  78   find_program(CMAKE_AR     NAMES lib  HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
  79   find_program(CMAKE_MT     NAMES mt   HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
  80
  81   list(APPEND _CMAKE_TOOL_VARS LINKER MT)
  82
  83 # in all other cases search for ar, ranlib, etc.
  84 else()
  85   if(CMAKE_C_COMPILER_EXTERNAL_TOOLCHAIN)
  86     set(_CMAKE_TOOLCHAIN_LOCATION ${_CMAKE_TOOLCHAIN_LOCATION} ${CMAKE_C_COMPILER_EXTERNAL_TOOLCHAIN}/bin)
  87   endif()
  88   if(CMAKE_CXX_COMPILER_EXTERNAL_TOOLCHAIN)
  89     set(_CMAKE_TOOLCHAIN_LOCATION ${_CMAKE_TOOLCHAIN_LOCATION} ${CMAKE_CXX_COMPILER_EXTERNAL_TOOLCHAIN}/bin)
  90   endif()
  91
  92   if("${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" STREQUAL Clang)
  93     set(_CMAKE_ADDITIONAL_AR_NAMES "llvm-ar")
  94     set(_CMAKE_ADDITIONAL_RANLIB_NAMES "llvm-ranlib")
  95     set(_CMAKE_ADDITIONAL_STRIP_NAMES "llvm-strip")
  96     set(_CMAKE_ADDITIONAL_LINKER_NAMES "ld.lld")
  97     set(_CMAKE_ADDITIONAL_NM_NAMES "llvm-nm")
  98     set(_CMAKE_ADDITIONAL_OBJDUMP_NAMES "llvm-objdump")
  99     set(_CMAKE_ADDITIONAL_OBJCOPY_NAMES "llvm-objcopy")
 100     set(_CMAKE_ADDITIONAL_READELF_NAMES "llvm-readelf")
 101     set(_CMAKE_ADDITIONAL_DLLTOOL_NAMES "llvm-dlltool")
 102     set(_CMAKE_ADDITIONAL_ADDR2LINE_NAMES "llvm-addr2line")
 103   endif()
 104
 105   find_program(CMAKE_AR NAMES ${_CMAKE_TOOLCHAIN_PREFIX}ar${_CMAKE_TOOLCHAIN_SUFFIX} ${_CMAKE_ADDITIONAL_AR_NAMES} HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
 106
 107   find_program(CMAKE_RANLIB NAMES ${_CMAKE_TOOLCHAIN_PREFIX}ranlib ${_CMAKE_ADDITIONAL_RANLIB_NAMES} HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
 108   if(NOT CMAKE_RANLIB)
 109     set(CMAKE_RANLIB : CACHE INTERNAL "noop for ranlib")
 110   endif()
 111
 112
 113   find_program(CMAKE_STRIP NAMES ${_CMAKE_TOOLCHAIN_PREFIX}strip${_CMAKE_TOOLCHAIN_SUFFIX} ${_CMAKE_ADDITIONAL_STRIP_NAMES} HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
 114   find_program(CMAKE_LINKER NAMES ${_CMAKE_TOOLCHAIN_PREFIX}ld ${_CMAKE_ADDITIONAL_LINKER_NAMES} HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
 115   find_program(CMAKE_NM NAMES ${_CMAKE_TOOLCHAIN_PREFIX}nm ${_CMAKE_ADDITIONAL_NM_NAMES} HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
 116   find_program(CMAKE_OBJDUMP NAMES ${_CMAKE_TOOLCHAIN_PREFIX}objdump ${_CMAKE_ADDITIONAL_OBJDUMP_NAMES} HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
 117   find_program(CMAKE_OBJCOPY NAMES ${_CMAKE_TOOLCHAIN_PREFIX}objcopy ${_CMAKE_ADDITIONAL_OBJCOPY_NAMES} HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
 118   find_program(CMAKE_READELF NAMES ${_CMAKE_TOOLCHAIN_PREFIX}readelf ${_CMAKE_ADDITIONAL_READELF_NAMES} HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
 119   find_program(CMAKE_DLLTOOL NAMES ${_CMAKE_TOOLCHAIN_PREFIX}dlltool ${_CMAKE_ADDITIONAL_DLLTOOL_NAMES} HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
 120   find_program(CMAKE_ADDR2LINE NAMES ${_CMAKE_TOOLCHAIN_PREFIX}addr2line ${_CMAKE_ADDITIONAL_ADDR2LINE_NAMES} HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
 121
 122   list(APPEND _CMAKE_TOOL_VARS AR RANLIB STRIP LINKER NM OBJDUMP OBJCOPY READELF DLLTOOL ADDR2LINE)
 123 endif()
 124
 125 if(CMAKE_PLATFORM_HAS_INSTALLNAME)
 126   find_program(CMAKE_INSTALL_NAME_TOOL NAMES ${_CMAKE_TOOLCHAIN_PREFIX}install_name_tool HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
 127
 128   if(NOT CMAKE_INSTALL_NAME_TOOL)
 129     message(FATAL_ERROR "Could not find install_name_tool, please check your installation.")
 130   endif()
 131
 132   list(APPEND _CMAKE_TOOL_VARS INSTALL_NAME_TOOL)
 133 endif()
 134
 135 # Mark any tool cache entries as advanced.
 136 foreach(var IN LISTS _CMAKE_TOOL_VARS)
 137   get_property(_CMAKE_TOOL_CACHED CACHE CMAKE_${var} PROPERTY TYPE)
 138   if(_CMAKE_TOOL_CACHED)
 139     mark_as_advanced(CMAKE_${var})
 140   endif()
 141   unset(_CMAKE_ADDITIONAL_${var}_NAMES)
 142 endforeach()
 143 unset(_CMAKE_TOOL_VARS)
 144 unset(_CMAKE_TOOL_CACHED)