CMakeLists.txt

   1 # Copyright (c) 2015 The Khronos Group Inc.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and/or associated documentation files (the
   5 # "Materials"), to deal in the Materials without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sublicense, and/or sell copies of the Materials, and to
   8 # permit persons to whom the Materials are furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice shall be included
  12 # in all copies or substantial portions of the Materials.
  13 #
  14 # MODIFICATIONS TO THIS FILE MAY MEAN IT NO LONGER ACCURATELY REFLECTS
  15 # KHRONOS STANDARDS. THE UNMODIFIED, NORMATIVE VERSIONS OF KHRONOS
  16 # SPECIFICATIONS AND HEADER INFORMATION ARE LOCATED AT
  17 #    https://www.khronos.org/registry/
  18 #
  19 # THE MATERIALS ARE PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  20 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  21 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  22 # IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  23 # CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  24 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  25 # MATERIALS OR THE USE OR OTHER DEALINGS IN THE MATERIALS.
  26
  27 cmake_minimum_required(VERSION 2.8)
  28 project(spirv-tools)
  29 set(SPIRV_TOOLS "SPIRV-Tools")
  30
  31 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
  32   add_definitions(-DSPIRV_LINUX)
  33 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
  34   add_definitions(-DSPIRV_WINDOWS)
  35 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
  36   add_definitions(-DSPIRV_MAC)
  37 else()
  38   message(FATAL_ERROR "Your platform '${CMAKE_SYSTEM_NAME}' is not supported!")
  39 endif()
  40
  41 if ("${CMAKE_BUILD_TYPE}" STREQUAL "")
  42   message(STATUS "No build type selected, default to Debug")
  43   set(CMAKE_BUILD_TYPE "Debug")
  44 endif()
  45
  46 option(SPIRV_WERROR "Enable error on warning" ON)
  47 if(UNIX)
  48   set(SPIRV_WARNINGS -Wall -Wextra -Wno-missing-field-initializers)
  49
  50   option(SPIRV_WARN_EVERYTHING "Enable -Weverything" OFF)
  51   if(${SPIRV_WARN_EVERYTHING})
  52     set(SPIRV_WARNINGS ${SPIRV_WARNINGS}
  53       -Weverything -Wno-c++98-compat -Wno-c++98-compat-pedantic -Wno-padded)
  54   endif()
  55
  56   if(${SPIRV_WERROR})
  57     set(SPIRV_WARNINGS ${SPIRV_WARNINGS} -Werror)
  58   endif()
  59 elseif(WIN32)
  60   set(SPIRV_WARNINGS -D_CRT_SECURE_NO_WARNINGS /wd4800)
  61
  62   if(${SPIRV_WERROR})
  63     set(SPIRV_WARNINGS ${SPIRV_WARNINGS} /WX)
  64   endif()
  65 endif()
  66
  67 option(SPIRV_COLOR_TERMINAL "Enable color terminal output" ON)
  68 if(${SPIRV_COLOR_TERMINAL})
  69   add_definitions(-DSPIRV_COLOR_TERMINAL)
  70 endif()
  71
  72 function(default_compile_options TARGET)
  73   target_compile_options(${TARGET} PRIVATE ${SPIRV_WARNINGS})
  74   if (UNIX)
  75     target_compile_options(${TARGET} PRIVATE
  76       -std=c++11 -fno-exceptions -fno-rtti)
  77     # For good call stacks in profiles, keep the frame pointers.
  78     if(NOT "${SPIRV_PERF}" STREQUAL "")
  79       target_compile_options(${TARGET} PRIVATE -fno-omit-frame-pointer)
  80     endif()
  81     if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  82       set(SPIRV_USE_SANITIZER "" CACHE STRING
  83         "Use the clang sanitizer [address|memory|thread|...]")
  84       if(NOT "${SPIRV_USE_SANITIZER}" STREQUAL "")
  85         target_compile_options(${TARGET} PRIVATE
  86           -fsanitize=${SPIRV_USE_SANITIZER})
  87       endif()
  88     endif()
  89   endif()
  90 endfunction()
  91
  92 set(SPIRV_SOURCES
  93   ${CMAKE_CURRENT_SOURCE_DIR}/include/libspirv/libspirv.h
  94   ${CMAKE_CURRENT_SOURCE_DIR}/include/util/bitutils.h
  95   ${CMAKE_CURRENT_SOURCE_DIR}/include/util/hex_float.h
  96   ${CMAKE_CURRENT_SOURCE_DIR}/source/assembly_grammar.h
  97   ${CMAKE_CURRENT_SOURCE_DIR}/source/binary.h
  98   ${CMAKE_CURRENT_SOURCE_DIR}/source/diagnostic.h
  99   ${CMAKE_CURRENT_SOURCE_DIR}/source/endian.h
 100   ${CMAKE_CURRENT_SOURCE_DIR}/source/ext_inst.h
 101   ${CMAKE_CURRENT_SOURCE_DIR}/source/instruction.h
 102   ${CMAKE_CURRENT_SOURCE_DIR}/source/opcode.h
 103   ${CMAKE_CURRENT_SOURCE_DIR}/source/operand.h
 104   ${CMAKE_CURRENT_SOURCE_DIR}/source/print.h
 105   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_constant.h
 106   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_definition.h
 107   ${CMAKE_CURRENT_SOURCE_DIR}/source/table.h
 108   ${CMAKE_CURRENT_SOURCE_DIR}/source/text.h
 109   ${CMAKE_CURRENT_SOURCE_DIR}/source/text_handler.h
 110   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate.h
 111   ${CMAKE_CURRENT_SOURCE_DIR}/source/assembly_grammar.cpp
 112   ${CMAKE_CURRENT_SOURCE_DIR}/source/binary.cpp
 113   ${CMAKE_CURRENT_SOURCE_DIR}/source/disassemble.cpp
 114   ${CMAKE_CURRENT_SOURCE_DIR}/source/diagnostic.cpp
 115   ${CMAKE_CURRENT_SOURCE_DIR}/source/endian.cpp
 116   ${CMAKE_CURRENT_SOURCE_DIR}/source/ext_inst.cpp
 117   ${CMAKE_CURRENT_SOURCE_DIR}/source/opcode.cpp
 118   ${CMAKE_CURRENT_SOURCE_DIR}/source/operand.cpp
 119   ${CMAKE_CURRENT_SOURCE_DIR}/source/print.cpp
 120   ${CMAKE_CURRENT_SOURCE_DIR}/source/table.cpp
 121   ${CMAKE_CURRENT_SOURCE_DIR}/source/text.cpp
 122   ${CMAKE_CURRENT_SOURCE_DIR}/source/text_handler.cpp
 123   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate.cpp
 124   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_id.cpp)
 125
 126 add_library(${SPIRV_TOOLS} ${SPIRV_SOURCES})
 127 default_compile_options(${SPIRV_TOOLS})
 128 target_include_directories(${SPIRV_TOOLS} PUBLIC
 129   ${CMAKE_CURRENT_SOURCE_DIR}/include
 130   ${CMAKE_CURRENT_SOURCE_DIR}/external/include)
 131
 132 option(SPIRV_SKIP_EXECUTABLES
 133   "Skip building the executables and tests along with the library" OFF)
 134 set(SPIRV_INSTALL_TARGETS ${SPIRV_TOOLS})
 135 if (NOT ${SPIRV_SKIP_EXECUTABLES})
 136   list(APPEND SPIRV_INSTALL_TARGETS spirv-as spirv-dis spirv-val)
 137
 138   add_executable(spirv-as ${CMAKE_CURRENT_SOURCE_DIR}/tools/as/as.cpp)
 139   default_compile_options(spirv-as)
 140   target_link_libraries(spirv-as PRIVATE ${SPIRV_TOOLS})
 141
 142   add_executable(spirv-dis ${CMAKE_CURRENT_SOURCE_DIR}/tools/dis/dis.cpp)
 143   default_compile_options(spirv-dis)
 144   target_link_libraries(spirv-dis PRIVATE ${SPIRV_TOOLS})
 145
 146   add_executable(spirv-val ${CMAKE_CURRENT_SOURCE_DIR}/tools/val/val.cpp)
 147   default_compile_options(spirv-val)
 148   target_link_libraries(spirv-val PRIVATE ${SPIRV_TOOLS})
 149
 150   set(GMOCK_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/googletest/googlemock)
 151   if(EXISTS ${GMOCK_DIR})
 152     if(WIN32)
 153       option(gtest_force_shared_crt
 154         "Use shared (DLL) run-time lib even when Google Test is built as static lib."
 155         ON)
 156     endif()
 157
 158     add_subdirectory(${GMOCK_DIR})
 159   endif()
 160   if (TARGET gmock)
 161     message(STATUS "Found Google Mock, building tests.")
 162
 163     set(TEST_SOURCES
 164       ${CMAKE_CURRENT_SOURCE_DIR}/test/TestFixture.h
 165       ${CMAKE_CURRENT_SOURCE_DIR}/test/UnitSPIRV.h
 166
 167       ${CMAKE_CURRENT_SOURCE_DIR}/test/AssemblyContext.cpp
 168       ${CMAKE_CURRENT_SOURCE_DIR}/test/AssemblyFormat.cpp
 169       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryDestroy.cpp
 170       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryEndianness.cpp
 171       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryHeaderGet.cpp
 172       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryParse.cpp
 173       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryToText.cpp
 174       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryToText.Literal.cpp
 175       ${CMAKE_CURRENT_SOURCE_DIR}/test/Comment.cpp
 176       ${CMAKE_CURRENT_SOURCE_DIR}/test/DiagnosticPrint.cpp
 177       ${CMAKE_CURRENT_SOURCE_DIR}/test/DiagnosticStream.cpp
 178       ${CMAKE_CURRENT_SOURCE_DIR}/test/ExtInstGLSLstd450.cpp
 179       ${CMAKE_CURRENT_SOURCE_DIR}/test/ExtInst.OpenCL.std.cpp
 180       ${CMAKE_CURRENT_SOURCE_DIR}/test/FixWord.cpp
 181       ${CMAKE_CURRENT_SOURCE_DIR}/test/GeneratorMagicNumber.cpp
 182       ${CMAKE_CURRENT_SOURCE_DIR}/test/HexFloat.cpp
 183       ${CMAKE_CURRENT_SOURCE_DIR}/test/ImmediateInt.cpp
 184       ${CMAKE_CURRENT_SOURCE_DIR}/test/LibspirvMacros.cpp
 185       ${CMAKE_CURRENT_SOURCE_DIR}/test/NamedId.cpp
 186       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeMake.cpp
 187       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeRequiresCapabilities.cpp
 188       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeSplit.cpp
 189       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeTableGet.cpp
 190       ${CMAKE_CURRENT_SOURCE_DIR}/test/OperandCapabilities.cpp
 191       ${CMAKE_CURRENT_SOURCE_DIR}/test/Operand.cpp
 192       ${CMAKE_CURRENT_SOURCE_DIR}/test/OperandPattern.cpp
 193       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextAdvance.cpp
 194       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextDestroy.cpp
 195       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextLiteral.cpp
 196       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextStartsNewInst.cpp
 197       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Annotation.cpp
 198       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Barrier.cpp
 199       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Constant.cpp
 200       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.ControlFlow.cpp
 201       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.cpp
 202       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Debug.cpp
 203       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.DeviceSideEnqueue.cpp
 204       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Extension.cpp
 205       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Function.cpp
 206       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Group.cpp
 207       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Image.cpp
 208       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Literal.cpp
 209       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Memory.cpp
 210       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Miscellaneous.cpp
 211       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.ModeSetting.cpp
 212       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.TypeDeclaration.cpp
 213       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextWordGet.cpp
 214       ${CMAKE_CURRENT_SOURCE_DIR}/test/UnitSPIRV.cpp
 215       ${CMAKE_CURRENT_SOURCE_DIR}/test/ValidateFixtures.cpp
 216       ${CMAKE_CURRENT_SOURCE_DIR}/test/Validate.SSA.cpp
 217       ${CMAKE_CURRENT_SOURCE_DIR}/test/ValidateID.cpp
 218       ${CMAKE_CURRENT_SOURCE_DIR}/test/main.cpp)
 219
 220     add_executable(UnitSPIRV ${TEST_SOURCES})
 221     default_compile_options(UnitSPIRV)
 222     target_include_directories(UnitSPIRV PRIVATE
 223       ${gmock_SOURCE_DIR}/include ${gtest_SOURCE_DIR}/include)
 224     target_link_libraries(UnitSPIRV PRIVATE ${SPIRV_TOOLS} gmock)
 225   else()
 226     message(STATUS "Did not find googletest, tests will not be built."
 227       "To enable tests place googletest in '<spirv-dir>/external/googletest'.")
 228   endif()
 229 endif()
 230
 231 install(TARGETS ${SPIRV_INSTALL_TARGETS}
 232   RUNTIME DESTINATION bin
 233   LIBRARY DESTINATION lib
 234   ARCHIVE DESTINATION lib)
 235
 236 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/include/libspirv/libspirv.h
 237   DESTINATION include/libspirv/)