Modules/CMakeCInformation.cmake

   1
   2 #=============================================================================
   3 # Copyright 2004-2011 Kitware, Inc.
   4 #
   5 # Distributed under the OSI-approved BSD License (the "License");
   6 # see accompanying file Copyright.txt for details.
   7 #
   8 # This software is distributed WITHOUT ANY WARRANTY; without even the
   9 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  10 # See the License for more information.
  11 #=============================================================================
  12 # (To distribute this file outside of CMake, substitute the full
  13 #  License text for the above reference.)
  14
  15 # This file sets the basic flags for the C language in CMake.
  16 # It also loads the available platform file for the system-compiler
  17 # if it exists.
  18 # It also loads a system - compiler - processor (or target hardware)
  19 # specific file, which is mainly useful for crosscompiling and embedded systems.
  20
  21 # some compilers use different extensions (e.g. sdcc uses .rel)
  22 # so set the extension here first so it can be overridden by the compiler specific file
  23 if(UNIX)
  24   set(CMAKE_C_OUTPUT_EXTENSION .o)
  25 else()
  26   set(CMAKE_C_OUTPUT_EXTENSION .obj)
  27 endif()
  28
  29 set(_INCLUDED_FILE 0)
  30
  31 # Load compiler-specific information.
  32 if(CMAKE_C_COMPILER_ID)
  33   include(Compiler/${CMAKE_C_COMPILER_ID}-C OPTIONAL)
  34 endif()
  35
  36 set(CMAKE_BASE_NAME)
  37 get_filename_component(CMAKE_BASE_NAME ${CMAKE_C_COMPILER} NAME_WE)
  38 if(CMAKE_COMPILER_IS_GNUCC)
  39   set(CMAKE_BASE_NAME gcc)
  40 endif()
  41
  42
  43 # load a hardware specific file, mostly useful for embedded compilers
  44 if(CMAKE_SYSTEM_PROCESSOR)
  45   if(CMAKE_C_COMPILER_ID)
  46     include(Platform/${CMAKE_SYSTEM_NAME}-${CMAKE_C_COMPILER_ID}-C-${CMAKE_SYSTEM_PROCESSOR} OPTIONAL RESULT_VARIABLE _INCLUDED_FILE)
  47   endif()
  48   if (NOT _INCLUDED_FILE)
  49     include(Platform/${CMAKE_SYSTEM_NAME}-${CMAKE_BASE_NAME}-${CMAKE_SYSTEM_PROCESSOR} OPTIONAL)
  50   endif ()
  51 endif()
  52
  53
  54 # load the system- and compiler specific files
  55 if(CMAKE_C_COMPILER_ID)
  56   include(Platform/${CMAKE_SYSTEM_NAME}-${CMAKE_C_COMPILER_ID}-C
  57     OPTIONAL RESULT_VARIABLE _INCLUDED_FILE)
  58 endif()
  59 if (NOT _INCLUDED_FILE)
  60   include(Platform/${CMAKE_SYSTEM_NAME}-${CMAKE_BASE_NAME}
  61     OPTIONAL RESULT_VARIABLE _INCLUDED_FILE)
  62 endif ()
  63 # We specify the compiler information in the system file for some
  64 # platforms, but this language may not have been enabled when the file
  65 # was first included.  Include it again to get the language info.
  66 # Remove this when all compiler info is removed from system files.
  67 if (NOT _INCLUDED_FILE)
  68   include(Platform/${CMAKE_SYSTEM_NAME} OPTIONAL)
  69 endif ()
  70
  71 if(CMAKE_C_SIZEOF_DATA_PTR)
  72   foreach(f ${CMAKE_C_ABI_FILES})
  73     include(${f})
  74   endforeach()
  75   unset(CMAKE_C_ABI_FILES)
  76 endif()
  77
  78 # This should be included before the _INIT variables are
  79 # used to initialize the cache.  Since the rule variables
  80 # have if blocks on them, users can still define them here.
  81 # But, it should still be after the platform file so changes can
  82 # be made to those values.
  83
  84 if(CMAKE_USER_MAKE_RULES_OVERRIDE)
  85   # Save the full path of the file so try_compile can use it.
  86   include(${CMAKE_USER_MAKE_RULES_OVERRIDE} RESULT_VARIABLE _override)
  87   set(CMAKE_USER_MAKE_RULES_OVERRIDE "${_override}")
  88 endif()
  89
  90 if(CMAKE_USER_MAKE_RULES_OVERRIDE_C)
  91   # Save the full path of the file so try_compile can use it.
  92   include(${CMAKE_USER_MAKE_RULES_OVERRIDE_C} RESULT_VARIABLE _override)
  93   set(CMAKE_USER_MAKE_RULES_OVERRIDE_C "${_override}")
  94 endif()
  95
  96
  97 # for most systems a module is the same as a shared library
  98 # so unless the variable CMAKE_MODULE_EXISTS is set just
  99 # copy the values from the LIBRARY variables
 100 if(NOT CMAKE_MODULE_EXISTS)
 101   set(CMAKE_SHARED_MODULE_C_FLAGS ${CMAKE_SHARED_LIBRARY_C_FLAGS})
 102   set(CMAKE_SHARED_MODULE_CREATE_C_FLAGS ${CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS})
 103 endif()
 104
 105 set(CMAKE_C_FLAGS_INIT "$ENV{CFLAGS} ${CMAKE_C_FLAGS_INIT}")
 106 # avoid just having a space as the initial value for the cache
 107 if(CMAKE_C_FLAGS_INIT STREQUAL " ")
 108   set(CMAKE_C_FLAGS_INIT)
 109 endif()
 110 set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS_INIT}" CACHE STRING
 111      "Flags used by the compiler during all build types.")
 112
 113 if(NOT CMAKE_NOT_USING_CONFIG_FLAGS)
 114 # default build type is none
 115   if(NOT CMAKE_NO_BUILD_TYPE)
 116     set (CMAKE_BUILD_TYPE ${CMAKE_BUILD_TYPE_INIT} CACHE STRING
 117       "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel.")
 118   endif()
 119   set (CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG_INIT}" CACHE STRING
 120     "Flags used by the compiler during debug builds.")
 121   set (CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL_INIT}" CACHE STRING
 122     "Flags used by the compiler during release minsize builds.")
 123   set (CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE_INIT}" CACHE STRING
 124     "Flags used by the compiler during release builds (/MD /Ob1 /Oi /Ot /Oy /Gs will produce slightly less optimized but smaller files).")
 125   set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO_INIT}" CACHE STRING
 126     "Flags used by the compiler during Release with Debug Info builds.")
 127 endif()
 128
 129 if(CMAKE_C_STANDARD_LIBRARIES_INIT)
 130   set(CMAKE_C_STANDARD_LIBRARIES "${CMAKE_C_STANDARD_LIBRARIES_INIT}"
 131     CACHE STRING "Libraries linked by defalut with all C applications.")
 132   mark_as_advanced(CMAKE_C_STANDARD_LIBRARIES)
 133 endif()
 134
 135 include(CMakeCommonLanguageInclude)
 136
 137 # now define the following rule variables
 138
 139 # CMAKE_C_CREATE_SHARED_LIBRARY
 140 # CMAKE_C_CREATE_SHARED_MODULE
 141 # CMAKE_C_COMPILE_OBJECT
 142 # CMAKE_C_LINK_EXECUTABLE
 143
 144 # variables supplied by the generator at use time
 145 # <TARGET>
 146 # <TARGET_BASE> the target without the suffix
 147 # <OBJECTS>
 148 # <OBJECT>
 149 # <LINK_LIBRARIES>
 150 # <FLAGS>
 151 # <LINK_FLAGS>
 152
 153 # C compiler information
 154 # <CMAKE_C_COMPILER>
 155 # <CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS>
 156 # <CMAKE_SHARED_MODULE_CREATE_C_FLAGS>
 157 # <CMAKE_C_LINK_FLAGS>
 158
 159 # Static library tools
 160 # <CMAKE_AR>
 161 # <CMAKE_RANLIB>
 162
 163
 164 # create a C shared library
 165 if(NOT CMAKE_C_CREATE_SHARED_LIBRARY)
 166   set(CMAKE_C_CREATE_SHARED_LIBRARY
 167       "<CMAKE_C_COMPILER> <CMAKE_SHARED_LIBRARY_C_FLAGS> <LANGUAGE_COMPILE_FLAGS> <LINK_FLAGS> <CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS> <SONAME_FLAG><TARGET_SONAME> -o <TARGET> <OBJECTS> <LINK_LIBRARIES>")
 168 endif()
 169
 170 # create a C shared module just copy the shared library rule
 171 if(NOT CMAKE_C_CREATE_SHARED_MODULE)
 172   set(CMAKE_C_CREATE_SHARED_MODULE ${CMAKE_C_CREATE_SHARED_LIBRARY})
 173 endif()
 174
 175 # Create a static archive incrementally for large object file counts.
 176 # If CMAKE_C_CREATE_STATIC_LIBRARY is set it will override these.
 177 if(NOT DEFINED CMAKE_C_ARCHIVE_CREATE)
 178   set(CMAKE_C_ARCHIVE_CREATE "<CMAKE_AR> cr <TARGET> <LINK_FLAGS> <OBJECTS>")
 179 endif()
 180 if(NOT DEFINED CMAKE_C_ARCHIVE_APPEND)
 181   set(CMAKE_C_ARCHIVE_APPEND "<CMAKE_AR> r  <TARGET> <LINK_FLAGS> <OBJECTS>")
 182 endif()
 183 if(NOT DEFINED CMAKE_C_ARCHIVE_FINISH)
 184   set(CMAKE_C_ARCHIVE_FINISH "<CMAKE_RANLIB> <TARGET>")
 185 endif()
 186
 187 # compile a C file into an object file
 188 if(NOT CMAKE_C_COMPILE_OBJECT)
 189   set(CMAKE_C_COMPILE_OBJECT
 190     "<CMAKE_C_COMPILER> <DEFINES> <FLAGS> -o <OBJECT>   -c <SOURCE>")
 191 endif()
 192
 193 if(NOT CMAKE_C_LINK_EXECUTABLE)
 194   set(CMAKE_C_LINK_EXECUTABLE
 195     "<CMAKE_C_COMPILER> <FLAGS> <CMAKE_C_LINK_FLAGS> <LINK_FLAGS> <OBJECTS>  -o <TARGET> <LINK_LIBRARIES>")
 196 endif()
 197
 198 if(NOT CMAKE_EXECUTABLE_RUNTIME_C_FLAG)
 199   set(CMAKE_EXECUTABLE_RUNTIME_C_FLAG ${CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG})
 200 endif()
 201
 202 if(NOT CMAKE_EXECUTABLE_RUNTIME_C_FLAG_SEP)
 203   set(CMAKE_EXECUTABLE_RUNTIME_C_FLAG_SEP ${CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG_SEP})
 204 endif()
 205
 206 if(NOT CMAKE_EXECUTABLE_RPATH_LINK_C_FLAG)
 207   set(CMAKE_EXECUTABLE_RPATH_LINK_C_FLAG ${CMAKE_SHARED_LIBRARY_RPATH_LINK_C_FLAG})
 208 endif()
 209
 210 mark_as_advanced(
 211 CMAKE_C_FLAGS
 212 CMAKE_C_FLAGS_DEBUG
 213 CMAKE_C_FLAGS_MINSIZEREL
 214 CMAKE_C_FLAGS_RELEASE
 215 CMAKE_C_FLAGS_RELWITHDEBINFO
 216 )
 217 set(CMAKE_C_INFORMATION_LOADED 1)
 218
 219