CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # --------------------------------------------------------------
  15 # Indicate CMake 2.7 and above that we don't want to mix relative
  16 #  and absolute paths in linker lib lists.
  17 # Run "cmake --help-policy CMP0003" for more information.
  18 # --------------------------------------------------------------
  19 if(COMMAND cmake_policy)
  20   cmake_policy(SET CMP0003 NEW)
  21 endif()
  22
  23 # Following block can broke build in case of cross-compilng
  24 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  25 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  26 if(NOT CMAKE_TOOLCHAIN_FILE)
  27   # it _must_ go before project(OpenCV) in order to work
  28   if(WIN32)
  29     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  30   else()
  31     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  32   endif()
  33
  34   if(MSVC)
  35     set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  36   endif()
  37 else(NOT CMAKE_TOOLCHAIN_FILE)
  38   #Android: set output folder to ${CMAKE_BINARY_DIR}
  39   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  40 endif(NOT CMAKE_TOOLCHAIN_FILE)
  41
  42 # --------------------------------------------------------------
  43 # Top level OpenCV project
  44 # --------------------------------------------------------------
  45 if(NOT IOS)
  46   cmake_minimum_required(VERSION 2.6.3)
  47 else()
  48   cmake_minimum_required(VERSION 2.8)
  49 endif()
  50
  51 project(OpenCV)
  52
  53 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  54 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  55   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  56 endif()
  57
  58 set(CMAKE_C_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  59 set(CMAKE_C_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  60 set(CMAKE_CXX_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  61 set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  62 set(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  63 set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  64 set(CMAKE_MODULE_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  65 set(CMAKE_MODULE_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  66 set(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  67 set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  68
  69 include(cmake/OpenCVUtils.cmake REQUIRED)
  70
  71 # ----------------------------------------------------------------------------
  72 # Detect compiler and target platform architecture
  73 # ----------------------------------------------------------------------------
  74 include(cmake/OpenCVDetectCXXCompiler.cmake REQUIRED)
  75
  76 # Add these standard paths to the search paths for FIND_LIBRARY
  77 # to find libraries from these locations first
  78 if(UNIX AND NOT ANDROID)
  79   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  80     if(EXISTS /lib64)
  81       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  82     else()
  83       list(APPEND CMAKE_LIBRARY_PATH /lib)
  84     endif()
  85     if(EXISTS /usr/lib64)
  86       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  87     else()
  88       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  89     endif()
  90   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  91     if(EXISTS /lib32)
  92       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  93     else()
  94       list(APPEND CMAKE_LIBRARY_PATH /lib)
  95     endif()
  96     if(EXISTS /usr/lib32)
  97       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
  98     else()
  99       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 100     endif()
 101   endif()
 102 endif()
 103
 104
 105 # ----------------------------------------------------------------------------
 106 # OpenCV cmake options
 107 # ----------------------------------------------------------------------------
 108
 109 # Optional 3rd party components
 110 # ===================================================
 111 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 112 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 113 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 114 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 115 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 116 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 117 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 118 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 119 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 120 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 121 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 122 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 123 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON   IF (NOT IOS) )
 124 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 125 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 126 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 127 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON   IF (NOT IOS) )
 128 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 129 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 130 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 131 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 132 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 133 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 134 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 135 OCV_OPTION(WITH_VIDEOINPUT     "Build HighGUI with DirectShow support"       ON   IF WIN32 )
 136 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF WIN32 )
 137 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 138
 139 # OpenCV build components
 140 # ===================================================
 141 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 142 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 143 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 144 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 145 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 146 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 147 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 148 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 149 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 150 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF ANDROID AND NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 151
 152 # 3rd party libs
 153 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"         WIN32 OR IOS )
 154 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"      WIN32 OR IOS OR ANDROID )
 155 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"    WIN32 OR IOS OR ANDROID )
 156 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"      WIN32 OR IOS OR ANDROID )
 157 OCV_OPTION(BUILD_PNG                "Build libpng from source"       WIN32 OR IOS OR ANDROID )
 158
 159 # OpenCV installation options
 160 # ===================================================
 161 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 162 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 163 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF  IF ANDROID )
 164 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 165
 166 # OpenCV build options
 167 # ===================================================
 168 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 169 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        MSVC_IDE IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 170 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 171 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX )
 172 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 173 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 174 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF (MSVC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 175 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF (MSVC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 176 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 OFF  IF (CV_ICC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 177 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 178 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF (CV_ICC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 179 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 180 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 181
 182 # uncategorized options
 183 # ===================================================
 184 OCV_OPTION(CMAKE_VERBOSE "Verbose mode" OFF )
 185
 186 # backward compatibility
 187 # ===================================================
 188 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 189
 190
 191 # ----------------------------------------------------------------------------
 192 #  Get actual OpenCV version number from sources
 193 # ----------------------------------------------------------------------------
 194 include(cmake/OpenCVVersion.cmake REQUIRED)
 195
 196
 197 # ----------------------------------------------------------------------------
 198 #  Build & install layouts
 199 # ----------------------------------------------------------------------------
 200
 201 # Save libs and executables in the same place
 202 set(LIBRARY_OUTPUT_PATH "${CMAKE_BINARY_DIR}/lib" CACHE PATH "Output directory for libraries" )
 203 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 204
 205 if(ANDROID OR WIN32)
 206     set(OPENCV_DOC_INSTALL_PATH doc)
 207 elseif(INSTALL_TO_MANGLED_PATHS)
 208     set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 209 else()
 210     set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 211 endif()
 212
 213 if(ANDROID)
 214     set(OPENCV_LIB_INSTALL_PATH libs/${ANDROID_NDK_ABI_NAME})
 215 else()
 216     set(OPENCV_LIB_INSTALL_PATH lib${LIB_SUFFIX})
 217 endif()
 218
 219 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 220 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 221
 222 set(OPENCV_INCLUDE_PREFIX include)
 223 if(INSTALL_TO_MANGLED_PATHS)
 224   set(OPENCV_INCLUDE_PREFIX include/opencv-${OPENCV_VERSION})
 225 endif()
 226
 227 if(WIN32)
 228   # Postfix of DLLs:
 229   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 230   set(OPENCV_DEBUG_POSTFIX d)
 231 else()
 232   # Postfix of so's:
 233   set(OPENCV_DLLVERSION "")
 234   set(OPENCV_DEBUG_POSTFIX "")
 235 endif()
 236
 237 if(DEFINED CMAKE_DEBUG_POSTFIX)
 238   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 239 endif()
 240
 241 if(CMAKE_VERBOSE)
 242   set(CMAKE_VERBOSE_MAKEFILE 1)
 243 endif()
 244
 245
 246 # ----------------------------------------------------------------------------
 247 #  Path for build/platform -specific headers
 248 # ----------------------------------------------------------------------------
 249 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 250 add_definitions(-DHAVE_CVCONFIG_H)
 251 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 252
 253
 254 # ----------------------------------------------------------------------------
 255 # Use statically or dynamically linked CRT?
 256 # Default: dynamic
 257 # ----------------------------------------------------------------------------
 258 if(MSVC)
 259   include(cmake/OpenCVCRTLinkage.cmake REQUIRED)
 260 endif(MSVC)
 261
 262
 263 # ----------------------------------------------------------------------------
 264 #  Autodetect if we are in a SVN repository
 265 # ----------------------------------------------------------------------------
 266 find_host_program(SVNVERSION_PATH svnversion)
 267 mark_as_advanced(force SVNVERSION_PATH)
 268 if(SVNVERSION_PATH)
 269     message(STATUS "Extracting svn version, please wait...")
 270     execute_process(COMMAND ${SVNVERSION_PATH} -n ${OpenCV_SOURCE_DIR} OUTPUT_VARIABLE SVNVERSION_RESULT)
 271
 272     if(SVNVERSION_RESULT MATCHES "exported")
 273         # This is NOT a svn repository:
 274         set(OPENCV_SVNVERSION "")
 275         message(STATUS "SVNVERSION: exported")
 276     else()
 277         set(OPENCV_SVNVERSION " svn:${SVNVERSION_RESULT}")
 278         message(STATUS "SVNVERSION: ${OPENCV_SVNVERSION}")
 279     endif()
 280 else()
 281     # We don't have svnversion:
 282     set(OPENCV_SVNVERSION "")
 283 endif()
 284
 285
 286 # ----------------------------------------------------------------------------
 287 # OpenCV compiler and linker options
 288 # ----------------------------------------------------------------------------
 289 include(cmake/OpenCVCompilerOptions.cmake REQUIRED)
 290
 291 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 292 if(CMAKE_GENERATOR MATCHES "Makefiles" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 293   set(CMAKE_BUILD_TYPE Release)
 294 endif()
 295
 296
 297 # ----------------------------------------------------------------------------
 298 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 299 # ----------------------------------------------------------------------------
 300 if(UNIX)
 301   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 302   include(CheckFunctionExists)
 303   include(CheckIncludeFile)
 304 endif()
 305
 306 include(cmake/OpenCVPCHSupport.cmake REQUIRED)
 307 include(cmake/OpenCVModule.cmake REQUIRED)
 308
 309 if(ANDROID)
 310   include(cmake/OpenCVAndroidProject.cmake REQUIRED)
 311 endif()
 312
 313
 314 # ----------------------------------------------------------------------------
 315 #  Detect 3rd-party tools and libraries
 316 # ----------------------------------------------------------------------------
 317
 318 # IO libraries
 319 include(cmake/OpenCVIOLibs.cmake REQUIRED)
 320
 321 #Graphic libraries
 322 set(HAVE_OPENGL 0)
 323 if(UNIX)
 324     if(NOT APPLE)
 325       if(WITH_GTK)
 326         CHECK_MODULE(gtk+-2.0 HAVE_GTK)
 327         CHECK_MODULE(gthread-2.0 HAVE_GTHREAD)
 328         if(WITH_OPENGL)
 329             CHECK_MODULE(gtkglext-1.0 HAVE_GTKGLEXT)
 330             if(HAVE_GTKGLEXT)
 331                 find_package(OpenGL QUIET)
 332                 if(OPENGL_FOUND)
 333                     set(HAVE_OPENGL 1)
 334                     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${OPENGL_LIBRARIES})
 335                     ocv_include_directories(${OPENGL_INCLUDE_DIR})
 336                 endif()
 337             endif()
 338         endif()
 339       else()
 340         set(HAVE_GTK FALSE)
 341         set(HAVE_GTHREAD FALSE)
 342       endif()
 343       if(WITH_GSTREAMER)
 344         CHECK_MODULE(gstreamer-base-0.10 HAVE_GSTREAMER)
 345         CHECK_MODULE(gstreamer-app-0.10 HAVE_GSTREAMER)
 346         CHECK_MODULE(gstreamer-video-0.10 HAVE_GSTREAMER)
 347       else()
 348         set(HAVE_GSTREAMER FALSE)
 349       endif()
 350     endif()
 351
 352     if(WITH_UNICAP)
 353       CHECK_MODULE(libunicap HAVE_UNICAP_)
 354       CHECK_MODULE(libucil HAVE_UNICAP_UCIL)
 355       if(HAVE_UNICAP_ AND HAVE_UNICAP_UCIL)
 356         set(HAVE_UNICAP 1)
 357       endif()
 358     else()
 359       set(HAVE_UNICAP FALSE)
 360     endif()
 361
 362     if(WITH_PVAPI)
 363       find_path(PVAPI_INCLUDE_PATH "PvApi.h"
 364                 PATHS "/usr/local/include" "/usr/include"
 365                 DOC "The path to PvAPI header")
 366       if(PVAPI_INCLUDE_PATH)
 367         set(HAVE_PVAPI 1)
 368       endif()
 369     endif()
 370
 371     set(HAVE_FFMPEG 0)
 372     if(WITH_FFMPEG)
 373       CHECK_MODULE(libavcodec HAVE_FFMPEG_CODEC)
 374       CHECK_MODULE(libavformat HAVE_FFMPEG_FORMAT)
 375       CHECK_MODULE(libavutil HAVE_FFMPEG_UTIL)
 376       CHECK_MODULE(libswscale HAVE_FFMPEG_SWSCALE)
 377       CHECK_INCLUDE_FILE(libavformat/avformat.h HAVE_GENTOO_FFMPEG)
 378       CHECK_INCLUDE_FILE(ffmpeg/avformat.h HAVE_FFMPEG_FFMPEG)
 379       if(NOT HAVE_GENTOO_FFMPEG AND NOT HAVE_FFMPEG_FFMPEG)
 380         if(EXISTS /usr/include/ffmpeg/libavformat/avformat.h OR HAVE_FFMPEG_SWSCALE)
 381           set(HAVE_GENTOO_FFMPEG 1)
 382         endif()
 383       endif()
 384       if(HAVE_FFMPEG_CODEC AND HAVE_FFMPEG_FORMAT AND HAVE_FFMPEG_UTIL)
 385         if(HAVE_FFMPEG_SWSCALE OR NOT HAVE_GENTOO_FFMPEG)
 386             set(HAVE_FFMPEG 1)
 387         endif()
 388       endif()
 389
 390       # Find the bzip2 library because it is required on some systems
 391       FIND_LIBRARY(BZIP2_LIBRARIES NAMES bz2 bzip2)
 392       if(NOT BZIP2_LIBRARIES)
 393         # Do an other trial
 394         FIND_FILE(BZIP2_LIBRARIES NAMES libbz2.so.1 PATHS /lib)
 395       endif()
 396     endif()
 397
 398     if(HAVE_FFMPEG)
 399     CHECK_MODULE(libavformat>=52.111.0 NEW_FFMPEG)
 400     endif()
 401
 402     if(WITH_1394)
 403       CHECK_MODULE(libdc1394-2 HAVE_DC1394_2)
 404       if(NOT HAVE_DC1394_2)
 405         CHECK_MODULE(libdc1394 HAVE_DC1394)
 406       endif()
 407     else()
 408       set(HAVE_DC1394_2 FALSE)
 409       set(HAVE_DC1394 FALSE)
 410     endif()
 411
 412     if(NOT APPLE)
 413         CHECK_INCLUDE_FILE(alloca.h HAVE_ALLOCA_H)
 414         CHECK_FUNCTION_EXISTS(alloca HAVE_ALLOCA)
 415         CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 416         CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 417
 418         if(WITH_XINE)
 419             CHECK_MODULE(libxine HAVE_XINE)
 420         else()
 421             set(HAVE_XINE FALSE)
 422         endif()
 423         if(WITH_V4L)
 424             CHECK_MODULE(libv4l1 HAVE_LIBV4L)
 425             CHECK_INCLUDE_FILE(linux/videodev.h HAVE_CAMV4L)
 426             CHECK_INCLUDE_FILE(linux/videodev2.h HAVE_CAMV4L2)
 427         else()
 428             set(HAVE_LIBV4L FALSE)
 429             set(HAVE_CAMV4L FALSE)
 430             set(HAVE_CAMV4L2 FALSE)
 431         endif()
 432
 433         if(ANDROID)
 434             set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 435         elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD" OR ${CMAKE_SYSTEM_NAME} MATCHES "NetBSD")
 436             set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 437         else()
 438             set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 439         endif()
 440     else()
 441         add_definitions(-DHAVE_ALLOCA -DHAVE_ALLOCA_H -DHAVE_LIBPTHREAD -DHAVE_UNISTD_H)
 442     endif()
 443 endif()
 444
 445 #################### LATEX for dpf documentation ##################
 446 if(BUILD_DOCS)
 447   include(cmake/OpenCVFindLATEX.cmake REQUIRED)
 448 endif()
 449
 450 ########################## Python Support #########################
 451 include(cmake/OpenCVDetectPython.cmake REQUIRED)
 452
 453 ########################### Java Support ##########################
 454 # current implementation of Java wrappers generator requires python at build time
 455 if((NOT DEFINED BUILD_opencv_java OR BUILD_opencv_java) AND PYTHON_EXECUTABLE)
 456   if(ANDROID)
 457     include(cmake/OpenCVDetectAndroidSDK.cmake REQUIRED)
 458     if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 459       message(WARNING "OpenCV requires Android SDK tool revision 14 or newer. Otherwise tests and samples will no be compiled.")
 460     endif()
 461   endif()
 462   include(cmake/OpenCVDetectApacheAnt.cmake REQUIRED)
 463
 464   if(ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_SDK_TARGET_LEVEL GREATER 7))
 465     SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 466   else()
 467     SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 468   endif()
 469 endif()
 470
 471 if(BUILD_ANDROID_EXAMPLES AND NOT CAN_BUILD_ANDROID_PROJECTS)
 472   if(HAVE_opencv_java)
 473     message(WARNING "Android examples are chosen for build, but required SDK tools are not found.")
 474   endif()
 475   unset(BUILD_ANDROID_EXAMPLES CACHE)
 476 endif()
 477
 478 ############################### QT ################################
 479 set(HAVE_QT 0)
 480 set(HAVE_QT_OPENGL 0)
 481
 482 if(WITH_QT)
 483   find_package(Qt4)
 484   if(QT4_FOUND)
 485     set(HAVE_QT 1)
 486     add_definitions(-DHAVE_QT) #We need to define te macro this way, using cvconfig.h.cmake does not work
 487
 488     if(WITH_OPENGL)
 489       find_package (OpenGL QUIET)
 490       if(QT_QTOPENGL_FOUND AND OPENGL_FOUND)
 491         set(HAVE_OPENGL 1)
 492         set(HAVE_QT_OPENGL 1)
 493         add_definitions(-DHAVE_QT_OPENGL)
 494         set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${OPENGL_LIBRARIES})
 495       endif()
 496     endif()
 497   endif()
 498 endif()
 499
 500 ############################### TBB ################################
 501 if(WITH_TBB)
 502   include(cmake/OpenCVDetectTBB.cmake REQUIRED)
 503 endif()
 504
 505 ############################ Intel IPP #############################
 506 set(IPP_FOUND)
 507
 508 if(WITH_IPP)
 509   include(cmake/OpenCVFindIPP.cmake)
 510 endif()
 511
 512 if(IPP_FOUND)
 513   add_definitions(-DHAVE_IPP)
 514   ocv_include_directories(${IPP_INCLUDE_DIRS})
 515   link_directories(${IPP_LIBRARY_DIRS})
 516   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${IPP_LIBRARIES})
 517 endif()
 518
 519 ############################### CUDA ################################
 520 if(WITH_CUDA)
 521   include(cmake/OpenCVDetectCUDA.cmake REQUIRED)
 522 endif()
 523
 524 ############################### OpenNI ################################
 525 set(HAVE_OPENNI FALSE)
 526 set(HAVE_OPENNI_PRIME_SENSOR_MODULE FALSE)
 527
 528 if(WITH_OPENNI)
 529   include(cmake/OpenCVFindOpenNI.cmake)
 530 endif()
 531
 532 ############################### XIMEA ################################
 533 set(HAVE_XIMEA FALSE)
 534
 535 if(WITH_XIMEA)
 536   include(cmake/OpenCVFindXimea.cmake)
 537 endif()
 538
 539 if(XIMEA_FOUND)
 540   set(HAVE_XIMEA TRUE)
 541 endif()
 542
 543 ############################## Eigen ##############################
 544 if(WITH_EIGEN)
 545   find_path(EIGEN_INCLUDE_PATH "Eigen/Core"
 546             PATHS "/usr/local/include/eigen2" "/opt/include/eigen2" "/usr/include/eigen2"
 547                   "/usr/local/include/eigen3" "/opt/include/eigen3" "/usr/include/eigen3"
 548             DOC "The path to Eigen2/Eigen3 headers")
 549   if(EIGEN_INCLUDE_PATH)
 550     ocv_include_directories(${EIGEN_INCLUDE_PATH})
 551     set(HAVE_EIGEN 1)
 552   endif()
 553 endif()
 554
 555 ################## Extra HighGUI libs on Windows ###################
 556 if(WIN32)
 557   set(HIGHGUI_LIBRARIES ${HIGHGUI_LIBRARIES} comctl32 gdi32 ole32)
 558
 559   if(WITH_VIDEOINPUT)
 560     set(HAVE_VIDEOINPUT 1)
 561   endif()
 562
 563   if(MSVC)
 564     set(HIGHGUI_LIBRARIES ${HIGHGUI_LIBRARIES} vfw32)
 565   endif()
 566
 567   if(MINGW)
 568     if(MINGW64)
 569       set(HIGHGUI_LIBRARIES ${HIGHGUI_LIBRARIES} msvfw32 avifil32 avicap32 winmm)
 570     else()
 571       set(HIGHGUI_LIBRARIES ${HIGHGUI_LIBRARIES} vfw32 winmm)
 572     endif()
 573   endif()
 574
 575   if(WITH_OPENGL AND NOT HAVE_QT_OPENGL)
 576     find_package(OpenGL QUIET)
 577
 578     if(OPENGL_FOUND)
 579       set(HAVE_OPENGL 1)
 580       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${OPENGL_LIBRARIES})
 581       ocv_include_directories(${OPENGL_INCLUDE_DIR})
 582     endif()
 583   endif()
 584 endif()
 585
 586
 587 # ----------------------------------------------------------------------------
 588 # Solution folders:
 589 # ----------------------------------------------------------------------------
 590 if(ENABLE_SOLUTION_FOLDERS)
 591   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 592   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 593 endif()
 594
 595 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 596 include(cmake/OpenCVExtraTargets.cmake REQUIRED)
 597
 598
 599 # ----------------------------------------------------------------------------
 600 # Process subdirectories
 601 # ----------------------------------------------------------------------------
 602
 603 # opencv.hpp and legacy headers
 604 add_subdirectory(include)
 605
 606 # OpenCV modules
 607 add_subdirectory(modules)
 608
 609 # Generate targets for documentation
 610 add_subdirectory(doc)
 611
 612 # various data that is used by cv libraries and/or demo applications.
 613 add_subdirectory(data)
 614
 615 # extra applications
 616 add_subdirectory(apps)
 617
 618 # examples
 619 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 620   add_subdirectory(samples)
 621 endif()
 622
 623
 624 # ----------------------------------------------------------------------------
 625 # Finalization: generate configuration-based files
 626 # ----------------------------------------------------------------------------
 627 ocv_track_build_dependencies()
 628
 629 # Generate platform-dependent and configuration-dependent headers
 630 include(cmake/OpenCVGenHeaders.cmake REQUIRED)
 631
 632 # Generate opencv.pc for pkg-config command
 633 include(cmake/OpenCVGenPkgconfig.cmake REQUIRED)
 634
 635 # Generate OpenCV.mk for ndk-build (Android build tool)
 636 include(cmake/OpenCVGenAndroidMK.cmake REQUIRED)
 637
 638 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 639 include(cmake/OpenCVGenConfig.cmake REQUIRED)
 640
 641
 642 # ----------------------------------------------------------------------------
 643 # Summary:
 644 # ----------------------------------------------------------------------------
 645 status("")
 646 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 647
 648 #build platform
 649 status("")
 650 status("  Platform:")
 651 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 652 status("    Target:"           ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 653 status("    CMake:"            ${CMAKE_VERSION})
 654 status("    CMake generator:"  ${CMAKE_GENERATOR})
 655 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 656 if(MSVC)
 657   status("    MSVC:"           ${MSVC_VERSION})
 658 endif()
 659 if(CMAKE_GENERATOR MATCHES Xcode)
 660   status("    Xcode:"          ${XCODE_VERSION})
 661 endif()
 662
 663 # C/C++ options
 664 status("")
 665 status("  C++:")
 666 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 667 status("    C++ Compiler:"           CMAKE_COMPILER    THEN "${CMAKE_COMPILER}" ELSE "${CMAKE_CXX_COMPILER}")
 668 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 669 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 670 if(WIN32)
 671   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 672   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 673 else()
 674   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 675   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 676 endif()
 677
 678 # OpenCV modules
 679 status("")
 680 status("  OpenCV modules:")
 681 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 682 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 683 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 684 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 685 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 686   set(__mdeps "")
 687   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 688     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 689       list(APPEND __mdeps ${d})
 690     endif()
 691   endforeach()
 692   list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 693 endforeach()
 694 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 695
 696 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 697 status("    Disabled by user:"       OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 698 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 699 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 700
 701 # Android extra
 702 if(ANDROID)
 703   status("")
 704   status("  Android: ")
 705   status("    Android ABI:" ${ANDROID_ABI})
 706   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 707   status("    SDK target:" "${ANDROID_SDK_TARGET}")
 708   if(BUILD_WITH_ANDROID_NDK)
 709     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 710   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 711     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 712   endif()
 713   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 714   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"            ELSE NO)
 715 endif()
 716
 717 #YV
 718 status("")
 719 status("  GUI: ")
 720
 721 if (HAVE_QT)
 722   status("    QT 4.x:"            HAVE_QT        THEN YES ELSE NO)
 723   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN YES ELSE NO)
 724 else()
 725   if(WIN32)
 726     status("    Win32 UI:" YES)
 727   else()
 728     if(APPLE)
 729       if(WITH_CARBON)
 730         status("    Carbon:" YES)
 731       else()
 732         status("    Cocoa:"  YES)
 733       endif()
 734     else()
 735       status("    GTK+ 2.x:" HAVE_GTK      THEN YES ELSE NO)
 736       status("    GThread :" HAVE_GTHREAD  THEN YES ELSE NO)
 737       status("    GtkGlExt:" HAVE_GTKGLEXT THEN YES ELSE NO)
 738     endif()
 739   endif()
 740 endif()
 741
 742 status("    OpenGL support:" HAVE_OPENGL THEN YES ELSE NO)
 743
 744 # media
 745 status("")
 746 status("  Media I/O: ")
 747 status("    ZLib:"         ZLIB_FOUND    THEN "${ZLIB_LIBRARY}"    ELSE build)
 748
 749 if(WITH_JPEG)
 750   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY}"    ELSE build)
 751 else()
 752   status("    JPEG:"       "NO")
 753 endif()
 754 if(WITH_PNG)
 755   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY}"     ELSE build)
 756 else()
 757   status("    PNG:"        "NO")
 758 endif()
 759 if(WITH_TIFF)
 760   status("    TIFF:"       TIFF_FOUND    THEN "${TIFF_LIBRARY}"    ELSE build)
 761 else()
 762   status("    TIFF:"       "NO")
 763 endif()
 764 if(WITH_JASPER)
 765   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY}"  ELSE build)
 766 else()
 767   status("    JPEG 2000:"  "NO")
 768 endif()
 769
 770 status("    OpenEXR:"   WITH_OPENEXR AND OPENEXR_FOUND     THEN YES             ELSE NO)
 771 status("    OpenNI:"    HAVE_OPENNI                        THEN YES             ELSE NO)
 772 status("    OpenNI PrimeSensor Modules:"
 773                         HAVE_OPENNI_PRIME_SENSOR_MODULE    THEN YES             ELSE NO)
 774 if(WIN32)
 775   status("    XIMEA:"     HAVE_XIMEA  THEN YES ELSE NO)
 776 endif()
 777
 778 # video
 779 status("")
 780 if(UNIX AND NOT APPLE)
 781   status("  Video I/O:")
 782   status("    DC1394 1.x:"     HAVE_DC1394         THEN YES ELSE NO)
 783   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN YES ELSE NO)
 784   status("    FFMPEG:"         HAVE_FFMPEG         THEN YES ELSE NO)
 785   status("      codec:"        HAVE_FFMPEG_CODEC   THEN YES ELSE NO)
 786   status("      format:"       HAVE_FFMPEG_FORMAT  THEN YES ELSE NO)
 787   status("      util:"         HAVE_FFMPEG_UTIL    THEN YES ELSE NO)
 788   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN YES ELSE NO)
 789   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES ELSE NO)
 790   status("    GStreamer:"      HAVE_GSTREAMER      THEN YES ELSE NO)
 791   status("    UniCap:"         HAVE_UNICAP         THEN YES ELSE NO)
 792   status("    PvAPI:"          HAVE_PVAPI          THEN YES ELSE NO)
 793   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l" ELSE ${HAVE_CAMV4L}/${HAVE_CAMV4L2})
 794   status("    Xine:"           HAVE_XINE           THEN YES ELSE NO)
 795
 796   if(ANDROID)
 797     if(HAVE_opencv_androidcamera)
 798       status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER THEN "YES, build for Android ${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 799     else()
 800       status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 801     endif()
 802   endif()
 803 elseif(APPLE)
 804   if(NOT IOS)
 805     status("  Video I/O:"    WITH_QUICKTIME      THEN QuickTime ELSE QTKit)
 806   else()
 807     status("  Video I/O: AVFoundation")
 808   endif()
 809 elseif(WIN32)
 810   status("  Video I/O:"        HAVE_VIDEOINPUT     THEN DirectShow ELSE NO)
 811 endif()
 812
 813 # Other third-party libraries
 814 status("")
 815 status("  Other third-party libraries:")
 816
 817 if(WITH_IPP AND IPP_FOUND)
 818   status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 819   status("         at:" "${IPP_ROOT_DIR}")
 820 else()
 821   status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 822 endif()
 823
 824 status("    Use TBB:"   HAVE_TBB   THEN YES ELSE NO)
 825 status("    Use Cuda:"  HAVE_CUDA  THEN YES ELSE NO)
 826 status("    Use Eigen:" HAVE_EIGEN THEN YES ELSE NO)
 827
 828 status("")
 829 status("  Python interpreter:"  PYTHON_EXECUTABLE        THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_MAJOR_MINOR})" ELSE NO)
 830 # interfaces to other languages
 831 status("")
 832 status("  Interfaces:")
 833 status("    Python:"              HAVE_opencv_python THEN YES ELSE NO)
 834 status("    Python numpy:"        PYTHON_USE_NUMPY THEN YES ELSE "NO (Python wrappers can not be generated)")
 835 if(ANDROID)
 836   status("    Java:" HAVE_opencv_java THEN YES ELSE NO)
 837 endif()
 838
 839 # documentation
 840 status("")
 841 status("  Documentation:")
 842 status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 843 status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 844 if(BUILD_DOCS AND HAVE_SPHINX)
 845   status("    Build Documentation:" PDFLATEX_COMPILER    THEN YES ELSE "YES (only HTML without math expressions)")
 846 else()
 847   status("    Build Documentation:" NO)
 848 endif()
 849
 850 # samples and tests
 851 status("")
 852 status("  Tests and samples:")
 853 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 854 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 855 status("    Examples:"          BUILD_EXAMPLES                       THEN YES ELSE NO)
 856
 857 if(ANDROID)
 858   status("    Android tests:"    BUILD_TESTS AND CAN_BUILD_ANDROID_PROJECTS THEN YES ELSE NO)
 859   status("    Android examples:" BUILD_ANDROID_EXAMPLES                     THEN YES ELSE NO)
 860 endif()
 861
 862 #auxiliary
 863 status("")
 864 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 865 status("")
 866 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 867 status("-----------------------------------------------------------------")
 868 status("")
 869
 870 # ----------------------------------------------------------------------------
 871 # Warn in the case of in-source build
 872 # ----------------------------------------------------------------------------
 873 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 874   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 875 endif()
 876