Modules/CMakeCXXInformation.cmake

   1
   2 #=============================================================================
   3 # Copyright 2004-2011 Kitware, Inc.
   4 #
   5 # Distributed under the OSI-approved BSD License (the "License");
   6 # see accompanying file Copyright.txt for details.
   7 #
   8 # This software is distributed WITHOUT ANY WARRANTY; without even the
   9 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  10 # See the License for more information.
  11 #=============================================================================
  12 # (To distribute this file outside of CMake, substitute the full
  13 #  License text for the above reference.)
  14
  15 # This file sets the basic flags for the C++ language in CMake.
  16 # It also loads the available platform file for the system-compiler
  17 # if it exists.
  18 # It also loads a system - compiler - processor (or target hardware)
  19 # specific file, which is mainly useful for crosscompiling and embedded systems.
  20
  21 # some compilers use different extensions (e.g. sdcc uses .rel)
  22 # so set the extension here first so it can be overridden by the compiler specific file
  23 if(UNIX)
  24   set(CMAKE_CXX_OUTPUT_EXTENSION .o)
  25 else()
  26   set(CMAKE_CXX_OUTPUT_EXTENSION .obj)
  27 endif()
  28
  29 set(_INCLUDED_FILE 0)
  30
  31 # Load compiler-specific information.
  32 if(CMAKE_CXX_COMPILER_ID)
  33   include(Compiler/${CMAKE_CXX_COMPILER_ID}-CXX OPTIONAL)
  34 endif()
  35
  36 set(CMAKE_BASE_NAME)
  37 get_filename_component(CMAKE_BASE_NAME ${CMAKE_CXX_COMPILER} NAME_WE)
  38 # since the gnu compiler has several names force g++
  39 if(CMAKE_COMPILER_IS_GNUCXX)
  40   set(CMAKE_BASE_NAME g++)
  41 endif()
  42
  43
  44 # load a hardware specific file, mostly useful for embedded compilers
  45 if(CMAKE_SYSTEM_PROCESSOR)
  46   if(CMAKE_CXX_COMPILER_ID)
  47     include(Platform/${CMAKE_SYSTEM_NAME}-${CMAKE_CXX_COMPILER_ID}-CXX-${CMAKE_SYSTEM_PROCESSOR} OPTIONAL RESULT_VARIABLE _INCLUDED_FILE)
  48   endif()
  49   if (NOT _INCLUDED_FILE)
  50     include(Platform/${CMAKE_SYSTEM_NAME}-${CMAKE_BASE_NAME}-${CMAKE_SYSTEM_PROCESSOR} OPTIONAL)
  51   endif ()
  52 endif()
  53
  54 # load the system- and compiler specific files
  55 if(CMAKE_CXX_COMPILER_ID)
  56   include(Platform/${CMAKE_SYSTEM_NAME}-${CMAKE_CXX_COMPILER_ID}-CXX OPTIONAL RESULT_VARIABLE _INCLUDED_FILE)
  57 endif()
  58 if (NOT _INCLUDED_FILE)
  59   include(Platform/${CMAKE_SYSTEM_NAME}-${CMAKE_BASE_NAME} OPTIONAL
  60           RESULT_VARIABLE _INCLUDED_FILE)
  61 endif ()
  62 # We specify the compiler information in the system file for some
  63 # platforms, but this language may not have been enabled when the file
  64 # was first included.  Include it again to get the language info.
  65 # Remove this when all compiler info is removed from system files.
  66 if (NOT _INCLUDED_FILE)
  67   include(Platform/${CMAKE_SYSTEM_NAME} OPTIONAL)
  68 endif ()
  69
  70 if(CMAKE_CXX_SIZEOF_DATA_PTR)
  71   foreach(f ${CMAKE_CXX_ABI_FILES})
  72     include(${f})
  73   endforeach()
  74   unset(CMAKE_CXX_ABI_FILES)
  75 endif()
  76
  77 # This should be included before the _INIT variables are
  78 # used to initialize the cache.  Since the rule variables
  79 # have if blocks on them, users can still define them here.
  80 # But, it should still be after the platform file so changes can
  81 # be made to those values.
  82
  83 if(CMAKE_USER_MAKE_RULES_OVERRIDE)
  84   # Save the full path of the file so try_compile can use it.
  85   include(${CMAKE_USER_MAKE_RULES_OVERRIDE} RESULT_VARIABLE _override)
  86   set(CMAKE_USER_MAKE_RULES_OVERRIDE "${_override}")
  87 endif()
  88
  89 if(CMAKE_USER_MAKE_RULES_OVERRIDE_CXX)
  90   # Save the full path of the file so try_compile can use it.
  91   include(${CMAKE_USER_MAKE_RULES_OVERRIDE_CXX} RESULT_VARIABLE _override)
  92   set(CMAKE_USER_MAKE_RULES_OVERRIDE_CXX "${_override}")
  93 endif()
  94
  95
  96 # Create a set of shared library variable specific to C++
  97 # For 90% of the systems, these are the same flags as the C versions
  98 # so if these are not set just copy the flags from the c version
  99 if(NOT CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS)
 100   set(CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS ${CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS})
 101 endif()
 102
 103 if(NOT CMAKE_CXX_COMPILE_OPTIONS_PIC)
 104   set(CMAKE_CXX_COMPILE_OPTIONS_PIC ${CMAKE_C_COMPILE_OPTIONS_PIC})
 105 endif()
 106
 107 if(NOT CMAKE_CXX_COMPILE_OPTIONS_PIE)
 108   set(CMAKE_CXX_COMPILE_OPTIONS_PIE ${CMAKE_C_COMPILE_OPTIONS_PIE})
 109 endif()
 110
 111 if(NOT CMAKE_CXX_COMPILE_OPTIONS_DLL)
 112   set(CMAKE_CXX_COMPILE_OPTIONS_DLL ${CMAKE_C_COMPILE_OPTIONS_DLL})
 113 endif()
 114
 115 if(NOT CMAKE_SHARED_LIBRARY_CXX_FLAGS)
 116   set(CMAKE_SHARED_LIBRARY_CXX_FLAGS ${CMAKE_SHARED_LIBRARY_C_FLAGS})
 117 endif()
 118
 119 if(NOT DEFINED CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS)
 120   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS ${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS})
 121 endif()
 122
 123 if(NOT CMAKE_SHARED_LIBRARY_RUNTIME_CXX_FLAG)
 124   set(CMAKE_SHARED_LIBRARY_RUNTIME_CXX_FLAG ${CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG})
 125 endif()
 126
 127 if(NOT CMAKE_SHARED_LIBRARY_RUNTIME_CXX_FLAG_SEP)
 128   set(CMAKE_SHARED_LIBRARY_RUNTIME_CXX_FLAG_SEP ${CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG_SEP})
 129 endif()
 130
 131 if(NOT CMAKE_SHARED_LIBRARY_RPATH_LINK_CXX_FLAG)
 132   set(CMAKE_SHARED_LIBRARY_RPATH_LINK_CXX_FLAG ${CMAKE_SHARED_LIBRARY_RPATH_LINK_C_FLAG})
 133 endif()
 134
 135 if(NOT DEFINED CMAKE_EXE_EXPORTS_CXX_FLAG)
 136   set(CMAKE_EXE_EXPORTS_CXX_FLAG ${CMAKE_EXE_EXPORTS_C_FLAG})
 137 endif()
 138
 139 if(NOT DEFINED CMAKE_SHARED_LIBRARY_SONAME_CXX_FLAG)
 140   set(CMAKE_SHARED_LIBRARY_SONAME_CXX_FLAG ${CMAKE_SHARED_LIBRARY_SONAME_C_FLAG})
 141 endif()
 142
 143 if(NOT CMAKE_EXECUTABLE_RUNTIME_CXX_FLAG)
 144   set(CMAKE_EXECUTABLE_RUNTIME_CXX_FLAG ${CMAKE_SHARED_LIBRARY_RUNTIME_CXX_FLAG})
 145 endif()
 146
 147 if(NOT CMAKE_EXECUTABLE_RUNTIME_CXX_FLAG_SEP)
 148   set(CMAKE_EXECUTABLE_RUNTIME_CXX_FLAG_SEP ${CMAKE_SHARED_LIBRARY_RUNTIME_CXX_FLAG_SEP})
 149 endif()
 150
 151 if(NOT CMAKE_EXECUTABLE_RPATH_LINK_CXX_FLAG)
 152   set(CMAKE_EXECUTABLE_RPATH_LINK_CXX_FLAG ${CMAKE_SHARED_LIBRARY_RPATH_LINK_CXX_FLAG})
 153 endif()
 154
 155 if(NOT DEFINED CMAKE_SHARED_LIBRARY_LINK_CXX_WITH_RUNTIME_PATH)
 156   set(CMAKE_SHARED_LIBRARY_LINK_CXX_WITH_RUNTIME_PATH ${CMAKE_SHARED_LIBRARY_LINK_C_WITH_RUNTIME_PATH})
 157 endif()
 158
 159 if(NOT CMAKE_INCLUDE_FLAG_CXX)
 160   set(CMAKE_INCLUDE_FLAG_CXX ${CMAKE_INCLUDE_FLAG_C})
 161 endif()
 162
 163 if(NOT CMAKE_INCLUDE_FLAG_SEP_CXX)
 164   set(CMAKE_INCLUDE_FLAG_SEP_CXX ${CMAKE_INCLUDE_FLAG_SEP_C})
 165 endif()
 166
 167 # for most systems a module is the same as a shared library
 168 # so unless the variable CMAKE_MODULE_EXISTS is set just
 169 # copy the values from the LIBRARY variables
 170 if(NOT CMAKE_MODULE_EXISTS)
 171   set(CMAKE_SHARED_MODULE_CXX_FLAGS ${CMAKE_SHARED_LIBRARY_CXX_FLAGS})
 172   set(CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS ${CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS})
 173 endif()
 174
 175 # repeat for modules
 176 if(NOT CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS)
 177   set(CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS ${CMAKE_SHARED_MODULE_CREATE_C_FLAGS})
 178 endif()
 179
 180 if(NOT CMAKE_SHARED_MODULE_CXX_FLAGS)
 181   set(CMAKE_SHARED_MODULE_CXX_FLAGS ${CMAKE_SHARED_MODULE_C_FLAGS})
 182 endif()
 183
 184 # Initialize CXX link type selection flags from C versions.
 185 foreach(type SHARED_LIBRARY SHARED_MODULE EXE)
 186   if(NOT CMAKE_${type}_LINK_STATIC_CXX_FLAGS)
 187     set(CMAKE_${type}_LINK_STATIC_CXX_FLAGS
 188       ${CMAKE_${type}_LINK_STATIC_C_FLAGS})
 189   endif()
 190   if(NOT CMAKE_${type}_LINK_DYNAMIC_CXX_FLAGS)
 191     set(CMAKE_${type}_LINK_DYNAMIC_CXX_FLAGS
 192       ${CMAKE_${type}_LINK_DYNAMIC_C_FLAGS})
 193   endif()
 194 endforeach()
 195
 196 # add the flags to the cache based
 197 # on the initial values computed in the platform/*.cmake files
 198 # use _INIT variables so that this only happens the first time
 199 # and you can set these flags in the cmake cache
 200 set(CMAKE_CXX_FLAGS_INIT "$ENV{CXXFLAGS} ${CMAKE_CXX_FLAGS_INIT}")
 201 # avoid just having a space as the initial value for the cache
 202 if(CMAKE_CXX_FLAGS_INIT STREQUAL " ")
 203   set(CMAKE_CXX_FLAGS_INIT)
 204 endif()
 205 set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS_INIT}" CACHE STRING
 206      "Flags used by the compiler during all build types.")
 207
 208 if(NOT CMAKE_NOT_USING_CONFIG_FLAGS)
 209   set (CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG_INIT}" CACHE STRING
 210      "Flags used by the compiler during debug builds.")
 211   set (CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL_INIT}" CACHE STRING
 212       "Flags used by the compiler during release minsize builds.")
 213   set (CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE_INIT}" CACHE STRING
 214      "Flags used by the compiler during release builds (/MD /Ob1 /Oi /Ot /Oy /Gs will produce slightly less optimized but smaller files).")
 215   set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO_INIT}" CACHE STRING
 216      "Flags used by the compiler during Release with Debug Info builds.")
 217
 218 endif()
 219
 220 if(CMAKE_CXX_STANDARD_LIBRARIES_INIT)
 221   set(CMAKE_CXX_STANDARD_LIBRARIES "${CMAKE_CXX_STANDARD_LIBRARIES_INIT}"
 222     CACHE STRING "Libraries linked by defalut with all C++ applications.")
 223   mark_as_advanced(CMAKE_CXX_STANDARD_LIBRARIES)
 224 endif()
 225
 226 include(CMakeCommonLanguageInclude)
 227
 228 # now define the following rules:
 229 # CMAKE_CXX_CREATE_SHARED_LIBRARY
 230 # CMAKE_CXX_CREATE_SHARED_MODULE
 231 # CMAKE_CXX_COMPILE_OBJECT
 232 # CMAKE_CXX_LINK_EXECUTABLE
 233
 234 # variables supplied by the generator at use time
 235 # <TARGET>
 236 # <TARGET_BASE> the target without the suffix
 237 # <OBJECTS>
 238 # <OBJECT>
 239 # <LINK_LIBRARIES>
 240 # <FLAGS>
 241 # <LINK_FLAGS>
 242
 243 # CXX compiler information
 244 # <CMAKE_CXX_COMPILER>
 245 # <CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS>
 246 # <CMAKE_CXX_SHARED_MODULE_CREATE_FLAGS>
 247 # <CMAKE_CXX_LINK_FLAGS>
 248
 249 # Static library tools
 250 # <CMAKE_AR>
 251 # <CMAKE_RANLIB>
 252
 253
 254 # create a shared C++ library
 255 if(NOT CMAKE_CXX_CREATE_SHARED_LIBRARY)
 256   set(CMAKE_CXX_CREATE_SHARED_LIBRARY
 257       "<CMAKE_CXX_COMPILER> <CMAKE_SHARED_LIBRARY_CXX_FLAGS> <LANGUAGE_COMPILE_FLAGS> <LINK_FLAGS> <CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS> <SONAME_FLAG><TARGET_SONAME> -o <TARGET> <OBJECTS> <LINK_LIBRARIES>")
 258 endif()
 259
 260 # create a c++ shared module copy the shared library rule by default
 261 if(NOT CMAKE_CXX_CREATE_SHARED_MODULE)
 262   set(CMAKE_CXX_CREATE_SHARED_MODULE ${CMAKE_CXX_CREATE_SHARED_LIBRARY})
 263 endif()
 264
 265
 266 # Create a static archive incrementally for large object file counts.
 267 # If CMAKE_CXX_CREATE_STATIC_LIBRARY is set it will override these.
 268 if(NOT DEFINED CMAKE_CXX_ARCHIVE_CREATE)
 269   set(CMAKE_CXX_ARCHIVE_CREATE "<CMAKE_AR> cr <TARGET> <LINK_FLAGS> <OBJECTS>")
 270 endif()
 271 if(NOT DEFINED CMAKE_CXX_ARCHIVE_APPEND)
 272   set(CMAKE_CXX_ARCHIVE_APPEND "<CMAKE_AR> r  <TARGET> <LINK_FLAGS> <OBJECTS>")
 273 endif()
 274 if(NOT DEFINED CMAKE_CXX_ARCHIVE_FINISH)
 275   set(CMAKE_CXX_ARCHIVE_FINISH "<CMAKE_RANLIB> <TARGET>")
 276 endif()
 277
 278 # compile a C++ file into an object file
 279 if(NOT CMAKE_CXX_COMPILE_OBJECT)
 280   set(CMAKE_CXX_COMPILE_OBJECT
 281     "<CMAKE_CXX_COMPILER>  <DEFINES> <FLAGS> -o <OBJECT> -c <SOURCE>")
 282 endif()
 283
 284 if(NOT CMAKE_CXX_LINK_EXECUTABLE)
 285   set(CMAKE_CXX_LINK_EXECUTABLE
 286     "<CMAKE_CXX_COMPILER>  <FLAGS> <CMAKE_CXX_LINK_FLAGS> <LINK_FLAGS> <OBJECTS>  -o <TARGET> <LINK_LIBRARIES>")
 287 endif()
 288
 289 mark_as_advanced(
 290 CMAKE_BUILD_TOOL
 291 CMAKE_VERBOSE_MAKEFILE
 292 CMAKE_CXX_FLAGS
 293 CMAKE_CXX_FLAGS_RELEASE
 294 CMAKE_CXX_FLAGS_RELWITHDEBINFO
 295 CMAKE_CXX_FLAGS_MINSIZEREL
 296 CMAKE_CXX_FLAGS_DEBUG)
 297
 298 set(CMAKE_CXX_INFORMATION_LOADED 1)
 299