LAPACKE/CMakeLists.txt

   1 message(STATUS "LAPACKE enable")
   2 enable_language(C)
   3
   4 set(LAPACK_INSTALL_EXPORT_NAME lapacke-targets)
   5
   6 # Create a header file lapacke_mangling.h for the routines called in my C programs
   7 include(FortranCInterface)
   8 ## Ensure that the fortran compiler and c compiler specified are compatible
   9 FortranCInterface_VERIFY()
  10 FortranCInterface_HEADER(${LAPACK_BINARY_DIR}/include/lapacke_mangling.h
  11   MACRO_NAMESPACE "LAPACK_"
  12   SYMBOL_NAMESPACE "LAPACK_")
  13 if(NOT FortranCInterface_GLOBAL_FOUND OR NOT FortranCInterface_MODULE_FOUND)
  14   message(WARNING "Reverting to pre-defined include/lapacke_mangling.h")
  15   configure_file(include/lapacke_mangling_with_flags.h.in
  16                  ${LAPACK_BINARY_DIR}/include/lapacke_mangling.h)
  17 endif()
  18
  19 if(WIN32 AND NOT UNIX)
  20   add_definitions(-DHAVE_LAPACK_CONFIG_H -DLAPACK_COMPLEX_STRUCTURE)
  21   message(STATUS "Windows BUILD")
  22 endif()
  23
  24 get_directory_property(DirDefs COMPILE_DEFINITIONS)
  25
  26 include_directories(include ${LAPACK_BINARY_DIR}/include)
  27 add_subdirectory(include)
  28 add_subdirectory(src)
  29 add_subdirectory(utils)
  30
  31 macro(append_subdir_files variable dirname)
  32   get_directory_property(holder DIRECTORY ${dirname} DEFINITION ${variable})
  33   foreach(depfile ${holder})
  34     list(APPEND ${variable} "${dirname}/${depfile}")
  35   endforeach()
  36 endmacro()
  37
  38 append_subdir_files(LAPACKE_INCLUDE "include")
  39 append_subdir_files(SOURCES "src")
  40 append_subdir_files(DEPRECATED "src")
  41 append_subdir_files(EXTENDED "src")
  42 append_subdir_files(MATGEN "src")
  43 append_subdir_files(UTILS "utils")
  44
  45 if(BUILD_DEPRECATED)
  46   list(APPEND SOURCES ${DEPRECATED})
  47 endif()
  48 if(USE_XBLAS)
  49   list(APPEND SOURCES ${EXTENDED})
  50 endif()
  51 if(LAPACKE_WITH_TMG)
  52   list(APPEND SOURCES ${MATGEN})
  53 endif()
  54 list(APPEND SOURCES ${UTILS})
  55
  56 add_library(lapacke ${SOURCES})
  57 set_target_properties(
  58   lapacke PROPERTIES
  59   LINKER_LANGUAGE C
  60   VERSION ${LAPACK_VERSION}
  61   SOVERSION ${LAPACK_MAJOR_VERSION}
  62   )
  63
  64 if(LAPACKE_WITH_TMG)
  65   target_link_libraries(lapacke PRIVATE tmglib)
  66 endif()
  67 target_link_libraries(lapacke PRIVATE ${LAPACK_LIBRARIES})
  68
  69 lapack_install_library(lapacke)
  70 install(FILES ${LAPACKE_INCLUDE} ${LAPACK_BINARY_DIR}/include/lapacke_mangling.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
  71
  72 if(BUILD_TESTING)
  73   add_subdirectory(example)
  74 endif()
  75
  76
  77 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/lapacke.pc.in ${CMAKE_CURRENT_BINARY_DIR}/lapacke.pc @ONLY)
  78 install(FILES
  79   ${CMAKE_CURRENT_BINARY_DIR}/lapacke.pc
  80   DESTINATION ${PKG_CONFIG_DIR}
  81   )
  82
  83 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake/lapacke-config-version.cmake.in
  84   ${LAPACK_BINARY_DIR}/lapacke-config-version.cmake @ONLY)
  85 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake/lapacke-config-build.cmake.in
  86   ${LAPACK_BINARY_DIR}/lapacke-config.cmake @ONLY)
  87
  88 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake/lapacke-config-install.cmake.in
  89   ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/lapacke-config.cmake @ONLY)
  90 install(FILES
  91   ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/lapacke-config.cmake
  92   ${LAPACK_BINARY_DIR}/lapacke-config-version.cmake
  93   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/lapacke-${LAPACK_VERSION}
  94   )
  95
  96 install(EXPORT lapacke-targets
  97   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/lapacke-${LAPACK_VERSION})