CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  21   cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
  22 elseif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  23   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  24   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  25   #CMake fails to find _fseeko() which leads to subsequent linker error.
  26   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  27   cmake_policy(VERSION 2.8)
  28 else()
  29   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  30 endif()
  31
  32 option(ENABLE_PIC "Generate position independent code (necessary for shared libraries)" TRUE)
  33 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_PIC})
  34
  35 # Following block can break build in case of cross-compiling
  36 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  37 # so we will try to detect cross-compiling by the presence of CMAKE_TOOLCHAIN_FILE
  38 if(NOT DEFINED CMAKE_INSTALL_PREFIX)
  39   if(NOT CMAKE_TOOLCHAIN_FILE)
  40     # it _must_ go before project(OpenCV) in order to work
  41     if(WIN32)
  42       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  43     else()
  44       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  45     endif()
  46   else()
  47     #Android: set output folder to ${CMAKE_BINARY_DIR}
  48     set(LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  49     # any cross-compiling
  50     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  51   endif()
  52 endif()
  53
  54 if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  55   set(WINRT TRUE)
  56 endif()
  57
  58 if(WINRT)
  59   add_definitions(-DWINRT -DNO_GETENV)
  60
  61   # Making definitions available to other configurations and
  62   # to filter dependency restrictions at compile time.
  63   if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone)
  64     set(WINRT_PHONE TRUE)
  65     add_definitions(-DWINRT_PHONE)
  66   elseif(CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  67     set(WINRT_STORE TRUE)
  68     add_definitions(-DWINRT_STORE)
  69   endif()
  70
  71   if(CMAKE_SYSTEM_VERSION MATCHES 10)
  72     set(WINRT_10 TRUE)
  73     add_definitions(-DWINRT_10)
  74   elseif(CMAKE_SYSTEM_VERSION MATCHES 8.1)
  75     set(WINRT_8_1 TRUE)
  76     add_definitions(-DWINRT_8_1)
  77   elseif(CMAKE_SYSTEM_VERSION MATCHES 8.0)
  78     set(WINRT_8_0 TRUE)
  79     add_definitions(-DWINRT_8_0)
  80   endif()
  81 endif()
  82
  83 if(POLICY CMP0026)
  84   cmake_policy(SET CMP0026 NEW)
  85 endif()
  86
  87 if(POLICY CMP0042)
  88   cmake_policy(SET CMP0042 NEW)
  89 endif()
  90
  91 if(POLICY CMP0046)
  92   cmake_policy(SET CMP0046 NEW)
  93 endif()
  94
  95 if(POLICY CMP0051)
  96   cmake_policy(SET CMP0051 NEW)
  97 endif()
  98
  99 if(POLICY CMP0054)  # CMake 3.1: Only interpret if() arguments as variables or keywords when unquoted.
 100   cmake_policy(SET CMP0054 NEW)
 101 endif()
 102
 103 if(POLICY CMP0056)
 104   cmake_policy(SET CMP0056 NEW)
 105 endif()
 106
 107 if(POLICY CMP0067)
 108   cmake_policy(SET CMP0067 NEW)
 109 endif()
 110
 111 include(cmake/OpenCVUtils.cmake)
 112 ocv_cmake_reset_hooks()
 113 ocv_check_environment_variables(OPENCV_CMAKE_HOOKS_DIR)
 114 if(DEFINED OPENCV_CMAKE_HOOKS_DIR)
 115   foreach(__dir ${OPENCV_CMAKE_HOOKS_DIR})
 116     get_filename_component(__dir "${__dir}" ABSOLUTE)
 117     ocv_cmake_hook_register_dir(${__dir})
 118   endforeach()
 119 endif()
 120
 121 ocv_cmake_hook(CMAKE_INIT)
 122
 123 # must go before the project command
 124 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
 125 if(DEFINED CMAKE_BUILD_TYPE)
 126   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
 127 endif()
 128
 129 enable_testing()
 130
 131 project(OpenCV CXX C)
 132
 133 if(MSVC)
 134   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 135 endif()
 136
 137 ocv_cmake_eval(DEBUG_PRE ONCE)
 138
 139 ocv_clear_vars(OpenCVModules_TARGETS)
 140
 141 include(cmake/OpenCVDownload.cmake)
 142
 143 set(BUILD_LIST "" CACHE STRING "Build only listed modules (comma-separated, e.g. 'videoio,dnn,ts')")
 144
 145 # ----------------------------------------------------------------------------
 146 # Break in case of popular CMake configuration mistakes
 147 # ----------------------------------------------------------------------------
 148 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 149   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 150   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 151 endif()
 152
 153 # ----------------------------------------------------------------------------
 154 # Detect compiler and target platform architecture
 155 # ----------------------------------------------------------------------------
 156 OCV_OPTION(ENABLE_CXX11 "Enable C++11 compilation mode" "${OPENCV_CXX11}")
 157 include(cmake/OpenCVDetectCXXCompiler.cmake)
 158 ocv_cmake_hook(POST_DETECT_COMPILER)
 159
 160 # Add these standard paths to the search paths for FIND_LIBRARY
 161 # to find libraries from these locations first
 162 if(UNIX AND NOT ANDROID)
 163   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 164     if(EXISTS /lib64)
 165       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 166     else()
 167       list(APPEND CMAKE_LIBRARY_PATH /lib)
 168     endif()
 169     if(EXISTS /usr/lib64)
 170       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 171     else()
 172       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 173     endif()
 174   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 175     if(EXISTS /lib32)
 176       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 177     else()
 178       list(APPEND CMAKE_LIBRARY_PATH /lib)
 179     endif()
 180     if(EXISTS /usr/lib32)
 181       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 182     else()
 183       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 184     endif()
 185   endif()
 186 endif()
 187
 188 # Add these standard paths to the search paths for FIND_PATH
 189 # to find include files from these locations first
 190 if(MINGW)
 191   if(EXISTS /mingw)
 192       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 193   endif()
 194   if(EXISTS /mingw32)
 195       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 196   endif()
 197   if(EXISTS /mingw64)
 198       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 199   endif()
 200 endif()
 201
 202 # ----------------------------------------------------------------------------
 203 # OpenCV cmake options
 204 # ----------------------------------------------------------------------------
 205
 206 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 207
 208 # 3rd party libs
 209 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE)
 210 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE)
 211 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE)
 212 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE)
 213 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE)
 214 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (WIN32 OR ANDROID OR APPLE) AND NOT WINRT)
 215 OCV_OPTION(BUILD_WEBP               "Build WebP from source"             (WIN32 OR ANDROID OR APPLE) AND NOT WINRT)
 216 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 217 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           NOT MINGW IF (X86_64 OR X86) AND NOT WINRT )
 218 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"        NOT MINGW IF (X86_64 OR X86) AND NOT WINRT AND NOT APPLE_FRAMEWORK )
 219
 220 # Optional 3rd party components
 221 # ===================================================
 222 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 223 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O (iOS/Mac)"    ON   IF APPLE)
 224 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa (OBSOLETE)"                               OFF IF APPLE )
 225 OCV_OPTION(WITH_CAROTENE       "Use NVidia carotene acceleration library for ARM platform"                   ON  IF (ARM OR AARCH64) AND NOT IOS AND NOT (CMAKE_VERSION VERSION_LESS "2.8.11"))
 226 OCV_OPTION(WITH_CPUFEATURES    "Use cpufeatures Android library"             ON   IF ANDROID)
 227 OCV_OPTION(WITH_VTK            "Include VTK library support (and build opencv_viz module eiher)"             ON  IF (NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING) )
 228 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"                                         OFF IF (NOT IOS AND NOT WINRT) )
 229 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (NOT IOS AND NOT WINRT) )
 230 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" ON IF (NOT IOS AND NOT WINRT) )
 231 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               ON IF (NOT IOS AND NOT APPLE) )
 232 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               (NOT CV_DISABLE_OPTIMIZATION)       IF (NOT WINRT AND NOT CMAKE_CROSSCOMPILING) )
 233 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 234 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 235 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 236 OCV_OPTION(WITH_GSTREAMER_0_10 "Enable Gstreamer 0.10 support (instead of 1.x)"                              OFF )
 237 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 238 OCV_OPTION(WITH_GTK_2_X        "Use GTK version 2"                           OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 239 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)  IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS )
 240 OCV_OPTION(WITH_HALIDE         "Include Halide support"                      OFF)
 241 OCV_OPTION(WITH_INF_ENGINE     "Include Intel Inference Engine support"      OFF)
 242 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 243 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 244 OCV_OPTION(WITH_WEBP           "Include WebP support"                        ON   IF (NOT WINRT) )
 245 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS AND NOT WINRT) )
 246 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT WINRT) )
 247 OCV_OPTION(WITH_OPENVX         "Include OpenVX support"                      OFF)
 248 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 249 OCV_OPTION(WITH_OPENNI2        "Include OpenNI2 support"                     OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 250 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 251 OCV_OPTION(WITH_GDCM           "Include DICOM support"                       OFF)
 252 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 253 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 254 OCV_OPTION(WITH_ARAVIS         "Include Aravis GigE support"                 OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32) )
 255 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 256 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 AND NOT WINRT)
 257 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O (OBSOLETE)"      OFF  IF APPLE )
 258 OCV_OPTION(WITH_QTKIT          "Use QTKit Video I/O backend"                 OFF  IF APPLE )
 259 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS AND NOT WINRT) )
 260 OCV_OPTION(WITH_OPENMP         "Include OpenMP support"                      OFF)
 261 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF (WIN32 AND NOT WINRT)  )
 262 OCV_OPTION(WITH_PTHREADS_PF    "Use pthreads-based parallel_for"             ON   IF (NOT WIN32 OR MINGW) )
 263 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 264 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 265 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID AND NOT APPLE) )
 266 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        OFF  IF (UNIX AND NOT ANDROID AND NOT APPLE) )
 267 OCV_OPTION(WITH_DSHOW          "Build VideoIO with DirectShow support"       ON   IF (WIN32 AND NOT ARM AND NOT WINRT) )
 268 OCV_OPTION(WITH_MSMF           "Build VideoIO with Media Foundation support" ON  IF WIN32 )
 269 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT WINRT) )
 270 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 271 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 272 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)  IF (NOT IOS AND NOT WINRT) )
 273 OCV_OPTION(WITH_OPENCL_SVM     "Include OpenCL Shared Virtual Memory support" OFF ) # experimental
 274 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 275 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 276 OCV_OPTION(WITH_DIRECTX        "Include DirectX support"                     ON   IF (WIN32 AND NOT WINRT) )
 277 OCV_OPTION(WITH_INTELPERC      "Include Intel Perceptual Computing support"  OFF  IF (WIN32 AND NOT WINRT) )
 278 OCV_OPTION(WITH_VA             "Include VA support"                          OFF  IF (UNIX AND NOT ANDROID) )
 279 OCV_OPTION(WITH_VA_INTEL       "Include Intel VA-API/OpenCL support"         OFF  IF (UNIX AND NOT ANDROID) )
 280 OCV_OPTION(WITH_MFX            "Include Intel Media SDK support"             OFF   IF ((UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)) )
 281 OCV_OPTION(WITH_GDAL           "Include GDAL Support"                        OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 282 OCV_OPTION(WITH_GPHOTO2        "Include gPhoto2 library support"             OFF  IF (UNIX AND NOT ANDROID AND NOT IOS) )
 283 OCV_OPTION(WITH_LAPACK         "Include Lapack library support"              (NOT CV_DISABLE_OPTIMIZATION)  IF (NOT ANDROID AND NOT IOS) )
 284 OCV_OPTION(WITH_ITT            "Include Intel ITT support"                   ON   IF (NOT APPLE_FRAMEWORK) )
 285 OCV_OPTION(WITH_PROTOBUF       "Enable libprotobuf"                          ON )
 286 OCV_OPTION(WITH_IMGCODEC_HDR   "Include HDR support"                         ON)
 287 OCV_OPTION(WITH_IMGCODEC_SUNRASTER "Include SUNRASTER support"               ON)
 288 OCV_OPTION(WITH_IMGCODEC_PXM   "Include PNM (PBM,PGM,PPM) and PAM formats support" ON)
 289 OCV_OPTION(WITH_QUIRC          "Include library QR-code decoding"            ON)
 290
 291 # OpenCV build components
 292 # ===================================================
 293 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 294 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 295 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 296 OCV_OPTION(BUILD_ANDROID_PROJECTS   "Build Android projects providing .apk files" ON  IF ANDROID )
 297 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 298 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" OFF  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 299 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 300 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 301 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT APPLE_FRAMEWORK) )
 302 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT APPLE_FRAMEWORK) )
 303 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into release binaries ('OFF' means default settings)" OFF )
 304 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 305 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 306 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create Java wrapper exporting all functions of OpenCV library (requires static build of OpenCV modules)" ANDROID IF NOT BUILD_SHARED_LIBS)
 307 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 308 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 309 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 310
 311 # OpenCV installation options
 312 # ===================================================
 313 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 314 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 315 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 316 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 317 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 318 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 319
 320 # OpenCV build options
 321 # ===================================================
 322 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND NOT IOS AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja")) )
 323 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON IF (MSVC OR (NOT IOS AND NOT CMAKE_CROSSCOMPILING) ) )
 324 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 325 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CV_GCC )
 326 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CV_GCC )
 327 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CV_GCC )
 328 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CV_GCC AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 329 OCV_OPTION(ENABLE_VSX                 "Enable POWER8 and above VSX (64-bit little-endian)"       ON   IF ((CV_GCC OR CV_CLANG) AND PPC64LE) )
 330 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CV_GCC AND (X86 OR X86_64)) )
 331 if(NOT IOS)  # Use CPU_BASELINE instead
 332 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 333 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 334 endif()
 335 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 336 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 337 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 338 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 339 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 340 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF ((NOT CMAKE_VERSION VERSION_LESS "2.8.11") AND CV_GCC) )
 341 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 342 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CV_GCC OR MSVC)
 343 OCV_OPTION(ENABLE_THIN_LTO            "Enable Thin LTO" OFF IF CV_CLANG)
 344 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 345 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 346 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 347 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 348 OCV_OPTION(OPENCV_GENERATE_SETUPVARS  "Generate setup_vars* scripts" ON IF (NOT ANDROID AND NOT APPLE_FRAMEWORK) )
 349
 350 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 351 OCV_OPTION(ENABLE_FLAKE8              "Add target with Python flake8 checker"                    (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 352
 353 if(ENABLE_IMPL_COLLECTION)
 354   add_definitions(-DCV_COLLECT_IMPL_DATA)
 355 endif()
 356
 357
 358 # ----------------------------------------------------------------------------
 359 #  Get actual OpenCV version number from sources
 360 # ----------------------------------------------------------------------------
 361 include(cmake/OpenCVVersion.cmake)
 362
 363 ocv_cmake_hook(POST_OPTIONS)
 364
 365 # ----------------------------------------------------------------------------
 366 #  Build & install layouts
 367 # ----------------------------------------------------------------------------
 368
 369 # Save libs and executables in the same place
 370 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 371
 372 if(ANDROID)
 373   if(ANDROID_ABI MATCHES "NEON")
 374     set(ENABLE_NEON ON)
 375   endif()
 376   if(ANDROID_ABI MATCHES "VFPV3")
 377     set(ENABLE_VFPV3 ON)
 378   endif()
 379 endif()
 380
 381 if(ANDROID OR WIN32)
 382   ocv_update(OPENCV_DOC_INSTALL_PATH doc)
 383 else()
 384   ocv_update(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 385 endif()
 386
 387 if(WIN32 AND CMAKE_HOST_SYSTEM_NAME MATCHES Windows)
 388   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 389     ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 390   else()
 391     message(STATUS "Can't detect runtime and/or arch")
 392     ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "")
 393   endif()
 394 elseif(ANDROID)
 395   ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "sdk/native/")
 396 else()
 397   ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "")
 398 endif()
 399
 400 if(ANDROID)
 401   ocv_update(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples/${ANDROID_NDK_ABI_NAME}")
 402 else()
 403   ocv_update(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 404 endif()
 405
 406 if(ANDROID)
 407   ocv_update(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin/${ANDROID_NDK_ABI_NAME}")
 408 else()
 409   ocv_update(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 410 endif()
 411
 412 if(NOT OPENCV_TEST_INSTALL_PATH)
 413   ocv_update(OPENCV_TEST_INSTALL_PATH "${OPENCV_BIN_INSTALL_PATH}")
 414 endif()
 415
 416 if (OPENCV_TEST_DATA_PATH)
 417   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 418 endif()
 419
 420 if(ANDROID)
 421   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "sdk/etc/testdata")
 422 elseif(WIN32)
 423   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "testdata")
 424 else()
 425   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "share/OpenCV/testdata")
 426 endif()
 427
 428 if(ANDROID)
 429   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 430   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 431   ocv_update(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 432   ocv_update(OPENCV_LIB_ARCHIVE_INSTALL_PATH sdk/native/staticlibs/${ANDROID_NDK_ABI_NAME})
 433   ocv_update(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 434   ocv_update(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 435   ocv_update(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 436   ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH samples/native)
 437   ocv_update(OPENCV_OTHER_INSTALL_PATH   sdk/etc)
 438 else()
 439   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 440   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 441
 442   if(WIN32 AND CMAKE_HOST_SYSTEM_NAME MATCHES Windows)
 443     if(OpenCV_STATIC)
 444       ocv_update(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 445     else()
 446       ocv_update(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 447     endif()
 448     ocv_update(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 449     ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH    samples)
 450     ocv_update(OPENCV_JAR_INSTALL_PATH java)
 451     ocv_update(OPENCV_OTHER_INSTALL_PATH   etc)
 452     ocv_update(OPENCV_CONFIG_INSTALL_PATH  ".")
 453   else()
 454     include(GNUInstallDirs)
 455     ocv_update(OPENCV_LIB_INSTALL_PATH     ${CMAKE_INSTALL_LIBDIR}${LIB_SUFFIX})
 456     ocv_update(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 457     ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH    share/OpenCV/samples)
 458     ocv_update(OPENCV_JAR_INSTALL_PATH share/OpenCV/java)
 459     ocv_update(OPENCV_OTHER_INSTALL_PATH   share/OpenCV)
 460
 461     if(NOT DEFINED OPENCV_CONFIG_INSTALL_PATH)
 462       math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 463       if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 464         ocv_update(OPENCV_CONFIG_INSTALL_PATH ${CMAKE_INSTALL_LIBDIR}${LIB_SUFFIX}/cmake/opencv)
 465       else()
 466         ocv_update(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 467       endif()
 468     endif()
 469   endif()
 470   ocv_update(OPENCV_INCLUDE_INSTALL_PATH "include")
 471 endif()
 472
 473 ocv_update(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 474 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 475
 476 if(INSTALL_TO_MANGLED_PATHS)
 477   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 478   foreach(v
 479       OPENCV_3P_LIB_INSTALL_PATH
 480       OPENCV_SAMPLES_SRC_INSTALL_PATH
 481       OPENCV_CONFIG_INSTALL_PATH
 482       OPENCV_DOC_INSTALL_PATH
 483       OPENCV_JAR_INSTALL_PATH
 484       OPENCV_TEST_DATA_INSTALL_PATH
 485       OPENCV_OTHER_INSTALL_PATH
 486     )
 487     string(REPLACE "OpenCV" "OpenCV-${OPENCV_VERSION}" ${v} "${${v}}")
 488     string(REPLACE "opencv" "opencv-${OPENCV_VERSION}" ${v} "${${v}}")
 489   endforeach()
 490 endif()
 491
 492 if(ANDROID)
 493   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_LIB_INSTALL_PATH}")
 494 elseif(INSTALL_CREATE_DISTRIB)
 495   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_JAR_INSTALL_PATH}/${OpenCV_ARCH}")
 496 else()
 497   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_JAR_INSTALL_PATH}")
 498 endif()
 499 ocv_update(OPENCV_JNI_BIN_INSTALL_PATH "${OPENCV_JNI_INSTALL_PATH}")
 500
 501 if(NOT OPENCV_LIB_ARCHIVE_INSTALL_PATH)
 502   set(OPENCV_LIB_ARCHIVE_INSTALL_PATH ${OPENCV_LIB_INSTALL_PATH})
 503 endif()
 504
 505 if(WIN32)
 506   # Postfix of DLLs:
 507   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 508   set(OPENCV_DEBUG_POSTFIX d)
 509 else()
 510   # Postfix of so's:
 511   set(OPENCV_DLLVERSION "")
 512   set(OPENCV_DEBUG_POSTFIX "")
 513 endif()
 514
 515 if(DEFINED CMAKE_DEBUG_POSTFIX)
 516   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 517 endif()
 518
 519 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 520   set(BUILD_opencv_world ON CACHE INTERNAL "")
 521 endif()
 522
 523 # ----------------------------------------------------------------------------
 524 #  Path for build/platform -specific headers
 525 # ----------------------------------------------------------------------------
 526 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 527 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 528
 529 # ----------------------------------------------------------------------------
 530 #  Path for additional modules
 531 # ----------------------------------------------------------------------------
 532 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules (can be ;-separated list of paths)")
 533
 534 # ----------------------------------------------------------------------------
 535 #  Autodetect if we are in a GIT repository
 536 # ----------------------------------------------------------------------------
 537 find_host_package(Git QUIET)
 538
 539 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 540   ocv_git_describe(OPENCV_VCSVERSION "${OpenCV_SOURCE_DIR}")
 541 elseif(NOT DEFINED OPENCV_VCSVERSION)
 542   # We don't have git:
 543   set(OPENCV_VCSVERSION "unknown")
 544 endif()
 545
 546
 547 # ----------------------------------------------------------------------------
 548 # OpenCV compiler and linker options
 549 # ----------------------------------------------------------------------------
 550 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 551 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 552   set(CMAKE_BUILD_TYPE Release)
 553 endif()
 554
 555 ocv_cmake_hook(POST_CMAKE_BUILD_OPTIONS)
 556
 557 # --- Python Support ---
 558 if(NOT IOS)
 559   include(cmake/OpenCVDetectPython.cmake)
 560 endif()
 561
 562 include(cmake/OpenCVCompilerOptions.cmake)
 563
 564 ocv_cmake_hook(POST_COMPILER_OPTIONS)
 565
 566 # ----------------------------------------------------------------------------
 567 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 568 # ----------------------------------------------------------------------------
 569 if(UNIX)
 570   if(NOT APPLE_FRAMEWORK OR OPENCV_ENABLE_PKG_CONFIG)
 571     if(CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG_LIBDIR}
 572         AND NOT OPENCV_ENABLE_PKG_CONFIG
 573     )
 574       if(NOT PkgConfig_FOUND)
 575         message(STATUS "OpenCV disables pkg-config to avoid using of host libraries. Consider using PKG_CONFIG_LIBDIR to specify target SYSROOT")
 576       elseif(OPENCV_SKIP_PKG_CONFIG_WARNING)
 577         message(WARNING "pkg-config is enabled in cross-compilation mode without defining of PKG_CONFIG_LIBDIR environment variable. This may lead to misconfigured host-based dependencies.")
 578       endif()
 579     elseif(OPENCV_DISABLE_PKG_CONFIG)
 580       if(PkgConfig_FOUND)
 581         message(WARNING "OPENCV_DISABLE_PKG_CONFIG flag has no effect")
 582       endif()
 583     else()
 584       find_package(PkgConfig QUIET)
 585     endif()
 586   endif()
 587   include(CheckFunctionExists)
 588   include(CheckIncludeFile)
 589   include(CheckSymbolExists)
 590
 591   if(NOT APPLE)
 592     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 593     if(ANDROID)
 594       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 595     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 596       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 597     elseif(EMSCRIPTEN)
 598       # no need to link to system libs with emscripten
 599     else()
 600       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 601     endif()
 602   else()
 603     set(HAVE_PTHREAD 1)
 604   endif()
 605
 606   CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 607   CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 608   if(HAVE_MALLOC_H)
 609     CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 610   endif()
 611 endif()
 612
 613 include(cmake/OpenCVPCHSupport.cmake)
 614 include(cmake/OpenCVModule.cmake)
 615
 616 # ----------------------------------------------------------------------------
 617 #  Detect endianness of build platform
 618 # ----------------------------------------------------------------------------
 619
 620 if(IOS)
 621   # test_big_endian needs try_compile, which doesn't work for iOS
 622   # http://public.kitware.com/Bug/view.php?id=12288
 623   set(WORDS_BIGENDIAN 0)
 624 else()
 625   include(TestBigEndian)
 626   test_big_endian(WORDS_BIGENDIAN)
 627 endif()
 628
 629 # ----------------------------------------------------------------------------
 630 #  Detect 3rd-party libraries
 631 # ----------------------------------------------------------------------------
 632
 633 if(ANDROID AND WITH_CPUFEATURES)
 634   add_subdirectory(3rdparty/cpufeatures)
 635   set(HAVE_CPUFEATURES 1)
 636 endif()
 637
 638 include(cmake/OpenCVFindLibsGrfmt.cmake)
 639 include(cmake/OpenCVFindLibsGUI.cmake)
 640 include(cmake/OpenCVFindLibsVideo.cmake)
 641 include(cmake/OpenCVFindLibsPerf.cmake)
 642 include(cmake/OpenCVFindLAPACK.cmake)
 643 include(cmake/OpenCVFindProtobuf.cmake)
 644
 645 # ----------------------------------------------------------------------------
 646 #  Detect other 3rd-party libraries/tools
 647 # ----------------------------------------------------------------------------
 648
 649 # --- Java Support ---
 650 if(BUILD_JAVA)
 651   if(ANDROID)
 652     include(cmake/android/OpenCVDetectAndroidSDK.cmake)
 653   else()
 654     include(cmake/OpenCVDetectApacheAnt.cmake)
 655     find_package(JNI)
 656   endif()
 657 endif()
 658
 659 if(ENABLE_PYLINT AND PYTHON_DEFAULT_AVAILABLE)
 660   include(cmake/OpenCVPylint.cmake)
 661 endif()
 662 if(ENABLE_FLAKE8 AND PYTHON_DEFAULT_AVAILABLE)
 663   find_package(Flake8 QUIET)
 664   if(NOT FLAKE8_FOUND OR NOT FLAKE8_EXECUTABLE)
 665     include("${CMAKE_CURRENT_LIST_DIR}/cmake/FindFlake8.cmake")
 666   endif()
 667   if(FLAKE8_FOUND)
 668     add_custom_target(check_flake8
 669         COMMAND "${FLAKE8_EXECUTABLE}" . --count --select=E9,E901,E999,F821,F822,F823 --show-source --statistics --exclude='.git,__pycache__,*.config.py,svgfig.py'
 670         WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 671         COMMENT "Running flake8"
 672     )
 673   endif()
 674 endif()
 675
 676
 677 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 678   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 679 else()
 680   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 681 endif()
 682
 683 # --- OpenCL ---
 684 if(WITH_OPENCL)
 685   include(cmake/OpenCVDetectOpenCL.cmake)
 686 endif()
 687
 688 # --- Halide ---
 689 if(WITH_HALIDE)
 690   include(cmake/OpenCVDetectHalide.cmake)
 691 endif()
 692
 693 # --- Inference Engine ---
 694 if(WITH_INF_ENGINE)
 695   include(cmake/OpenCVDetectInferenceEngine.cmake)
 696 endif()
 697
 698 # --- DirectX ---
 699 if(WITH_DIRECTX)
 700   include(cmake/OpenCVDetectDirectX.cmake)
 701 endif()
 702
 703 if(WITH_VTK)
 704   include(cmake/OpenCVDetectVTK.cmake)
 705 endif()
 706
 707 if(WITH_OPENVX)
 708   include(cmake/FindOpenVX.cmake)
 709 endif()
 710
 711 if(WITH_QUIRC)
 712   add_subdirectory(3rdparty/quirc)
 713   set(HAVE_QUIRC TRUE)
 714 endif()
 715 # ----------------------------------------------------------------------------
 716 # OpenCV HAL
 717 # ----------------------------------------------------------------------------
 718 set(_hal_includes "")
 719 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 720   # 1. libraries
 721   foreach (l ${${HAL_LIBRARIES_VAR}})
 722     if(NOT TARGET ${l})
 723       get_filename_component(l "${l}" ABSOLUTE)
 724     endif()
 725     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 726   endforeach()
 727   # 2. headers
 728   foreach (h ${${HAL_HEADERS_VAR}})
 729     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 730   endforeach()
 731   # 3. include paths
 732   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 733 endmacro()
 734
 735 if(NOT DEFINED OpenCV_HAL)
 736   set(OpenCV_HAL "OpenCV_HAL")
 737 endif()
 738
 739 if(HAVE_OPENVX)
 740   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 741     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 742   endif()
 743 endif()
 744
 745 if(WITH_CAROTENE)
 746   ocv_debug_message(STATUS "Enable carotene acceleration")
 747   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 748     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 749   endif()
 750 endif()
 751
 752 foreach(hal ${OpenCV_HAL})
 753   if(hal STREQUAL "carotene")
 754     add_subdirectory(3rdparty/carotene/hal)
 755     ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 756     list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 757   elseif(hal STREQUAL "openvx")
 758     add_subdirectory(3rdparty/openvx)
 759     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 760     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 761   else()
 762     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 763     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 764     find_package(${hal} NO_MODULE QUIET)
 765     if(${hal}_FOUND)
 766       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 767       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 768     endif()
 769   endif()
 770 endforeach()
 771 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 772 unset(_hal_includes)
 773
 774
 775 # ----------------------------------------------------------------------------
 776 # Add CUDA libraries (needed for apps/tools, samples)
 777 # ----------------------------------------------------------------------------
 778 if(HAVE_CUDA)
 779   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 780   if(HAVE_CUBLAS)
 781     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 782   endif()
 783   if(HAVE_CUFFT)
 784     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 785   endif()
 786   foreach(p ${CUDA_LIBS_PATH})
 787     if(MSVC AND CMAKE_GENERATOR MATCHES "Ninja|JOM")
 788       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}"${p}")
 789     else()
 790       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}${p})
 791     endif()
 792   endforeach()
 793 endif()
 794
 795
 796 # ----------------------------------------------------------------------------
 797 # Code trace support
 798 # ----------------------------------------------------------------------------
 799 if(CV_TRACE)
 800   include(cmake/OpenCVDetectTrace.cmake)
 801 endif()
 802
 803 ocv_cmake_hook(POST_DETECT_DEPENDECIES)
 804
 805 # ----------------------------------------------------------------------------
 806 # Solution folders:
 807 # ----------------------------------------------------------------------------
 808 if(ENABLE_SOLUTION_FOLDERS)
 809   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 810   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 811 endif()
 812
 813 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 814 include(cmake/OpenCVExtraTargets.cmake)
 815
 816 # ----------------------------------------------------------------------------
 817 # Process subdirectories
 818 # ----------------------------------------------------------------------------
 819
 820 # opencv.hpp and legacy headers
 821 add_subdirectory(include)
 822
 823 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 824 ocv_add_modules_compiler_options()
 825
 826 # OpenCV modules
 827 add_subdirectory(modules)
 828
 829 # Generate targets for documentation
 830 add_subdirectory(doc)
 831
 832 # various data that is used by cv libraries and/or demo applications.
 833 add_subdirectory(data)
 834
 835 # extra applications
 836 if(BUILD_opencv_apps)
 837   add_subdirectory(apps)
 838 endif()
 839
 840 # examples
 841 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_C_EXAMPLES)
 842   add_subdirectory(samples)
 843 endif()
 844
 845 if(ANDROID)
 846   add_subdirectory(platforms/android/service)
 847 endif()
 848
 849 # ----------------------------------------------------------------------------
 850 # Finalization: generate configuration-based files
 851 # ----------------------------------------------------------------------------
 852
 853 ocv_cmake_hook(PRE_FINALIZE)
 854
 855 # Generate platform-dependent and configuration-dependent headers
 856 include(cmake/OpenCVGenHeaders.cmake)
 857
 858 # Generate opencv.pc for pkg-config command
 859 if(NOT OPENCV_SKIP_PKGCONFIG_GENERATION
 860     AND NOT CMAKE_GENERATOR MATCHES "Xcode")
 861   include(cmake/OpenCVGenPkgconfig.cmake)
 862 endif()
 863
 864 # Generate OpenCV.mk for ndk-build (Android build tool)
 865 include(cmake/OpenCVGenAndroidMK.cmake)
 866
 867 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 868 include(cmake/OpenCVGenConfig.cmake)
 869
 870 # Generate Info.plist for the IOS framework
 871 if(APPLE_FRAMEWORK)
 872   include(cmake/OpenCVGenInfoPlist.cmake)
 873 endif()
 874
 875 # Generate ABI descriptor
 876 include(cmake/OpenCVGenABI.cmake)
 877
 878 # Generate environment setup file
 879 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
 880   if(ANDROID)
 881     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
 882     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
 883                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 884     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 885             DESTINATION ./ COMPONENT tests)
 886   elseif(WIN32)
 887     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
 888                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
 889     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
 890             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 891   elseif(UNIX)
 892     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
 893                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 894     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 895             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 896   endif()
 897 endif()
 898
 899 if(NOT OPENCV_README_FILE)
 900   if(ANDROID)
 901     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
 902   endif()
 903 endif()
 904
 905 if(NOT OPENCV_LICENSE_FILE)
 906   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 907 endif()
 908
 909 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
 910 if(ANDROID OR NOT UNIX)
 911   install(FILES ${OPENCV_LICENSE_FILE}
 912         PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 913         DESTINATION ./ COMPONENT libs)
 914   if(OPENCV_README_FILE)
 915     install(FILES ${OPENCV_README_FILE}
 916             PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 917             DESTINATION ./ COMPONENT libs)
 918   endif()
 919 endif()
 920
 921 if(COMMAND ocv_pylint_finalize)
 922   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
 923   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
 924   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
 925   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
 926   ocv_pylint_finalize()
 927 endif()
 928
 929 if(OPENCV_GENERATE_SETUPVARS)
 930   include(cmake/OpenCVGenSetupVars.cmake)
 931 endif()
 932
 933 # ----------------------------------------------------------------------------
 934 # Summary:
 935 # ----------------------------------------------------------------------------
 936 status("")
 937 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 938 if(OPENCV_VCSVERSION)
 939   status("  Version control:" ${OPENCV_VCSVERSION})
 940 endif()
 941 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
 942   set(__dump_extra_header OFF)
 943   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
 944     if(EXISTS ${p})
 945       if(NOT __dump_extra_header)
 946         set(__dump_extra_header ON)
 947         status("")
 948         status("  Extra modules:")
 949       else()
 950         status("")
 951       endif()
 952       ocv_git_describe(EXTRA_MODULES_VCSVERSION "${p}")
 953       status("    Location (extra):" ${p})
 954       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
 955     endif()
 956   endforeach()
 957   unset(__dump_extra_header)
 958 endif()
 959
 960 # ========================== build platform ==========================
 961 status("")
 962 status("  Platform:")
 963 if(NOT DEFINED OPENCV_TIMESTAMP
 964     AND NOT CMAKE_VERSION VERSION_LESS 2.8.11
 965     AND NOT BUILD_INFO_SKIP_TIMESTAMP
 966 )
 967   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
 968   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
 969 endif()
 970 if(OPENCV_TIMESTAMP)
 971   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
 972 endif()
 973 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 974 if(CMAKE_CROSSCOMPILING)
 975   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 976 endif()
 977 status("    CMake:"            ${CMAKE_VERSION})
 978 status("    CMake generator:"  ${CMAKE_GENERATOR})
 979 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 980 if(MSVC)
 981   status("    MSVC:"           ${MSVC_VERSION})
 982 endif()
 983 if(CMAKE_GENERATOR MATCHES Xcode)
 984   status("    Xcode:"          ${XCODE_VERSION})
 985 endif()
 986 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 987   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 988 endif()
 989
 990
 991 # ========================= CPU code generation mode =========================
 992 status("")
 993 status("  CPU/HW features:")
 994 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
 995 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
 996   status("      requested:"  "${CPU_BASELINE}")
 997 endif()
 998 if(CPU_BASELINE_REQUIRE)
 999   status("      required:"  "${CPU_BASELINE_REQUIRE}")
1000 endif()
1001 if(CPU_BASELINE_DISABLE)
1002   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
1003 endif()
1004 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
1005   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
1006   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
1007     status("      requested:"  "${CPU_DISPATCH}")
1008   endif()
1009   if(CPU_DISPATCH_REQUIRE)
1010     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
1011   endif()
1012   foreach(OPT ${CPU_DISPATCH_FINAL})
1013     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
1014   endforeach()
1015 endif()
1016
1017 # ========================== C/C++ options ==========================
1018 if(CMAKE_CXX_COMPILER_VERSION)
1019   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
1020 else()
1021   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1022 endif()
1023 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
1024
1025 status("")
1026 status("  C/C++:")
1027 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
1028 if(ENABLE_CXX11 OR HAVE_CXX11)
1029 status("    C++11:" HAVE_CXX11 THEN YES ELSE NO)
1030 endif()
1031 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
1032 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
1033 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
1034 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
1035 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
1036 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
1037 if(WIN32)
1038   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
1039   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
1040 else()
1041   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
1042   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
1043 endif()
1044 status("    ccache:"                  OPENCV_COMPILER_IS_CCACHE THEN YES ELSE NO)
1045 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1046
1047 # ========================== Dependencies ============================
1048 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1049 status("    Extra dependencies:" ${deps_extra})
1050 status("    3rdparty dependencies:" ${deps_3rdparty})
1051
1052 # ========================== OpenCV modules ==========================
1053 status("")
1054 status("  OpenCV modules:")
1055 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
1056 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1057 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1058 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1059 list(SORT OPENCV_MODULES_BUILD_ST)
1060 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1061 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1062 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1063 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1064 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1065 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1066 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1067
1068 ocv_build_features_string(apps_status
1069   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1070   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1071   IF BUILD_EXAMPLES THEN "examples"
1072   IF BUILD_opencv_apps THEN "apps"
1073   IF BUILD_ANDROID_SERVICE THEN "android_service"
1074   IF BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1075   ELSE "-")
1076 status("    Applications:" "${apps_status}")
1077 ocv_build_features_string(docs_status
1078     IF TARGET doxygen_cpp THEN "doxygen"
1079     IF TARGET doxygen_python THEN "python"
1080     IF TARGET doxygen_javadoc THEN "javadoc"
1081     IF BUILD_opencv_js OR DEFINED OPENCV_JS_LOCATION THEN "js"
1082     ELSE "NO"
1083 )
1084 status("    Documentation:" "${docs_status}")
1085 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1086
1087 # ========================== Android details ==========================
1088 if(ANDROID)
1089   status("")
1090   if(DEFINED ANDROID_NDK_REVISION)
1091     set(__msg "${ANDROID_NDK} (ver ${ANDROID_NDK_REVISION})")
1092   else()
1093     set(__msg "location: ${ANDROID_NDK}")
1094   endif()
1095   status("  Android NDK: " ${__msg})
1096   status("    Android ABI:" ${ANDROID_ABI})
1097   if(BUILD_WITH_STANDALONE_TOOLCHAIN)
1098     status("    NDK toolchain:" "standalone: ${ANDROID_STANDALONE_TOOLCHAIN}")
1099   elseif(BUILD_WITH_ANDROID_NDK OR DEFINED ANDROID_TOOLCHAIN_NAME)
1100     status("    NDK toolchain:" "${ANDROID_TOOLCHAIN_NAME}")
1101   endif()
1102   status("    STL type:" ${ANDROID_STL})
1103   status("    Native API level:" ${ANDROID_NATIVE_API_LEVEL})
1104
1105   if(BUILD_ANDROID_PROJECTS)
1106     status("  Android SDK: " "${ANDROID_SDK} (tools: ${ANDROID_SDK_TOOLS_VERSION} build tools: ${ANDROID_SDK_BUILD_TOOLS_VERSION})")
1107     if(ANDROID_EXECUTABLE)
1108       status("    android tool:"  "${ANDROID_EXECUTABLE}")
1109     endif()
1110   else()
1111     status("  Android SDK: " "not used, projects are not built")
1112   endif()
1113   if(DEFINED ANDROID_SDK_COMPATIBLE_TARGET)
1114     status("    SDK target:" "${ANDROID_SDK_COMPATIBLE_TARGET}")
1115   endif()
1116   if(DEFINED ANDROID_PROJECTS_BUILD_TYPE)
1117     if(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1118       status("    Projects build scripts:" "Ant/Eclipse compatible")
1119     elseif(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1120       status("    Projects build scripts:" "Gradle")
1121     endif()
1122   endif()
1123 endif()
1124
1125 # ================== Windows RT features ==================
1126 if(WIN32)
1127 status("")
1128 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1129   if(WINRT)
1130     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1131     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1132     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1133     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1134       status("    Building for C++ without CX extensions")
1135     endif()
1136   endif()
1137 endif(WIN32)
1138
1139 # ========================== GUI ==========================
1140 status("")
1141 status("  GUI: ")
1142
1143 if(WITH_QT OR HAVE_QT)
1144   if(HAVE_QT5)
1145     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1146     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1147   elseif(HAVE_QT)
1148     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1149     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1150   else()
1151     status("    QT:" "NO")
1152   endif()
1153 endif()
1154
1155 if(WITH_WIN32UI)
1156   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1157 endif()
1158
1159 if(APPLE)
1160   if(WITH_CARBON)
1161     status("    Carbon:" YES)
1162   else()
1163     status("    Cocoa:"  YES)
1164   endif()
1165 endif()
1166
1167 if(WITH_GTK OR HAVE_GTK)
1168   if(HAVE_GTK3)
1169     status("    GTK+:" "YES (ver ${ALIASOF_gtk+-3.0_VERSION})")
1170   elseif(HAVE_GTK)
1171     status("    GTK+:" "YES (ver ${ALIASOF_gtk+-2.0_VERSION})")
1172   else()
1173     status("    GTK+:" "NO")
1174   endif()
1175   if(HAVE_GTK)
1176     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})" ELSE NO)
1177     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
1178   endif()
1179 endif()
1180
1181 if(WITH_OPENGL OR HAVE_OPENGL)
1182   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1183 endif()
1184
1185 if(WITH_VTK OR HAVE_VTK)
1186   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1187 endif()
1188
1189 # ========================== MEDIA IO ==========================
1190 status("")
1191 status("  Media I/O: ")
1192 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1193
1194 if(WITH_JPEG OR HAVE_JPEG)
1195   if(NOT HAVE_JPEG)
1196     status("    JPEG:" NO)
1197   elseif(BUILD_JPEG)
1198     status("    JPEG:" "build-${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1199   else()
1200     status("    JPEG:" "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1201   endif()
1202 endif()
1203
1204 if(WITH_WEBP OR HAVE_WEBP)
1205   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1206 endif()
1207
1208 if(WITH_PNG OR HAVE_PNG)
1209   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1210 endif()
1211
1212 if(WITH_TIFF OR HAVE_TIFF)
1213   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1214 endif()
1215
1216 if(WITH_JASPER OR HAVE_JASPER)
1217   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
1218 endif()
1219
1220 if(WITH_OPENEXR OR HAVE_OPENEXR)
1221   status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1222 endif()
1223
1224 if(WITH_GDAL OR HAVE_GDAL)
1225   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1226 endif()
1227
1228 if(WITH_GDCM OR HAVE_GDCM)
1229   status("    GDCM:" HAVE_GDCM THEN "YES (ver ${GDCM_VERSION})" ELSE "NO")
1230 endif()
1231
1232 if(WITH_IMGCODEC_HDR OR DEFINED HAVE_IMGCODEC_HDR)
1233   status("    HDR:" HAVE_IMGCODEC_HDR THEN "YES" ELSE "NO")
1234 endif()
1235
1236 if(WITH_IMGCODEC_SUNRASTER OR DEFINED HAVE_IMGCODEC_SUNRASTER)
1237   status("    SUNRASTER:" HAVE_IMGCODEC_SUNRASTER THEN "YES" ELSE "NO")
1238 endif()
1239
1240 if(WITH_IMGCODEC_PXM OR DEFINED HAVE_IMGCODEC_PXM)
1241   status("    PXM:" HAVE_IMGCODEC_PXM THEN "YES" ELSE "NO")
1242 endif()
1243
1244 # ========================== VIDEO IO ==========================
1245 status("")
1246 status("  Video I/O:")
1247
1248 if(WITH_VFW OR HAVE_VFW)
1249   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
1250 endif()
1251
1252 if(WITH_1394 OR HAVE_DC1394)
1253   if (HAVE_DC1394_2)
1254     status("    DC1394:" "YES (ver ${ALIASOF_libdc1394-2_VERSION})")
1255   elseif (HAVE_DC1394)
1256     status("    DC1394:" "YES (ver ${ALIASOF_libdc1394_VERSION})")
1257   else()
1258     status("    DC1394:" "NO")
1259   endif()
1260 endif()
1261
1262 if(WITH_FFMPEG OR HAVE_FFMPEG)
1263   if(OPENCV_FFMPEG_USE_FIND_PACKAGE)
1264     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (find_package)"                       ELSE "NO (find_package)")
1265   elseif(WIN32)
1266     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1267   else()
1268     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1269   endif()
1270   status("      avcodec:"      FFMPEG_libavcodec_FOUND    THEN "YES (ver ${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1271   status("      avformat:"     FFMPEG_libavformat_FOUND   THEN "YES (ver ${FFMPEG_libavformat_VERSION})"   ELSE NO)
1272   status("      avutil:"       FFMPEG_libavutil_FOUND     THEN "YES (ver ${FFMPEG_libavutil_VERSION})"     ELSE NO)
1273   status("      swscale:"      FFMPEG_libswscale_FOUND    THEN "YES (ver ${FFMPEG_libswscale_VERSION})"    ELSE NO)
1274   status("      avresample:"   FFMPEG_libavresample_FOUND THEN "YES (ver ${FFMPEG_libavresample_VERSION})" ELSE NO)
1275 endif()
1276
1277 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1278   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
1279   if(HAVE_GSTREAMER)
1280     status("      base:"       "YES (ver ${GSTREAMER_BASE_VERSION})")
1281     status("      video:"      "YES (ver ${GSTREAMER_VIDEO_VERSION})")
1282     status("      app:"        "YES (ver ${GSTREAMER_APP_VERSION})")
1283     status("      riff:"       "YES (ver ${GSTREAMER_RIFF_VERSION})")
1284     status("      pbutils:"    "YES (ver ${GSTREAMER_PBUTILS_VERSION})")
1285   endif(HAVE_GSTREAMER)
1286 endif()
1287
1288 if(WITH_OPENNI OR HAVE_OPENNI)
1289   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})" ELSE NO)
1290   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
1291 endif()
1292
1293 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1294   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (ver ${OPENNI2_VERSION_STRING}, build ${OPENNI2_VERSION_BUILD})" ELSE NO)
1295 endif()
1296
1297 if(WITH_PVAPI OR HAVE_PVAPI)
1298   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
1299 endif()
1300
1301 if(WITH_GIGEAPI OR HAVE_GIGE_API)
1302   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
1303 endif()
1304
1305 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1306   status("    Aravis SDK:"     HAVE_ARAVIS_API     THEN "YES (${ARAVIS_LIBRARIES})"                ELSE NO)
1307 endif()
1308
1309 if(APPLE)
1310   status("    AVFoundation:"   HAVE_AVFOUNDATION   THEN YES                                        ELSE NO)
1311   if(WITH_QUICKTIME OR HAVE_QUICKTIME)
1312     status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
1313   endif()
1314   if(WITH_QTKIT OR HAVE_QTKIT)
1315     status("    QTKit:"          HAVE_QTKIT          THEN "YES (deprecated)"                         ELSE NO)
1316   endif()
1317 endif()
1318
1319 if(WITH_UNICAP OR HAVE_UNICAP)
1320   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
1321   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
1322 endif()
1323
1324 if(WITH_V4L OR WITH_LIBV4L OR HAVE_LIBV4L OR HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
1325   status("    libv4l/libv4l2:" HAVE_LIBV4L THEN "${ALIASOF_libv4l1_VERSION} / ${ALIASOF_libv4l2_VERSION}" ELSE "NO")
1326   ocv_build_features_string(v4l_status
1327     IF HAVE_CAMV4L THEN "linux/videodev.h"
1328     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1329     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1330     ELSE "NO")
1331   status("    v4l/v4l2:" "${v4l_status}")
1332 endif()
1333
1334 if(WITH_DSHOW OR HAVE_DSHOW)
1335   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
1336 endif()
1337
1338 if(WITH_MSMF OR HAVE_MSMF)
1339   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
1340 endif()
1341
1342 if(WITH_XIMEA OR HAVE_XIMEA)
1343   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
1344 endif()
1345
1346 if(WITH_XINE OR HAVE_XINE)
1347   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
1348 endif()
1349
1350 if(WITH_INTELPERC OR HAVE_INTELPERC)
1351   status("    Intel PerC:"     HAVE_INTELPERC      THEN "YES"                                 ELSE NO)
1352 endif()
1353
1354 if(WITH_MFX OR HAVE_MFX)
1355   status("    Intel Media SDK:" HAVE_MFX      THEN "YES (${MFX_LIBRARY})" ELSE NO)
1356 endif()
1357
1358 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1359   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1360 endif()
1361
1362 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1363 ocv_build_features_string(parallel_status EXCLUSIVE
1364   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1365   IF HAVE_CSTRIPES THEN "C="
1366   IF HAVE_OPENMP THEN "OpenMP"
1367   IF HAVE_GCD THEN "GCD"
1368   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1369   IF HAVE_PTHREADS_PF THEN "pthreads"
1370   ELSE "none")
1371 status("")
1372 status("  Parallel framework:" "${parallel_status}")
1373
1374 if(CV_TRACE OR OPENCV_TRACE)
1375   ocv_build_features_string(trace_status EXCLUSIVE
1376     IF HAVE_ITT THEN "with Intel ITT"
1377     ELSE "built-in")
1378   status("")
1379   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1380 endif()
1381
1382 # ========================== Other third-party libraries ==========================
1383 status("")
1384 status("  Other third-party libraries:")
1385
1386 if(WITH_IPP AND HAVE_IPP)
1387   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1388   status("           at:" "${IPP_ROOT_DIR}")
1389   if(NOT HAVE_IPP_ICV)
1390     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1391   endif()
1392   if(HAVE_IPP_IW)
1393     if(BUILD_IPP_IW)
1394       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1395     else()
1396       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1397     endif()
1398     status("              at:" "${IPP_IW_PATH}")
1399   else()
1400     status("    Intel IPP IW:"   NO)
1401   endif()
1402 endif()
1403
1404 if(WITH_VA OR HAVE_VA)
1405   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1406 endif()
1407
1408 if(WITH_VA_INTEL OR HAVE_VA_INTEL)
1409   status("    Intel VA-API/OpenCL:"  HAVE_VA_INTEL       THEN "YES (OpenCL: ${VA_INTEL_IOCL_ROOT})" ELSE NO)
1410 endif()
1411
1412 if(WITH_LAPACK OR HAVE_LAPACK)
1413   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1414 endif()
1415
1416 if(WITH_HALIDE OR HAVE_HALIDE)
1417   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1418 endif()
1419
1420 if(WITH_INF_ENGINE OR INF_ENGINE_TARGET)
1421   if(INF_ENGINE_TARGET)
1422     set(__msg "YES (${INF_ENGINE_RELEASE} / ${INF_ENGINE_VERSION})")
1423     get_target_property(_lib ${INF_ENGINE_TARGET} IMPORTED_LOCATION)
1424     if(NOT _lib)
1425       get_target_property(_lib_rel ${INF_ENGINE_TARGET} IMPORTED_IMPLIB_RELEASE)
1426       get_target_property(_lib_dbg ${INF_ENGINE_TARGET} IMPORTED_IMPLIB_DEBUG)
1427       set(_lib "${_lib_rel} / ${_lib_dbg}")
1428     endif()
1429     get_target_property(_inc ${INF_ENGINE_TARGET} INTERFACE_INCLUDE_DIRECTORIES)
1430     status("    Inference Engine:" "${__msg}")
1431     status("                libs:" "${_lib}")
1432     status("            includes:" "${_inc}")
1433   else()
1434     status("    Inference Engine:"     "NO")
1435   endif()
1436 endif()
1437
1438 if(WITH_EIGEN OR HAVE_EIGEN)
1439   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1440 endif()
1441
1442 if(WITH_OPENVX OR HAVE_OPENVX)
1443   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1444 endif()
1445
1446 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1447
1448 foreach(s ${CUSTOM_STATUS})
1449   status(${CUSTOM_STATUS_${s}})
1450 endforeach()
1451
1452 if(WITH_CUDA OR HAVE_CUDA)
1453   ocv_build_features_string(cuda_features
1454     IF HAVE_CUFFT THEN "CUFFT"
1455     IF HAVE_CUBLAS THEN "CUBLAS"
1456     IF HAVE_NVCUVID THEN "NVCUVID"
1457     IF CUDA_FAST_MATH THEN "FAST_MATH"
1458     ELSE "no extra features")
1459   status("")
1460   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1461   if(HAVE_CUDA)
1462     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1463     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1464   endif()
1465 endif()
1466
1467 if(WITH_OPENCL OR HAVE_OPENCL)
1468   ocv_build_features_string(opencl_features
1469     IF HAVE_OPENCL_SVM THEN "SVM"
1470     IF HAVE_CLAMDFFT THEN "AMDFFT"
1471     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1472     ELSE "no extra features")
1473   status("")
1474   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1475   if(HAVE_OPENCL)
1476     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1477     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1478   endif()
1479 endif()
1480
1481 # ========================== python ==========================
1482 if(BUILD_opencv_python2)
1483   status("")
1484   status("  Python 2:")
1485   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1486   if(PYTHON2LIBS_VERSION_STRING)
1487     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1488   else()
1489     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1490   endif()
1491   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1492   status("    packages path:" PYTHON2_EXECUTABLE         THEN "${PYTHON2_PACKAGES_PATH}"                                    ELSE "-")
1493 endif()
1494
1495 if(BUILD_opencv_python3)
1496   status("")
1497   status("  Python 3:")
1498   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1499   if(PYTHON3LIBS_VERSION_STRING)
1500     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1501   else()
1502     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1503   endif()
1504   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1505   status("    packages path:" PYTHON3_EXECUTABLE         THEN "${PYTHON3_PACKAGES_PATH}"                                    ELSE "-")
1506 endif()
1507
1508 status("")
1509 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1510 if(PYLINT_FOUND AND PYLINT_EXECUTABLE)
1511   status("    Pylint:"  PYLINT_FOUND THEN "${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}, checks: ${PYLINT_TOTAL_TARGETS})" ELSE NO)
1512 endif()
1513 if(FLAKE8_FOUND AND FLAKE8_EXECUTABLE)
1514   status("    Flake8:"  FLAKE8_FOUND THEN "${FLAKE8_EXECUTABLE} (ver: ${FLAKE8_VERSION})" ELSE NO)
1515 endif()
1516
1517 # ========================== java ==========================
1518 if(BUILD_JAVA OR BUILD_opencv_java)
1519   status("")
1520   status("  Java:"            BUILD_FAT_JAVA_LIB  THEN "export all functions"                                      ELSE "")
1521   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1522   if(NOT ANDROID)
1523     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1524   endif()
1525   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1526   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1527 endif()
1528
1529 ocv_cmake_hook(STATUS_DUMP_EXTRA)
1530
1531 # ========================== auxiliary ==========================
1532 status("")
1533 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1534 status("-----------------------------------------------------------------")
1535 status("")
1536
1537
1538 ocv_finalize_status()
1539
1540 ocv_cmake_hook(POST_FINALIZE)
1541
1542 # ----------------------------------------------------------------------------
1543 # CPack stuff
1544 # ----------------------------------------------------------------------------
1545
1546 include(cmake/OpenCVPackaging.cmake)
1547
1548 # This should be the last command
1549 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1550 ocv_cmake_eval(DEBUG_POST ONCE)