CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.11)
   2
   3 # This must come before the project command.
   4 set(CMAKE_OSX_DEPLOYMENT_TARGET "10.12" CACHE STRING "Minimum OS X deployment version")
   5
   6 project(Vulkan-Tools)
   7
   8 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
   9
  10 option(BUILD_CUBE "Build cube" ON)
  11 option(BUILD_VULKANINFO "Build vulkaninfo" ON)
  12 option(BUILD_ICD "Build icd" ON)
  13 # Installing the Mock ICD to system directories is probably not desired since
  14 # this ICD is not a very complete implementation.
  15 # Require the user to ask that it be installed if they really want it.
  16 option(INSTALL_ICD "Install icd" OFF)
  17
  18 # Enable IDE GUI folders
  19 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  20 # "Helper" targets that don't have interesting source code should set their FOLDER property to this
  21 set(TOOLS_TARGET_FOLDER "Helper Targets")
  22
  23 # Find Vulkan Headers and Loader
  24 # Search order:
  25 #  User-supplied CMAKE_PREFIX_PATH containing paths to the header and/or loader install dirs
  26 #  CMake options VULKAN_HEADERS_INSTALL_DIR and/or VULKAN_LOADER_INSTALL_DIR
  27 #  Env vars VULKAN_HEADERS_INSTALL_DIR and/or VULKAN_LOADER_INSTALL_DIR
  28 #  Fallback to FindVulkan operation using SDK install or system installed components.
  29 set(VULKAN_HEADERS_INSTALL_DIR "HEADERS-NOTFOUND" CACHE PATH "Absolute path to a Vulkan-Headers install directory")
  30 set(VULKAN_LOADER_INSTALL_DIR "LOADER-NOTFOUND" CACHE PATH "Absolute path to a Vulkan-Loader install directory")
  31 set(CMAKE_PREFIX_PATH ${CMAKE_PREFIX_PATH};${VULKAN_HEADERS_INSTALL_DIR};${VULKAN_LOADER_INSTALL_DIR};
  32                        $ENV{VULKAN_HEADERS_INSTALL_DIR};$ENV{VULKAN_LOADER_INSTALL_DIR})
  33 message(STATUS "Using find_package to locate Vulkan")
  34 find_package(Vulkan)
  35 find_package(VulkanHeaders)
  36 # "Vulkan::Vulkan" on macOS causes the framework to be linked to the app instead of an individual library
  37 set(LIBVK "Vulkan::Vulkan")
  38 message(STATUS "Vulkan FOUND = ${Vulkan_FOUND}")
  39 message(STATUS "Vulkan Lib = ${Vulkan_LIBRARY}")
  40 message(STATUS "Vulkan Headers Include = ${VulkanHeaders_INCLUDE_DIR}")
  41 message(STATUS "Vulkan Headers Registry = ${VulkanRegistry_DIR}")
  42
  43 # Install-related settings
  44 include(GNUInstallDirs)
  45 # Set a better default install location for Windows only if the user did not provide one.
  46 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND WIN32)
  47     set (CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "default install path" FORCE )
  48 endif()
  49
  50 # uninstall target
  51 if (NOT TARGET uninstall)
  52     configure_file(
  53         "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
  54         "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
  55         IMMEDIATE @ONLY)
  56
  57     add_custom_target(uninstall
  58         COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
  59     set_target_properties(uninstall PROPERTIES FOLDER ${TOOLS_TARGET_FOLDER})
  60 endif()
  61
  62 if(APPLE)
  63     # CMake versions 3 or later need CMAKE_MACOSX_RPATH defined.
  64     # This avoids the CMP0042 policy message.
  65     set(CMAKE_MACOSX_RPATH 1)
  66     # The "install" target for MacOS fixes up bundles in place.
  67     set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR})
  68 endif()
  69
  70 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  71     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  72     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  73
  74     # For GCC version 7.1 or greater, we need to disable the implicit fallthrough warning since
  75     # there's no consistent way to satisfy all compilers until they all accept the C++17 standard
  76     if (CMAKE_COMPILER_IS_GNUCC AND NOT (CMAKE_CXX_COMPILER_VERSION LESS 7.1))
  77         set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -Wimplicit-fallthrough=0")
  78     endif()
  79
  80     if (APPLE)
  81         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${COMMON_COMPILE_FLAGS}")
  82     else()
  83         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
  84     endif()
  85     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
  86     if (UNIX)
  87         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
  88         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
  89     endif()
  90 endif()
  91
  92 if(APPLE)
  93     include(mac_common.cmake)
  94 endif()
  95 if(BUILD_CUBE)
  96     add_subdirectory(cube)
  97 endif()
  98 if(BUILD_VULKANINFO)
  99     add_subdirectory(vulkaninfo)
 100 endif()
 101 if(BUILD_ICD)
 102     add_subdirectory(icd)
 103 endif()