CMakeLists.txt

   1 # The name of our project is "VULKAN". CMakeLists files in this project can
   2 # refer to the root source directory of the project as ${VULKAN_SOURCE_DIR} and
   3 # to the root binary directory of the project as ${VULKAN_BINARY_DIR}.
   4 cmake_minimum_required(VERSION 2.8.11)
   5 project (VULKAN)
   6 # set (CMAKE_VERBOSE_MAKEFILE 1)
   7
   8 # The API_NAME allows renaming builds to avoid conflicts with installed SDKs
   9 # The MAJOR number of the version we're building, used in naming
  10 # <api-name>-<major>.dll (and other files).
  11 set(API_NAME "Vulkan" CACHE STRING "API name to use when building")
  12 set(MAJOR "1")
  13 string(TOLOWER ${API_NAME} API_LOWERCASE)
  14
  15 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  16 find_package(PythonInterp 3 REQUIRED)
  17
  18 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  19     set(FALLBACK_CONFIG_DIRS "/etc/xdg" CACHE STRING
  20         "Search path to use when XDG_CONFIG_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  21     set(FALLBACK_DATA_DIRS "/usr/local/share:/usr/share" CACHE STRING
  22         "Search path to use when XDG_DATA_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  23
  24     include(FindPkgConfig)
  25     option(BUILD_WSI_XCB_SUPPORT "Build XCB WSI support" ON)
  26     option(BUILD_WSI_XLIB_SUPPORT "Build Xlib WSI support" ON)
  27     option(BUILD_WSI_WAYLAND_SUPPORT "Build Wayland WSI support" ON)
  28     option(BUILD_WSI_MIR_SUPPORT "Build Mir WSI support" ON)
  29     set(DEMOS_WSI_SELECTION "XCB" CACHE STRING "Select WSI target for demos (XCB, XLIB, WAYLAND, MIR, DISPLAY)")
  30
  31     if (BUILD_WSI_XCB_SUPPORT)
  32         find_package(XCB REQUIRED)
  33     endif()
  34
  35     if (BUILD_WSI_XLIB_SUPPORT)
  36         find_package(X11 REQUIRED)
  37     endif()
  38
  39     if (BUILD_WSI_WAYLAND_SUPPORT)
  40         find_package(Wayland REQUIRED)
  41         include_directories(${WAYLAND_CLIENT_INCLUDE_DIR})
  42     endif()
  43
  44     if (BUILD_WSI_MIR_SUPPORT)
  45         find_package(Mir REQUIRED)
  46     endif()
  47 endif()
  48
  49 set(SCRIPTS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/scripts")
  50
  51 # Header file for CMake settings
  52 include_directories("${PROJECT_SOURCE_DIR}/include")
  53
  54 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  55     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  56     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  57     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
  58     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
  59     if (UNIX)
  60         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
  61         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
  62     endif()
  63 endif()
  64
  65 if(WIN32)
  66     # Treat warnings as errors
  67     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/WX>")
  68     # Disable RTTI
  69     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/GR->")
  70     # Warn about nested declarations
  71     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34456>")
  72 endif()
  73
  74 if(NOT WIN32)
  75     set (BUILDTGT_DIR build)
  76     set (BINDATA_DIR Bin)
  77     set (LIBSOURCE_DIR Lib)
  78 else()
  79     option(DISABLE_BUILD_PATH_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with MSVC build type info" OFF)
  80     option(DISABLE_BUILDTGT_DIR_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with target info" OFF)
  81
  82     # For Windows, since 32-bit and 64-bit items can co-exist, we build each in its own build directory.
  83     # 32-bit target data goes in build32, and 64-bit target data goes into build.  So, include/link the
  84     # appropriate data at build time.
  85     if (DISABLE_BUILDTGT_DIR_DECORATION)
  86         set (BUILDTGT_DIR "")
  87         set (BINDATA_DIR "")
  88         set (LIBSOURCE_DIR "")
  89     elseif (CMAKE_CL_64)
  90         set (BUILDTGT_DIR build)
  91         set (BINDATA_DIR Bin)
  92         set (LIBSOURCE_DIR Lib)
  93     else()
  94         set (BUILDTGT_DIR build32)
  95         set (BINDATA_DIR Bin32)
  96         set (LIBSOURCE_DIR Lib32)
  97     endif()
  98 endif()
  99
 100 option(BUILD_LOADER "Build loader" ON)
 101 option(BUILD_TESTS "Build tests" ON)
 102 option(BUILD_LAYERS "Build layers" ON)
 103 option(BUILD_DEMOS "Build demos" ON)
 104 option(BUILD_VKJSON "Build vkjson" ON)
 105 option(CUSTOM_GLSLANG_BIN_ROOT "Use the user defined GLSLANG_BINARY_ROOT" OFF)
 106 option(CUSTOM_SPIRV_TOOLS_BIN_ROOT "Use the user defined SPIRV_TOOLS_BINARY_ROOT" OFF)
 107
 108 #Choose natural default paths for glslang and SPIRV-Tools binaries to support custom definition by the user on the CMake command line or in the GUI
 109 set(GLSLANG_BINARY_ROOT "${CMAKE_BINARY_DIR}/../glslang" CACHE STRING "User defined path to the glslang binaries for this project")
 110 set(SPIRV_TOOLS_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools" CACHE STRING "User defined path to the SPIRV-Tools binaries for this project")
 111
 112 # Define a variable for a default root location to the gslang, SPIRV-Tools and other external sources and cache it to allow the user to customize it as needed
 113 set(EXTERNAL_SOURCE_ROOT "${CMAKE_SOURCE_DIR}/external" CACHE STRING "Root path to external sources such as glslang and SPIRV-Tools")
 114
 115
 116 if (WIN32)
 117     if(CUSTOM_GLSLANG_BIN_ROOT)
 118         set(GSLANG_FINAL_BINARY_PATH ${GLSLANG_BINARY_ROOT}/${BUILDTGT_DIR})
 119     else()
 120         set(GSLANG_FINAL_BINARY_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}")
 121     endif()
 122
 123     if(DISABLE_BUILD_PATH_DECORATION)
 124         set (DEBUG_DECORATION "")
 125         set (RELEASE_DECORATION "")
 126     else()
 127         set (DEBUG_DECORATION "Debug")
 128         set (RELEASE_DECORATION "Release")
 129     endif()
 130
 131     # Take some steps to set up a variable pointing to the final glslang binaries given the variety of input options
 132     set (GLSLANG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${RELEASE_DECORATION}"
 133                              "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${RELEASE_DECORATION}"
 134                              "${GSLANG_FINAL_BINARY_PATH}/hlsl/${RELEASE_DECORATION}"
 135                              "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${RELEASE_DECORATION}"
 136                              "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${RELEASE_DECORATION}" )
 137
 138     set (GLSLANG_DEBUG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${DEBUG_DECORATION}"
 139                                    "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${DEBUG_DECORATION}"
 140                                    "${GSLANG_FINAL_BINARY_PATH}/hlsl/${DEBUG_DECORATION}"
 141                                    "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${DEBUG_DECORATION}"
 142                                    "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${DEBUG_DECORATION}")
 143
 144     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 145         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 146         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 147     else()
 148         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 149         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 150     endif()
 151 else()
 152     #non windows
 153     if(CUSTOM_GLSLANG_BIN_ROOT)
 154         set (GLSLANG_SEARCH_PATH "${GLSLANG_BINARY_ROOT}/install/lib"
 155                                  "${GLSLANG_BINARY_ROOT}/glslang"
 156                                  "${GLSLANG_BINARY_ROOT}/glslang/OSDependent/Unix"
 157                                  "${GLSLANG_BINARY_ROOT}/OGLCompilersDLL"
 158                                  "${GLSLANG_BINARY_ROOT}/SPIRV"
 159                                  "${GLSLANG_BINARY_ROOT}/hlsl"
 160                                  "${GLSLANG_BINARY_ROOT}/StandAlone")
 161     else()
 162         set (GLSLANG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/lib" "${CMAKE_SOURCE_DIR}/../x86_64/lib/glslang" )
 163     endif()
 164
 165     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 166         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/source" )
 167     else()
 168         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 169     endif()
 170 endif()
 171
 172 find_program(GLSLANG_VALIDATOR NAMES glslangValidator
 173              HINTS "${CMAKE_SOURCE_DIR}/external/glslang/${BUILDTGT_DIR}/install/bin"
 174                    "${GLSLANG_BINARY_ROOT}/StandAlone"
 175                    "${PROJECT_SOURCE_DIR}/external/${BINDATA_DIR}")
 176
 177 find_path(GLSLANG_SPIRV_INCLUDE_DIR SPIRV/spirv.hpp HINTS "${EXTERNAL_SOURCE_ROOT}/glslang"
 178                                                     "${CMAKE_SOURCE_DIR}/../glslang"
 179                                               DOC "Path to SPIRV/spirv.hpp")
 180
 181 find_path(SPIRV_TOOLS_INCLUDE_DIR spirv-tools/libspirv.h HINTS "${EXTERNAL_SOURCE_ROOT}/spirv-tools/include"
 182                                                    "${EXTERNAL_SOURCE_ROOT}/SPIRV-Tools/include"
 183                                                    "${CMAKE_SOURCE_DIR}/../spirv-tools/include"
 184                                                    "${CMAKE_SOURCE_DIR}/../SPIRV-Tools/include"
 185                                                    "${EXTERNAL_SOURCE_ROOT}/source/spirv-tools/external/include"
 186                                              DOC "Path to spirv-tools/libspirv.h")
 187
 188 find_library(GLSLANG_LIB NAMES glslang
 189              HINTS ${GLSLANG_SEARCH_PATH} )
 190
 191 find_library(OGLCompiler_LIB NAMES OGLCompiler
 192              HINTS ${GLSLANG_SEARCH_PATH} )
 193
 194 find_library(OSDependent_LIB NAMES OSDependent
 195              HINTS ${GLSLANG_SEARCH_PATH} )
 196
 197 find_library(HLSL_LIB NAMES HLSL
 198              HINTS ${GLSLANG_SEARCH_PATH} )
 199
 200 find_library(SPIRV_LIB NAMES SPIRV
 201              HINTS ${GLSLANG_SEARCH_PATH} )
 202
 203 find_library(SPIRV_REMAPPER_LIB NAMES SPVRemapper
 204              HINTS ${GLSLANG_SEARCH_PATH} )
 205
 206 find_library(SPIRV_TOOLS_LIB NAMES SPIRV-Tools
 207              HINTS ${SPIRV_TOOLS_SEARCH_PATH} )
 208
 209 if (WIN32)
 210     add_library(glslang     STATIC IMPORTED)
 211     add_library(OGLCompiler STATIC IMPORTED)
 212     add_library(OSDependent STATIC IMPORTED)
 213     add_library(HLSL        STATIC IMPORTED)
 214     add_library(SPIRV       STATIC IMPORTED)
 215     add_library(SPVRemapper       STATIC IMPORTED)
 216     add_library(Loader      STATIC IMPORTED)
 217     add_library(SPIRV-Tools STATIC IMPORTED)
 218
 219     find_library(GLSLANG_DLIB NAMES glslangd
 220                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 221     find_library(OGLCompiler_DLIB NAMES OGLCompilerd
 222                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 223     find_library(OSDependent_DLIB NAMES OSDependentd
 224                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 225     find_library(HLSL_DLIB NAMES HLSLd
 226                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 227     find_library(SPIRV_DLIB NAMES SPIRVd
 228                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 229     find_library(SPIRV_REMAPPER_DLIB NAMES SPVRemapperd
 230                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 231     find_library(SPIRV_TOOLS_DLIB NAMES SPIRV-Tools
 232                  HINTS ${SPIRV_TOOLS_DEBUG_SEARCH_PATH} )
 233
 234     set_target_properties(glslang PROPERTIES
 235                          IMPORTED_LOCATION       "${GLSLANG_LIB}"
 236                          IMPORTED_LOCATION_DEBUG "${GLSLANG_DLIB}")
 237     set_target_properties(OGLCompiler PROPERTIES
 238                          IMPORTED_LOCATION       "${OGLCompiler_LIB}"
 239                          IMPORTED_LOCATION_DEBUG "${OGLCompiler_DLIB}")
 240     set_target_properties(OSDependent PROPERTIES
 241                          IMPORTED_LOCATION       "${OSDependent_LIB}"
 242                          IMPORTED_LOCATION_DEBUG "${OSDependent_DLIB}")
 243     set_target_properties(HLSL PROPERTIES
 244                          IMPORTED_LOCATION       "${HLSL_LIB}"
 245                          IMPORTED_LOCATION_DEBUG "${HLSL_DLIB}")
 246     set_target_properties(SPIRV PROPERTIES
 247                          IMPORTED_LOCATION       "${SPIRV_LIB}"
 248                          IMPORTED_LOCATION_DEBUG "${SPIRV_DLIB}")
 249     set_target_properties(SPVRemapper PROPERTIES
 250                          IMPORTED_LOCATION       "${SPIRV_REMAPPER_LIB}"
 251                          IMPORTED_LOCATION_DEBUG "${SPIRV_REMAPPER_DLIB}")
 252     set_target_properties(SPIRV-Tools PROPERTIES
 253                          IMPORTED_LOCATION       "${SPIRV_TOOLS_LIB}"
 254                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_DLIB}")
 255
 256     set (GLSLANG_LIBRARIES glslang OGLCompiler OSDependent HLSL SPIRV SPVRemapper)
 257     set (SPIRV_TOOLS_LIBRARIES SPIRV-Tools)
 258 else ()
 259     set (GLSLANG_LIBRARIES ${GLSLANG_LIB} ${OGLCompiler_LIB} ${OSDependent_LIB} ${HLSL_LIB} ${SPIRV_LIB} ${SPIRV_REMAPPER_LIB})
 260     set (SPIRV_TOOLS_LIBRARIES ${SPIRV_TOOLS_LIB})
 261 endif()
 262
 263 set (PYTHON_CMD ${PYTHON_EXECUTABLE})
 264
 265 # Define macro used for building vkxml generated files
 266 macro(run_vk_xml_generate dependency output)
 267     add_custom_command(OUTPUT ${output}
 268     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/lvl_genvk.py -registry ${SCRIPTS_DIR}/vk.xml ${output}
 269     DEPENDS ${SCRIPTS_DIR}/vk.xml ${SCRIPTS_DIR}/generator.py ${SCRIPTS_DIR}/${dependency} ${SCRIPTS_DIR}/lvl_genvk.py ${SCRIPTS_DIR}/reg.py
 270     )
 271 endmacro()
 272
 273 # Custom target for generated vulkan helper file dependencies
 274 add_custom_target(generate_helper_files DEPENDS
 275     vk_dispatch_table_helper.h
 276     vk_enum_string_helper.h
 277     vk_struct_size_helper.h
 278     vk_struct_size_helper.c
 279     vk_safe_struct.h
 280     vk_safe_struct.cpp
 281     )
 282
 283 # Rules to build generated helper files
 284 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.h)
 285 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.cpp)
 286 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.h)
 287 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.c)
 288 run_vk_xml_generate(helper_file_generator.py vk_enum_string_helper.h)
 289 run_vk_xml_generate(dispatch_table_generator.py vk_dispatch_table_helper.h)
 290
 291 if(NOT WIN32)
 292     include(GNUInstallDirs)
 293
 294     add_definitions(-DFALLBACK_CONFIG_DIRS="${FALLBACK_CONFIG_DIRS}")
 295     add_definitions(-DFALLBACK_DATA_DIRS="${FALLBACK_DATA_DIRS}")
 296     add_definitions(-DSYSCONFDIR="${CMAKE_INSTALL_FULL_SYSCONFDIR}")
 297
 298     # Make sure /etc is searched by the loader
 299     if(NOT (CMAKE_INSTALL_FULL_SYSCONFDIR STREQUAL "/etc"))
 300         add_definitions(-DEXTRASYSCONFDIR="/etc")
 301     endif()
 302 endif()
 303
 304 if(UNIX)
 305     install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 306 endif()
 307
 308 # loader: Generic VULKAN ICD loader
 309 # tests: VULKAN tests
 310 if(BUILD_LOADER)
 311     add_subdirectory(loader)
 312 endif()
 313
 314 if(BUILD_TESTS)
 315     add_subdirectory(tests)
 316 endif()
 317
 318 if(BUILD_LAYERS)
 319     add_subdirectory(layers)
 320 endif()
 321
 322 if(BUILD_DEMOS)
 323     add_subdirectory(demos)
 324 endif()
 325
 326 if(BUILD_VKJSON)
 327     add_subdirectory(libs/vkjson)
 328 endif()