Modules/CMakeDetermineFortranCompiler.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4
   5 # determine the compiler to use for Fortran programs
   6 # NOTE, a generator may set CMAKE_Fortran_COMPILER before
   7 # loading this file to force a compiler.
   8 # use environment variable FC first if defined by user, next use
   9 # the cmake variable CMAKE_GENERATOR_FC which can be defined by a generator
  10 # as a default compiler
  11
  12 include(${CMAKE_ROOT}/Modules/CMakeDetermineCompiler.cmake)
  13 include(Platform/${CMAKE_SYSTEM_NAME}-Determine-Fortran OPTIONAL)
  14 include(Platform/${CMAKE_SYSTEM_NAME}-Fortran OPTIONAL)
  15 if(NOT CMAKE_Fortran_COMPILER_NAMES)
  16   set(CMAKE_Fortran_COMPILER_NAMES f95)
  17 endif()
  18
  19 if(${CMAKE_GENERATOR} MATCHES "Visual Studio")
  20 elseif("${CMAKE_GENERATOR}" MATCHES "Xcode")
  21   set(CMAKE_Fortran_COMPILER_XCODE_TYPE sourcecode.fortran.f90)
  22   _cmake_find_compiler_path(Fortran)
  23 else()
  24   if(NOT CMAKE_Fortran_COMPILER)
  25     # prefer the environment variable CC
  26     if(NOT $ENV{FC} STREQUAL "")
  27       get_filename_component(CMAKE_Fortran_COMPILER_INIT $ENV{FC} PROGRAM PROGRAM_ARGS CMAKE_Fortran_FLAGS_ENV_INIT)
  28       if(CMAKE_Fortran_FLAGS_ENV_INIT)
  29         set(CMAKE_Fortran_COMPILER_ARG1 "${CMAKE_Fortran_FLAGS_ENV_INIT}" CACHE STRING "Arguments to Fortran compiler")
  30       endif()
  31       if(EXISTS ${CMAKE_Fortran_COMPILER_INIT})
  32       else()
  33         message(FATAL_ERROR "Could not find compiler set in environment variable FC:\n$ENV{FC}.")
  34       endif()
  35     endif()
  36
  37     # next try prefer the compiler specified by the generator
  38     if(CMAKE_GENERATOR_FC)
  39       if(NOT CMAKE_Fortran_COMPILER_INIT)
  40         set(CMAKE_Fortran_COMPILER_INIT ${CMAKE_GENERATOR_FC})
  41       endif()
  42     endif()
  43
  44     # finally list compilers to try
  45     if(NOT CMAKE_Fortran_COMPILER_INIT)
  46       # Known compilers:
  47       #  ftn: Cray fortran compiler wrapper
  48       #  gfortran: putative GNU Fortran 95+ compiler (in progress)
  49       #  frt: Fujitsu Fortran compiler
  50       #  pathf90/pathf95/pathf2003: PathScale Fortran compiler
  51       #  pgfortran: Portland Group Fortran compilers
  52       #  nvfortran: NVHPC Fotran compiler
  53       #  flang: Flang Fortran compiler
  54       #  xlf: IBM (AIX) Fortran compiler
  55       #  lf95: Lahey-Fujitsu F95 compiler
  56       #  fl32: Microsoft Fortran 77 "PowerStation" compiler
  57       #  af77: Apogee F77 compiler for Intergraph hardware running CLIX
  58       #  epcf90: "Edinburgh Portable Compiler" F90
  59       #  fort: Compaq (now HP) Fortran 90/95 compiler for Tru64 and Linux/Alpha
  60       #  ifx: Intel Fortran LLVM-based compiler
  61       #  ifort: Intel Classic Fortran compiler
  62       #  nagfor: NAG Fortran compiler
  63       #
  64       #  GNU is last to be searched,
  65       #  so if you paid for a compiler it is picked by default.
  66       set(CMAKE_Fortran_COMPILER_LIST
  67         ftn
  68         ifx ifort nvfortran pgfortran lf95 xlf fort
  69         flang lfortran frt nagfor
  70         gfortran
  71         )
  72
  73       # Vendor-specific compiler names.
  74       set(_Fortran_COMPILER_NAMES_LCC       lfortran gfortran)
  75       set(_Fortran_COMPILER_NAMES_GNU       gfortran)
  76       set(_Fortran_COMPILER_NAMES_Intel     ifort ifc efc ifx)
  77       set(_Fortran_COMPILER_NAMES_Absoft    af95 af90 af77)
  78       set(_Fortran_COMPILER_NAMES_PGI       pgf95 pgfortran pgf90 pgf77)
  79       set(_Fortran_COMPILER_NAMES_Flang     flang)
  80       set(_Fortran_COMPILER_NAMES_LLVMFlang flang)
  81       set(_Fortran_COMPILER_NAMES_PathScale pathf2003 pathf95 pathf90)
  82       set(_Fortran_COMPILER_NAMES_XL        xlf)
  83       set(_Fortran_COMPILER_NAMES_VisualAge xlf95 xlf90 xlf)
  84       set(_Fortran_COMPILER_NAMES_NAG       nagfor)
  85       set(_Fortran_COMPILER_NAMES_NVHPC     nvfortran)
  86     endif()
  87
  88     _cmake_find_compiler(Fortran)
  89
  90   else()
  91     _cmake_find_compiler_path(Fortran)
  92   endif()
  93   mark_as_advanced(CMAKE_Fortran_COMPILER)
  94
  95   # Each entry in this list is a set of extra flags to try
  96   # adding to the compile line to see if it helps produce
  97   # a valid identification executable.
  98   set(CMAKE_Fortran_COMPILER_ID_TEST_FLAGS_FIRST
  99     # Get verbose output to help distinguish compilers.
 100     "-v"
 101     )
 102   set(CMAKE_Fortran_COMPILER_ID_TEST_FLAGS
 103     # Try compiling to an object file only.
 104     "-c"
 105
 106     # Intel on windows does not preprocess by default.
 107     "-fpp"
 108     )
 109 endif()
 110
 111 # Build a small source file to identify the compiler.
 112 if(NOT CMAKE_Fortran_COMPILER_ID_RUN)
 113   set(CMAKE_Fortran_COMPILER_ID_RUN 1)
 114
 115   # Table of per-vendor compiler output regular expressions.
 116   list(APPEND CMAKE_Fortran_COMPILER_ID_MATCH_VENDORS CCur)
 117   set(CMAKE_Fortran_COMPILER_ID_MATCH_VENDOR_REGEX_CCur "Concurrent Fortran [0-9]+ Compiler")
 118
 119   # Table of per-vendor compiler id flags with expected output.
 120   list(APPEND CMAKE_Fortran_COMPILER_ID_VENDORS Compaq)
 121   set(CMAKE_Fortran_COMPILER_ID_VENDOR_FLAGS_Compaq "-what")
 122   set(CMAKE_Fortran_COMPILER_ID_VENDOR_REGEX_Compaq "Compaq Visual Fortran")
 123   list(APPEND CMAKE_Fortran_COMPILER_ID_VENDORS NAG) # Numerical Algorithms Group
 124   set(CMAKE_Fortran_COMPILER_ID_VENDOR_FLAGS_NAG "-V")
 125   set(CMAKE_Fortran_COMPILER_ID_VENDOR_REGEX_NAG "NAG Fortran Compiler")
 126
 127   # Match the link line from xcodebuild output of the form
 128   #  Ld ...
 129   #      ...
 130   #      /path/to/cc ...CompilerIdFortran/...
 131   # to extract the compiler front-end for the language.
 132   set(CMAKE_Fortran_COMPILER_ID_TOOL_MATCH_REGEX "\nLd[^\n]*(\n[ \t]+[^\n]*)*\n[ \t]+([^ \t\r\n]+)[^\r\n]*-o[^\r\n]*CompilerIdFortran/(\\./)?(CompilerIdFortran.xctest/)?CompilerIdFortran[ \t\n\\\"]")
 133   set(CMAKE_Fortran_COMPILER_ID_TOOL_MATCH_INDEX 2)
 134
 135   set(_version_info "")
 136   foreach(m MAJOR MINOR PATCH TWEAK)
 137     set(_COMP "_${m}")
 138     string(APPEND _version_info "
 139 #if defined(COMPILER_VERSION${_COMP})")
 140     foreach(d 1 2 3 4 5 6 7 8)
 141       string(APPEND _version_info "
 142 # undef DEC
 143 # undef HEX
 144 # define DEC(n) DEC_${d}(n)
 145 # define HEX(n) HEX_${d}(n)
 146 # if COMPILER_VERSION${_COMP} == 0
 147         PRINT *, 'INFO:compiler_version${_COMP}_digit_${d}[0]'
 148 # elif COMPILER_VERSION${_COMP} == 1
 149         PRINT *, 'INFO:compiler_version${_COMP}_digit_${d}[1]'
 150 # elif COMPILER_VERSION${_COMP} == 2
 151         PRINT *, 'INFO:compiler_version${_COMP}_digit_${d}[2]'
 152 # elif COMPILER_VERSION${_COMP} == 3
 153         PRINT *, 'INFO:compiler_version${_COMP}_digit_${d}[3]'
 154 # elif COMPILER_VERSION${_COMP} == 4
 155         PRINT *, 'INFO:compiler_version${_COMP}_digit_${d}[4]'
 156 # elif COMPILER_VERSION${_COMP} == 5
 157         PRINT *, 'INFO:compiler_version${_COMP}_digit_${d}[5]'
 158 # elif COMPILER_VERSION${_COMP} == 6
 159         PRINT *, 'INFO:compiler_version${_COMP}_digit_${d}[6]'
 160 # elif COMPILER_VERSION${_COMP} == 7
 161         PRINT *, 'INFO:compiler_version${_COMP}_digit_${d}[7]'
 162 # elif COMPILER_VERSION${_COMP} == 8
 163         PRINT *, 'INFO:compiler_version${_COMP}_digit_${d}[8]'
 164 # elif COMPILER_VERSION${_COMP} == 9
 165         PRINT *, 'INFO:compiler_version${_COMP}_digit_${d}[9]'
 166 # endif
 167 ")
 168     endforeach()
 169     string(APPEND _version_info "
 170 #endif")
 171   endforeach()
 172   set(CMAKE_Fortran_COMPILER_ID_VERSION_INFO "${_version_info}")
 173   unset(_version_info)
 174   unset(_COMP)
 175
 176   # Try to identify the compiler.
 177   set(CMAKE_Fortran_COMPILER_ID)
 178   include(${CMAKE_ROOT}/Modules/CMakeDetermineCompilerId.cmake)
 179   CMAKE_DETERMINE_COMPILER_ID(Fortran FFLAGS CMakeFortranCompilerId.F)
 180
 181   _cmake_find_compiler_sysroot(Fortran)
 182
 183   # Fall back to old is-GNU test.
 184   if(NOT CMAKE_Fortran_COMPILER_ID)
 185     execute_process(COMMAND ${CMAKE_Fortran_COMPILER} ${CMAKE_Fortran_COMPILER_ID_FLAGS_LIST} -E "${CMAKE_ROOT}/Modules/CMakeTestGNU.c"
 186       OUTPUT_VARIABLE CMAKE_COMPILER_OUTPUT RESULT_VARIABLE CMAKE_COMPILER_RETURN)
 187     if(NOT CMAKE_COMPILER_RETURN)
 188       if(CMAKE_COMPILER_OUTPUT MATCHES "THIS_IS_GNU")
 189         set(CMAKE_Fortran_COMPILER_ID "GNU")
 190         file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
 191           "Determining if the Fortran compiler is GNU succeeded with "
 192           "the following output:\n${CMAKE_COMPILER_OUTPUT}\n\n")
 193       else()
 194         file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
 195           "Determining if the Fortran compiler is GNU failed with "
 196           "the following output:\n${CMAKE_COMPILER_OUTPUT}\n\n")
 197       endif()
 198       if(NOT CMAKE_Fortran_PLATFORM_ID)
 199         if(CMAKE_COMPILER_OUTPUT MATCHES "THIS_IS_MINGW")
 200           set(CMAKE_Fortran_PLATFORM_ID "MinGW")
 201         endif()
 202         if(CMAKE_COMPILER_OUTPUT MATCHES "THIS_IS_CYGWIN")
 203           set(CMAKE_Fortran_PLATFORM_ID "Cygwin")
 204         endif()
 205       endif()
 206     endif()
 207   endif()
 208
 209   # Fall back for GNU MINGW, which is not always detected correctly
 210   # (__MINGW32__ is defined for the C language, but perhaps not for Fortran!)
 211   if(CMAKE_Fortran_COMPILER_ID MATCHES "GNU" AND NOT CMAKE_Fortran_PLATFORM_ID)
 212     execute_process(COMMAND ${CMAKE_Fortran_COMPILER} ${CMAKE_Fortran_COMPILER_ID_FLAGS_LIST} -E "${CMAKE_ROOT}/Modules/CMakeTestGNU.c"
 213       OUTPUT_VARIABLE CMAKE_COMPILER_OUTPUT RESULT_VARIABLE CMAKE_COMPILER_RETURN)
 214     if(NOT CMAKE_COMPILER_RETURN)
 215       if(CMAKE_COMPILER_OUTPUT MATCHES "THIS_IS_MINGW")
 216         set(CMAKE_Fortran_PLATFORM_ID "MinGW")
 217       endif()
 218       if(CMAKE_COMPILER_OUTPUT MATCHES "THIS_IS_CYGWIN")
 219         set(CMAKE_Fortran_PLATFORM_ID "Cygwin")
 220       endif()
 221     endif()
 222   endif()
 223
 224   # Set old compiler and platform id variables.
 225   if(CMAKE_Fortran_COMPILER_ID MATCHES "GNU")
 226     set(CMAKE_COMPILER_IS_GNUG77 1)
 227   endif()
 228 endif()
 229
 230 if (NOT _CMAKE_TOOLCHAIN_LOCATION)
 231   get_filename_component(_CMAKE_TOOLCHAIN_LOCATION "${CMAKE_Fortran_COMPILER}" PATH)
 232 endif ()
 233
 234 # if we have a fortran cross compiler, they have usually some prefix, like
 235 # e.g. powerpc-linux-gfortran, arm-elf-gfortran or i586-mingw32msvc-gfortran , optionally
 236 # with a 3-component version number at the end (e.g. arm-eabi-gcc-4.5.2).
 237 # The other tools of the toolchain usually have the same prefix
 238 # NAME_WE cannot be used since then this test will fail for names like
 239 # "arm-unknown-nto-qnx6.3.0-gcc.exe", where BASENAME would be
 240 # "arm-unknown-nto-qnx6" instead of the correct "arm-unknown-nto-qnx6.3.0-"
 241 if (NOT _CMAKE_TOOLCHAIN_PREFIX)
 242
 243   if(CMAKE_Fortran_COMPILER_ID MATCHES "GNU")
 244     get_filename_component(COMPILER_BASENAME "${CMAKE_Fortran_COMPILER}" NAME)
 245     if (COMPILER_BASENAME MATCHES "^(.+-)g?fortran(-[0-9]+\\.[0-9]+\\.[0-9]+)?(\\.exe)?$")
 246       set(_CMAKE_TOOLCHAIN_PREFIX ${CMAKE_MATCH_1})
 247     endif ()
 248
 249     # if "llvm-" is part of the prefix, remove it, since llvm doesn't have its own binutils
 250     # but uses the regular ar, objcopy, etc. (instead of llvm-objcopy etc.)
 251     if ("${_CMAKE_TOOLCHAIN_PREFIX}" MATCHES "(.+-)?llvm-$")
 252       set(_CMAKE_TOOLCHAIN_PREFIX ${CMAKE_MATCH_1})
 253     endif ()
 254   endif()
 255
 256 endif ()
 257
 258 set(_CMAKE_PROCESSING_LANGUAGE "Fortran")
 259 include(CMakeFindBinUtils)
 260 include(Compiler/${CMAKE_Fortran_COMPILER_ID}-FindBinUtils OPTIONAL)
 261 unset(_CMAKE_PROCESSING_LANGUAGE)
 262
 263 if(CMAKE_Fortran_XL_CPP)
 264   set(_SET_CMAKE_Fortran_XL_CPP
 265     "set(CMAKE_Fortran_XL_CPP \"${CMAKE_Fortran_XL_CPP}\")")
 266 endif()
 267
 268 if(CMAKE_Fortran_COMPILER_SYSROOT)
 269   string(CONCAT _SET_CMAKE_Fortran_COMPILER_SYSROOT
 270     "set(CMAKE_Fortran_COMPILER_SYSROOT \"${CMAKE_Fortran_COMPILER_SYSROOT}\")\n"
 271     "set(CMAKE_COMPILER_SYSROOT \"${CMAKE_Fortran_COMPILER_SYSROOT}\")")
 272 else()
 273   set(_SET_CMAKE_Fortran_COMPILER_SYSROOT "")
 274 endif()
 275
 276 if(CMAKE_Fortran_COMPILER_ARCHITECTURE_ID)
 277   set(_SET_CMAKE_Fortran_COMPILER_ARCHITECTURE_ID
 278     "set(CMAKE_Fortran_COMPILER_ARCHITECTURE_ID ${CMAKE_Fortran_COMPILER_ARCHITECTURE_ID})")
 279 else()
 280   set(_SET_CMAKE_Fortran_COMPILER_ARCHITECTURE_ID "")
 281 endif()
 282
 283 if(MSVC_Fortran_ARCHITECTURE_ID)
 284   set(SET_MSVC_Fortran_ARCHITECTURE_ID
 285     "set(MSVC_Fortran_ARCHITECTURE_ID ${MSVC_Fortran_ARCHITECTURE_ID})")
 286 endif()
 287 # configure variables set in this file for fast reload later on
 288 configure_file(${CMAKE_ROOT}/Modules/CMakeFortranCompiler.cmake.in
 289   ${CMAKE_PLATFORM_INFO_DIR}/CMakeFortranCompiler.cmake
 290   @ONLY
 291   )
 292 set(CMAKE_Fortran_COMPILER_ENV_VAR "FC")