CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 if(NOT DEFINED CMAKE_BUILD_TYPE)
   4         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type")
   5 endif()
   6
   7 project(libwebsockets C)
   8
   9 set(PACKAGE "libwebsockets")
  10 set(CPACK_PACKAGE_NAME "${PACKAGE}")
  11 set(CPACK_PACKAGE_VERSION_MAJOR "1")
  12 set(CPACK_PACKAGE_VERSION_MINOR "4")
  13 set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}")
  14 set(CPACK_PACKAGE_VENDOR "andy@warmcat.com")
  15 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "${PACKAGE} ${PACKAGE_VERSION}")
  16 set(SOVERSION "5")
  17 set(CPACK_SOURCE_GENERATOR "TGZ")
  18 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  19 set(VERSION "${CPACK_PACKAGE_VERSION}")
  20
  21 set(LWS_LIBRARY_VERSION ${CPACK_PACKAGE_VERSION})
  22 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake/")
  23
  24 message(STATUS "CMAKE_TOOLCHAIN_FILE='${CMAKE_TOOLCHAIN_FILE}'")
  25
  26 # Try to find the current Git hash.
  27 find_package(Git)
  28 if(GIT_EXECUTABLE)
  29         execute_process(
  30     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  31     COMMAND "${GIT_EXECUTABLE}" log -n 1 --pretty=%h
  32     OUTPUT_VARIABLE GIT_HASH
  33     OUTPUT_STRIP_TRAILING_WHITESPACE
  34     )
  35
  36     set(LWS_BUILD_HASH ${GIT_HASH})
  37     message("Git commit hash: ${LWS_BUILD_HASH}")
  38 endif()
  39
  40 set(LWS_USE_BUNDLED_ZLIB_DEFAULT OFF)
  41 if(WIN32)
  42         set(LWS_USE_BUNDLED_ZLIB_DEFAULT ON)
  43 endif()
  44
  45 option(LWS_WITH_STATIC "Build the static version of the library" ON)
  46 option(LWS_WITH_SHARED "Build the shared version of the library" ON)
  47 option(LWS_WITH_SSL "Include SSL support (default OpenSSL, CyaSSL if LWS_USE_CYASSL is set)" ON)
  48 option(LWS_USE_CYASSL "Use CyaSSL replacement for OpenSSL. When settings this, you also need to specify LWS_CYASSL_LIBRARIES and LWS_CYASSL_INCLUDE_DIRS" OFF)
  49 option(LWS_WITH_ZLIB "Include zlib support (required for extensions)" ON)
  50 option(LWS_WITH_LIBEV "Compile with support for libev" OFF)
  51 option(LWS_USE_BUNDLED_ZLIB "Use bundled zlib version (Windows only)" ${LWS_USE_BUNDLED_ZLIB_DEFAULT})
  52 option(LWS_SSL_CLIENT_USE_OS_CA_CERTS "SSL support should make use of OS installed CA root certs" ON)
  53 option(LWS_WITHOUT_BUILTIN_GETIFADDRS "Don't use BSD getifaddrs implementation from libwebsockets if it is missing (this will result in a compilation error) ... Default is your libc provides it. On some systems such as uclibc it doesn't exist." OFF)
  54 option(LWS_WITHOUT_CLIENT "Don't build the client part of the library" OFF)
  55 option(LWS_WITHOUT_SERVER "Don't build the server part of the library" OFF)
  56 option(LWS_LINK_TESTAPPS_DYNAMIC "Link the test apps to the shared version of the library. Default is to link statically" OFF)
  57 option(LWS_WITHOUT_TESTAPPS "Don't build the libwebsocket-test-apps" OFF)
  58 option(LWS_WITHOUT_TEST_SERVER "Don't build the test server" OFF)
  59 option(LWS_WITHOUT_TEST_SERVER_EXTPOLL "Don't build the test server version that uses external poll" OFF)
  60 option(LWS_WITHOUT_TEST_PING "Don't build the ping test application" OFF)
  61 option(LWS_WITHOUT_TEST_CLIENT "Don't build the client test application" OFF)
  62 option(LWS_WITHOUT_TEST_FRAGGLE "Don't build the ping test application" OFF)
  63 option(LWS_WITHOUT_EXTENSIONS "Don't compile with extensions" OFF)
  64 option(LWS_WITH_LATENCY "Build latency measuring code into the library" OFF)
  65 option(LWS_WITHOUT_DAEMONIZE "Don't build the daemonization api" ON)
  66 option(LWS_IPV6 "Compile with support for ipv6" OFF)
  67 option(LWS_WITH_HTTP2 "Compile with support for http2" OFF)
  68
  69 # Allow the user to override installation directories.
  70 set(LWS_INSTALL_LIB_DIR       lib CACHE PATH "Installation directory for libraries")
  71 set(LWS_INSTALL_BIN_DIR       bin CACHE PATH "Installation directory for executables")
  72 set(LWS_INSTALL_INCLUDE_DIR   include CACHE PATH "Installation directory for header files")
  73 set(LWS_INSTALL_EXAMPLES_DIR  bin CACHE PATH "Installation directory for example files")
  74
  75 if (LWS_WITHOUT_CLIENT AND LWS_WITHOUT_SERVER)
  76         message(FATAL_ERROR "Makes no sense to compile without both client or server.")
  77 endif()
  78
  79 if (NOT (LWS_WITH_STATIC OR LWS_WITH_SHARED))
  80         message(FATAL_ERROR "Makes no sense to compile without both static or shared libraries.")
  81 endif()
  82
  83 if (NOT LWS_WITHOUT_EXTENSIONS)
  84         if (NOT LWS_WITH_ZLIB)
  85                 message(FATAL_ERROR "zlib is required for extensions.")
  86         endif()
  87 endif()
  88
  89 set(LWS_ZLIB_LIBRARIES CACHE PATH "Path to the zlib library")
  90 set(LWS_ZLIB_INCLUDE_DIRS CACHE PATH "Path to the zlib include directory")
  91 set(LWS_OPENSSL_LIBRARIES CACHE PATH "Path to the OpenSSL library")
  92 set(LWS_OPENSSL_INCLUDE_DIRS CACHE PATH "Path to the OpenSSL include directory")
  93 set(LWS_CYASSL_LIBRARIES CACHE PATH "Path to the CyaSSL library")
  94 set(LWS_CYASSL_INCLUDE_DIRS CACHE PATH "Path to the CyaSSL include directory")
  95 set(LWS_LIBEV_LIBRARIES CACHE PATH "Path to the libev library")
  96 set(LWS_LIBEV_INCLUDE_DIRS CACHE PATH "Path to the libev include directory")
  97
  98 if (LWS_WITH_SSL AND NOT LWS_USE_CYASSL)
  99         if ("${LWS_OPENSSL_LIBRARIES}" STREQUAL "" OR "${LWS_OPENSSL_INCLUDE_DIRS}" STREQUAL "")
 100         else()
 101                 set(OPENSSL_LIBRARIES ${LWS_OPENSSL_LIBRARIES})
 102                 set(OPENSSL_INCLUDE_DIRS ${LWS_OPENSSL_INCLUDE_DIRS})
 103                 set(OPENSSL_FOUND 1)
 104         endif()
 105 endif()
 106
 107 if (LWS_WITH_SSL AND LWS_USE_CYASSL)
 108         if ("${LWS_CYASSL_LIBRARIES}" STREQUAL "" OR "${LWS_CYASSL_INCLUDE_DIRS}" STREQUAL "")
 109                 if (NOT CYASSL_FOUND)
 110                         message(FATAL_ERROR "You must set LWS_CYASSL_LIBRARIES and LWS_CYASSL_INCLUDE_DIRS when LWS_USE_CYASSL is turned on.")
 111                 endif()
 112         else()
 113                 set(CYASSL_LIBRARIES ${LWS_CYASSL_LIBRARIES})
 114                 set(CYASSL_INCLUDE_DIRS ${LWS_CYASSL_INCLUDE_DIRS})
 115                 set(CYASSL_FOUND 1)
 116         endif()
 117         set(USE_CYASSL 1)
 118 endif()
 119
 120 if (LWS_WITH_ZLIB AND NOT LWS_USE_BUNDLED_ZLIB)
 121         if ("${LWS_ZLIB_LIBRARIES}" STREQUAL "" OR "${LWS_ZLIB_INCLUDE_DIRS}" STREQUAL "")
 122         else()
 123                 set(ZLIB_LIBRARIES ${LWS_ZLIB_LIBRARIES})
 124                 set(ZLIB_INCLUDE_DIRS ${LWS_ZLIB_INCLUDE_DIRS})
 125                 set(ZLIB_FOUND 1)
 126         endif()
 127 endif()
 128
 129 if (LWS_WITH_LIBEV)
 130         if ("${LWS_LIBEV_LIBRARIES}" STREQUAL "" OR "${LWS_LIBEV_INCLUDE_DIRS}" STREQUAL "")
 131         else()
 132                 set(LIBEV_LIBRARIES ${LWS_LIBEV_LIBRARIES})
 133                 set(LIBEV_INCLUDE_DIRS ${LWS_LIBEV_INCLUDE_DIRS})
 134                 set(LIBEV_FOUND 1)
 135         endif()
 136 endif()
 137
 138 # FIXME: This must be runtime-only option.
 139 # The base dir where the test-apps look for the SSL certs.
 140 set(LWS_OPENSSL_CLIENT_CERTS ../share CACHE PATH "Server SSL certificate directory")
 141 if (WIN32)
 142         set(LWS_OPENSSL_CLIENT_CERTS . CACHE PATH "Client SSL certificate directory")
 143
 144         if (LWS_IPV6)
 145                 set(LWS_IPV6 OFF)
 146                 message(WARNING "IPv6 does currently not work on Windows!")
 147         endif()
 148 else()
 149         set(LWS_OPENSSL_CLIENT_CERTS /etc/pki/tls/certs/ CACHE PATH "Client SSL certificate directory")
 150 endif()
 151
 152 if (LWS_WITHOUT_EXTENSIONS)
 153         set(LWS_NO_EXTENSIONS 1)
 154 endif()
 155
 156 if (LWS_WITH_SSL)
 157         set(LWS_OPENSSL_SUPPORT 1)
 158 endif()
 159
 160 if (LWS_SSL_CLIENT_USE_OS_CA_CERTS)
 161         set(LWS_SSL_CLIENT_USE_OS_CA_CERTS 1)
 162 endif()
 163
 164 if (LWS_WITH_LATENCY)
 165         set(LWS_LATENCY 1)
 166 endif()
 167
 168 if (LWS_WITHOUT_DAEMONIZE OR WIN32)
 169         set(LWS_NO_DAEMONIZE 1)
 170 endif()
 171
 172 if (LWS_WITHOUT_SERVER)
 173         set(LWS_NO_SERVER 1)
 174 endif()
 175
 176 if (LWS_WITHOUT_CLIENT)
 177         set(LWS_NO_CLIENT 1)
 178 endif()
 179
 180 if (LWS_WITH_LIBEV)
 181         set(LWS_USE_LIBEV 1)
 182 endif()
 183
 184 if (LWS_IPV6)
 185         set(LWS_USE_IPV6 1)
 186 endif()
 187
 188 if (LWS_WITH_HTTP2)
 189         set(LWS_USE_HTTP2 1)
 190 endif()
 191
 192 if (MINGW)
 193         set(LWS_MINGW_SUPPORT 1)
 194 endif()
 195
 196 include_directories("${PROJECT_BINARY_DIR}")
 197
 198 include(CheckCSourceCompiles)
 199
 200 # Check for different inline keyword versions.
 201 foreach(KEYWORD "inline" "__inline__" "__inline")
 202         set(CMAKE_REQUIRED_DEFINITIONS "-DKEYWORD=${KEYWORD}")
 203         CHECK_C_SOURCE_COMPILES(
 204                 "
 205                 #include <stdio.h>
 206                 static KEYWORD void a() {}
 207                 int main(int argc, char **argv) { a(); return 0; }
 208                 " HAVE_${KEYWORD})
 209 endforeach()
 210
 211 if (NOT HAVE_inline)
 212         if (HAVE___inline__)
 213                 set(inline __inline__)
 214         elseif(HAVE___inline)
 215                 set(inline __inline)
 216         endif()
 217 endif()
 218
 219 # Put the libaries and binaries that get built into directories at the
 220 # top of the build tree rather than in hard-to-find leaf directories.
 221 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin")
 222 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 223 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 224
 225 # Put absolute path of dynamic libraries into the object code. Some
 226 # architectures, notably Mac OS X, need this.
 227 SET(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}")
 228
 229 include(CheckFunctionExists)
 230 include(CheckIncludeFile)
 231 include(CheckIncludeFiles)
 232 include(CheckLibraryExists)
 233 include(CheckTypeSize)
 234
 235 CHECK_FUNCTION_EXISTS(bzero HAVE_BZERO)
 236 CHECK_FUNCTION_EXISTS(fork HAVE_FORK)
 237 CHECK_FUNCTION_EXISTS(getenv HAVE_GETENV)
 238 CHECK_FUNCTION_EXISTS(malloc HAVE_MALLOC)
 239 CHECK_FUNCTION_EXISTS(memset HAVE_MEMSET)
 240 CHECK_FUNCTION_EXISTS(realloc HAVE_REALLOC)
 241 CHECK_FUNCTION_EXISTS(socket HAVE_SOCKET)
 242 CHECK_FUNCTION_EXISTS(strerror HAVE_STRERROR)
 243 CHECK_FUNCTION_EXISTS(vfork HAVE_VFORK)
 244 CHECK_FUNCTION_EXISTS(getifaddrs HAVE_GETIFADDRS)
 245
 246 if (NOT HAVE_GETIFADDRS)
 247         if (LWS_WITHOUT_BUILTIN_GETIFADDRS)
 248                 message(FATAL_ERROR "No getifaddrs was found on the system. Turn off the LWS_WITHOUT_BUILTIN_GETIFADDRS compile option to use the supplied BSD version.")
 249         endif()
 250         set(LWS_BUILTIN_GETIFADDRS 1)
 251 endif()
 252
 253 CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 254 CHECK_INCLUDE_FILE(fcntl.h HAVE_FCNTL_H)
 255 CHECK_INCLUDE_FILE(in6addr.h HAVE_IN6ADDR_H)
 256 CHECK_INCLUDE_FILE(inttypes.h HAVE_INTTYPES_H)
 257 CHECK_INCLUDE_FILE(memory.h HAVE_MEMORY_H)
 258 CHECK_INCLUDE_FILE(netinet/in.h HAVE_NETINET_IN_H)
 259 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 260 CHECK_INCLUDE_FILE(stdlib.h HAVE_STDLIB_H)
 261 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 262 CHECK_INCLUDE_FILE(string.h HAVE_STRING_H)
 263 CHECK_INCLUDE_FILE(sys/prctl.h HAVE_SYS_PRCTL_H)
 264 CHECK_INCLUDE_FILE(sys/socket.h HAVE_SYS_SOCKET_H)
 265 CHECK_INCLUDE_FILE(sys/stat.h HAVE_SYS_STAT_H)
 266 CHECK_INCLUDE_FILE(sys/types.h HAVE_SYS_TYPES_H)
 267 CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 268 CHECK_INCLUDE_FILE(vfork.h HAVE_VFORK_H)
 269 CHECK_INCLUDE_FILE(zlib.h HAVE_ZLIB_H)
 270
 271 # TODO: These can be tested if they actually work also...
 272 set(HAVE_WORKING_FORK HAVE_FORK)
 273 set(HAVE_WORKING_VFORK HAVE_VFORK)
 274
 275 CHECK_INCLUDE_FILES("stdlib.h;stdarg.h;string.h;float.h" STDC_HEADERS)
 276
 277 CHECK_TYPE_SIZE(pid_t PID_T_SIZE)
 278 CHECK_TYPE_SIZE(size_t SIZE_T_SIZE)
 279
 280 if (NOT PID_T_SIZE)
 281         set(pid_t int)
 282 endif()
 283
 284 if (NOT SIZE_T_SIZE)
 285         set(size_t "unsigned int")
 286 endif()
 287
 288 if (NOT HAVE_MALLOC)
 289         set(malloc rpl_malloc)
 290 endif()
 291
 292 if (NOT HAVE_REALLOC)
 293         set(realloc rpl_realloc)
 294 endif()
 295
 296 # Generate the lws_config.h that includes all the compilation settings.
 297 configure_file(
 298        "${PROJECT_SOURCE_DIR}/lws_config.h.in"
 299        "${PROJECT_BINARY_DIR}/lws_config.h")
 300
 301 if (MSVC)
 302         # Turn off stupid microsoft security warnings.
 303         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 304 endif(MSVC)
 305
 306 include_directories("${PROJECT_SOURCE_DIR}/lib")
 307
 308 # Group headers and sources.
 309 # Some IDEs use this for nicer file structure.
 310 set(HDR_PRIVATE
 311         lib/private-libwebsockets.h)
 312
 313 set(HDR_PUBLIC
 314         "${PROJECT_SOURCE_DIR}/lib/libwebsockets.h"
 315         "${PROJECT_BINARY_DIR}/lws_config.h")
 316
 317 set(SOURCES
 318         lib/base64-decode.c
 319         lib/handshake.c
 320         lib/libwebsockets.c
 321         lib/service.c
 322         lib/pollfd.c
 323         lib/output.c
 324         lib/parsers.c
 325         lib/context.c
 326         lib/sha-1.c
 327         lib/alloc.c
 328         lib/header.c)
 329
 330 if (NOT LWS_WITHOUT_CLIENT)
 331         list(APPEND SOURCES
 332                 lib/client.c
 333                 lib/client-handshake.c
 334                 lib/client-parser.c)
 335 endif()
 336
 337 if (LWS_WITH_SSL)
 338         list(APPEND SOURCES
 339                 lib/ssl.c)
 340 endif()
 341
 342 if (LWS_WITH_HTTP2)
 343         list(APPEND SOURCES
 344                 lib/http2.c
 345                 lib/hpack.c
 346                 lib/ssl-http2.c)
 347 endif()
 348 # select the active platform files
 349
 350 if (WIN32)
 351         list(APPEND SOURCES
 352                 lib/lws-plat-win.c)
 353 else()
 354         list(APPEND SOURCES
 355                 lib/lws-plat-unix.c)
 356 endif()
 357
 358 if (NOT LWS_WITHOUT_SERVER)
 359         list(APPEND SOURCES
 360                 lib/server.c
 361                 lib/server-handshake.c)
 362 endif()
 363
 364 if (NOT LWS_WITHOUT_EXTENSIONS)
 365         list(APPEND HDR_PRIVATE
 366                 lib/extension-deflate-frame.h
 367                 lib/extension-deflate-stream.h)
 368         list(APPEND SOURCES
 369                 lib/extension.c
 370                 lib/extension-deflate-frame.c
 371                 lib/extension-deflate-stream.c)
 372 endif()
 373
 374 if (LWS_WITH_LIBEV)
 375         list(APPEND SOURCES
 376                 lib/libev.c)
 377 endif(LWS_WITH_LIBEV)
 378
 379 # Add helper files for Windows.
 380 if (WIN32)
 381         set(WIN32_HELPERS_PATH win32port/win32helpers)
 382         include_directories(${WIN32_HELPERS_PATH})
 383 else()
 384         # Unix.
 385         if (NOT LWS_WITHOUT_DAEMONIZE)
 386                 list(APPEND SOURCES
 387                         lib/daemonize.c)
 388         endif()
 389 endif()
 390
 391 if (UNIX)
 392         if (NOT HAVE_GETIFADDRS)
 393                 list(APPEND HDR_PRIVATE lib/getifaddrs.h)
 394                 list(APPEND SOURCES lib/getifaddrs.c)
 395         endif()
 396 endif()
 397
 398 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 399     include (CheckCCompilerFlag)
 400     CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY)
 401     if (HAVE_VISIBILITY)
 402                 set(VISIBILITY_FLAG -fvisibility=hidden)
 403     endif()
 404     if (UNIX)
 405                 set(CMAKE_C_FLAGS "-Wall -Werror -O3 ${VISIBILITY_FLAG} ${CMAKE_C_FLAGS}" )
 406     else(UNIX)
 407                 set(CMAKE_C_FLAGS "-Wall -O3 ${VISIBILITY_FLAG} ${CMAKE_C_FLAGS}" )
 408     endif(UNIX)
 409 endif ()
 410
 411 source_group("Headers Private"  FILES ${HDR_PRIVATE})
 412 source_group("Headers Public"   FILES ${HDR_PUBLIC})
 413 source_group("Sources"          FILES ${SOURCES})
 414
 415 #
 416 # Create the lib.
 417 #
 418 set(LWS_LIBRARIES)
 419 if (LWS_WITH_STATIC)
 420         add_library(websockets STATIC
 421                                 ${HDR_PRIVATE}
 422                                 ${HDR_PUBLIC}
 423                                 ${SOURCES})
 424         list(APPEND LWS_LIBRARIES websockets)
 425 endif()
 426 if (LWS_WITH_SHARED)
 427         add_library(websockets_shared SHARED
 428                                 ${HDR_PRIVATE}
 429                                 ${HDR_PUBLIC}
 430                                 ${SOURCES})
 431         list(APPEND LWS_LIBRARIES websockets_shared)
 432 endif()
 433
 434 if (WIN32)
 435         if (LWS_WITH_SHARED)
 436                 # Compile as DLL (export function declarations)
 437                 set_property(
 438                         TARGET websockets_shared
 439                         PROPERTY COMPILE_DEFINITIONS
 440                         LWS_DLL
 441                         LWS_INTERNAL)
 442         endif()
 443 elseif(APPLE)
 444         if (LWS_WITH_SHARED)
 445                 set_property(TARGET websockets_shared PROPERTY MACOSX_RPATH YES)
 446         endif()
 447 endif()
 448
 449 # Set the so version of the lib.
 450 # Equivalent to LDFLAGS=-version-info x:x:x
 451 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 452         foreach(lib ${LWS_LIBRARIES})
 453                 set_target_properties(${lib}
 454                         PROPERTIES
 455                         SOVERSION ${SOVERSION})
 456         endforeach()
 457 endif()
 458
 459 set(LIB_LIST)
 460
 461 #
 462 # Find libraries.
 463 #
 464
 465 #
 466 # ZLIB (Only needed for deflate extensions).
 467 #
 468 if (LWS_WITH_ZLIB)
 469         if (LWS_USE_BUNDLED_ZLIB)
 470                 if (WIN32)
 471                         set(WIN32_ZLIB_PATH "win32port/zlib")
 472                         set(ZLIB_SRCS
 473                                 ${WIN32_ZLIB_PATH}/adler32.c
 474                                 ${WIN32_ZLIB_PATH}/compress.c
 475                                 ${WIN32_ZLIB_PATH}/crc32.c
 476                                 ${WIN32_ZLIB_PATH}/deflate.c
 477                                 ${WIN32_ZLIB_PATH}/gzclose.c
 478                                 ${WIN32_ZLIB_PATH}/gzio.c
 479                                 ${WIN32_ZLIB_PATH}/gzlib.c
 480                                 ${WIN32_ZLIB_PATH}/gzread.c
 481                                 ${WIN32_ZLIB_PATH}/gzwrite.c
 482                                 ${WIN32_ZLIB_PATH}/infback.c
 483                                 ${WIN32_ZLIB_PATH}/inffast.c
 484                                 ${WIN32_ZLIB_PATH}/inflate.c
 485                                 ${WIN32_ZLIB_PATH}/inftrees.c
 486                                 ${WIN32_ZLIB_PATH}/trees.c
 487                                 ${WIN32_ZLIB_PATH}/uncompr.c
 488                                 ${WIN32_ZLIB_PATH}/zutil.c)
 489                         add_library(zlib_internal STATIC ${ZLIB_SRCS})
 490                         set(ZLIB_INCLUDE_DIRS ${WIN32_ZLIB_PATH})
 491                         get_property(ZLIB_LIBRARIES TARGET zlib_internal PROPERTY LOCATION)
 492                         set(ZLIB_FOUND 1)
 493                         # Make sure zlib_internal is compiled before the libs.
 494                         foreach (lib ${LWS_LIBRARIES})
 495                                 add_dependencies(${lib} zlib_internal)
 496                         endforeach()
 497                 else()
 498                         message(FATAL_ERROR "Don't have bundled zlib for that platform")
 499                 endif()
 500         elseif (NOT ZLIB_FOUND)
 501                 find_package(ZLIB REQUIRED)
 502         endif()
 503         message("zlib include dirs: ${ZLIB_INCLUDE_DIRS}")
 504         message("zlib libraries: ${ZLIB_LIBRARIES}")
 505         include_directories(${ZLIB_INCLUDE_DIRS})
 506         list(APPEND LIB_LIST ${ZLIB_LIBRARIES})
 507 endif()
 508
 509 #
 510 # OpenSSL
 511 #
 512 if (LWS_WITH_SSL)
 513         message("Compiling with SSL support")
 514
 515         if (LWS_USE_CYASSL)
 516                 # Use CyaSSL as OpenSSL replacement.
 517                 # TODO: Add a find_package command for this also.
 518                 message("CyaSSL include dir: ${CYASSL_INCLUDE_DIRS}")
 519                 message("CyaSSL libraries: ${CYASSL_LIBRARIES}")
 520
 521                 # Additional to the root directory we need to include
 522                 # the cyassl/ subdirectory which contains the OpenSSL
 523                 # compatability layer headers.
 524                 foreach(inc ${CYASSL_LIBRARIES})
 525                         include_directories("${inc}" "${inc}/cyassl")
 526                 endforeach()
 527
 528                 list(APPEND LIB_LIST "${CYASSL_LIBRARIES}")
 529         else()
 530                 if (NOT OPENSSL_FOUND)
 531                         # TODO: Add support for STATIC also.
 532                         find_package(OpenSSL REQUIRED)
 533                         set(OPENSSL_INCLUDE_DIRS "${OPENSSL_INCLUDE_DIR}")
 534                 endif()
 535
 536                 message("OpenSSL include dir: ${OPENSSL_INCLUDE_DIRS}")
 537                 message("OpenSSL libraries: ${OPENSSL_LIBRARIES}")
 538
 539                 include_directories("${OPENSSL_INCLUDE_DIRS}")
 540                 list(APPEND LIB_LIST ${OPENSSL_LIBRARIES})
 541         endif()
 542 endif(LWS_WITH_SSL)
 543
 544 if (LWS_WITH_LIBEV)
 545         if (NOT LIBEV_FOUND)
 546                 find_path(LIBEV_INCLUDE_DIRS NAMES ev.h)
 547                 find_library(LIBEV_LIBRARIES NAMES ev)
 548                 if(LIBEV_INCLUDE_DIRS AND LIBEV_LIBRARIES)
 549                         set(LIBEV_FOUND 1)
 550                 endif()
 551         endif()
 552         message("libev include dir: ${LIBEV_INCLUDE_DIRS}")
 553         message("libev libraries: ${LIBEV_LIBRARIES}")
 554         include_directories("${LIBEV_INCLUDE_DIRS}")
 555         list(APPEND LIB_LIST ${LIBEV_LIBRARIES})
 556 endif(LWS_WITH_LIBEV)
 557
 558 #
 559 # Platform specific libs.
 560 #
 561 if (WINCE)
 562         list(APPEND LIB_LIST ws2.lib)
 563 elseif (WIN32)
 564         list(APPEND LIB_LIST ws2_32.lib)
 565 endif()
 566
 567 if (UNIX)
 568         list(APPEND LIB_LIST m)
 569 endif()
 570
 571 # Setup the linking for all libs.
 572 foreach (lib ${LWS_LIBRARIES})
 573         target_link_libraries(${lib} ${LIB_LIST})
 574 endforeach()
 575
 576 #
 577 # Test applications
 578 #
 579 set(TEST_APP_LIST)
 580 if (NOT LWS_WITHOUT_TESTAPPS)
 581         #
 582         # Helper function for adding a test app.
 583         #
 584         macro(create_test_app TEST_NAME MAIN_SRC)
 585
 586                 set(TEST_SRCS ${MAIN_SRC})
 587                 set(TEST_HDR)
 588
 589                 if (WIN32)
 590                         list(APPEND TEST_SRCS
 591                                 ${WIN32_HELPERS_PATH}/getopt.c
 592                                 ${WIN32_HELPERS_PATH}/getopt_long.c
 593                                 ${WIN32_HELPERS_PATH}/gettimeofday.c
 594                         )
 595
 596                         list(APPEND TEST_HDR
 597                                 ${WIN32_HELPERS_PATH}/getopt.h
 598                                 ${WIN32_HELPERS_PATH}/gettimeofday.h
 599                         )
 600                 endif(WIN32)
 601
 602                 source_group("Headers Private"   FILES ${TEST_HDR})
 603                 source_group("Sources"   FILES ${TEST_SRCS})
 604                 add_executable(${TEST_NAME} ${TEST_SRCS} ${TEST_HDR})
 605
 606                 if (LWS_LINK_TESTAPPS_DYNAMIC)
 607                         if (NOT LWS_WITH_SHARED)
 608                                 message(FATAL_ERROR "Build of shared library is disabled. LWS_LINK_TESTAPPS_DYNAMIC must be combined with LWS_WITH_SHARED.")
 609                         endif()
 610                         target_link_libraries(${TEST_NAME} websockets_shared)
 611                         add_dependencies(${TEST_NAME} websockets_shared)
 612                 else()
 613                         if (NOT LWS_WITH_STATIC)
 614                                 message(FATAL_ERROR "Build of static library is disabled. Disabled LWS_LINK_TESTAPPS_DYNAMIC must be combined with LWS_WITH_STATIC.")
 615                         endif()
 616                         target_link_libraries(${TEST_NAME} websockets)
 617                         add_dependencies(${TEST_NAME} websockets)
 618                 endif()
 619
 620                 # Set test app specific defines.
 621                 set_property(TARGET ${TEST_NAME}
 622                                         PROPERTY COMPILE_DEFINITIONS
 623                                                 INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 624                                         )
 625
 626                 # Prefix the binary names with libwebsockets.
 627                 set_target_properties(${TEST_NAME}
 628                         PROPERTIES
 629                         OUTPUT_NAME libwebsockets-${TEST_NAME})
 630
 631                 # Add to the list of tests.
 632                 list(APPEND TEST_APP_LIST ${TEST_NAME})
 633         endmacro()
 634
 635         if (LWS_WITH_SSL AND NOT LWS_USE_CYASSL)
 636                 message("Searching for OpenSSL executable and dlls")
 637                 find_package(OpenSSLbins)
 638                 message("OpenSSL executable: ${OPENSSL_EXECUTABLE}")
 639         endif()
 640
 641         if (NOT LWS_WITHOUT_SERVER)
 642                 #
 643                 # test-server
 644                 #
 645                 if (NOT LWS_WITHOUT_TEST_SERVER)
 646                         create_test_app(test-server "test-server/test-server.c")
 647                 endif()
 648
 649                 #
 650                 # test-server-extpoll
 651                 #
 652                 if (NOT LWS_WITHOUT_TEST_SERVER_EXTPOLL)
 653                         create_test_app(test-server-extpoll "test-server/test-server.c")
 654                         # Set defines for this executable only.
 655                         set_property(
 656                                 TARGET test-server-extpoll
 657                                 PROPERTY COMPILE_DEFINITIONS
 658                                         EXTERNAL_POLL
 659                                         INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 660                                 )
 661
 662                         # We need to link against winsock code.
 663                         if (WIN32)
 664                                 target_link_libraries(test-server-extpoll ws2_32.lib)
 665                         endif(WIN32)
 666                 endif()
 667
 668                 # Data files for running the test server.
 669                 set(TEST_SERVER_DATA
 670                         "${PROJECT_SOURCE_DIR}/test-server/favicon.ico"
 671                         "${PROJECT_SOURCE_DIR}/test-server/leaf.jpg"
 672                         "${PROJECT_SOURCE_DIR}/test-server/libwebsockets.org-logo.png"
 673                         "${PROJECT_SOURCE_DIR}/test-server/test.html")
 674
 675                 # Generate self-signed SSL certs for the test-server.
 676                 if (LWS_WITH_SSL AND OPENSSL_EXECUTABLE AND NOT LWS_WITHOUT_TEST_SERVER)
 677                         message("Generating SSL Certificates for the test-server...")
 678
 679                         set(TEST_SERVER_SSL_KEY "${PROJECT_BINARY_DIR}/libwebsockets-test-server.key.pem")
 680                         set(TEST_SERVER_SSL_CERT "${PROJECT_BINARY_DIR}/libwebsockets-test-server.pem")
 681
 682                         if (WIN32)
 683                                 file(WRITE "${PROJECT_BINARY_DIR}/openssl_input.txt"
 684                                         "GB\n"
 685                                         "Erewhon\n"
 686                                         "All around\n"
 687                                         "libwebsockets-test\n"
 688                                         "localhost\n"
 689                                         "none@invalid.org\n\n"
 690                                         )
 691
 692                                 # The "type" command is a bit picky with paths.
 693                                 file(TO_NATIVE_PATH "${PROJECT_BINARY_DIR}/openssl_input.txt" OPENSSL_INPUT_WIN_PATH)
 694                                 message("OPENSSL_INPUT_WIN_PATH = ${OPENSSL_INPUT_WIN_PATH}")
 695                                 message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 696
 697                                 execute_process(
 698                                         COMMAND cmd /c type "${OPENSSL_INPUT_WIN_PATH}"
 699                                         COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 700                                         RESULT_VARIABLE OPENSSL_RETURN_CODE
 701                                         OUTPUT_QUIET ERROR_QUIET)
 702
 703                                 message("\n")
 704
 705                                 if (OPENSSL_RETURN_CODE)
 706                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server using cmd.exe !!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 707                                 else()
 708                                         message("SUCCSESFULLY generated SSL certificate")
 709                                 endif()
 710                         else()
 711                                 # Unix.
 712                                 execute_process(
 713                                         COMMAND printf "GB\\nErewhon\\nAll around\\nlibwebsockets-test\\n\\nlocalhost\\nnone@invalid.org\\n"
 714                                         COMMAND "${OPENSSL_EXECUTABLE}"
 715                                                 req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 716                                         RESULT_VARIABLE OPENSSL_RETURN_CODE
 717                                         OUTPUT_QUIET ERROR_QUIET)
 718
 719                                 if (OPENSSL_RETURN_CODE)
 720                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server!!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 721                                 else()
 722                                         message("SUCCSESFULLY generated SSL certificate")
 723                                 endif()
 724                         endif()
 725
 726                         list(APPEND TEST_SERVER_DATA
 727                                 "${TEST_SERVER_SSL_KEY}"
 728                                 "${TEST_SERVER_SSL_CERT}")
 729                 endif()
 730
 731                 add_custom_command(TARGET test-server
 732                                                 POST_BUILD
 733                                                 COMMAND "${CMAKE_COMMAND}" -E make_directory "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server")
 734
 735                 # Copy the file needed to run the server so that the test apps can
 736                 # reach them from their default output location
 737                 foreach (TEST_FILE ${TEST_SERVER_DATA})
 738                         if (EXISTS ${TEST_FILE})
 739                                 add_custom_command(TARGET test-server
 740                                                         POST_BUILD
 741                                                         COMMAND "${CMAKE_COMMAND}" -E copy "${TEST_FILE}" "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server" VERBATIM)
 742                         endif()
 743                 endforeach()
 744         endif(NOT LWS_WITHOUT_SERVER)
 745
 746         if (NOT LWS_WITHOUT_CLIENT)
 747                 #
 748                 # test-client
 749                 #
 750                 if (NOT LWS_WITHOUT_TEST_CLIENT)
 751                         create_test_app(test-client "test-server/test-client.c")
 752                 endif()
 753
 754                 #
 755                 # test-fraggle
 756                 #
 757                 if (NOT LWS_WITHOUT_TEST_FRAGGLE)
 758                         create_test_app(test-fraggle "test-server/test-fraggle.c")
 759                 endif()
 760
 761                 #
 762                 # test-ping
 763                 #
 764                 if (NOT LWS_WITHOUT_TEST_PING)
 765                         create_test_app(test-ping "test-server/test-ping.c")
 766                 endif()
 767                 #
 768                 # test-echo
 769                 #
 770                 if (NOT WITHOUT_TEST_ECHO)
 771                         create_test_app(test-echo "test-server/test-echo.c")
 772                 endif()
 773
 774         endif(NOT LWS_WITHOUT_CLIENT)
 775
 776         #
 777         # Copy OpenSSL dlls to the output directory on Windows.
 778         # (Otherwise we'll get an error when trying to run)
 779         #
 780         if (WIN32 AND LWS_WITH_SSL AND NOT LWS_USE_CYASSL)
 781                 if(OPENSSL_BIN_FOUND)
 782                         message("OpenSSL dlls found:")
 783                         message("  Libeay: ${LIBEAY_BIN}")
 784                         message("  SSLeay: ${SSLEAY_BIN}")
 785
 786                         foreach(TARGET_BIN ${TEST_APP_LIST})
 787                                 add_custom_command(TARGET ${TARGET_BIN}
 788                                         POST_BUILD
 789                                         COMMAND "${CMAKE_COMMAND}" -E copy "${LIBEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 790                                 add_custom_command(TARGET ${TARGET_BIN}
 791                                         POST_BUILD
 792                                         COMMAND "${CMAKE_COMMAND}" -E copy "${SSLEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 793                         endforeach()
 794                 endif()
 795         endif()
 796 endif(NOT LWS_WITHOUT_TESTAPPS)
 797
 798 if (UNIX)
 799         # Generate documentation.
 800         # TODO: Fix this on Windows.
 801         message("Generating API documentation")
 802         file(GLOB C_FILES "${PROJECT_SOURCE_DIR}/lib/*.c")
 803         execute_process(COMMAND "${CMAKE_COMMAND}" -E make_directory "${PROJECT_BINARY_DIR}/doc/")
 804
 805         execute_process(
 806                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -html ${C_FILES} ${HDR_PUBLIC}
 807                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.html"
 808                 ERROR_QUIET)
 809
 810         execute_process(
 811                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -text ${C_FILES} ${HDR_PUBLIC}
 812                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.txt"
 813                 ERROR_QUIET)
 814
 815 # Generate and install pkgconfig.
 816 # (This is not indented, because the tabs will be part of the output)
 817 file(WRITE "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 818 "prefix=\"${CMAKE_INSTALL_PREFIX}\"
 819 exec_prefix=\${prefix}
 820 libdir=\${exec_prefix}/lib${LIB_SUFFIX}
 821 includedir=\${prefix}/include
 822
 823 Name: libwebsockets
 824 Description: Websockets server and client library
 825 Version: ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}
 826
 827 Libs: -L\${libdir} -lwebsockets
 828 Cflags: -I\${includedir}"
 829 )
 830
 831         install(FILES "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 832                 DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 833 endif(UNIX)
 834
 835 #
 836 # Installation preparations.
 837 #
 838
 839 if(WIN32 AND NOT CYGWIN)
 840   set(DEF_INSTALL_CMAKE_DIR cmake)
 841 else()
 842   set(DEF_INSTALL_CMAKE_DIR lib/cmake/libwebsockets)
 843 endif()
 844
 845 set(LWS_INSTALL_CMAKE_DIR ${DEF_INSTALL_CMAKE_DIR} CACHE PATH "Installation directory for CMake files")
 846
 847 # Export targets (This is used for other CMake projects to easily find the libraries and include files).
 848 export(TARGETS ${LWS_LIBRARIES}
 849         FILE "${PROJECT_BINARY_DIR}/LibwebsocketsTargets.cmake")
 850 export(PACKAGE libwebsockets)
 851
 852 # Generate the config file for the build-tree.
 853 set(LWS__INCLUDE_DIRS
 854     "${PROJECT_SOURCE_DIR}/lib"
 855     "${PROJECT_BINARY_DIR}")
 856 set(LIBWEBSOCKETS_INCLUDE_DIRS ${LWS__INCLUDE_DIRS} CACHE PATH "Libwebsockets include directories")
 857 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 858                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfig.cmake
 859                 @ONLY)
 860
 861 # Generate the config file for the installation tree.
 862 get_filename_component(LWS_ABSOLUTE_INSTALL_CMAKE_DIR ${LWS_INSTALL_CMAKE_DIR} ABSOLUTE)
 863 get_filename_component(LWS_ABSOLUTE_INSTALL_INCLUDE_DIR ${LWS_INSTALL_INCLUDE_DIR} ABSOLUTE)
 864 file(RELATIVE_PATH
 865     REL_INCLUDE_DIR
 866     "${LWS_ABSOLUTE_INSTALL_CMAKE_DIR}"
 867     "${LWS_ABSOLUTE_INSTALL_INCLUDE_DIR}") # Calculate the relative directory from the cmake dir.
 868
 869 # Note the EVENT_CMAKE_DIR is defined in JanssonConfig.cmake.in,
 870 # we escape it here so it's evaluated when it is included instead
 871 # so that the include dirs are given relative to where the
 872 # config file is located.
 873 set(LWS__INCLUDE_DIRS
 874     "\${LWS_CMAKE_DIR}/${REL_INCLUDE_DIR}")
 875 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 876                 ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/LibwebsocketsConfig.cmake
 877                 @ONLY)
 878
 879 # Generate version info for both build-tree and install-tree.
 880 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfigVersion.cmake.in
 881                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfigVersion.cmake
 882                 @ONLY)
 883
 884                         set_target_properties(${LWS_LIBRARIES}
 885                                         PROPERTIES PUBLIC_HEADER "${HDR_PUBLIC}")
 886
 887 #
 888 # Installation.
 889 #
 890
 891 # Install libs and headers.
 892 install(TARGETS ${LWS_LIBRARIES}
 893                 EXPORT LibwebsocketsTargets
 894                 LIBRARY DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
 895                 ARCHIVE DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
 896                 RUNTIME DESTINATION "${LWS_INSTALL_BIN_DIR}" COMPONENT libraries # Windows DLLs
 897                 PUBLIC_HEADER DESTINATION "${LWS_INSTALL_INCLUDE_DIR}" COMPONENT dev)
 898 set(CPACK_COMPONENT_LIBRARIES_DISPLAY_NAME "Libraries")
 899 set(CPACK_COMPONENT_DEV_DISPLAY_NAME "Development files")
 900
 901 # Install test apps.
 902 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_CLIENT)
 903         install(TARGETS test-client ${TEST_APP_LIST}
 904                         RUNTIME DESTINATION ${LWS_INSTALL_EXAMPLES_DIR}
 905                         COMPONENT examples)
 906         set(CPACK_COMPONENT_EXAMPLES_DISPLAY_NAME "Example files")
 907 endif()
 908
 909 # Programs shared files used by the test-server.
 910 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_SERVER)
 911         install(FILES ${TEST_SERVER_DATA}
 912                         DESTINATION share/libwebsockets-test-server
 913                         COMPONENT examples)
 914 endif()
 915
 916 # Install exports for the install-tree.
 917 install(EXPORT LibwebsocketsTargets
 918                 DESTINATION "${LWS_INSTALL_CMAKE_DIR}" COMPONENT dev)
 919
 920 # build subdir is not part of sources
 921 set(CPACK_SOURCE_IGNORE_FILES $(CPACK_SOURCE_IGNORE_FILES) ".git" "build" "tgz" "tar.gz")
 922
 923 # Most people are more used to "make dist" compared to "make package_source"
 924 add_custom_target(dist COMMAND "${CMAKE_MAKE_PROGRAM}" package_source)
 925
 926 include(UseRPMTools)
 927 if (RPMTools_FOUND)
 928         RPMTools_ADD_RPM_TARGETS(libwebsockets libwebsockets.spec)
 929 endif()
 930
 931 message("---------------------------------------------------------------------")
 932 message("  Settings:  (For more help do cmake -LH <srcpath>)")
 933 message("---------------------------------------------------------------------")
 934 message(" LWS_WITH_SSL = ${LWS_WITH_SSL}  (SSL Support)")
 935 message(" LWS_SSL_CLIENT_USE_OS_CA_CERTS = ${LWS_SSL_CLIENT_USE_OS_CA_CERTS}")
 936 message(" LWS_USE_CYASSL = ${LWS_USE_CYASSL} (CyaSSL replacement for OpenSSL)")
 937 if (LWS_USE_CYASSL)
 938         message("   LWS_CYASSL_LIBRARIES = ${LWS_CYASSL_LIBRARIES}")
 939         message("   LWS_CYASSL_INCLUDE_DIRS = ${LWS_CYASSL_INCLUDE_DIRS}")
 940 endif()
 941 message(" LWS_WITHOUT_BUILTIN_GETIFADDRS = ${LWS_WITHOUT_BUILTIN_GETIFADDRS}")
 942 message(" LWS_WITHOUT_CLIENT = ${LWS_WITHOUT_CLIENT}")
 943 message(" LWS_WITHOUT_SERVER = ${LWS_WITHOUT_SERVER}")
 944 message(" LWS_LINK_TESTAPPS_DYNAMIC = ${LWS_LINK_TESTAPPS_DYNAMIC}")
 945 message(" LWS_WITHOUT_TESTAPPS = ${LWS_WITHOUT_TESTAPPS}")
 946 message(" LWS_WITHOUT_TEST_SERVER = ${LWS_WITHOUT_TEST_SERVER}")
 947 message(" LWS_WITHOUT_TEST_SERVER_EXTPOLL = ${LWS_WITHOUT_TEST_SERVER_EXTPOLL}")
 948 message(" LWS_WITHOUT_TEST_PING = ${LWS_WITHOUT_TEST_PING}")
 949 message(" LWS_WITHOUT_TEST_CLIENT = ${LWS_WITHOUT_TEST_CLIENT}")
 950 message(" LWS_WITHOUT_TEST_FRAGGLE = ${LWS_WITHOUT_TEST_FRAGGLE}")
 951 message(" LWS_WITHOUT_EXTENSIONS = ${LWS_WITHOUT_EXTENSIONS}")
 952 message(" LWS_WITH_LATENCY = ${LWS_WITH_LATENCY}")
 953 message(" LWS_WITHOUT_DAEMONIZE = ${LWS_WITHOUT_DAEMONIZE}")
 954 message(" LWS_USE_LIBEV = ${LWS_USE_LIBEV}")
 955 message(" LWS_IPV6 = ${LWS_IPV6}")
 956 message(" LWS_WITH_HTTP2 = ${LWS_WITH_HTTP2}")
 957 message("---------------------------------------------------------------------")
 958
 959 # These will be available to parent projects including libwebsockets using add_subdirectory()
 960 set(LIBWEBSOCKETS_LIBRARIES ${LWS_LIBRARIES} CACHE STRING "Libwebsocket libraries")
 961 if (LWS_WITH_STATIC)
 962         set(LIBWEBSOCKETS_LIBRARIES_STATIC websocket CACHE STRING "Libwebsocket static library")
 963 endif()
 964 if (LWS_WITH_SHARED)
 965         set(LIBWEBSOCKETS_LIBRARIES_SHARED websockets_shared CACHE STRING "Libwebsocket shared library")
 966 endif()
 967
 968 # This must always be last!
 969 include(CPack)