Modules/CMakeFindBinUtils.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4
   5 # search for additional tools required for C/C++ (and other languages ?)
   6 #
   7 # If the internal cmake variable _CMAKE_TOOLCHAIN_PREFIX is set, this is used
   8 # as prefix for the tools (e.g. arm-elf-gcc etc.)
   9 # If the cmake variable _CMAKE_TOOLCHAIN_LOCATION is set, the compiler is
  10 # searched only there. The other tools are at first searched there, then
  11 # also in the default locations.
  12 #
  13 # Sets the following variables:
  14 #   CMAKE_AR
  15 #   CMAKE_RANLIB
  16 #   CMAKE_LINKER
  17 #   CMAKE_MT
  18 #   CMAKE_STRIP
  19 #   CMAKE_INSTALL_NAME_TOOL
  20
  21 # on UNIX, cygwin and mingw
  22
  23 cmake_policy(PUSH)
  24 cmake_policy(SET CMP0057 NEW) # if IN_LIST
  25
  26 # Resolve full path of CMAKE_TOOL from user-defined name and SEARCH_PATH.
  27 function(__resolve_tool_path CMAKE_TOOL SEARCH_PATH DOCSTRING)
  28
  29   if(${CMAKE_TOOL})
  30     # We only get here if CMAKE_TOOL was
  31     # specified using -D or a pre-made CMakeCache.txt (e.g. via ctest)
  32     # or set in CMAKE_TOOLCHAIN_FILE.
  33
  34     get_filename_component(_CMAKE_USER_TOOL_PATH "${${CMAKE_TOOL}}" DIRECTORY)
  35     # Is CMAKE_TOOL a user-defined name instead of a full path?
  36     if(NOT _CMAKE_USER_TOOL_PATH)
  37
  38       # Find CMAKE_TOOL in the SEARCH_PATH directory by user-defined name.
  39       find_program(_CMAKE_TOOL_WITH_PATH NAMES ${${CMAKE_TOOL}} HINTS ${SEARCH_PATH} NO_CMAKE_PATH NO_CMAKE_ENVIRONMENT_PATH)
  40       if(_CMAKE_TOOL_WITH_PATH)
  41
  42         # Overwrite CMAKE_TOOL with full path found in SEARCH_PATH.
  43         set(${CMAKE_TOOL} ${_CMAKE_TOOL_WITH_PATH} PARENT_SCOPE)
  44
  45         get_property(_CMAKE_TOOL_CACHED CACHE ${CMAKE_TOOL} PROPERTY TYPE)
  46         # If CMAKE_TOOL is present in the CMake Cache, then overwrit it as well.
  47         if(_CMAKE_TOOL_CACHED)
  48           set(${CMAKE_TOOL} "${_CMAKE_TOOL_WITH_PATH}" CACHE STRING ${DOCSTRING} FORCE)
  49         endif()
  50
  51       endif()
  52       unset(_CMAKE_TOOL_WITH_PATH CACHE)
  53
  54     endif()
  55
  56   endif()
  57
  58 endfunction()
  59
  60 __resolve_tool_path(CMAKE_LINKER "${_CMAKE_TOOLCHAIN_LOCATION}" "Default Linker")
  61 __resolve_tool_path(CMAKE_MT     "${_CMAKE_TOOLCHAIN_LOCATION}" "Default Manifest Tool")
  62
  63 set(_CMAKE_TOOL_VARS "")
  64
  65 # if it's the MS C/CXX compiler, search for link
  66 if(("x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_SIMULATE_ID}" STREQUAL "xMSVC" AND
  67    ("x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_FRONTEND_VARIANT}" STREQUAL "xMSVC"
  68     OR NOT "x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" STREQUAL "xClang"))
  69    OR "x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" STREQUAL "xMSVC"
  70    OR (CMAKE_HOST_WIN32 AND "x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" STREQUAL "xPGI")
  71    OR (CMAKE_HOST_WIN32 AND "x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" STREQUAL "xNVIDIA")
  72    OR (CMAKE_HOST_WIN32 AND "x${_CMAKE_PROCESSING_LANGUAGE}" STREQUAL "xISPC")
  73    OR (CMAKE_GENERATOR MATCHES "Visual Studio"
  74        AND NOT CMAKE_VS_PLATFORM_NAME STREQUAL "Tegra-Android"))
  75
  76   # Start with the canonical names.
  77   set(_CMAKE_LINKER_NAMES "link")
  78   set(_CMAKE_AR_NAMES "lib")
  79   set(_CMAKE_MT_NAMES "mt")
  80
  81   # Prepend toolchain-specific names.
  82   if("x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" STREQUAL "xClang")
  83     set(_CMAKE_NM_NAMES "llvm-nm" "nm")
  84     list(PREPEND _CMAKE_AR_NAMES "llvm-lib")
  85     # llvm-mt does not support all flags we need in vs_link_exe
  86     # list(PREPEND _CMAKE_MT_NAMES "llvm-mt")
  87     list(PREPEND _CMAKE_LINKER_NAMES "lld-link")
  88     list(APPEND _CMAKE_TOOL_VARS NM)
  89   elseif("x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" STREQUAL "xIntel")
  90     list(PREPEND _CMAKE_AR_NAMES "xilib")
  91     list(PREPEND _CMAKE_LINKER_NAMES "xilink")
  92   endif()
  93
  94   list(APPEND _CMAKE_TOOL_VARS LINKER MT AR)
  95
  96 elseif("x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" MATCHES "^x(Open)?Watcom$")
  97   set(_CMAKE_LINKER_NAMES "wlink")
  98   set(_CMAKE_AR_NAMES "wlib")
  99   list(APPEND _CMAKE_TOOL_VARS LINKER AR)
 100
 101 elseif("x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" MATCHES "^xIAR$")
 102   # Small helper declaring an IAR tool (e.g. linker) to avoid repeating the same idiom every time
 103   macro(__append_IAR_tool TOOL_VAR NAME)
 104     set(_CMAKE_${TOOL_VAR}_NAMES "${NAME}" "${NAME}.exe")
 105     list(APPEND _CMAKE_TOOL_VARS ${TOOL_VAR})
 106   endmacro()
 107
 108   # Resolve hint path from an IAR compiler
 109   function(__resolve_IAR_hints COMPILER RESULT)
 110     get_filename_component(_CMAKE_IAR_HINT "${COMPILER}" REALPATH)
 111     get_filename_component(_CMAKE_IAR_HINT "${_CMAKE_IAR_HINT}" DIRECTORY)
 112     list(APPEND _IAR_HINTS "${_CMAKE_IAR_HINT}")
 113
 114     get_filename_component(_CMAKE_IAR_HINT "${COMPILER}" DIRECTORY)
 115     list(APPEND _IAR_HINTS "${_CMAKE_IAR_HINT}")
 116
 117     set(${RESULT} "${_IAR_HINTS}" PARENT_SCOPE)
 118   endfunction()
 119
 120   __resolve_IAR_hints("${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER}" _CMAKE_TOOLCHAIN_LOCATION)
 121   set(_CMAKE_IAR_ITOOLS "ARM" "RX" "RH850" "RL78" "RISCV" "RISC-V" "STM8")
 122   set(_CMAKE_IAR_XTOOLS "AVR" "MSP430" "V850" "8051")
 123
 124   if("${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ARCHITECTURE_ID}" IN_LIST _CMAKE_IAR_ITOOLS)
 125     string(TOLOWER "${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ARCHITECTURE_ID}" _CMAKE_IAR_LOWER_ARCHITECTURE_ID)
 126
 127     __append_IAR_tool(AR "iarchive")
 128     __append_IAR_tool(LINKER "ilink${_CMAKE_IAR_LOWER_ARCHITECTURE_ID}")
 129
 130     __append_IAR_tool(IAR_ELFDUMP "ielfdump${_CMAKE_IAR_LOWER_ARCHITECTURE_ID}")
 131     __append_IAR_tool(IAR_ELFTOOL "ielftool")
 132     __append_IAR_tool(IAR_OBJMANIP "iobjmanip")
 133     __append_IAR_tool(IAR_SYMEXPORT "isymexport")
 134
 135     unset(_CMAKE_IAR_LOWER_ARCHITECTURE_ID)
 136
 137   elseif("${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ARCHITECTURE_ID}" IN_LIST _CMAKE_IAR_XTOOLS)
 138     __append_IAR_tool(AR "xar")
 139     __append_IAR_tool(LINKER "xlink")
 140
 141   else()
 142     message(FATAL_ERROR "Failed to find linker and librarian for ${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID} on ${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ARCHITECTURE_ID}.")
 143   endif()
 144
 145   unset(_CMAKE_IAR_ITOOLS)
 146   unset(_CMAKE_IAR_XTOOLS)
 147
 148 # in all other cases search for ar, ranlib, etc.
 149 else()
 150   if(CMAKE_C_COMPILER_EXTERNAL_TOOLCHAIN)
 151     set(_CMAKE_TOOLCHAIN_LOCATION ${_CMAKE_TOOLCHAIN_LOCATION} ${CMAKE_C_COMPILER_EXTERNAL_TOOLCHAIN}/bin)
 152   endif()
 153   if(CMAKE_CXX_COMPILER_EXTERNAL_TOOLCHAIN)
 154     set(_CMAKE_TOOLCHAIN_LOCATION ${_CMAKE_TOOLCHAIN_LOCATION} ${CMAKE_CXX_COMPILER_EXTERNAL_TOOLCHAIN}/bin)
 155   endif()
 156
 157   # Start with the canonical names.
 158   set(_CMAKE_AR_NAMES "ar")
 159   set(_CMAKE_RANLIB_NAMES "ranlib")
 160   set(_CMAKE_STRIP_NAMES "strip")
 161   set(_CMAKE_LINKER_NAMES "ld")
 162   set(_CMAKE_NM_NAMES "nm")
 163   set(_CMAKE_OBJDUMP_NAMES "objdump")
 164   set(_CMAKE_OBJCOPY_NAMES "objcopy")
 165   set(_CMAKE_READELF_NAMES "readelf")
 166   set(_CMAKE_DLLTOOL_NAMES "dlltool")
 167   set(_CMAKE_ADDR2LINE_NAMES "addr2line")
 168
 169   # Prepend toolchain-specific names.
 170   if("${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" STREQUAL Clang)
 171     if("x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_SIMULATE_ID}" STREQUAL "xMSVC")
 172       list(PREPEND _CMAKE_LINKER_NAMES "lld-link")
 173     elseif(NOT APPLE)
 174       list(PREPEND _CMAKE_LINKER_NAMES "ld.lld")
 175     endif()
 176     if(APPLE)
 177       # llvm-ar does not generate a symbol table that the Apple ld64 linker accepts.
 178       # FIXME(#23333): We still need to consider 'llvm-ar' as a fallback because
 179       # the 'APPLE' definition may be based on the host in this context, and a
 180       # cross-compiling toolchain may not have 'ar'.
 181       list(APPEND _CMAKE_AR_NAMES "llvm-ar")
 182     else()
 183       list(PREPEND _CMAKE_AR_NAMES "llvm-ar")
 184     endif()
 185     list(PREPEND _CMAKE_RANLIB_NAMES "llvm-ranlib")
 186     if("${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_VERSION}" VERSION_GREATER_EQUAL 11)
 187       # llvm-strip versions prior to 11 require additional flags we do not yet add.
 188       list(PREPEND _CMAKE_STRIP_NAMES "llvm-strip")
 189     endif()
 190     list(PREPEND _CMAKE_NM_NAMES "llvm-nm")
 191     if("${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_VERSION}" VERSION_GREATER_EQUAL 9)
 192       # llvm-objdump versions prior to 9 did not support everything we need.
 193       list(PREPEND _CMAKE_OBJDUMP_NAMES "llvm-objdump")
 194     endif()
 195     list(PREPEND _CMAKE_OBJCOPY_NAMES "llvm-objcopy")
 196     list(PREPEND _CMAKE_READELF_NAMES "llvm-readelf")
 197     list(PREPEND _CMAKE_DLLTOOL_NAMES "llvm-dlltool")
 198     list(PREPEND _CMAKE_ADDR2LINE_NAMES "llvm-addr2line")
 199   elseif("${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" STREQUAL ARMClang)
 200     list(PREPEND _CMAKE_AR_NAMES "armar")
 201     list(PREPEND _CMAKE_LINKER_NAMES "armlink")
 202   endif()
 203
 204   list(APPEND _CMAKE_TOOL_VARS AR RANLIB STRIP LINKER NM OBJDUMP OBJCOPY READELF DLLTOOL ADDR2LINE)
 205 endif()
 206
 207 foreach(_CMAKE_TOOL IN LISTS _CMAKE_TOOL_VARS)
 208   # Build the final list of prefixed/suffixed names.
 209   set(_CMAKE_${_CMAKE_TOOL}_FIND_NAMES "")
 210   foreach(_CMAKE_TOOL_NAME IN LISTS _CMAKE_${_CMAKE_TOOL}_NAMES)
 211     list(APPEND _CMAKE_${_CMAKE_TOOL}_FIND_NAMES
 212       ${_CMAKE_TOOLCHAIN_PREFIX}${_CMAKE_TOOL_NAME}${_CMAKE_TOOLCHAIN_SUFFIX}
 213       ${_CMAKE_TOOLCHAIN_PREFIX}${_CMAKE_TOOL_NAME}
 214       ${_CMAKE_TOOL_NAME}${_CMAKE_TOOLCHAIN_SUFFIX}
 215       ${_CMAKE_TOOL_NAME}
 216       )
 217   endforeach()
 218   list(REMOVE_DUPLICATES _CMAKE_${_CMAKE_TOOL}_FIND_NAMES)
 219
 220   find_program(CMAKE_${_CMAKE_TOOL} NAMES ${_CMAKE_${_CMAKE_TOOL}_FIND_NAMES} HINTS ${_CMAKE_TOOLCHAIN_LOCATION} NO_CMAKE_PATH NO_CMAKE_ENVIRONMENT_PATH)
 221   unset(_CMAKE_${_CMAKE_TOOL}_FIND_NAMES)
 222 endforeach()
 223
 224 if(NOT CMAKE_RANLIB)
 225     set(CMAKE_RANLIB : CACHE INTERNAL "noop for ranlib")
 226 endif()
 227
 228
 229 if(CMAKE_PLATFORM_HAS_INSTALLNAME)
 230   find_program(CMAKE_INSTALL_NAME_TOOL NAMES ${_CMAKE_TOOLCHAIN_PREFIX}install_name_tool HINTS ${_CMAKE_TOOLCHAIN_LOCATION} NO_CMAKE_PATH NO_CMAKE_ENVIRONMENT_PATH)
 231
 232   if(NOT CMAKE_INSTALL_NAME_TOOL)
 233     message(FATAL_ERROR "Could not find install_name_tool, please check your installation.")
 234   endif()
 235
 236   list(APPEND _CMAKE_TOOL_VARS INSTALL_NAME_TOOL)
 237 endif()
 238
 239 # Mark any tool cache entries as advanced.
 240 foreach(_CMAKE_TOOL IN LISTS _CMAKE_TOOL_VARS)
 241   get_property(_CMAKE_TOOL_CACHED CACHE CMAKE_${_CMAKE_TOOL} PROPERTY TYPE)
 242   if(_CMAKE_TOOL_CACHED)
 243     mark_as_advanced(CMAKE_${_CMAKE_TOOL})
 244   endif()
 245   unset(_CMAKE_${_CMAKE_TOOL}_NAMES)
 246 endforeach()
 247 unset(_CMAKE_TOOL_VARS)
 248 unset(_CMAKE_TOOL_CACHED)
 249 unset(_CMAKE_TOOL_NAME)
 250 unset(_CMAKE_TOOL)
 251
 252 if("x${CMAKE_${_CMAKE_PROCESSING_LANGUAGE}_COMPILER_ID}" MATCHES "^xIAR$")
 253   # Set for backwards compatibility
 254   set(CMAKE_IAR_ARCHIVE "${CMAKE_AR}" CACHE FILEPATH "The IAR archiver")
 255   set(CMAKE_IAR_LINKER "${CMAKE_LINKER}" CACHE FILEPATH "The IAR ILINK linker")
 256   mark_as_advanced(CMAKE_IAR_LINKER CMAKE_IAR_AR)
 257 endif()
 258
 259 cmake_policy(POP)